config/cfgroot/ids-functions.pl

   1 #!/usr/bin/perl -w
   2 ############################################################################
   3 #                                                                          #
   4 # This file is part of the IPFire Firewall.                                #
   5 #                                                                          #
   6 # IPFire is free software; you can redistribute it and/or modify           #
   7 # it under the terms of the GNU General Public License as published by     #
   8 # the Free Software Foundation; either version 2 of the License, or        #
   9 # (at your option) any later version.                                      #
  10 #                                                                          #
  11 # IPFire is distributed in the hope that it will be useful,                #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of           #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the            #
  14 # GNU General Public License for more details.                             #
  15 #                                                                          #
  16 # You should have received a copy of the GNU General Public License        #
  17 # along with IPFire; if not, write to the Free Software                    #
  18 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA #
  19 #                                                                          #
  20 # Copyright (C) 2018 IPFire Team <info@ipfire.org>.                        #
  21 #                                                                          #
  22 ############################################################################
  23
  24 package IDS;
  25
  26 require '/var/ipfire/general-functions.pl';
  27
  28 # Location where all config and settings files are stored.
  29 our $settingsdir = "${General::swroot}/suricata";
  30
  31 # Location and name of the tarball which contains the ruleset.
  32 our $rulestarball = "/var/tmp/idsrules.tar.gz";
  33
  34 # File to store any errors, which also will be read and displayed by the wui.
  35 our $storederrorfile = "/tmp/ids_storederror";
  36
  37 # Location where the rulefiles are stored.
  38 our $rulespath = "/var/lib/suricata";
  39
  40 # File which contains a list of all supported ruleset sources.
  41 # (Sourcefire, Emergingthreads, etc..)
  42 our $rulesetsourcesfile = "$settingsdir/ruleset-sources";
  43
  44 # The pidfile of the IDS.
  45 our $idspidfile = "/var/run/suricata.pid";
  46
  47 # Location of suricatactrl.
  48 my $suricatactrl = "/usr/local/bin/suricatactrl";
  49
  50 # Array with allowed commands of suricatactrl.
  51 my @suricatactrl_cmds = ( 'start', 'stop', 'restart', 'reload', 'fix-rules-dir', 'cron' );
  52
  53 # Array with supported cron intervals.
  54 my @cron_intervals = ('off', 'daily', 'weekly' );
  55
  56 #
  57 ## Function for checking if at least 300MB of free disk space are available
  58 ## on the "/var" partition.
  59 #
  60 sub checkdiskspace () {
  61         # Call diskfree to gather the free disk space of /var.
  62         my @df = `/bin/df -B M /var`;
  63
  64         # Loop through the output.
  65         foreach my $line (@df) {
  66                 # Ignore header line.
  67                 next if $line =~ m/^Filesystem/;
  68
  69                 # Search for a line with the device information.
  70                 if ($line =~ m/dev/ ) {
  71                         # Split the line into single pieces.
  72                         my @values = split(' ', $line);
  73                         my ($filesystem, $blocks, $used, $available, $used_perenctage, $mounted_on) = @values;
  74
  75                         # Check if the available disk space is more than 300MB.
  76                         if ($available < 300) {
  77                                 # Log error to syslog.
  78                                 &_log_to_syslog("Not enough free disk space on /var. Only $available MB from 300 MB available.");
  79
  80                                 # Exit function and return "1" - False.
  81                                 return 1;
  82                         }
  83                 }
  84         }
  85
  86         # Everything okay, return nothing.
  87         return;
  88 }
  89
  90 #
  91 ## This function is responsible for downloading the configured snort ruleset.
  92 ##
  93 ## * At first it obtains from the stored snortsettings which ruleset should be downloaded.
  94 ## * The next step is to get the download locations for all available rulesets.
  95 ## * After that, the function will check if an upstream proxy should be used and grab the settings.
  96 ## * The last step will be to generate the final download url, by obtaining the URL for the desired
  97 ##   ruleset, add the settings for the upstream proxy and final grab the rules tarball from the server.
  98 #
  99 sub downloadruleset {
 100         # Get snort settings.
 101         my %snortsettings=();
 102         &General::readhash("$settingsdir/settings", \%snortsettings);
 103
 104         # Check if a ruleset has been configured.
 105         unless($snortsettings{'RULES'}) {
 106                 # Log that no ruleset has been configured and abort.
 107                 &_log_to_syslog("No ruleset source has been configured.");
 108
 109                 # Return "1".
 110                 return 1;
 111         }
 112
 113         # Get all available ruleset locations.
 114         my %rulesetsources=();
 115         &General::readhash($rulesetsourcesfile, \%rulesetsources);
 116
 117         # Read proxysettings.
 118         my %proxysettings=();
 119         &General::readhash("${General::swroot}/proxy/settings", \%proxysettings);
 120
 121         # Load required perl module to handle the download.
 122         use LWP::UserAgent;
 123
 124         # Init the download module.
 125         my $downloader = LWP::UserAgent->new;
 126
 127         # Set timeout to 10 seconds.
 128         $downloader->timeout(10);
 129
 130         # Check if an upstream proxy is configured.
 131         if ($proxysettings{'UPSTREAM_PROXY'}) {
 132                 my ($peer, $peerport) = (/^(?:[a-zA-Z ]+\:\/\/)?(?:[A-Za-z0-9\_\.\-]*?(?:\:[A-Za-z0-9\_\.\-]*?)?\@)?([a-zA-Z0-9\.\_\-]*?)(?:\:([0-9]{1,5}))?(?:\/.*?)?$/);
 133                 my $proxy_url;
 134
 135                 # Check if we got a peer.
 136                 if ($peer) {
 137                         $proxy_url = "http://";
 138
 139                         # Check if the proxy requires authentication.
 140                         if (($proxysettings{'UPSTREAM_USER'}) && ($proxysettings{'UPSTREAM_PASSWORD'})) {
 141                                 $proxy_url .= "$proxysettings{'UPSTREAM_USER'}\:$proxysettings{'UPSTREAM_PASSWORD'}\@";
 142                         }
 143
 144                         # Add proxy server address and port.
 145                         $proxy_url .= "$peer\:$peerport";
 146                 } else {
 147                         # Log error message and break.
 148                         &_log_to_syslog("Could not proper configure the proxy server access.");
 149
 150                         # Return "1" - false.
 151                         return 1;
 152                 }
 153
 154                 # Setup proxy settings.
 155                 $downloader->proxy('http', $proxy_url);
 156         }
 157
 158         # Grab the right url based on the configured vendor.
 159         my $url = $rulesetsources{$snortsettings{'RULES'}};
 160
 161         # Check if the vendor requires an oinkcode and add it if needed.
 162         $url =~ s/\<oinkcode\>/$snortsettings{'OINKCODE'}/g;
 163
 164         # Abort if no url could be determined for the vendor.
 165         unless ($url) {
 166                 # Log error and abort.
 167                 &_log_to_syslog("Unable to gather a download URL for the selected ruleset.");
 168                 return 1;
 169         }
 170
 171         # Pass the requested url to the downloader.
 172         my $request = HTTP::Request->new(GET => $url);
 173
 174         # Perform the request and save the output into the "$rulestarball" file.
 175         my $response = $downloader->request($request, $rulestarball);
 176
 177         # Check if there was any error.
 178         unless ($response->is_success) {
 179                 # Obtain error.
 180                 my $error = $response->content;
 181
 182                 # Log error message.
 183                 &_log_to_syslog("Unable to download the ruleset. \($error\)");
 184
 185                 # Return "1" - false.
 186                 return 1;
 187         }
 188
 189         # If we got here, everything worked fine. Return nothing.
 190         return;
 191 }
 192
 193 #
 194 ## A tiny wrapper function to call the oinkmaster script.
 195 #
 196 sub oinkmaster () {
 197         # Check if the files in rulesdir have the correct permissions.
 198         &_check_rulesdir_permissions();
 199
 200         # Cleanup the rules directory before filling it with the new rulest.
 201         &_cleanup_rulesdir();
 202
 203         # Load perl module to talk to the kernel syslog.
 204         use Sys::Syslog qw(:DEFAULT setlogsock);
 205
 206         # Establish the connection to the syslog service.
 207         openlog('oinkmaster', 'cons,pid', 'user');
 208
 209         # Call oinkmaster to generate ruleset.
 210         open(OINKMASTER, "/usr/local/bin/oinkmaster.pl -v -s -u file://$rulestarball -C $settingsdir/oinkmaster.conf -o $rulespath|") or die "Could not execute oinkmaster $!\n";
 211
 212         # Log output of oinkmaster to syslog.
 213         while(<OINKMASTER>) {
 214                 # The syslog function works best with an array based input,
 215                 # so generate one before passing the message details to syslog.
 216                 my @syslog = ("INFO", "$_");
 217
 218                 # Send the log message.
 219                 syslog(@syslog);
 220         }
 221
 222         # Close the pipe to oinkmaster process.
 223         close(OINKMASTER);
 224
 225         # Close the log handle.
 226         closelog();
 227 }
 228
 229 #
 230 ## Function to do all the logging stuff if the downloading or updating of the ruleset fails.
 231 #
 232 sub log_error ($) {
 233         my ($error) = @_;
 234
 235         # Remove any newline.
 236         chomp($error);
 237
 238         # Call private function to log the error message to syslog.
 239         &_log_to_syslog($error);
 240
 241         # Call private function to write/store the error message in the storederrorfile.
 242         &_store_error_message($error);
 243 }
 244
 245 #
 246 ## Function to log a given error message to the kernel syslog.
 247 #
 248 sub _log_to_syslog ($) {
 249         my ($message) = @_;
 250
 251         # Load perl module to talk to the kernel syslog.
 252         use Sys::Syslog qw(:DEFAULT setlogsock);
 253
 254         # The syslog function works best with an array based input,
 255         # so generate one before passing the message details to syslog.
 256         my @syslog = ("ERR", "<ERROR> $message");
 257
 258         # Establish the connection to the syslog service.
 259         openlog('oinkmaster', 'cons,pid', 'user');
 260
 261         # Send the log message.
 262         syslog(@syslog);
 263
 264         # Close the log handle.
 265         closelog();
 266 }
 267
 268 #
 269 ## Private function to write a given error message to the storederror file.
 270 #
 271 sub _store_error_message ($) {
 272         my ($message) = @_;
 273
 274         # Remove any newline.
 275         chomp($message);
 276
 277         # Open file for writing.
 278         open (ERRORFILE, ">$storederrorfile") or die "Could not write to $storederrorfile. $!\n";
 279
 280         # Write error to file.
 281         print ERRORFILE "$message\n";
 282
 283         # Close file.
 284         close (ERRORFILE);
 285 }
 286
 287 #
 288 ## Function to get a list of all available network zones.
 289 #
 290 sub get_available_network_zones () {
 291         # Get netsettings.
 292         my %netsettings = ();
 293         &General::readhash("${General::swroot}/ethernet/settings", \%netsettings);
 294
 295         # Obtain the configuration type from the netsettings hash.
 296         my $config_type = $netsettings{'CONFIG_TYPE'};
 297
 298         # Hash which contains the conversation from the config mode
 299         # to the existing network interface names. They are stored like
 300         # an array.
 301         #
 302         # Mode "0" red is a modem and green
 303         # Mode "1" red is a netdev and green
 304         # Mode "2" red, green and orange
 305         # Mode "3" red, green and blue
 306         # Mode "4" red, green, blue, orange
 307         my %config_type_to_interfaces = (
 308                 "0" => [ "red", "green" ],
 309                 "1" => [ "red", "green" ],
 310                 "2" => [ "red", "green", "orange" ],
 311                 "3" => [ "red", "green", "blue" ],
 312                 "4" => [ "red", "green", "blue", "orange" ]
 313         );
 314
 315         # Obtain and dereference the corresponding network interaces based on the read
 316         # network config type.
 317         my @network_zones = @{ $config_type_to_interfaces{$config_type} };
 318
 319         # Return them.
 320         return @network_zones;
 321 }
 322
 323 #
 324 ## Function to check if the IDS is running.
 325 #
 326 sub ids_is_running () {
 327         if(-f $idspidfile) {
 328                 # Open PID file for reading.
 329                 open(PIDFILE, "$idspidfile") or die "Could not open $idspidfile. $!\n";
 330
 331                 # Grab the process-id.
 332                 my $pid = <PIDFILE>;
 333
 334                 # Close filehandle.
 335                 close(PIDFILE);
 336
 337                 # Remove any newline.
 338                 chomp($pid);
 339
 340                 # Check if a directory for the process-id exists in proc.
 341                 if(-d "/proc/$pid") {
 342                         # The IDS daemon is running return the process id.
 343                         return $pid;
 344                 }
 345         }
 346
 347         # Return nothing - IDS is not running.
 348         return;
 349 }
 350
 351 #
 352 ## Function to call suricatactrl binary with a given command.
 353 #
 354 sub call_suricatactrl ($) {
 355         # Get called option.
 356         my ($option, $interval) = @_;
 357
 358         # Loop through the array of supported commands and check if
 359         # the given one is part of it.
 360         foreach my $cmd (@suricatactrl_cmds) {
 361                 # Skip current command unless the given one has been found.
 362                 next unless($cmd eq $option);
 363
 364                 # Check if the given command is "cron".
 365                 if ($option eq "cron") {
 366                         # Check if an interval has been given.
 367                         if ($interval) {
 368                                 # Check if the given interval is valid.
 369                                 foreach my $element (@cron_intervals) {
 370                                         # Skip current element until the given one has been found.
 371                                         next unless($element eq $interval);
 372
 373                                         # Call the suricatactrl binary and pass the "cron" command
 374                                         # with the requrested interval.
 375                                         system("$suricatactrl $option $interval &>/dev/null");
 376
 377                                         # Return "1" - True.
 378                                         return 1;
 379                                 }
 380                         }
 381
 382                         # If we got here, the given interval is not supported or none has been given. - Return nothing.
 383                         return;
 384                 } else {
 385                         # Call the suricatactrl binary and pass the requrested
 386                         # option to it.
 387                         system("$suricatactrl $option &>/dev/null");
 388
 389                         # Return "1" - True.
 390                         return 1;
 391                 }
 392         }
 393
 394         # Command not found - return nothing.
 395         return;
 396 }
 397
 398 #
 399 ## Function to create a new empty file.
 400 #
 401 sub create_empty_file($) {
 402         my ($file) = @_;
 403
 404         # Check if the given file exists.
 405         if(-e $file) {
 406                 # Do nothing to prevent from overwriting existing files.
 407                 return;
 408         }
 409
 410         # Open the file for writing.
 411         open(FILE, ">$file") or die "Could not write to $file. $!\n";
 412
 413         # Close file handle.
 414         close(FILE);
 415
 416         # Return true.
 417         return 1;
 418 }
 419
 420 #
 421 ## Private function to check if the file permission of the rulespath are correct.
 422 ## If not, call suricatactrl to fix them.
 423 #
 424 sub _check_rulesdir_permissions() {
 425         # Check if the rulepath main directory is writable.
 426         unless (-W $rulespath) {
 427                 # If not call suricatctrl to fix it.
 428                 &call_suricatactrl("fix-rules-dir");
 429         }
 430
 431         # Open snort rules directory and do a directory listing.
 432         opendir(DIR, $rulespath) or die $!;
 433         # Loop through the direcory.
 434         while (my $file = readdir(DIR)) {
 435                 # We only want files.
 436                 next unless (-f "$rulespath/$file");
 437
 438                 # Check if the file is writable by the user.
 439                 if (-W "$rulespath/$file") {
 440                         # Everything is okay - go on to the next file.
 441                         next;
 442                 } else {
 443                         # There are wrong permissions, call suricatactrl to fix it.
 444                         &call_suricatactrl("fix-rules-dir");
 445                 }
 446         }
 447 }
 448
 449 #
 450 ## Private function to cleanup the directory which contains
 451 ## the IDS rules, before extracting and modifing the new ruleset.
 452 #
 453 sub _cleanup_rulesdir() {
 454         # Open rules directory and do a directory listing.
 455         opendir(DIR, $rulespath) or die $!;
 456
 457         # Loop through the direcory.
 458         while (my $file = readdir(DIR)) {
 459                 # We only want files.
 460                 next unless (-f "$rulespath/$file");
 461
 462                 # Skip element if it has config as file extension.
 463                 next if ($file =~ m/\.config$/);
 464
 465                 # Delete the current processed file, if not, exit this function
 466                 # and return an error message.
 467                 unlink("$rulespath/$file") or return "Could not delete $rulespath/$file. $!\n";
 468         }
 469
 470         # Return nothing;
 471         return;
 472 }
 473
 474 1;