     [file configdoc.texi not included]

     START-INFO-DIR-ENTRY
     * Ld: (ld).                       The GNU linker.
     END-INFO-DIR-ENTRY

This file documents the GNU linker LD.

Copyright (C) 1991, 92, 93, 94, 95, 1996 Free Software Foundation, Inc.

Permission is granted to make and distribute verbatim copies of this manual provided the copyright notice and this permission notice are preserved on all copies.

Permission is granted to copy and distribute modified versions of this manual under the conditions for verbatim copying, provided also that the entire resulting derived work is distributed under the terms of a permission notice identical to this one.

Permission is granted to copy and distribute translations of this manual into another language, under the above conditions for modified versions.

Using ld
********

This file documents the GNU linker ld.

Overview
********

ld combines a number of object and archive files, relocates their data and ties up symbol references. Usually the last step in compiling a program is to run ld.

ld accepts Linker Command Language files written in a superset of AT&T's Link Editor Command Language syntax, to provide explicit and total control over the linking process.

This version of ld uses the general purpose BFD libraries to operate on object files. This allows ld to read, combine, and write object files in many different formats---for example, COFF or a.out.  Different formats may be linked together to produce any available kind of object file.  See BFD, for more information.

Aside from its flexibility, the GNU linker is more helpful than other linkers in providing diagnostic information.  Many linkers abandon execution immediately upon encountering an error; whenever possible, ld continues executing, allowing you to identify other errors (or, in some cases, to get an output file in spite of the error).

Invocation
**********

The GNU linker ld is meant to cover a broad range of situations, and to be as compatible as possible with other linkers.  As a result, you have many choices to control its behavior.

The linker supports a plethora of command-line options, but in actual practice few of them are used in any particular context. For instance, a frequent use of ld is to link standard Unix object files on a standard, supported Unix system.  On such a system, to link a file hello.o:

     ld -o OUTPUT /lib/crt0.o hello.o -lc

This tells ld to produce a file called OUTPUT as the result of linking the file /lib/crt0.o with hello.o and the library libc.a, which will come from the standard search directories.  (See the discussion of the -l option below.)

The command-line options to ld may be specified in any order, and may be repeated at will.  Repeating most options with a different argument will either have no further effect, or override prior occurrences (those further to the left on the command line) of that option.  Options which may be meaningfully specified more than once are noted in the descriptions below.

Non-option arguments are objects files which are to be linked together. They may follow, precede, or be mixed in with command-line options, except that an object file argument may not be placed between an option and its argument.

Usually the linker is invoked with at least one object file, but you can specify other forms of binary input files using -l, -R, and the script command language.  If no binary input files at all are specified, the linker does not produce any output, and issues the message No input files.

If the linker can not recognize the format of an object file, it will assume that it is a linker script.  A script specified in this way augments the main linker script used for the link (either the default linker script or the one specified by using -T).  This feature permits the linker to link against a file which appears to be an object or an archive, but actually merely defines some symbol values, or uses INPUT or GROUP to load other objects.  See Commands.

For options whose names are a single letter, option arguments must either follow the option letter without intervening whitespace, or be given as separate arguments immediately following the option that requires them.

For options whose names are multiple letters, either one dash or two can precede the option name; for example, --oformat and -oformat are equivalent.  Arguments to multiple-letter options must either be separated from the option name by an equals sign, or be given as separate arguments immediately following the option that requires them.  For example, --oformat srec and --oformat=srec are equivalent.  Unique abbreviations of the names of multiple-letter options are accepted.

-aKEYWORD
     This option is supported for HP/UX compatibility.  The KEYWORD argument must be one of the strings archive, shared, or default.  -aarchive is functionally equivalent to -Bstatic, and the other two keywords are functionally equivalent to -Bdynamic.  This option may be used any number of times.

-b INPUT-FORMAT
--format=INPUT-FORMAT
     ld may be configured to support more than one kind of object file.  If your ld is configured this way, you can use the -b option to specify the binary format for input object files that follow this option on the command line.  Even when ld is configured to support alternative object formats, you don't usually need to specify this, as ld should be configured to expect as a default input format the most usual format on each machine. INPUT-FORMAT is a text string, the name of a particular format supported by the BFD libraries.  (You can list the available binary formats with objdump -i.) See BFD.

     You may want to use this option if you are linking files with an unusual binary format.  You can also use -b to switch formats explicitly (when linking object files of different formats), by including -b INPUT-FORMAT before each group of object files in a particular format.

     The default format is taken from the environment variable GNUTARGET. You can also define the input format from a script, using the command TARGET; see Option Commands.

-c MRI-COMMANDFILE
--mri-script=MRI-COMMANDFILE
     For compatibility with linkers produced by MRI, ld accepts script files written in an alternate, restricted command language, described in MRI Compatible Script Files.  Introduce MRI script files with the option -c; use the -T option to run linker scripts written in the general-purpose ld scripting language. If MRI-CMDFILE does not exist, ld looks for it in the directories specified by any -L options.

-d
-dc
-dp
     These three options are equivalent; multiple forms are supported for compatibility with other linkers.  They assign space to common symbols even if a relocatable output file is specified (with -r).  The script command FORCE_COMMON_ALLOCATION has the same effect.  See Option Commands.

-e ENTRY
--entry=ENTRY
     Use ENTRY as the explicit symbol for beginning execution of your program, rather than the default entry point. See Entry Point, for a discussion of defaults and other ways of specifying the entry point.

-E
-export-dynamic
     When creating a dynamically linked executable, add all symbols to the dynamic symbol table.  Normally, the dynamic symbol table contains only symbols which are used by a dynamic object.  This option is needed for some uses of dlopen.

-F
-FFORMAT
     Ignored.  Some older linkers used this option throughout a compilation toolchain for specifying object-file format for both input and output object files.  The mechanisms ld uses for this purpose (the -b or -format options for input files, -oformat option or the TARGET command in linker scripts for output files, the GNUTARGET environment variable) are more flexible, but ld accepts the -F option for compatibility with scripts written to call the old linker.

--force-exe-suffix
     Make sure that an output file has a .exe suffix.

     If a successfully built fully linked output file does not have a .exe or .dll suffix, this option forces the linker to copy the output file to one of the same name with a .exe suffix. This option is useful when using unmodified Unix makefiles on a Microsoft Windows host, since some versions of Windows won't run an image unless it ends in a .exe suffix.

-g
     Ignored.  Provided for compatibility with other tools.

-GVALUE
--gpsize=VALUE
     Set the maximum size of objects to be optimized using the GP register to SIZE.  This is only meaningful for object file formats such as MIPS ECOFF which supports putting large and small objects into different sections.  This is ignored for other object file formats.

-hNAME
-soname=NAME
     When creating an ELF shared object, set the internal DT_SONAME field to the specified name.  When an executable is linked with a shared object which has a DT_SONAME field, then when the executable is run the dynamic linker will attempt to load the shared object specified by the DT_SONAME field rather than the using the file name given to the linker.

-i
     Perform an incremental link (same as option -r).

-lARCHIVE
--library=ARCHIVE
     Add archive file ARCHIVE to the list of files to link.  This option may be used any number of times.  ld will search its path-list for occurrences of libARCHIVE.a for every ARCHIVE specified.  File extensions other than .a may be used on certain systems.

-LSEARCHDIR
--library-path=SEARCHDIR
     Add path SEARCHDIR to the list of paths that ld will search for archive libraries and ld control scripts.  You may use this option any number of times.  The directories are searched in the order in which they are specified on the command line.  Directories specified on the command line are searched before the default directories.  All -L options apply to all -l options, regardless of the order in which the options appear.

     The paths can also be specified in a link script with the SEARCH_DIR command.  Directories specified this way are searched at the point in which the linker script appears in the command line.

