configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT([libloc],
   3         [0.9.1],
   4         [michael.tremer@ipfire.org],
   5         [libloc],
   6         [https://www.ipfire.org/])
   7
   8 AC_CONFIG_SRCDIR([src/libloc.c])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AM_INIT_AUTOMAKE([
  11         foreign
  12         1.11
  13         -Wall
  14         -Wno-portability
  15         silent-rules
  16         tar-pax
  17         no-dist-gzip
  18         dist-xz
  19         subdir-objects
  20 ])
  21 AC_PROG_CC_STDC
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AM_SILENT_RULES([yes])
  26 LT_INIT([
  27         disable-static
  28         pic-only
  29 ])
  30 AC_PREFIX_DEFAULT([/usr])
  31 gl_LD_VERSION_SCRIPT
  32
  33 IT_PROG_INTLTOOL([0.40.0])
  34 GETTEXT_PACKAGE=${PACKAGE_TARNAME}
  35 AC_SUBST(GETTEXT_PACKAGE)
  36
  37 AC_PROG_SED
  38 AC_PROG_MKDIR_P
  39
  40 # - man ------------------------------------------------------------------------
  41
  42 have_manpages=no
  43 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-man-pages],
  44         [do not install man pages]))
  45 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
  46 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
  47
  48 AC_PATH_PROG([XSLTPROC], [xsltproc])
  49
  50 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
  51 if test "${have_manpages}" = "yes" && test -z "${ASCIIDOC}"; then
  52         AC_MSG_ERROR([Required program 'asciidoc' not found])
  53 fi
  54 # - debug ----------------------------------------------------------------------
  55
  56 AC_ARG_ENABLE([debug],
  57         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  58         [], [enable_debug=no])
  59 AS_IF([test "x$enable_debug" = "xyes"], [
  60         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  61 ])
  62
  63 AC_CHECK_HEADERS_ONCE([
  64         arpa/inet.h \
  65         arpa/nameser.h \
  66         arpa/nameser_compat.h \
  67         endian.h \
  68         netinet/in.h \
  69     resolv.h \
  70         string.h \
  71 ])
  72
  73 AC_CHECK_FUNCS([ \
  74     be16toh \
  75     be32toh \
  76     be64toh \
  77     htobe16 \
  78     htobe32 \
  79     htobe64 \
  80     mmap \
  81     munmap \
  82     res_query \
  83         __secure_getenv \
  84         secure_getenv \
  85     qsort \
  86 ])
  87
  88 my_CFLAGS="\
  89 -Wall \
  90 -Wchar-subscripts \
  91 -Wformat-security \
  92 -Wmissing-declarations \
  93 -Wmissing-prototypes \
  94 -Wnested-externs \
  95 -Wpointer-arith \
  96 -Wshadow \
  97 -Wsign-compare \
  98 -Wstrict-prototypes \
  99 -Wtype-limits \
 100 "
 101 AC_SUBST([my_CFLAGS])
 102
 103 # ------------------------------------------------------------------------------
 104
 105 AC_ARG_WITH([systemd],
 106         AS_HELP_STRING([--with-systemd], [Enable systemd support.])
 107 )
 108
 109 AS_IF([test "x$with_systemd" != "xno"],
 110       [PKG_CHECK_MODULES(systemd, [libsystemd],
 111       [have_systemd=yes], [have_systemd=no])],
 112       [have_systemd=no]
 113 )
 114
 115 AS_IF([test "x$have_systemd" = "xyes"],
 116       [AC_MSG_CHECKING([for systemd system unit directory])
 117         AC_ARG_WITH([systemdsystemunitdir],
 118                 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 119                 [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)]
 120         )
 121
 122         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 123
 124         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
 125                 AC_MSG_RESULT([$systemdsystemunitdir])
 126         else
 127                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
 128         fi
 129       ],
 130       [AS_IF([test "x$with_systemd" = "xyes"],
 131              [AC_MSG_ERROR([Systemd support is enabled but no systemd has been found.])
 132       ])
 133 ])
 134
 135 AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" = "xyes"])
 136
 137 # ------------------------------------------------------------------------------
 138
 139 # Python
 140 AM_PATH_PYTHON([3.4])
 141 PKG_CHECK_MODULES([PYTHON], [python-${PYTHON_VERSION}])
 142
 143 # Perl
 144 AC_PATH_PROG(PERL, perl, no)
 145 AC_SUBST(PERL)
 146
 147 AX_PROG_PERL_MODULES(ExtUtils::MakeMaker,, AC_MSG_WARN(Need some Perl modules))
 148
 149 AC_ARG_ENABLE(perl, AS_HELP_STRING([--disable-perl], [do not build the perl modules]), [],[enable_perl=yes])
 150 AM_CONDITIONAL(ENABLE_PERL, test "$enable_perl" = "yes")
 151
 152 dnl Checking for libresolv
 153 case "${host}" in
 154         *-gnu*)
 155                 AC_CHECK_LIB(resolv, ns_msg_getflag, [LIBS="-lresolv $LIBS"], AC_MSG_ERROR([libresolv has not been found]), -lresolv)
 156                 ;;
 157         *)
 158                 AC_CHECK_LIB(resolv, res_init, [LIBS="-lresolv $LIBS"], AC_MSG_ERROR([libresolv has not been found]), -lresolv)
 159                 ;;
 160 esac
 161 RESOLV_LIBS="${LIBS}"
 162 AC_SUBST(RESOLV_LIBS)
 163
 164 dnl Checking for OpenSSL
 165 LIBS=
 166 AC_CHECK_LIB(crypto, EVP_EncryptInit,, AC_MSG_ERROR([libcrypto has not been found]))
 167 OPENSSL_LIBS="${LIBS}"
 168 AC_SUBST(OPENSSL_LIBS)
 169
 170 AC_CONFIG_HEADERS(config.h)
 171 AC_CONFIG_FILES([
 172         Makefile
 173         po/Makefile.in
 174 ])
 175
 176 AC_OUTPUT
 177 AC_MSG_RESULT([
 178         $PACKAGE $VERSION
 179         =====
 180
 181         prefix:                 ${prefix}
 182         sysconfdir:             ${sysconfdir}
 183         libdir:                 ${libdir}
 184         includedir:             ${includedir}
 185
 186         compiler:               ${CC}
 187         cflags:                 ${CFLAGS}
 188         ldflags:                ${LDFLAGS}
 189
 190         debug:                  ${enable_debug}
 191         systemd support:        ${have_systemd}
 192
 193         Bindings:
 194           perl:                 ${enable_perl}
 195 ])