mdadm: don't inherit autotools

mdadm doesn't use autotools at all:
- do_configure does nothing as it can't find configure.ac or configure
- do_compile is overridden to pass SYSROOT
- do_install is overridden but still calls autotools_do_install (which
  is just 'make install DESTDIR=$D') and then appended.

Clean this up by passing SYSROOT and STRIP in EXTRA_OEMAKE, removing the
now-obsolete do_compile(), and merging the do_install()s.

Signed-off-by: Ross Burton <ross.burton@arm.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

diff --git a/meta/recipes-extended/mdadm/mdadm_4.3.bb b/meta/recipes-extended/mdadm/mdadm_4.3.bb
index 63c61b68c96ceb50008211a871f2af57c6b86072..d90497d5a74581e60255e96ec32c7d2bfac934ff 100644 (file)
--- a/meta/recipes-extended/mdadm/mdadm_4.3.bb
+++ b/meta/recipes-extended/mdadm/mdadm_4.3.bb
@@ -28,7 +28,7 @@ SRC_URI = "${KERNELORG_MIRROR}/linux/utils/raid/mdadm/${BPN}-${PV}.tar.xz \
 
 SRC_URI[sha256sum] = "416727ae1f1080ea6e3090cea36dd076826fc369151e36ab736557ba92196f9f"
 
-inherit autotools-brokensep ptest systemd
+inherit ptest systemd
 
 DEPENDS = "udev"
 
@@ -44,30 +44,19 @@ CFLAGS:append:mipsarchn64 = ' -D__SANE_USERSPACE_TYPES__'
 CFLAGS:append:mipsarchn32 = ' -D__SANE_USERSPACE_TYPES__'
 
 EXTRA_OEMAKE = 'CHECK_RUN_DIR=0 CXFLAGS="${CFLAGS}" SYSTEMD_DIR=${systemd_system_unitdir} \
-                BINDIR="${base_sbindir}" UDEVDIR="${nonarch_base_libdir}/udev" LDFLAGS="${LDFLAGS}"'
+                BINDIR="${base_sbindir}" UDEVDIR="${nonarch_base_libdir}/udev" LDFLAGS="${LDFLAGS}" \
+                SYSROOT="${STAGING_DIR_TARGET}" STRIP='
 
 DEBUG_OPTIMIZATION:append = " -Wno-error"
 
-do_compile() {
-       oe_runmake SYSROOT="${STAGING_DIR_TARGET}"
-}
-
 do_install() {
-       export STRIP=""
-       autotools_do_install
-}
-
-do_install:append() {
+        oe_runmake 'DESTDIR=${D}' install install-systemd
         install -d ${D}/${sysconfdir}/
         install -m 644 ${S}/mdadm.conf-example ${D}${sysconfdir}/mdadm.conf
         install -d ${D}/${sysconfdir}/init.d
         install -m 755 ${UNPACKDIR}/mdadm.init ${D}${sysconfdir}/init.d/mdmonitor
 }
 
-do_install:append() {
-        oe_runmake install-systemd DESTDIR=${D}
-}
-
 do_compile_ptest() {
        oe_runmake test
 }