sysdeps/unix/sysv/linux/aarch64/clone.S

   1 /* Copyright (C) 1996-2016 Free Software Foundation, Inc.
   2
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* clone() is even more special than fork() as it mucks with stacks
  20    and invokes a function in the right context after its all over.  */
  21
  22 #include <sysdep.h>
  23 #define _ERRNO_H        1
  24 #include <bits/errno.h>
  25
  26 #define CLONE_VM_BIT      8
  27 #define CLONE_VM          (1 << CLONE_VM_BIT)
  28
  29 #define CLONE_THREAD_BIT  16
  30 #define CLONE_THREAD      (1 << CLONE_THREAD_BIT)
  31
  32 /* int clone(int (*fn)(void *arg),            x0
  33              void *child_stack,               x1
  34              int flags,                       x2
  35              void *arg,                       x3
  36              pid_t *ptid,                     x4
  37              struct user_desc *tls,           x5
  38              pid_t *ctid);                    x6
  39  */
  40         .text
  41 ENTRY(__clone)
  42         DELOUSE (0)
  43         DELOUSE (1)
  44         DELOUSE (2)
  45         DELOUSE (3)
  46         DELOUSE (4)
  47         DELOUSE (5)
  48         DELOUSE (6)
  49         /* Save args for the child.  */
  50         mov     x10, x0
  51         mov     x11, x2
  52         mov     x12, x3
  53
  54         /* Sanity check args.  */
  55         mov     x0, #-EINVAL
  56         cbz     x10, .Lsyscall_error
  57         cbz     x1, .Lsyscall_error
  58
  59         /* Do the system call.  */
  60         /* X0:flags, x1:newsp, x2:parenttidptr, x3:newtls, x4:childtid.  */
  61         mov     x0, x2                  /* flags  */
  62         /* New sp is already in x1.  */
  63         mov     x2, x4                  /* ptid  */
  64         mov     x3, x5                  /* tls  */
  65         mov     x4, x6                  /* ctid  */
  66         mov     x8, #SYS_ify(clone)
  67         svc     0x0
  68
  69         cmp     x0, #0
  70         beq     thread_start
  71         blt     .Lsyscall_error
  72         RET
  73 PSEUDO_END (__clone)
  74
  75         .align 4
  76         .type thread_start, %function
  77 thread_start:
  78         cfi_startproc
  79         cfi_undefined (x30)
  80         mov     x29, 0
  81
  82         /* Pick the function arg and execute.  */
  83         mov     x0, x12
  84         blr     x10
  85
  86         /* We are done, pass the return value through x0.  */
  87         b       HIDDEN_JUMPTARGET(_exit)
  88         cfi_endproc
  89         .size thread_start, .-thread_start
  90
  91 libc_hidden_def (__clone)
  92 weak_alias (__clone, clone)