-mEMULATION
     Emulate the EMULATION linker.  You can list the available emulations with the --verbose or -V options.  The default depends on how your ld was configured.

-M
--print-map
     Print (to the standard output) a link map---diagnostic information about where symbols are mapped by ld, and information on global common storage allocation.

-n
--nmagic
     Set the text segment to be read only, and mark the output as NMAGIC if possible.

-N
--omagic
     Set the text and data sections to be readable and writable.  Also, do not page-align the data segment.  If the output format supports Unix style magic numbers, mark the output as OMAGIC.

-o OUTPUT
--output=OUTPUT
     Use OUTPUT as the name for the program produced by ld; if this option is not specified, the name a.out is used by default.  The script command OUTPUT can also specify the output file name.

-r
--relocateable
     Generate relocatable output---i.e., generate an output file that can in turn serve as input to ld.  This is often called partial linking.  As a side effect, in environments that support standard Unix magic numbers, this option also sets the output file's magic number to OMAGIC. If this option is not specified, an absolute file is produced.  When linking C++ programs, this option will not resolve references to constructors; to do that, use -Ur.

     This option does the same thing as -i.

-R FILENAME
--just-symbols=FILENAME
     Read symbol names and their addresses from FILENAME, but do not relocate it or include it in the output.  This allows your output file to refer symbolically to absolute locations of memory defined in other programs.  You may use this option more than once.

     For compatibility with other ELF linkers, if the -R option is followed by a directory name, rather than a file name, it is treated as the -rpath option.

-s
--strip-all
     Omit all symbol information from the output file.

-S
--strip-debug
     Omit debugger symbol information (but not all symbols) from the output file.

-t
--trace
     Print the names of the input files as ld processes them.

-T COMMANDFILE
--script=COMMANDFILE
     Read link commands from the file COMMANDFILE.  These commands replace ld's default link script (rather than adding to it), so COMMANDFILE must specify everything necessary to describe the target format.  See Commands.  If COMMANDFILE does not exist, ld looks for it in the directories specified by any preceding -L options.  Multiple -T options accumulate.

-u SYMBOL
--undefined=SYMBOL
     Force SYMBOL to be entered in the output file as an undefined symbol. Doing this may, for example, trigger linking of additional modules from standard libraries.  -u may be repeated with different option arguments to enter additional undefined symbols.

-v
--version
-V
     Display the version number for ld.  The -V option also lists the supported emulations.

-x
--discard-all
     Delete all local symbols.

-X
--discard-locals
     Delete all temporary local symbols.  For most targets, this is all local symbols whose names begin with L.

-y SYMBOL
--trace-symbol=SYMBOL
     Print the name of each linked file in which SYMBOL appears.  This option may be given any number of times.  On many systems it is necessary to prepend an underscore.

     This option is useful when you have an undefined symbol in your link but don't know where the reference is coming from.

-Y PATH
     Add PATH to the default library search path.  This option exists for Solaris compatibility.

-z KEYWORD
     This option is ignored for Solaris compatibility.

-( ARCHIVES -)
--start-group ARCHIVES --end-group
     The ARCHIVES should be a list of archive files.  They may be either explicit file names, or -l options.

     The specified archives are searched repeatedly until no new undefined references are created.  Normally, an archive is searched only once in the order that it is specified on the command line.  If a symbol in that archive is needed to resolve an undefined symbol referred to by an object in an archive that appears later on the command line, the linker would not be able to resolve that reference.  By grouping the archives, they all be searched repeatedly until all possible references are resolved.

     Using this option has a significant performance cost.  It is best to use it only when there are unavoidable circular references between two or more archives.

-assert KEYWORD
     This option is ignored for SunOS compatibility.

-Bdynamic
-dy
-call_shared
     Link against dynamic libraries.  This is only meaningful on platforms for which shared libraries are supported.  This option is normally the default on such platforms.  The different variants of this option are for compatibility with various systems.  You may use this option multiple times on the command line: it affects library searching for -l options which follow it.

-Bstatic
-dn
-non_shared
-static
     Do not link against shared libraries.  This is only meaningful on platforms for which shared libraries are supported.  The different variants of this option are for compatibility with various systems.  You may use this option multiple times on the command line: it affects library searching for -l options which follow it.

-Bsymbolic
     When creating a shared library, bind references to global symbols to the definition within the shared library, if any.  Normally, it is possible for a program linked against a shared library to override the definition within the shared library.  This option is only meaningful on ELF platforms which support shared libraries.

--cref
     Output a cross reference table.  If a linker map file is being generated, the cross reference table is printed to the map file. Otherwise, it is printed on the standard output.

     The format of the table is intentionally simple, so that it may be easily processed by a script if necessary.  The symbols are printed out, sorted by name.  For each symbol, a list of file names is given.  If the symbol is defined, the first file listed is the location of the definition.  The remaining files contain references to the symbol.

--defsym SYMBOL=EXPRESSION
     Create a global symbol in the output file, containing the absolute address given by EXPRESSION.  You may use this option as many times as necessary to define multiple symbols in the command line.  A limited form of arithmetic is supported for the EXPRESSION in this context: you may give a hexadecimal constant or the name of an existing symbol, or use + and - to add or subtract hexadecimal constants or symbols.  If you need more elaborate expressions, consider using the linker command language from a script (see Assignment: Symbol Definitions).  Note:  there should be no white space between SYMBOL, the equals sign (``=''), and EXPRESSION.

--dynamic-linker FILE
     Set the name of the dynamic linker.  This is only meaningful when generating dynamically linked ELF executables.  The default dynamic linker is normally correct; don't use this unless you know what you are doing.

-EB
     Link big-endian objects.  This affects the default output format.

-EL
     Link little-endian objects.  This affects the default output format.

-embedded-relocs
     This option is only meaningful when linking MIPS embedded PIC code, generated by the -membedded-pic option to the GNU compiler and assembler.  It causes the linker to create a table which may be used at runtime to relocate any data which was statically initialized to pointer values.  See the code in testsuite/ld-empic for details.

--help
     Print a summary of the command-line options on the standard output and exit.

-Map MAPFILE
     Print to the file MAPFILE a link map---diagnostic information about where symbols are mapped by ld, and information on global common storage allocation.

--no-keep-memory
     ld normally optimizes for speed over memory usage by caching the symbol tables of input files in memory.  This option tells ld to instead optimize for memory usage, by rereading the symbol tables as necessary.  This may be required if ld runs out of memory space while linking a large executable.

--no-whole-archive
     Turn off the effect of the --whole-archive option for subsequent archive files.

--noinhibit-exec
     Retain the executable output file whenever it is still usable. Normally, the linker will not produce an output file if it encounters errors during the link process; it exits without writing an output file when it issues any error whatsoever.

-oformat OUTPUT-FORMAT
     ld may be configured to support more than one kind of object file.  If your ld is configured this way, you can use the -oformat option to specify the binary format for the output object file.  Even when ld is configured to support alternative object formats, you don't usually need to specify this, as ld should be configured to produce as a default output format the most usual format on each machine.  OUTPUT-FORMAT is a text string, the name of a particular format supported by the BFD libraries.  (You can list the available binary formats with objdump -i.)  The script command OUTPUT_FORMAT can also specify the output format, but this option overrides it.  See BFD.

-qmagic
     This option is ignored for Linux compatibility.

-Qy
     This option is ignored for SVR4 compatibility.

--relax
     An option with machine dependent effects.

     On some platforms, the --relax option performs global optimizations that become possible when the linker resolves addressing in the program, such as relaxing address modes and synthesizing new instructions in the output object file.

