sysdeps/unix/sysv/linux/i386/clone.S

   1 /* Copyright (C) 1996 Free Software Foundation, Inc.
   2    Contributed by Richard Henderson (rth@tamu.edu)
   3
   4 The GNU C Library is free software; you can redistribute it and/or
   5 modify it under the terms of the GNU Library General Public License as
   6 published by the Free Software Foundation; either version 2 of the
   7 License, or (at your option) any later version.
   8
   9 The GNU C Library is distributed in the hope that it will be useful,
  10 but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 Library General Public License for more details.
  13
  14 You should have received a copy of the GNU Library General Public
  15 License along with the GNU C Library; see the file COPYING.LIB.  If
  16 not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  17 Cambridge, MA 02139, USA.  */
  18
  19 /* clone() is even more special than fork() as it mucks with stacks
  20    and invokes a function in the right context after its all over.  */
  21
  22 #include <sysdep.h>
  23 #include <errnos.h>
  24
  25 /* int clone(int (*fn)(), void *child_stack, int flags, int nargs, ...) */
  26
  27         .text
  28 ENTRY(__clone)
  29         /* Sanity check arguments.  */
  30         movl    $-EINVAL,%eax
  31         movl    4(%esp),%ecx            /* no NULL function pointers */
  32         testl   %ecx,%ecx
  33         jz      syscall_error
  34         movl    8(%esp),%ecx            /* no NULL stack pointers */
  35         testl   %ecx,%ecx
  36         jz      syscall_error
  37         movl    16(%esp),%edx           /* no negative argument counts */
  38         testl   %edx,%edx
  39         js      syscall_error
  40
  41         /* Allocate space on the new stack and copy args over */
  42         movl    %edx,%eax
  43         negl    %eax
  44         lea     -4(%ecx,%eax,4),%ecx
  45         jz      2f
  46 1:      movl    16(%esp,%edx,4),%eax
  47         movl    %eax,0(%ecx,%edx,4)
  48         dec     %edx
  49         jnz     1b
  50 2:
  51         /* Save the function pointer as the zeroth argument.
  52            It will be popped off in the child in the ebx frobbing below.  */
  53         movl    4(%esp),%eax
  54         movl    %eax,0(%ecx)
  55
  56         /* Do the system call */
  57         pushl   %ebx
  58         movl    16(%esp),%ebx
  59         movl    $SYS_ify(clone),%eax
  60         int     $0x80
  61         popl    %ebx
  62
  63         test    %eax,%eax
  64         jl      syscall_error
  65         jz      thread_start
  66
  67         ret
  68
  69         SYSCALL_ERROR_HANDLER
  70
  71 thread_start:
  72         subl    %ebp,%ebp       /* terminate the stack frame */
  73         call    *%ebx
  74         pushl   %eax
  75 #ifdef PIC
  76         call    _exit@PLT
  77 #else
  78         call    _exit
  79 #endif
  80
  81 weak_alias(__clone, clone)