sysdeps/sparc/sparc64/fpu/s_ceil.S

   1 /* ceil function, sparc64 version.
   2    Copyright (C) 2012-2013 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2012.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22         /* Since changing the rounding mode is extremely expensive, we
  23            try to round up using a method that is rounding mode
  24            agnostic.
  25
  26            We add then subtract (or subtract than add if the initial
  27            value was negative) 2**23 to the value, then subtract it
  28            back out.
  29
  30            This will clear out the fractional portion of the value.
  31            One of two things will happen for non-whole initial values.
  32            Either the rounding mode will round it up, or it will be
  33            rounded down.  If the value started out whole, it will be
  34            equal after the addition and subtraction.  This means we
  35            can accurately detect with one test whether we need to add
  36            another 1.0 to round it up properly.
  37
  38            We pop constants into the FPU registers using the incoming
  39            argument stack slots, since this avoid having to use any
  40            PIC references.  We also thus avoid having to allocate a
  41            register window.
  42
  43            VIS instructions are used to facilitate the formation of
  44            easier constants, and the propagation of the sign bit.  */
  45
  46 #define TWO_FIFTYTWO    0x43300000              /* 2**52 */
  47 #define ONE_DOT_ZERO    0x3ff00000              /* 1.0 */
  48
  49 #define ZERO            %f10                    /* 0.0 */
  50 #define SIGN_BIT        %f12                    /* -0.0 */
  51
  52 ENTRY (__ceil)
  53         sethi   %hi(TWO_FIFTYTWO), %o2
  54         sethi   %hi(ONE_DOT_ZERO), %o3
  55         fzero   ZERO
  56
  57         sllx    %o2, 32, %o2
  58         fnegd   ZERO, SIGN_BIT
  59
  60         sllx    %o3, 32, %o3
  61         stx     %o2, [%sp + STACK_BIAS + 128]
  62         fabsd   %f0, %f14
  63
  64         ldd     [%sp + STACK_BIAS + 128], %f16
  65         fcmpd   %fcc3, %f14, %f16
  66
  67         fmovduge %fcc3, ZERO, %f16
  68         fand    %f0, SIGN_BIT, SIGN_BIT
  69
  70         for     %f16, SIGN_BIT, %f16
  71         faddd   %f0, %f16, %f18
  72         fsubd   %f18, %f16, %f18
  73         fcmpd   %fcc2, %f18, %f0
  74         stx     %o3, [%sp + STACK_BIAS + 128]
  75
  76         ldd     [%sp + STACK_BIAS + 128], %f20
  77         fmovduge %fcc2, ZERO, %f20
  78         faddd   %f18, %f20, %f0
  79         fabsd   %f0, %f0
  80         retl
  81          for    %f0, SIGN_BIT, %f0
  82 END (__ceil)
  83 weak_alias (__ceil, ceil)