--retain-symbols-file FILENAME
     Retain only the symbols listed in the file FILENAME, discarding all others.  FILENAME is simply a flat file, with one symbol name per line.  This option is especially useful in environments where a large global symbol table is accumulated gradually, to conserve run-time memory.

     -retain-symbols-file does not discard undefined symbols, or symbols needed for relocations.

     You may only specify -retain-symbols-file once in the command line.  It overrides -s and -S.

-shared
-Bshareable
     Create a shared library.  This is currently only supported on ELF, XCOFF and SunOS platforms.  On SunOS, the linker will automatically create a shared library if the -e option is not used and there are undefined symbols in the link.

--sort-common
     This option tells ld to sort the common symbols by size when it places them in the appropriate output sections.  First come all the one byte symbols, then all the two bytes, then all the four bytes, and then everything else.  This is to prevent gaps between symbols due to alignment constraints.

--split-by-file
     Similar to --split-by-reloc but creates a new output section for each input file.

--split-by-reloc COUNT
     Trys to creates extra sections in the output file so that no single output section in the file contains more than COUNT relocations. This is useful when generating huge relocatable for downloading into certain real time kernels with the COFF object file format; since COFF cannot represent more than 65535 relocations in a single section.  Note that this will fail to work with object file formats which do not support arbitrary sections.  The linker will not split up individual input sections for redistribution, so if a single input section contains more than COUNT relocations one output section will contain that many relocations.

--stats
     Compute and display statistics about the operation of the linker, such as execution time and memory usage.

-traditional-format
     For some targets, the output of ld is different in some ways from the output of some existing linker.  This switch requests ld to use the traditional format instead.

     For example, on SunOS, ld combines duplicate entries in the symbol string table.  This can reduce the size of an output file with full debugging information by over 30 percent.  Unfortunately, the SunOS dbx program can not read the resulting program (gdb has no trouble).  The -traditional-format switch tells ld to not combine duplicate entries.

-Tbss ORG
-Tdata ORG
-Ttext ORG
     Use ORG as the starting address for---respectively---the bss, data, or the text segment of the output file. ORG must be a single hexadecimal integer; for compatibility with other linkers, you may omit the leading 0x usually associated with hexadecimal values.

-Ur
     For anything other than C++ programs, this option is equivalent to -r: it generates relocatable output---i.e., an output file that can in turn serve as input to ld.  When linking C++ programs, -Ur does resolve references to constructors, unlike -r. It does not work to use -Ur on files that were themselves linked with -Ur; once the constructor table has been built, it cannot be added to.  Use -Ur only for the last partial link, and -r for the others.

--verbose
     Display the version number for ld and list the linker emulations supported.  Display which input files can and cannot be opened.  Display the linker script if using a default builtin script.

