location: Create a page that explains how to report problems

[ipfire.org.git] / configure.ac

AC_PREREQ([2.64])

AC_INIT([ipfire.org],
	[000],
	[michael.tremer@ipfire.org],
	[ipfire.org],
	[https://www.ipfire.org/])

AC_CONFIG_AUX_DIR([build-aux])

AC_PREFIX_DEFAULT([/usr])

AM_INIT_AUTOMAKE([
	foreign
	1.11
	-Wall
	-Wno-portability
	silent-rules
	tar-pax
	subdir-objects
])
AM_SILENT_RULES([yes])

AC_PROG_LN_S
AC_PROG_MKDIR_P
AC_PROG_SED

# Python
AM_PATH_PYTHON([3.4])

# scss
AC_CHECK_PROG(SASSC, [sassc], [sassc])
if test -z "${SASSC}"; then
	AC_MSG_ERROR([sassc is required])
fi

# convert from ImageMagick
AC_CHECK_PROG(CONVERT, [convert], [convert])
if test -z "${CONVERT}"; then
	AC_MSG_ERROR([convert is required])
fi

# ------------------------------------------------------------------------------

AC_ARG_WITH([systemd],
	AS_HELP_STRING([--with-systemd], [Enable systemd support.])
)

AS_IF([test "x$with_systemd" != "xno"],
      [PKG_CHECK_MODULES(systemd, [libsystemd],
      [have_systemd=yes], [have_systemd=no])],
      [have_systemd=no]
)

AS_IF([test "x$have_systemd" = "xyes"],
      [AC_MSG_CHECKING([for systemd system unit directory])
	AC_ARG_WITH([systemdsystemunitdir],
		AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
		[], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)]
	)

	AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])

	if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
		AC_MSG_RESULT([$systemdsystemunitdir])
	else
		AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
	fi
      ],
      [AS_IF([test "x$with_systemd" = "xyes"],
             [AC_MSG_ERROR([Systemd support is enabled but no systemd has been found.])
      ])
])

AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" = "xyes"])

datadir="${datadir}/ipfire.org"
localedir="${datadir}/translations"

AC_CONFIG_FILES([
	Makefile
])

AC_OUTPUT
AC_MSG_RESULT([
	${PACKAGE_NAME} ${VERSION}

	prefix:			${prefix}
	sysconfdir:		${sysconfdir}
	datadir:		${datadir}
	localedir:		${localedir}

	systemd support		${have_systemd}
	Python version:		${PYTHON_VERSION}
])