config/firewall/rules.pl

   1 #!/usr/bin/perl -w
   2 ###############################################################################
   3 #                                                                             #
   4 # IPFire.org - A linux based firewall                                         #
   5 # Copyright (C) 2013 Alexander Marx <amarx@ipfire.org>                        #
   6 #                                                                             #
   7 # This program is free software: you can redistribute it and/or modify        #
   8 # it under the terms of the GNU General Public License as published by        #
   9 # the Free Software Foundation, either version 3 of the License, or           #
  10 # (at your option) any later version.                                         #
  11 #                                                                             #
  12 # This program is distributed in the hope that it will be useful,             #
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  15 # GNU General Public License for more details.                                #
  16 #                                                                             #
  17 # You should have received a copy of the GNU General Public License           #
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  19 #                                                                             #
  20 ###############################################################################
  21
  22 use strict;
  23
  24 require '/var/ipfire/general-functions.pl';
  25 require "${General::swroot}/lang.pl";
  26 require "/usr/lib/firewall/firewall-lib.pl";
  27
  28 # Set to one to enable debugging mode.
  29 my $DEBUG = 0;
  30
  31 my $IPTABLES = "iptables --wait";
  32
  33 # iptables chains
  34 my $CHAIN_INPUT           = "INPUTFW";
  35 my $CHAIN_FORWARD         = "FORWARDFW";
  36 my $CHAIN_OUTPUT          = "OUTGOINGFW";
  37 my $CHAIN                 = $CHAIN_FORWARD;
  38 my $CHAIN_NAT_SOURCE      = "NAT_SOURCE";
  39 my $CHAIN_NAT_DESTINATION = "NAT_DESTINATION";
  40 my $CHAIN_MANGLE_NAT_DESTINATION_FIX = "NAT_DESTINATION";
  41 my @VALID_CHAINS          = ($CHAIN_INPUT, $CHAIN_FORWARD, $CHAIN_OUTPUT);
  42 my @ANY_ADDRESSES         = ("0.0.0.0/0.0.0.0", "0.0.0.0/0", "0/0");
  43
  44 my @PROTOCOLS = ("tcp", "udp", "icmp", "igmp", "ah", "esp", "gre", "ipv6", "ipip");
  45 my @PROTOCOLS_WITH_PORTS = ("tcp", "udp");
  46
  47 my @VALID_TARGETS = ("ACCEPT", "DROP", "REJECT");
  48
  49 my %fwdfwsettings=();
  50 my %fwoptions = ();
  51 my %defaultNetworks=();
  52 my %configfwdfw=();;
  53 my %customgrp=();
  54 my %configinputfw=();
  55 my %configoutgoingfw=();
  56 my %confignatfw=();
  57 my @p2ps=();
  58
  59 my $configfwdfw         = "${General::swroot}/firewall/config";
  60 my $configinput     = "${General::swroot}/firewall/input";
  61 my $configoutgoing  = "${General::swroot}/firewall/outgoing";
  62 my $p2pfile                     = "${General::swroot}/firewall/p2protocols";
  63 my $configgrp           = "${General::swroot}/fwhosts/customgroups";
  64 my $netsettings         = "${General::swroot}/ethernet/settings";
  65
  66 &General::readhash("${General::swroot}/firewall/settings", \%fwdfwsettings);
  67 &General::readhash("${General::swroot}/optionsfw/settings", \%fwoptions);
  68 &General::readhash("$netsettings", \%defaultNetworks);
  69 &General::readhasharray($configfwdfw, \%configfwdfw);
  70 &General::readhasharray($configinput, \%configinputfw);
  71 &General::readhasharray($configoutgoing, \%configoutgoingfw);
  72 &General::readhasharray($configgrp, \%customgrp);
  73
  74 my @log_limit_options = &make_log_limit_options();
  75
  76 my $POLICY_INPUT_ALLOWED   = 0;
  77 my $POLICY_FORWARD_ALLOWED = ($fwdfwsettings{"POLICY"} eq "MODE2");
  78 my $POLICY_OUTPUT_ALLOWED  = ($fwdfwsettings{"POLICY1"} eq "MODE2");
  79
  80 my $POLICY_INPUT_ACTION    = $fwoptions{"FWPOLICY2"};
  81 my $POLICY_FORWARD_ACTION  = $fwoptions{"FWPOLICY"};
  82 my $POLICY_OUTPUT_ACTION   = $fwoptions{"FWPOLICY1"};
  83
  84 # MAIN
  85 &main();
  86
  87 sub main {
  88         # Flush all chains.
  89         &flush();
  90
  91         # Reload firewall rules.
  92         &preparerules();
  93
  94         # Load P2P block rules.
  95         &p2pblock();
  96
  97         # Reload firewall policy.
  98         run("/usr/sbin/firewall-policy");
  99 }
 100
 101 sub run {
 102         # Executes or prints the given shell command.
 103         my $command = shift;
 104
 105         if ($DEBUG) {
 106                 print "$command\n";
 107         } else {
 108                 system "$command";
 109
 110                 if ($?) {
 111                         print_error("ERROR: $command");
 112                 }
 113         }
 114 }
 115
 116 sub print_error {
 117         my $message = shift;
 118
 119         print STDERR "$message\n";
 120 }
 121
 122 sub print_rule {
 123         my $hash = shift;
 124
 125         print "\nRULE:";
 126
 127         my $i = 0;
 128         foreach (@$hash) {
 129                 printf("  %2d: %s", $i++, $_);
 130         }
 131         print "\n";
 132 }
 133
 134 sub flush {
 135         run("$IPTABLES -F $CHAIN_INPUT");
 136         run("$IPTABLES -F $CHAIN_FORWARD");
 137         run("$IPTABLES -F $CHAIN_OUTPUT");
 138         run("$IPTABLES -t nat -F $CHAIN_NAT_SOURCE");
 139         run("$IPTABLES -t nat -F $CHAIN_NAT_DESTINATION");
 140         run("$IPTABLES -t mangle -F $CHAIN_MANGLE_NAT_DESTINATION_FIX");
 141 }
 142
 143 sub preparerules {
 144         if (! -z  "${General::swroot}/firewall/input"){
 145                 &buildrules(\%configinputfw);
 146         }
 147         if (! -z  "${General::swroot}/firewall/outgoing"){
 148                 &buildrules(\%configoutgoingfw);
 149         }
 150         if (! -z  "${General::swroot}/firewall/config"){
 151                 &buildrules(\%configfwdfw);
 152         }
 153 }
 154
 155 sub buildrules {
 156         my $hash = shift;
 157
 158         # Search for targets that need to be specially handled when adding
 159         # forwarding rules. Additional rules will automatically get inserted
 160         # into the INPUT/OUTPUT chains for these targets.
 161         my @special_input_targets = ();
 162         if (!$POLICY_FORWARD_ALLOWED) {
 163                 push(@special_input_targets, "ACCEPT");
 164         }
 165
 166         if ($POLICY_INPUT_ACTION eq "DROP") {
 167                 push(@special_input_targets, "REJECT");
 168         } elsif ($POLICY_INPUT_ACTION eq "REJECT") {
 169                 push(@special_input_targets, "DROP");
 170         }
 171
 172         my @special_output_targets = ();
 173         if ($POLICY_OUTPUT_ALLOWED) {
 174                 push(@special_output_targets, ("DROP", "REJECT"));
 175         } else {
 176                 push(@special_output_targets, "ACCEPT");
 177
 178                 if ($POLICY_OUTPUT_ACTION eq "DROP") {
 179                         push(@special_output_targets, "REJECT");
 180                 } elsif ($POLICY_OUTPUT_ACTION eq "REJECT") {
 181                         push(@special_output_targets, "DROP");
 182                 }
 183         }
 184
 185         foreach my $key (sort {$a <=> $b} keys %$hash) {
 186                 # Skip disabled rules.
 187                 next unless ($$hash{$key}[2] eq 'ON');
 188
 189                 if ($DEBUG) {
 190                         print_rule($$hash{$key});
 191                 }
 192
 193                 # Check if the target is valid.
 194                 my $target = $$hash{$key}[0];
 195                 if (!$target ~~ @VALID_TARGETS) {
 196                         print_error("Invalid target '$target' for rule $key");
 197                         next;
 198                 }
 199
 200                 # Check if the chain is valid.
 201                 my $chain = $$hash{$key}[1];
 202                 if (!$chain ~~ @VALID_CHAINS) {
 203                         print_error("Invalid chain '$chain' in rule $key");
 204                         next;
 205                 }
 206
 207                 # Collect all sources.
 208                 my @sources = &fwlib::get_addresses($hash, $key, "src");
 209
 210                 # Collect all destinations.
 211                 my @destinations = &fwlib::get_addresses($hash, $key, "tgt");
 212
 213                 # True if the destination is the firewall itself.
 214                 my $destination_is_firewall = ($$hash{$key}[5] eq "ipfire");
 215
 216                 # Check if logging should be enabled.
 217                 my $LOG = ($$hash{$key}[17] eq 'ON');
 218
 219                 # Check if NAT is enabled and initialize variables, that we use for that.
 220                 my $NAT = ($$hash{$key}[28] eq 'ON');
 221                 my $NAT_MODE;
 222                 if ($NAT) {
 223                         $NAT_MODE = uc($$hash{$key}[31]);
 224                 }
 225
 226                 # Set up time constraints.
 227                 my @time_options = ();
 228                 if ($$hash{$key}[18] eq 'ON') {
 229                         push(@time_options, ("-m", "time"));
 230
 231                         # Select all days of the week this match is active.
 232                         my @weekdays = ();
 233                         if ($$hash{$key}[19] ne '') {
 234                                 push (@weekdays, "Mon");
 235                         }
 236                         if ($$hash{$key}[20] ne '') {
 237                                 push (@weekdays, "Tue");
 238                         }
 239                         if ($$hash{$key}[21] ne '') {
 240                                 push (@weekdays, "Wed");
 241                         }
 242                         if ($$hash{$key}[22] ne '') {
 243                                 push (@weekdays, "Thu");
 244                         }
 245                         if ($$hash{$key}[23] ne '') {
 246                                 push (@weekdays, "Fri");
 247                         }
 248                         if ($$hash{$key}[24] ne '') {
 249                                 push (@weekdays, "Sat");
 250                         }
 251                         if ($$hash{$key}[25] ne '') {
 252                                 push (@weekdays, "Sun");
 253                         }
 254                         if (@weekdays) {
 255                                 push(@time_options, ("--weekdays", join(",", @weekdays)));
 256                         }
 257
 258                         # Convert start time.
 259                         my $time_start = &format_time($$hash{$key}[26]);
 260                         if ($time_start) {
 261                                 push(@time_options, ("--timestart", $time_start));
 262                         }
 263
 264                         # Convert end time.
 265                         my $time_stop = &format_time($$hash{$key}[27]);
 266                         if ($time_stop) {
 267                                 push(@time_options, ("--timestop", $time_stop));
 268                         }
 269                 }
 270
 271                 # Check which protocols are used in this rule and so that we can
 272                 # later group rules by protocols.
 273                 my @protocols = &get_protocols($hash, $key);
 274                 if (!@protocols) {
 275                         print_error("Invalid protocol configuration for rule $key");
 276                         next;
 277                 }
 278
 279                 foreach my $protocol (@protocols) {
 280                         # Check if the given protocol is supported.
 281                         if (($protocol ne "all") && (!$protocol ~~ @PROTOCOLS)) {
 282                                 print_error("Protocol $protocol is not supported (rule $key)");
 283                                 next;
 284                         }
 285
 286                         # Prepare protocol options (like ICMP types, ports, etc...).
 287                         my @protocol_options = &get_protocol_options($hash, $key, $protocol, 0);
 288
 289                         # Check if this protocol knows ports.
 290                         my $protocol_has_ports = ($protocol ~~ @PROTOCOLS_WITH_PORTS);
 291
 292                         foreach my $src (@sources) {
 293                                 # Skip invalid source.
 294                                 next unless (@$src[0]);
 295
 296                                 # Sanitize source.
 297                                 my $source = @$src[0];
 298                                 if ($source ~~ @ANY_ADDRESSES) {
 299                                         $source = "";
 300                                 }
 301
 302                                 my $source_intf = @$src[1];
 303
 304                                 foreach my $dst (@destinations) {
 305                                         # Skip invalid rules.
 306                                         next if (!@$dst[0] || (@$dst[0] eq "none"));
 307
 308                                         # Sanitize destination.
 309                                         my $destination = @$dst[0];
 310                                         if ($destination ~~ @ANY_ADDRESSES) {
 311                                                 $destination = "";
 312                                         }
 313
 314                                         my $destination_intf = @$dst[1];
 315
 316                                         # Array with iptables arguments.
 317                                         my @options = ();
 318
 319                                         # Append protocol.
 320                                         if ($protocol ne "all") {
 321                                                 push(@options, @protocol_options);
 322                                         }
 323
 324                                         # Prepare source options.
 325                                         my @source_options = ();
 326                                         if ($source =~ /mac/) {
 327                                                 push(@source_options, $source);
 328                                         } elsif ($source) {
 329                                                 push(@source_options, ("-s", $source));
 330                                         }
 331
 332                                         if ($source_intf) {
 333                                                 push(@source_options, ("-i", $source_intf));
 334                                         }
 335
 336                                         # Prepare destination options.
 337                                         my @destination_options = ();
 338                                         if ($destination) {
 339                                                 push(@destination_options, ("-d", $destination));
 340                                         }
 341
 342                                         if ($destination_intf) {
 343                                                 push(@destination_options, ("-o", $destination_intf));
 344                                         }
 345
 346                                         # Add time constraint options.
 347                                         push(@options, @time_options);
 348
 349                                         my $firewall_is_in_source_subnet = 1;
 350                                         if ($source) {
 351                                                 $firewall_is_in_source_subnet = &firewall_is_in_subnet($source);
 352                                         }
 353
 354                                         my $firewall_is_in_destination_subnet = 1;
 355                                         if ($destination) {
 356                                                 $firewall_is_in_destination_subnet = &firewall_is_in_subnet($destination);
 357                                         }
 358
 359                                         # Process NAT rules.
 360                                         if ($NAT) {
 361                                                 my $nat_address = &fwlib::get_nat_address($$hash{$key}[29], $source);
 362
 363                                                 # Skip NAT rules if the NAT address is unknown
 364                                                 # (i.e. no internet connection has been established, yet).
 365                                                 next unless ($nat_address);
 366
 367                                                 # Destination NAT
 368                                                 if ($NAT_MODE eq "DNAT") {
 369                                                         my @nat_options = ();
 370                                                         if ($protocol ne "all") {
 371                                                                 my @nat_protocol_options = &get_protocol_options($hash, $key, $protocol, 1);
 372                                                                 push(@nat_options, @nat_protocol_options);
 373                                                         }
 374                                                         push(@nat_options, @time_options);
 375
 376                                                         # Make port-forwardings useable from the internal networks.
 377                                                         my @internal_addresses = &fwlib::get_internal_firewall_ip_addresses(1);
 378                                                         unless ($nat_address ~~ @internal_addresses) {
 379                                                                 &add_dnat_mangle_rules($nat_address, $source_intf, @nat_options);
 380                                                         }
 381
 382                                                         push(@nat_options, @source_options);
 383                                                         push(@nat_options, ("-d", $nat_address));
 384
 385                                                         my $dnat_port;
 386                                                         if ($protocol_has_ports) {
 387                                                                 $dnat_port = &get_dnat_target_port($hash, $key);
 388                                                         }
 389
 390                                                         my @nat_action_options = ();
 391
 392                                                         # Use iptables REDIRECT
 393                                                         my $use_redirect = ($destination_is_firewall && !$destination && $protocol_has_ports && $dnat_port);
 394                                                         if ($use_redirect) {
 395                                                                 push(@nat_action_options, ("-j", "REDIRECT", "--to-ports", $dnat_port));
 396
 397                                                         # Use iptables DNAT
 398                                                         } else {
 399                                                                 if ($destination_is_firewall && !$destination) {
 400                                                                         $destination = &fwlib::get_external_address();
 401                                                                 }
 402                                                                 next unless ($destination);
 403
 404                                                                 my ($dnat_address, $dnat_mask) = split("/", $destination);
 405                                                                 @destination_options = ("-d", $dnat_address);
 406
 407                                                                 if ($protocol_has_ports) {
 408                                                                         my $dnat_port = &get_dnat_target_port($hash, $key);
 409
 410                                                                         if ($dnat_port) {
 411                                                                                 $dnat_address .= ":$dnat_port";
 412                                                                         }
 413                                                                 }
 414
 415                                                                 push(@nat_action_options, ("-j", "DNAT", "--to-destination", $dnat_address));
 416                                                         }
 417
 418                                                         if ($LOG) {
 419                                                                 run("$IPTABLES -t nat -A $CHAIN_NAT_DESTINATION @nat_options @log_limit_options -j LOG --log-prefix 'DNAT '");
 420                                                         }
 421                                                         run("$IPTABLES -t nat -A $CHAIN_NAT_DESTINATION @nat_options @nat_action_options");
 422
 423                                                 # Source NAT
 424                                                 } elsif ($NAT_MODE eq "SNAT") {
 425                                                         my @nat_options = @options;
 426
 427                                                         push(@nat_options, @source_options);
 428                                                         push(@nat_options, @destination_options);
 429
 430                                                         if ($LOG) {
 431                                                                 run("$IPTABLES -t nat -A $CHAIN_NAT_SOURCE @nat_options @log_limit_options -j LOG --log-prefix 'SNAT '");
 432                                                         }
 433                                                         run("$IPTABLES -t nat -A $CHAIN_NAT_SOURCE @nat_options -j SNAT --to-source $nat_address");
 434                                                 }
 435                                         }
 436
 437                                         push(@options, @source_options);
 438                                         push(@options, @destination_options);
 439
 440                                         # Insert firewall rule.
 441                                         if ($LOG && !$NAT) {
 442                                                 run("$IPTABLES -A $chain @options @log_limit_options -j LOG --log-prefix '$chain '");
 443                                         }
 444                                         run("$IPTABLES -A $chain @options -j $target");
 445
 446                                         # Handle forwarding rules and add corresponding rules for firewall access.
 447                                         if ($chain eq $CHAIN_FORWARD) {
 448                                                 # If the firewall is part of the destination subnet and access to the destination network
 449                                                 # is granted/forbidden for any network that the firewall itself is part of, we grant/forbid access
 450                                                 # for the firewall, too.
 451                                                 if ($firewall_is_in_destination_subnet && ($target ~~ @special_input_targets)) {
 452                                                         if ($LOG && !$NAT) {
 453                                                                 run("$IPTABLES -A $CHAIN_INPUT @options @log_limit_options -j LOG --log-prefix '$CHAIN_INPUT '");
 454                                                         }
 455                                                         run("$IPTABLES -A $CHAIN_INPUT @options -j $target");
 456                                                 }
 457
 458                                                 # Likewise.
 459                                                 if ($firewall_is_in_source_subnet && ($target ~~ @special_output_targets)) {
 460                                                         if ($LOG && !$NAT) {
 461                                                                 run("$IPTABLES -A $CHAIN_OUTPUT @options @log_limit_options -j LOG --log-prefix '$CHAIN_OUTPUT '");
 462                                                         }
 463                                                         run("$IPTABLES -A $CHAIN_OUTPUT @options -j $target");
 464                                                 }
 465                                         }
 466                                 }
 467                         }
 468                 }
 469         }
 470 }
 471
 472 # Formats the given timestamp into the iptables format which is "hh:mm" UTC.
 473 sub format_time {
 474         my $val = shift;
 475
 476         # Convert the given time into minutes.
 477         my $minutes = &time_convert_to_minutes($val);
 478
 479         # Move the timestamp into UTC.
 480         $minutes += &time_utc_offset();
 481
 482         # Make sure $minutes is between 00:00 and 23:59.
 483         if ($minutes < 0) {
 484                 $minutes += 1440;
 485         }
 486
 487         if ($minutes > 1440) {
 488                 $minutes -= 1440;
 489         }
 490
 491         # Format as hh:mm.
 492         return sprintf("%02d:%02d", $minutes / 60, $minutes % 60);
 493 }
 494
 495 # Calculates the offsets in minutes from the local timezone to UTC.
 496 sub time_utc_offset {
 497         my @localtime = localtime(time);
 498         my @gmtime = gmtime(time);
 499
 500         return ($gmtime[2] * 60 + $gmtime[1] % 60) - ($localtime[2] * 60 + $localtime[1] % 60);
 501 }
 502
 503 # Takes a timestamp like "14:00" and converts it into minutes since midnight.
 504 sub time_convert_to_minutes {
 505         my ($hrs, $min) = split(":", shift);
 506
 507         return ($hrs * 60) + $min;
 508 }
 509
 510 sub p2pblock {
 511         my $search_action;
 512         my $target;
 513
 514         if ($fwdfwsettings{"POLICY"} eq "MODE1") {
 515                 $search_action = "on";
 516                 $target = "ACCEPT";
 517         } else {
 518                 $search_action = "off";
 519                 $target = "DROP";
 520         }
 521
 522         open(FILE, "<$p2pfile") or die "Unable to read $p2pfile";
 523         my @protocols = ();
 524         foreach my $p2pentry (<FILE>) {
 525                 my @p2pline = split(/\;/, $p2pentry);
 526                 next unless ($p2pline[2] eq $search_action);
 527
 528                 push(@protocols, "--$p2pline[1]");
 529         }
 530         close(FILE);
 531
 532         if (@protocols) {
 533                 run("$IPTABLES -A FORWARDFW -m ipp2p @protocols -j $target");
 534         }
 535 }
 536
 537 sub get_protocols {
 538         my $hash = shift;
 539         my $key = shift;
 540
 541         my $uses_source_ports = ($$hash{$key}[7] eq "ON");
 542         my $uses_services = ($$hash{$key}[11] eq "ON");
 543
 544         my @protocols = ();
 545
 546         # Rules which don't have source ports or services (like ICMP, ESP, ...).
 547         if (!$uses_source_ports && !$uses_services) {
 548                 push(@protocols, $$hash{$key}[8]);
 549
 550         # Rules which either use ports or services.
 551         } elsif ($uses_source_ports || $uses_services) {
 552                 # Check if service group or service
 553                 if ($$hash{$key}[14] eq 'cust_srv') {
 554                         push(@protocols, &fwlib::get_srv_prot($$hash{$key}[15]));
 555
 556                 } elsif($$hash{$key}[14] eq 'cust_srvgrp'){
 557                         my $protos = &fwlib::get_srvgrp_prot($$hash{$key}[15]);
 558                         push(@protocols, split(",", $protos));
 559
 560                 } else {
 561                         # Fetch the protocol for this rule.
 562                         my $protocol = lc($$hash{$key}[8]);
 563
 564                         # Fetch source and destination ports for this rule.
 565                         my $source_ports = $$hash{$key}[10];
 566                         my $destination_ports = $$hash{$key}[15];
 567
 568                         # Check if ports are set for protocols which do not support ports.
 569                         if (!($protocol ~~ @PROTOCOLS_WITH_PORTS) && ($source_ports || $destination_ports)) {
 570                                 print_error("$protocol does not support ports");
 571                                 return ();
 572                         }
 573
 574                         push(@protocols, $protocol);
 575                 }
 576         }
 577
 578         # Remove all empty elements
 579         @protocols = map { $_ ? $_ : () } @protocols;
 580
 581         # If no protocol has been defined, we assume "all".
 582         if (!@protocols) {
 583                 push(@protocols, "all");
 584         }
 585
 586         # Make all protocol names lowercase.
 587         @protocols = map { lc } @protocols;
 588
 589         return @protocols;
 590 }
 591
 592 sub get_protocol_options {
 593         my $hash = shift;
 594         my $key  = shift;
 595         my $protocol = shift;
 596         my $nat_options_wanted = shift;
 597         my @options = ();
 598
 599         # Nothing to do if no protocol is specified.
 600         if ($protocol eq "all") {
 601                 return @options;
 602         } else {
 603                 push(@options, ("-p", $protocol));
 604         }
 605
 606         if ($protocol ~~ @PROTOCOLS_WITH_PORTS) {
 607                 # Process source ports.
 608                 my $use_src_ports = ($$hash{$key}[7] eq "ON");
 609                 my $src_ports     = $$hash{$key}[10];
 610
 611                 if ($use_src_ports && $src_ports) {
 612                         push(@options, &format_ports($src_ports, "src"));
 613                 }
 614
 615                 # Process destination ports.
 616                 my $use_dst_ports  = ($$hash{$key}[11] eq "ON");
 617                 my $use_dnat       = (($$hash{$key}[28] eq "ON") && ($$hash{$key}[31] eq "dnat"));
 618
 619                 if ($use_dst_ports) {
 620                         my $dst_ports_mode = $$hash{$key}[14];
 621                         my $dst_ports      = $$hash{$key}[15];
 622
 623                         if (($dst_ports_mode eq "TGT_PORT") && $dst_ports) {
 624                                 if ($nat_options_wanted && $use_dnat && $$hash{$key}[30]) {
 625                                         $dst_ports = $$hash{$key}[30];
 626                                 }
 627                                 push(@options, &format_ports($dst_ports, "dst"));
 628
 629                         } elsif ($dst_ports_mode eq "cust_srv") {
 630                                 if ($protocol eq "ICMP") {
 631                                         push(@options, ("--icmp-type", &fwlib::get_srv_port($dst_ports, 3, "ICMP")));
 632                                 } else {
 633                                         $dst_ports = &fwlib::get_srv_port($dst_ports, 1, uc($protocol));
 634                                         push(@options, &format_ports($dst_ports, "dst"));
 635                                 }
 636
 637                         } elsif ($dst_ports_mode eq "cust_srvgrp") {
 638                                 push(@options, &fwlib::get_srvgrp_port($dst_ports, uc($protocol)));
 639                         }
 640                 }
 641         }
 642
 643         # Check if a single ICMP type is selected.
 644         if ($protocol eq "icmp") {
 645                 my $icmp_type = $$hash{$key}[9];
 646
 647                 if (($icmp_type ne "All ICMP-Types") && $icmp_type) {
 648                         push(@options, ("--icmp-type", $icmp_type));
 649                 }
 650         }
 651
 652         return @options;
 653 }
 654
 655 sub format_ports {
 656         my $ports = shift;
 657         my $type = shift;
 658
 659         my $arg;
 660         if ($type eq "src") {
 661                 $arg = "--sport";
 662         } elsif ($type eq "dst") {
 663                 $arg = "--dport";
 664         }
 665
 666         my @options = ();
 667
 668         if ($ports =~ /\|/) {
 669                 $ports =~ s/\|/,/g;
 670                 push(@options, ("-m", "multiport"));
 671         }
 672
 673         if ($ports) {
 674                 push(@options, ($arg, $ports));
 675         }
 676
 677         return @options;
 678 }
 679
 680 sub get_dnat_target_port {
 681         my $hash = shift;
 682         my $key  = shift;
 683
 684         if ($$hash{$key}[14] eq "TGT_PORT") {
 685                 my $port = $$hash{$key}[15];
 686                 my $external_port = $$hash{$key}[30];
 687
 688                 if ($external_port && ($port ne $external_port)) {
 689                         return $$hash{$key}[15];
 690                 }
 691         }
 692 }
 693
 694 sub add_dnat_mangle_rules {
 695         my $nat_address = shift;
 696         my $interface = shift;
 697         my @options = @_;
 698
 699         my $mark = 0;
 700         foreach my $zone ("GREEN", "BLUE", "ORANGE") {
 701                 $mark++;
 702
 703                 # Skip rule if not all required information exists.
 704                 next unless (exists $defaultNetworks{$zone . "_NETADDRESS"});
 705                 next unless (exists $defaultNetworks{$zone . "_NETMASK"});
 706
 707                 next if ($interface && $interface ne $defaultNetworks{$zone . "_DEV"});
 708
 709                 my @mangle_options = @options;
 710
 711                 my $netaddress = $defaultNetworks{$zone . "_NETADDRESS"};
 712                 $netaddress .= "/" . $defaultNetworks{$zone . "_NETMASK"};
 713
 714                 push(@mangle_options, ("-s", $netaddress, "-d", $nat_address));
 715                 push(@mangle_options, ("-j", "MARK", "--set-mark", $mark));
 716
 717                 run("$IPTABLES -t mangle -A $CHAIN_MANGLE_NAT_DESTINATION_FIX @mangle_options");
 718         }
 719 }
 720
 721 sub make_log_limit_options {
 722         my @options = ("-m", "limit");
 723
 724         # Maybe we should get this from the configuration.
 725         my $limit = 10;
 726
 727         # We limit log messages to $limit messages per minute.
 728         push(@options, ("--limit", "$limit/min"));
 729
 730         # And we allow bursts of 2x $limit.
 731         push(@options, ("--limit-burst", $limit * 2));
 732
 733         return @options;
 734 }
 735
 736 sub firewall_is_in_subnet {
 737         my $subnet = shift;
 738
 739         # ORANGE is missing here, because nothing may ever access
 740         # the firewall from this network.
 741         my $address = &fwlib::get_internal_firewall_ip_address($subnet, 0);
 742
 743         if ($address) {
 744                 return 1;
 745         }
 746
 747         return 0;
 748 }