-warn-common
     Warn when a common symbol is combined with another common symbol or with a symbol definition.  Unix linkers allow this somewhat sloppy practice, but linkers on some other operating systems do not.  This option allows you to find potential problems from combining global symbols. Unfortunately, some C libraries use this practice, so you may get some warnings about symbols in the libraries as well as in your programs.

     There are three kinds of global symbols, illustrated here by C examples:

     int i = 1;
          A definition, which goes in the initialized data section of the output file.

     extern int i;
          An undefined reference, which does not allocate space. There must be either a definition or a common symbol for the variable somewhere.

     int i;
          A common symbol.  If there are only (one or more) common symbols for a variable, it goes in the uninitialized data area of the output file. The linker merges multiple common symbols for the same variable into a single symbol.  If they are of different sizes, it picks the largest size.  The linker turns a common symbol into a declaration, if there is a definition of the same variable.

     The -warn-common option can produce five kinds of warnings.  Each warning consists of a pair of lines: the first describes the symbol just encountered, and the second describes the previous symbol encountered with the same name.  One or both of the two symbols will be a common symbol.

      1. Turning a common symbol into a reference, because there is already a definition for the symbol.

               FILE(SECTION): warning: common of `SYMBOL'
                  overridden by definition
               FILE(SECTION): warning: defined here

      2. Turning a common symbol into a reference, because a later definition for the symbol is encountered.  This is the same as the previous case, except that the symbols are encountered in a different order.

               FILE(SECTION): warning: definition of `SYMBOL'
                  overriding common
               FILE(SECTION): warning: common is here

      3. Merging a common symbol with a previous same-sized common symbol.

               FILE(SECTION): warning: multiple common
                  of `SYMBOL'
               FILE(SECTION): warning: previous common is here

      4. Merging a common symbol with a previous larger common symbol.

               FILE(SECTION): warning: common of `SYMBOL'
                  overridden by larger common
               FILE(SECTION): warning: larger common is here

      5. Merging a common symbol with a previous smaller common symbol.  This is the same as the previous case, except that the symbols are encountered in a different order.

               FILE(SECTION): warning: common of `SYMBOL'
                  overriding smaller common
               FILE(SECTION): warning: smaller common is here

-warn-constructors
     Warn if any global constructors are used.  This is only useful for a few object file formats.  For formats like COFF or ELF, the linker can not detect the use of global constructors.

-warn-multiple-gp
     Warn if multiple global pointer values are required in the output file. This is only meaningful for certain processors, such as the Alpha. Specifically, some processors put large-valued constants in a special section.  A special register (the global pointer) points into the middle of this section, so that constants can be loaded efficiently via a base-register relative addressing mode.  Since the offset in base-register relative mode is fixed and relatively small (e.g., 16 bits), this limits the maximum size of the constant pool.  Thus, in large programs, it is often necessary to use multiple global pointer values in order to be able to address all possible constants.  This option causes a warning to be issued whenever this case occurs.

-warn-once
     Only warn once for each undefined symbol, rather than once per module which refers to it.

--whole-archive
     For each archive mentioned on the command line after the --whole-archive option, include every object file in the archive in the link, rather than searching the archive for the required object files.  This is normally used to turn an archive file into a shared library, forcing every object to be included in the resulting shared library.  This option may be used more than once.

--wrap SYMBOL
     Use a wrapper function for SYMBOL.  Any undefined reference to SYMBOL will be resolved to __wrap_SYMBOL.  Any undefined reference to __real_SYMBOL will be resolved to SYMBOL.

     This can be used to provide a wrapper for a system function.  The wrapper function should be called __wrap_SYMBOL.  If it wishes to call the system function, it should call __real_SYMBOL.

     Here is a trivial example:

          void *
          __wrap_malloc (int c)
          {
            printf ("malloc called with %ld\n", c);
            return __real_malloc (c);
          }

     If you link other code with this file using --wrap malloc, then all calls to malloc will call the function __wrap_malloc instead.  The call to __real_malloc in __wrap_malloc will call the real malloc function.

     You may wish to provide a __real_malloc function as well, so that links without the --wrap option will succeed.  If you do this, you should not put the definition of __real_malloc in the same file as __wrap_malloc; if you do, the assembler may resolve the call before the linker has a chance to wrap it to malloc.

Command Language
****************

The command language provides explicit control over the link process, allowing complete specification of the mapping between the linker's input files and its output.  It controls:

  * input files

  * file formats

  * output file layout

  * addresses of sections

  * placement of common blocks

You may supply a command file (also known as a link script) to the linker either explicitly through the -T option, or implicitly as an ordinary file. If the linker opens a file which it cannot recognize as a supported object or archive format, it reports an error.

Linker Scripts
==============

The ld command language is a collection of statements; some are simple keywords setting a particular option, some are used to select and group input files or name output files; and two statement types have a fundamental and pervasive impact on the linking process.

The most fundamental command of the ld command language is the SECTIONS command (see SECTIONS).  Every meaningful command script must have a SECTIONS command: it specifies a ``picture'' of the output file's layout, in varying degrees of detail. No other command is required in all cases.

The MEMORY command complements SECTIONS by describing the available memory in the target architecture.  This command is optional; if you don't use a MEMORY command, ld assumes sufficient memory is available in a contiguous block for all output. See MEMORY.

You may include comments in linker scripts just as in C: delimited by /* and */.  As in C, comments are syntactically equivalent to whitespace.

Expressions
===========

Many useful commands involve arithmetic expressions.  The syntax for expressions in the command language is identical to that of C expressions, with the following features:

  * All expressions evaluated as integers and are of ``long'' or ``unsigned long'' type.

  * All constants are integers.

  * All of the C arithmetic operators are provided.

  * You may reference, define, and create global variables.

  * You may call special purpose built-in functions.

Integers
--------

An octal integer is 0 followed by zero or more of the octal digits (01234567).

     _as_octal = 0157255;

A decimal integer starts with a non-zero digit followed by zero or more digits (0123456789).

     _as_decimal = 57005;

A hexadecimal integer is 0x or 0X followed by one or more hexadecimal digits chosen from 0123456789abcdefABCDEF.

     _as_hex = 0xdead;

To write a negative integer, use the prefix operator - (see Operators).

     _as_neg = -57005;

Additionally the suffixes K and M may be used to scale a constant by 1024 or 1024*1024 respectively. For example, the following all refer to the same quantity:

             _fourk_1 = 4K;
             _fourk_2 = 4096;
             _fourk_3 = 0x1000;

Symbol Names
------------

Unless quoted, symbol names start with a letter, underscore, or point and may include any letters, underscores, digits, points, and hyphens.  Unquoted symbol names must not conflict with any keywords.  You can specify a symbol which contains odd characters or has the same name as a keyword, by surrounding the symbol name in double quotes:

             "SECTION" = 9;
             "with a space" = "also with a space" + 10;

Since symbols can contain many non-alphabetic characters, it is safest to delimit symbols with spaces.  For example, A-B is one symbol, whereas A - B is an expression involving subtraction.

The Location Counter
--------------------

The special linker variable dot . always contains the current output location counter. Since the . always refers to a location in an output section, it must always appear in an expression within a SECTIONS command. The . symbol may appear anywhere that an ordinary symbol is allowed in an expression, but its assignments have a side effect. Assigning a value to the . symbol will cause the location counter to be moved. This may be used to create holes in the output section.  The location counter may never be moved backwards.

     SECTIONS
     {
       output :
       {
       file1(.text)
       . = . + 1000;
       file2(.text)
       . += 1000;
       file3(.text)
       } = 0x1234;
     }

In the previous example, file1 is located at the beginning of the output section, then there is a 1000 byte gap.  Then file2 appears, also with a 1000 byte gap following before file3 is loaded.  The notation = 0x1234 specifies what data to write in the gaps (see Section Options).

Operators
---------

The linker recognizes  the standard C set of arithmetic operators, with the standard bindings and precedence levels:

     precedence      associativity   Operators                Notes
     (highest)
     1               left            !  -  ~                  (1)
     2               left            *  /  %
     3               left            +  -
     4               left            >>  <<
     5               left            ==  !=  >  <  <=  >=
     6               left            &
     7               left            |
     8               left            &&
     9               left            ||
     10              right           ? :
     11              right           &=  +=  -=  *=  /=       (2)
     (lowest)

Notes: (1) Prefix operators (2) See Assignment.

Evaluation
----------

The linker uses ``lazy evaluation'' for expressions; it only calculates an expression when absolutely necessary.  The linker needs the value of the start address, and the lengths of memory regions, in order to do any linking at all; these values are computed as soon as possible when the linker reads in the command file.  However, other values (such as symbol values) are not known or needed until after storage allocation.  Such values are evaluated later, when other information (such as the sizes of output sections) is available for use in the symbol assignment expression.

Assignment: Defining Symbols
----------------------------

You may create global symbols, and assign values (addresses) to global symbols, using any of the C assignment operators:

SYMBOL  = EXPRESSION ;
SYMBOL &= EXPRESSION ;
SYMBOL += EXPRESSION ;
SYMBOL -= EXPRESSION ;
SYMBOL *= EXPRESSION ;
SYMBOL /= EXPRESSION ;

Two things distinguish assignment from other operators in ld expressions.

  * Assignment may only be used at the root of an expression; a=b+3; is allowed, but a+b=3; is an error.

  * You must place a trailing semicolon (``;'') at the end of an assignment statement.

Assignment statements may appear:

  * as commands in their own right in an ld script; or

  * as independent statements within a SECTIONS command; or

  * as part of the contents of a section definition in a SECTIONS command.

The first two cases are equivalent in effect---both define a symbol with an absolute address.  The last case defines a symbol whose address is relative to a particular section (see SECTIONS).

When a linker expression is evaluated and assigned to a variable, it is given either an absolute or a relocatable type. An absolute expression type is one in which the symbol contains the value that it will have in the output file; a relocatable expression type is one in which the value is expressed as a fixed offset from the base of a section.

The type of the expression is controlled by its position in the script file.  A symbol assigned within a section definition is created relative to the base of the section; a symbol assigned in any other place is created as an absolute symbol. Since a symbol created within a section definition is relative to the base of the section, it will remain relocatable if relocatable output is requested.  A symbol may be created with an absolute value even when assigned to within a section definition by using the absolute assignment function ABSOLUTE.  For example, to create an absolute symbol whose address is the last byte of an output section named .data:

     SECTIONS{ ...
       .data :
         {
           *(.data)
           _edata = ABSOLUTE(.) ;
         }
     ... }

The linker tries to put off the evaluation of an assignment until all the terms in the source expression are known (see Evaluation).  For instance, the sizes of sections cannot be known until after allocation, so assignments dependent upon these are not performed until after allocation. Some expressions, such as those depending upon the location counter dot, . must be evaluated during allocation. If the result of an expression is required, but the value is not available, then an error results.  For example, a script like the following

     SECTIONS { ...
       text 9+this_isnt_constant :
         { ...
         }
     ... }

will cause the error message ``Non constant expression for initial address''.

In some cases, it is desirable for a linker script to define a symbol only if it is referenced, and only if it is not defined by any object included in the link.  For example, traditional linkers defined the symbol etext.  However, ANSI C requires that the user be able to use etext as a function name without encountering an error. The PROVIDE keyword may be used to define a symbol, such as etext, only if it is referenced but not defined.  The syntax is PROVIDE(SYMBOL = EXPRESSION).

Arithmetic Functions
--------------------

The command language includes a number of built-in functions for use in link script expressions.

ABSOLUTE(EXP)
     Return the absolute (non-relocatable, as opposed to non-negative) value of the expression EXP.  Primarily useful to assign an absolute value to a symbol within a section definition, where symbol values are normally section-relative.

ADDR(SECTION)
     Return the absolute address of the named SECTION.  Your script must previously have defined the location of that section. In the following example, symbol_1 and symbol_2 are assigned identical values:

          SECTIONS{ ...
            .output1 :
              {
              start_of_output_1 = ABSOLUTE(.);
              ...
              }
            .output :
              {
              symbol_1 = ADDR(.output1);
              symbol_2 = start_of_output_1;
              }
          ... }

ALIGN(EXP)
     Return the result of the current location counter (.) aligned to the next EXP boundary.  EXP must be an expression whose value is a power of two.  This is equivalent to

          (. + EXP - 1) & ~(EXP - 1)

     ALIGN doesn't change the value of the location counter---it just does arithmetic on it.  As an example, to align the output .data section to the next 0x2000 byte boundary after the preceding section and to set a variable within the section to the next 0x8000 boundary after the input sections:

          SECTIONS{ ...
            .data ALIGN(0x2000): {
              *(.data)
              variable = ALIGN(0x8000);
            }
          ... }

     The first use of ALIGN in this example specifies the location of a section because it is used as the optional START attribute of a section definition (see Section Options).  The second use simply defines the value of a variable.

     The built-in NEXT is closely related to ALIGN.

DEFINED(SYMBOL)
     Return 1 if SYMBOL is in the linker global symbol table and is defined, otherwise return 0.  You can use this function to provide default values for symbols.  For example, the following command-file fragment shows how to set a global symbol begin to the first location in the .text section---but if a symbol called begin already existed, its value is preserved:

          SECTIONS{ ...
            .text : {
              begin = DEFINED(begin) ? begin : . ;
              ...
            }
          ... }

NEXT(EXP)
     Return the next unallocated address that is a multiple of EXP. This function is closely related to ALIGN(EXP); unless you use the MEMORY command to define discontinuous memory for the output file, the two functions are equivalent.

SIZEOF(SECTION)
     Return the size in bytes of the named SECTION, if that section has been allocated.  In the following example, symbol_1 and symbol_2 are assigned identical values:

          SECTIONS{ ...
            .output {
              .start = . ;
              ...
              .end = . ;
              }
            symbol_1 = .end - .start ;
            symbol_2 = SIZEOF(.output);
          ... }

SIZEOF_HEADERS
sizeof_headers
     Return the size in bytes of the output file's headers.  You can use this number as the start address of the first section, if you choose, to facilitate paging.

Semicolons
----------

Semicolons (``;'') are required in the following places.  In all other places they can appear for aesthetic reasons but are otherwise ignored.

Assignment
     Semicolons must appear at the end of assignment expressions. See Assignment

PHDRS
     Semicolons must appear at the end of a PHDRS statement. See PHDRS

Memory Layout
=============

The linker's default configuration permits allocation of all available memory. You can override this configuration by using the MEMORY command.  The MEMORY command describes the location and size of blocks of memory in the target.  By using it carefully, you can describe which memory regions may be used by the linker, and which memory regions it must avoid.  The linker does not shuffle sections to fit into the available regions, but does move the requested sections into the correct regions and issue errors when the regions become too full.

A command file may contain at most one use of the MEMORY command; however, you can define as many blocks of memory within it as you wish.  The syntax is:

     MEMORY
       {
         NAME (ATTR) : ORIGIN = ORIGIN, LENGTH = LEN
         ...
       }

NAME
     is a name used internally by the linker to refer to the region. Any symbol name may be used.  The region names are stored in a separate name space, and will not conflict with symbols, file names or section names.  Use distinct names to specify multiple regions.

(ATTR)
     is an optional list of attributes, permitted for compatibility with the AT&T linker but not used by ld beyond checking that the attribute list is valid.  Valid attribute lists must be made up of the characters ``LIRWX''.  If you omit the attribute list, you may omit the parentheses around it as well.

ORIGIN
     is the start address of the region in physical memory.  It is an expression that must evaluate to a constant before memory allocation is performed. The keyword ORIGIN may be abbreviated to org or o (but not, for example, ORG).

LEN
     is the size in bytes of the region (an expression). The keyword LENGTH may be abbreviated to len or l.

For example, to specify that memory has two regions available for allocation---one starting at 0 for 256 kilobytes, and the other starting at 0x40000000 for four megabytes:

     MEMORY
       {
       rom : ORIGIN = 0, LENGTH = 256K
       ram : org = 0x40000000, l = 4M
       }

Once you have defined a region of memory named MEM, you can direct specific output sections there by using a command ending in >MEM within the SECTIONS command (see Section Options).  If the combined output sections directed to a region are too big for the region, the linker will issue an error message.

Specifying Output Sections
==========================

The SECTIONS command controls exactly where input sections are placed into output sections, their order in the output file, and to which output sections they are allocated.

You may use at most one SECTIONS command in a script file, but you can have as many statements within it as you wish.  Statements within the SECTIONS command can do one of three things:

  * define the entry point;

  * assign a value to a symbol;

  * describe the placement of a named output section, and which input sections go into it.

You can also use the first two operations---defining the entry point and defining symbols---outside the SECTIONS command: see Entry Point, and Assignment.  They are permitted here as well for your convenience in reading the script, so that symbols and the entry point can be defined at meaningful points in your output-file layout.

If you do not use a SECTIONS command, the linker places each input section into an identically named output section in the order that the sections are first encountered in the input files.  If all input sections are present in the first file, for example, the order of sections in the output file will match the order in the first input file.

Section Definitions
-------------------

The most frequently used statement in the SECTIONS command is the section definition, which specifies the properties of an output section: its location, alignment, contents, fill pattern, and target memory region.  Most of these specifications are optional; the simplest form of a section definition is

     SECTIONS { ...
       SECNAME : {
         CONTENTS
       }
     ... }

SECNAME is the name of the output section, and CONTENTS a specification of what goes there---for example, a list of input files or sections of input files (see Section Placement).  As you might assume, the whitespace shown is optional.  You do need the colon : and the braces {}, however.

SECNAME must meet the constraints of your output format.  In formats which only support a limited number of sections, such as a.out, the name must be one of the names supported by the format (a.out, for example, allows only .text, .data or .bss). If the output format supports any number of sections, but with numbers and not names (as is the case for Oasys), the name should be supplied as a quoted numeric string.  A section name may consist of any sequence of characters, but any name which does not conform to the standard ld symbol name syntax must be quoted. See Symbol Names.

The special SECNAME /DISCARD/ may be used to discard input sections.  Any sections which are assigned to an output section named /DISCARD/ are not included in the final link output.

The linker will not create output sections which do not have any contents.  This is for convenience when referring to input sections that may or may not exist.  For example,

     .foo { *(.foo) }

will only create a .foo section in the output file if there is a .foo section in at least one input file.

Section Placement
-----------------

In a section definition, you can specify the contents of an output section by listing particular input files, by listing particular input-file sections, or by a combination of the two.  You can also place arbitrary data in the section, and define symbols relative to the beginning of the section.

The CONTENTS of a section definition may include any of the following kinds of statement.  You can include as many of these as you like in a single section definition, separated from one another by whitespace.

FILENAME
     You may simply name a particular input file to be placed in the current output section; all sections from that file are placed in the current section definition.  If the file name has already been mentioned in another section definition, with an explicit section name list, then only those sections which have not yet been allocated are used.

     To specify a list of particular files by name:

          .data : { afile.o bfile.o cfile.o }

     The example also illustrates that multiple statements can be included in the contents of a section definition, since each file name is a separate statement.

FILENAME( SECTION )
FILENAME( SECTION , SECTION, ... )
FILENAME( SECTION SECTION ... )
     You can name one or more sections from your input files, for insertion in the current output section.  If you wish to specify a list of input-file sections inside the parentheses, you may separate the section names by either commas or whitespace.

* (SECTION)
* (SECTION, SECTION, ...)
* (SECTION SECTION ...)
     Instead of explicitly naming particular input files in a link control script, you can refer to all files from the ld command line: use * instead of a particular file name before the parenthesized input-file section list.

     If you have already explicitly included some files by name, * refers to all remaining files---those whose places in the output file have not yet been defined.

     For example, to copy sections 1 through 4 from an Oasys file into the .text section of an a.out file, and sections 13 and 14 into the .data section:

          SECTIONS {
            .text :{
              *("1" "2" "3" "4")
            }

            .data :{
              *("13" "14")
            }
          }

     [ SECTION ... ] used to be accepted as an alternate way to specify named sections from all unallocated input files.  Because some operating systems (VMS) allow brackets in file names, that notation is no longer supported.

FILENAME( COMMON )
*( COMMON )
     Specify where in your output file to place uninitialized data with this notation.  *(COMMON) by itself refers to all uninitialized data from all input files (so far as it is not yet allocated); FILENAME(COMMON) refers to uninitialized data from a particular file.  Both are special cases of the general mechanisms for specifying where to place input-file sections: ld permits you to refer to uninitialized data as if it were in an input-file section named COMMON, regardless of the input file's format.

In any place where you may use a specific file or section name, you may also use a wildcard pattern.  The wildcard handling is similar to that used by the Unix shell.  A * character matches any number of characters.  A ? character matches any single character.  The sequence [CHARS] will match a single instance of any of the CHARS; the - character may be used to specify a range of characters, as in [a-z] to match any lower case letter.  A \ character may be used to quote the following character.

When using a wildcard to match a file name, the wildcard characters will not match a / character (used to separate directory names on Unix).  A pattern consisting of a single * character is an exception; it will always match any file name.  The wildcard characters will match a / character in a section name.

In the following example, the command script arranges the output file into three consecutive sections, named .text, .data, and .bss, taking the input for each from the correspondingly named sections of all the input files:

     SECTIONS {
       .text : { *(.text) }
       .data : { *(.data) }
       .bss :  { *(.bss)  *(COMMON) }
     }

The following example reads all of the sections from file all.o and places them at the start of output section outputa which starts at location 0x10000. All of section .input1 from file foo.o follows immediately, in the same output section.  All of section .input2 from foo.o goes into output section outputb, followed by section .input1 from foo1.o. All of the remaining .input1 and .input2 sections from any files are written to output section outputc.

     SECTIONS {
       outputa 0x10000 :
         {
         all.o
         foo.o (.input1)
         }
       outputb :
         {
         foo.o (.input2)
         foo1.o (.input1)
         }
       outputc :
         {
         *(.input1)
         *(.input2)
         }
     }

This example shows how wildcard patterns might be used to partition files.  All .text sections are placed in .text, and all .bss sections are placed in .bss.  For all files beginning with an upper case character, the .data section is placed into .DATA; for all other files, the .data section is placed into .data.

     SECTIONS {
       .text : { *(.text) }
       .DATA : { [A-Z]*(.data) }
       .data : { *(.data) }
       .bss : { *(.bss) }
     }

Section Data Expressions
------------------------

The foregoing statements arrange, in your output file, data originating from your input files.  You can also place data directly in an output section from the link command script.  Most of these additional statements involve expressions (see Expressions).  Although these statements are shown separately here for ease of presentation, no such segregation is needed within a section definition in the SECTIONS command; you can intermix them freely with any of the statements we've just described.

CREATE_OBJECT_SYMBOLS
     Create a symbol for each input file in the current section, set to the address of the first byte of data written from that input file.  For instance, with a.out files it is conventional to have a symbol for each input file.  You can accomplish this by defining the output .text section as follows:

          SECTIONS {
            .text 0x2020 :
               {
              CREATE_OBJECT_SYMBOLS
              *(.text)
              _etext = ALIGN(0x2000);
              }
            ...
          }

     If sample.ld is a file containing this script, and a.o, b.o, c.o, and d.o are four input files with contents like the following---

          /* a.c */

          afunction() { }
          int adata=1;
          int abss;

     ld -M -T sample.ld a.o b.o c.o d.o would create a map like this, containing symbols matching the object file names:

          00000000 A __DYNAMIC
          00004020 B _abss
          00004000 D _adata
          00002020 T _afunction
          00004024 B _bbss
          00004008 D _bdata
          00002038 T _bfunction
          00004028 B _cbss
          00004010 D _cdata
          00002050 T _cfunction
          0000402c B _dbss
          00004018 D _ddata
          00002068 T _dfunction
          00004020 D _edata
          00004030 B _end
          00004000 T _etext
          00002020 t a.o
          00002038 t b.o
          00002050 t c.o
          00002068 t d.o

SYMBOL = EXPRESSION ;
SYMBOL F= EXPRESSION ;
     SYMBOL is any symbol name (see Symbols).  ``F='' refers to any of the operators &= += -= *= /= which combine arithmetic and assignment.

     When you assign a value to a symbol within a particular section definition, the value is relative to the beginning of the section (see Assignment).  If you write

          SECTIONS {
            abs = 14 ;
            ...
            .data : { ... rel = 14 ; ... }
            abs2 = 14 + ADDR(.data);
            ...
          }

     abs and rel do not have the same value; rel has the same value as abs2.

BYTE(EXPRESSION)
SHORT(EXPRESSION)
LONG(EXPRESSION)
QUAD(EXPRESSION)
     By including one of these four statements in a section definition, you can explicitly place one, two, four, or eight bytes (respectively) at the current address of that section.  QUAD is only supported when using a 64 bit host or target.

     Multiple-byte quantities are represented in whatever byte order is appropriate for the output file format (see BFD).

FILL(EXPRESSION)
     Specify the ``fill pattern'' for the current section.  Any otherwise unspecified regions of memory within the section (for example, regions you skip over by assigning a new value to the location counter .) are filled with the two least significant bytes from the EXPRESSION argument.  A FILL statement covers memory locations after the point it occurs in the section definition; by including more than one FILL statement, you can have different fill patterns in different parts of an output section.

Optional Section Attributes
---------------------------

Here is the full syntax of a section definition, including all the optional portions:

     SECTIONS {
     ...
     SECNAME START BLOCK(ALIGN) (NOLOAD) : AT ( LDADR )
       { CONTENTS } >REGION :PHDR =FILL
     ...
     }

SECNAME and CONTENTS are required.  See Section Definition, and Section Placement, for details on CONTENTS.  The remaining elements---START, BLOCK(ALIGN), (NOLOAD), AT ( LDADR ), >REGION, :PHDR, and =FILL---are all optional.

START
     You can force the output section to be loaded at a specified address by specifying START immediately following the section name. START can be represented as any expression. The following example generates section OUTPUT at location 0x40000000:

          SECTIONS {
            ...
            output 0x40000000: {
              ...
              }
            ...
          }

BLOCK(ALIGN)
     You can include BLOCK() specification to advance the location counter . prior to the beginning of the section, so that the section will begin at the specified alignment.  ALIGN is an expression.

(NOLOAD)
     Use (NOLOAD) to prevent a section from being loaded into memory each time it is accessed.  For example, in the script sample below, the ROM segment is addressed at memory location 0 and does not need to be loaded into each object file:

          SECTIONS {
            ROM  0  (NOLOAD)  : { ... }
            ...
          }

AT ( LDADR )
     The expression LDADR that follows the AT keyword specifies the load address of the section.  The default (if you do not use the AT keyword) is to make the load address the same as the relocation address.  This feature is designed to make it easy to build a ROM image.  For example, this SECTIONS definition creates two output sections: one called .text, which starts at 0x1000, and one called .mdata, which is loaded at the end of the .text section even though its relocation address is 0x2000.  The symbol _data is defined with the value 0x2000:

          SECTIONS
            {
            .text 0x1000 : { *(.text) _etext = . ; }
            .mdata 0x2000 :
              AT ( ADDR(.text) + SIZEOF ( .text ) )
              { _data = . ; *(.data); _edata = . ;  }
            .bss 0x3000 :
              { _bstart = . ;  *(.bss) *(COMMON) ; _bend = . ;}
          }

     The run-time initialization code (for C programs, usually crt0) for use with a ROM generated this way has to include something like the following, to copy the initialized data from the ROM image to its runtime address:

          char *src = _etext;
          char *dst = _data;

          /* ROM has data at end of text; copy it. */
          while (dst < _edata) {
            *dst++ = *src++;
          }

          /* Zero bss */
          for (dst = _bstart; dst< _bend; dst++)
            *dst = 0;

>REGION
     Assign this section to a previously defined region of memory. See MEMORY.

:PHDR
     Assign this section to a segment described by a program header. See PHDRS.  If a section is assigned to one or more segments, then all subsequent allocated sections will be assigned to those segments as well, unless they use an explicitly :PHDR modifier.  To prevent a section from being assigned to a segment when it would normally default to one, use :NONE.

=FILL
     Including =FILL in a section definition specifies the initial fill value for that section.  You may use any expression to specify FILL.  Any unallocated holes in the current output section when written to the output file will be filled with the two least significant bytes of the value, repeated as necessary.  You can also change the fill value with a FILL statement in the CONTENTS of a section definition.

ELF Program Headers
===================

The ELF object file format uses program headers, which are read by the system loader and describe how the program should be loaded into memory.  These program headers must be set correctly in order to run the program on a native ELF system.  The linker will create reasonable program headers by default.  However, in some cases, it is desirable to specify the program headers more precisely; the PHDRS command may be used for this purpose.  When the PHDRS command is used, the linker will not generate any program headers itself.

The PHDRS command is only meaningful when generating an ELF output file.  It is ignored in other cases.  This manual does not describe the details of how the system loader interprets program headers; for more information, see the ELF ABI.  The program headers of an ELF file may be displayed using the -p option of the objdump command.

This is the syntax of the PHDRS command.  The words PHDRS, FILEHDR, AT, and FLAGS are keywords.

     PHDRS
     {
       NAME TYPE [ FILEHDR ] [ PHDRS ] [ AT ( ADDRESS ) ]
             [ FLAGS ( FLAGS ) ] ;
     }

The NAME is used only for reference in the SECTIONS command of the linker script.  It does not get put into the output file.

Certain program header types describe segments of memory which are loaded from the file by the system loader.  In the linker script, the contents of these segments are specified by directing allocated output sections to be placed in the segment.  To do this, the command describing the output section in the SECTIONS command should use :NAME, where NAME is the name of the program header as it appears in the PHDRS command.  See Section Options.

It is normal for certain sections to appear in more than one segment. This merely implies that one segment of memory contains another.  This is specified by repeating :NAME, using it once for each program header in which the section is to appear.

If a section is placed in one or more segments using :NAME, then all subsequent allocated sections which do not specify :NAME are placed in the same segments.  This is for convenience, since generally a whole set of contiguous sections will be placed in a single segment.  To prevent a section from being assigned to a segment when it would normally default to one, use :NONE.

The FILEHDR and PHDRS keywords which may appear after the program header type also indicate contents of the segment of memory. The FILEHDR keyword means that the segment should include the ELF file header.  The PHDRS keyword means that the segment should include the ELF program headers themselves.

The TYPE may be one of the following.  The numbers indicate the value of the keyword.

PT_NULL (0)
     Indicates an unused program header.

PT_LOAD (1)
     Indicates that this program header describes a segment to be loaded from the file.

PT_DYNAMIC (2)
     Indicates a segment where dynamic linking information can be found.

PT_INTERP (3)
     Indicates a segment where the name of the program interpreter may be found.

PT_NOTE (4)
     Indicates a segment holding note information.

PT_SHLIB (5)
     A reserved program header type, defined but not specified by the ELF ABI.

PT_PHDR (6)
     Indicates a segment where the program headers may be found.

EXPRESSION
     An expression giving the numeric type of the program header.  This may be used for types not defined above.

It is possible to specify that a segment should be loaded at a particular address in memory.  This is done using an AT expression.  This is identical to the AT command used in the SECTIONS command (see Section Options).  Using the AT command for a program header overrides any information in the SECTIONS command.

Normally the segment flags are set based on the sections.  The FLAGS keyword may be used to explicitly specify the segment flags.  The value of FLAGS must be an integer.  It is used to set the p_flags field of the program header.

Here is an example of the use of PHDRS.  This shows a typical set of program headers used on a native ELF system.

     PHDRS
     {
       headers PT_PHDR PHDRS ;
       interp PT_INTERP ;
       text PT_LOAD FILEHDR PHDRS ;
       data PT_LOAD ;
       dynamic PT_DYNAMIC ;
     }

     SECTIONS
     {
       . = SIZEOF_HEADERS;
       .interp : { *(.interp) } :text :interp
       .text : { *(.text) } :text
       .rodata : { *(.rodata) } /* defaults to :text */
       ...
       . = . + 0x1000; /* move to a new page in memory */
       .data : { *(.data) } :data
       .dynamic : { *(.dynamic) } :data :dynamic
       ...
     }

The Entry Point
===============

The linker command language includes a command specifically for defining the first executable instruction in an output file (its entry point).  Its argument is a symbol name:

     ENTRY(SYMBOL)

Like symbol assignments, the ENTRY command may be placed either as an independent command in the command file, or among the section definitions within the SECTIONS command---whatever makes the most sense for your layout.

ENTRY is only one of several ways of choosing the entry point. You may indicate it in any of the following ways (shown in descending order of priority: methods higher in the list override methods lower down).

  * the -e ENTRY command-line option;

  * the ENTRY(SYMBOL) command in a linker control script;

  * the value of the symbol start, if present;

  * the address of the first byte of the .text section, if present;

  * The address 0.

For example, you can use these rules to generate an entry point with an assignment statement: if no symbol start is defined within your input files, you can simply define it, assigning it an appropriate value---

     start = 0x2020;

The example shows an absolute address, but you can use any expression. For example, if your input object files use some other symbol-name convention for the entry point, you can just assign the value of whatever symbol contains the start address to start:

     start = other_symbol ;

Option Commands
===============

The command language includes a number of other commands that you can use for specialized purposes.  They are similar in purpose to command-line options.

CONSTRUCTORS
     When linking using the a.out object file format, the linker uses an unusual set construct to support C++ global constructors and destructors.  When linking object file formats which do not support arbitrary sections, such as ECOFF and XCOFF, the linker will automatically recognize C++ global constructors and destructors by name.  For these object file formats, the CONSTRUCTORS command tells the linker where this information should be placed.  The CONSTRUCTORS command is ignored for other object file formats.

     The symbol __CTOR_LIST__ marks the start of the global constructors, and the symbol __DTOR_LIST marks the end.  The first word in the list is the number of entries, followed by the address of each constructor or destructor, followed by a zero word.  The compiler must arrange to actually run the code.  For these object file formats GNU C++ calls constructors from a subroutine __main; a call to __main is automatically inserted into the startup code for main.  GNU C++ runs destructors either by using atexit, or directly from the function exit.

     For object file formats such as COFF or ELF which support multiple sections, GNU C++ will normally arrange to put the addresses of global constructors and destructors into the .ctors and .dtors sections.  Placing the following sequence into your linker script will build the sort of table which the GNU C++ runtime code expects to see.

                __CTOR_LIST__ = .;
                LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
                *(.ctors)
                LONG(0)
                __CTOR_END__ = .;
                __DTOR_LIST__ = .;
                LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
                *(.dtors)
                LONG(0)
                __DTOR_END__ = .;

     Normally the compiler and linker will handle these issues automatically, and you will not need to concern yourself with them.  However, you may need to consider this if you are using C++ and writing your own linker scripts.

FLOAT
NOFLOAT
     These keywords were used in some older linkers to request a particular math subroutine library.  ld doesn't use the keywords, assuming instead that any necessary subroutines are in libraries specified using the general mechanisms for linking to archives; but to permit the use of scripts that were written for the older linkers, the keywords FLOAT and NOFLOAT are accepted and ignored.

FORCE_COMMON_ALLOCATION
     This command has the same effect as the -d command-line option: to make ld assign space to common symbols even if a relocatable output file is specified (-r).

INPUT ( FILE, FILE, ... )
INPUT ( FILE FILE ... )
     Use this command to include binary input files in the link, without including them in a particular section definition. Specify the full name for each FILE, including .a if required.

     ld searches for each FILE through the archive-library search path, just as for files you specify on the command line. See the description of -L in Command Line Options.

     If you use -lFILE, ld will transform the name to libFILE.a as with the command line argument -l.

GROUP ( FILE, FILE, ... )
GROUP ( FILE FILE ... )
     This command is like INPUT, except that the named files should all be archives, and they are searched repeatedly until no new undefined references are created.  See the description of -( in Command Line Options.

OUTPUT ( FILENAME )
     Use this command to name the link output file FILENAME.  The effect of OUTPUT(FILENAME) is identical to the effect of -o FILENAME, which overrides it.  You can use this command to supply a default output-file name other than a.out.

OUTPUT_ARCH ( BFDNAME )
     Specify a particular output machine architecture, with one of the names used by the BFD back-end routines (see BFD).  This command is often unnecessary; the architecture is most often set implicitly by either the system BFD configuration or as a side effect of the OUTPUT_FORMAT command.

OUTPUT_FORMAT ( BFDNAME )
     When ld is configured to support multiple object code formats, you can use this command to specify a particular output format. BFDNAME is one of the names used by the BFD back-end routines (see BFD).  The effect is identical to the effect of the -oformat command-line option.  This selection affects only the output file; the related command TARGET affects primarily input files.

SEARCH_DIR ( PATH )
     Add PATH to the list of paths where ld looks for archive libraries.  SEARCH_DIR(PATH) has the same effect as -LPATH on the command line.

STARTUP ( FILENAME )
     Ensure that FILENAME is the first input file used in the link process.

TARGET ( FORMAT )
     When ld is configured to support multiple object code formats, you can use this command to change the input-file object code format (like the command-line option -b or its synonym -format). The argument FORMAT is one of the strings used by BFD to name binary formats.  If TARGET is specified but OUTPUT_FORMAT is not, the last TARGET argument is also used as the default format for the ld output file.  See BFD.

     If you don't use the TARGET command, ld uses the value of the environment variable GNUTARGET, if available, to select the output file format.  If that variable is also absent, ld uses the default format configured for your machine in the BFD libraries.

BFD
***

The linker accesses object and archive files using the BFD libraries. These libraries allow the linker to use the same routines to operate on object files whatever the object file format.  A different object file format can be supported simply by creating a new BFD back end and adding it to the library.  To conserve runtime memory, however, the linker and associated tools are usually configured to support only a subset of the object file formats available.  You can use objdump -i (see objdump (The GNU Binary Utilities)) to list all the formats available for your configuration.

As with most implementations, BFD is a compromise between several conflicting requirements. The major factor influencing BFD design was efficiency: any time used converting between formats is time which would not have been spent had BFD not been involved. This is partly offset by abstraction payback; since BFD simplifies applications and back ends, more time and care may be spent optimizing algorithms for a greater speed.

One minor artifact of the BFD solution which you should bear in mind is the potential for information loss.  There are two places where useful information can be lost using the BFD mechanism: during conversion and during output. See BFD information loss.

How it works: an outline of BFD
===============================

     [file bfdsumm.texi not included]

MRI Compatible Script Files
***************************

To aid users making the transition to GNU ld from the MRI linker, ld can use MRI compatible linker scripts as an alternative to the more general-purpose linker scripting language described in Command Language.  MRI compatible linker scripts have a much simpler command set than the scripting language otherwise used with ld.  GNU ld supports the most commonly used MRI linker commands; these commands are described here.

In general, MRI scripts aren't of much use with the a.out object file format, since it only has three sections and MRI scripts lack some features to make use of them.

You can specify a file containing an MRI-compatible script using the -c command-line option.

Each command in an MRI-compatible script occupies its own line; each command line starts with the keyword that identifies the command (though blank lines are also allowed for punctuation).  If a line of an MRI-compatible script begins with an unrecognized keyword, ld issues a warning message, but continues processing the script.

Lines beginning with * are comments.

You can write these commands using all upper-case letters, or all lower case; for example, chip is the same as CHIP. The following list shows only the upper-case form of each command.

ABSOLUTE SECNAME
ABSOLUTE SECNAME, SECNAME, ... SECNAME
     Normally, ld includes in the output file all sections from all the input files.  However, in an MRI-compatible script, you can use the ABSOLUTE command to restrict the sections that will be present in your output program.  If the ABSOLUTE command is used at all in a script, then only the sections named explicitly in ABSOLUTE commands will appear in the linker output.  You can still use other input sections (whatever you select on the command line, or using LOAD) to resolve addresses in the output file.

ALIAS OUT-SECNAME, IN-SECNAME
     Use this command to place the data from input section IN-SECNAME in a section called OUT-SECNAME in the linker output file.

     IN-SECNAME may be an integer.

ALIGN SECNAME = EXPRESSION
     Align the section called SECNAME to EXPRESSION.  The EXPRESSION should be a power of two.

BASE EXPRESSION
     Use the value of EXPRESSION as the lowest address (other than absolute addresses) in the output file.

CHIP EXPRESSION
CHIP EXPRESSION, EXPRESSION
     This command does nothing; it is accepted only for compatibility.

END
     This command does nothing whatever; it's only accepted for compatibility.

FORMAT OUTPUT-FORMAT
     Similar to the OUTPUT_FORMAT command in the more general linker language, but restricted to one of these output formats:

      1. S-records, if OUTPUT-FORMAT is S

      2. IEEE, if OUTPUT-FORMAT is IEEE

      3. COFF (the coff-m68k variant in BFD), if OUTPUT-FORMAT is COFF

LIST ANYTHING...
     Print (to the standard output file) a link map, as produced by the ld command-line option -M.

     The keyword LIST may be followed by anything on the same line, with no change in its effect.

LOAD FILENAME
LOAD FILENAME, FILENAME, ... FILENAME
     Include one or more object file FILENAME in the link; this has the same effect as specifying FILENAME directly on the ld command line.

NAME OUTPUT-NAME
     OUTPUT-NAME is the name for the program produced by ld; the MRI-compatible command NAME is equivalent to the command-line option -o or the general script language command OUTPUT.

ORDER SECNAME, SECNAME, ... SECNAME
ORDER SECNAME SECNAME SECNAME
     Normally, ld orders the sections in its output file in the order in which they first appear in the input files.  In an MRI-compatible script, you can override this ordering with the ORDER command.  The sections you list with ORDER will appear first in your output file, in the order specified.

PUBLIC NAME=EXPRESSION
PUBLIC NAME,EXPRESSION
PUBLIC NAME EXPRESSION
     Supply a value (EXPRESSION) for external symbol NAME used in the linker input files.

SECT SECNAME, EXPRESSION
SECT SECNAME=EXPRESSION
SECT SECNAME EXPRESSION
     You can use any of these three forms of the SECT command to specify the start address (EXPRESSION) for section SECNAME. If you have more than one SECT statement for the same SECNAME, only the first sets the start address.