scripts/checkstack.pl

   1 #!/usr/bin/perl
   2
   3 #       Check the stack usage of functions
   4 #
   5 #       Copyright Joern Engel <joern@lazybastard.org>
   6 #       Inspired by Linus Torvalds
   7 #       Original idea maybe from Keith Owens
   8 #       s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
   9 #       Mips port by Juan Quintela <quintela@mandrakesoft.com>
  10 #       IA64 port via Andreas Dilger
  11 #       Arm port by Holger Schurig
  12 #       sh64 port by Paul Mundt
  13 #       Random bits by Matt Mackall <mpm@selenic.com>
  14 #       M68k port by Geert Uytterhoeven and Andreas Schwab
  15 #       AArch64, PARISC ports by Kyle McMartin
  16 #       sparc port by Martin Habets <errandir_news@mph.eclipse.co.uk>
  17 #
  18 #       Usage:
  19 #       objdump -d vmlinux | scripts/checkstack.pl [arch]
  20 #
  21 #       TODO :  Port to all architectures (one regex per arch)
  22
  23 use strict;
  24
  25 # check for arch
  26 #
  27 # $re is used for two matches:
  28 # $& (whole re) matches the complete objdump line with the stack growth
  29 # $1 (first bracket) matches the size of the stack growth
  30 #
  31 # $dre is similar, but for dynamic stack redutions:
  32 # $& (whole re) matches the complete objdump line with the stack growth
  33 # $1 (first bracket) matches the dynamic amount of the stack growth
  34 #
  35 # use anything else and feel the pain ;)
  36 my (@stack, $re, $dre, $x, $xs, $funcre);
  37 {
  38         my $arch = shift;
  39         if ($arch eq "") {
  40                 $arch = `uname -m`;
  41                 chomp($arch);
  42         }
  43
  44         $x      = "[0-9a-f]";   # hex character
  45         $xs     = "[0-9a-f ]";  # hex character or space
  46         $funcre = qr/^$x* <(.*)>:$/;
  47         if ($arch eq 'aarch64') {
  48                 #ffffffc0006325cc:       a9bb7bfd        stp     x29, x30, [sp,#-80]!
  49                 $re = qr/^.*stp.*sp,\#-([0-9]{1,8})\]\!/o;
  50         } elsif ($arch eq 'arm') {
  51                 #c0008ffc:      e24dd064        sub     sp, sp, #100    ; 0x64
  52                 $re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o;
  53         } elsif ($arch =~ /^x86(_64)?$/ || $arch =~ /^i[3456]86$/) {
  54                 #c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
  55                 # or
  56                 #    2f60:    48 81 ec e8 05 00 00       sub    $0x5e8,%rsp
  57                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%(e|r)sp$/o;
  58                 $dre = qr/^.*[as][du][db]    (%.*),\%(e|r)sp$/o;
  59         } elsif ($arch eq 'ia64') {
  60                 #e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
  61                 $re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
  62         } elsif ($arch eq 'm68k') {
  63                 #    2b6c:       4e56 fb70       linkw %fp,#-1168
  64                 #  1df770:       defc ffe4       addaw #-28,%sp
  65                 $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
  66         } elsif ($arch eq 'metag') {
  67                 #400026fc:       40 00 00 82     ADD       A0StP,A0StP,#0x8
  68                 $re = qr/.*ADD.*A0StP,A0StP,\#(0x$x{1,8})/o;
  69                 $funcre = qr/^$x* <[^\$](.*)>:$/;
  70         } elsif ($arch eq 'mips64') {
  71                 #8800402c:       67bdfff0        daddiu  sp,sp,-16
  72                 $re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  73         } elsif ($arch eq 'mips') {
  74                 #88003254:       27bdffe0        addiu   sp,sp,-32
  75                 $re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  76         } elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
  77                 $re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
  78         } elsif ($arch eq 'ppc') {
  79                 #c00029f4:       94 21 ff 30     stwu    r1,-208(r1)
  80                 $re = qr/.*stwu.*r1,-($x{1,8})\(r1\)/o;
  81         } elsif ($arch eq 'ppc64') {
  82                 #XXX
  83                 $re = qr/.*stdu.*r1,-($x{1,8})\(r1\)/o;
  84         } elsif ($arch eq 'powerpc') {
  85                 $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
  86         } elsif ($arch =~ /^s390x?$/) {
  87                 #   11160:       a7 fb ff 60             aghi   %r15,-160
  88                 # or
  89                 #  100092:       e3 f0 ff c8 ff 71       lay     %r15,-56(%r15)
  90                 $re = qr/.*(?:lay|ag?hi).*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})
  91                       (?:\(\%r15\))?$/ox;
  92         } elsif ($arch =~ /^sh64$/) {
  93                 #XXX: we only check for the immediate case presently,
  94                 #     though we will want to check for the movi/sub
  95                 #     pair for larger users. -- PFM.
  96                 #a00048e0:       d4fc40f0        addi.l  r15,-240,r15
  97                 $re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
  98         } elsif ($arch =~ /^blackfin$/) {
  99                 #   0:   00 e8 38 01     LINK 0x4e0;
 100                 $re = qr/.*[[:space:]]LINK[[:space:]]*(0x$x{1,8})/o;
 101         } elsif ($arch eq 'sparc' || $arch eq 'sparc64') {
 102                 # f0019d10:       9d e3 bf 90     save  %sp, -112, %sp
 103                 $re = qr/.*save.*%sp, -(([0-9]{2}|[3-9])[0-9]{2}), %sp/o;
 104         } else {
 105                 print("wrong or unknown architecture \"$arch\"\n");
 106                 exit
 107         }
 108 }
 109
 110 #
 111 # main()
 112 #
 113 my ($func, $file, $lastslash);
 114
 115 while (my $line = <STDIN>) {
 116         if ($line =~ m/$funcre/) {
 117                 $func = $1;
 118         }
 119         elsif ($line =~ m/(.*):\s*file format/) {
 120                 $file = $1;
 121                 $file =~ s/\.ko//;
 122                 $lastslash = rindex($file, "/");
 123                 if ($lastslash != -1) {
 124                         $file = substr($file, $lastslash + 1);
 125                 }
 126         }
 127         elsif ($line =~ m/$re/) {
 128                 my $size = $1;
 129                 $size = hex($size) if ($size =~ /^0x/);
 130
 131                 if ($size > 0xf0000000) {
 132                         $size = - $size;
 133                         $size += 0x80000000;
 134                         $size += 0x80000000;
 135                 }
 136                 next if ($size > 0x10000000);
 137
 138                 next if $line !~ m/^($xs*)/;
 139                 my $addr = $1;
 140                 $addr =~ s/ /0/g;
 141                 $addr = "0x$addr";
 142
 143                 my $intro = "$addr $func [$file]:";
 144                 my $padlen = 56 - length($intro);
 145                 while ($padlen > 0) {
 146                         $intro .= '     ';
 147                         $padlen -= 8;
 148                 }
 149                 next if ($size < 100);
 150                 push @stack, "$intro$size\n";
 151         }
 152         elsif (defined $dre && $line =~ m/$dre/) {
 153                 my $size = "Dynamic ($1)";
 154
 155                 next if $line !~ m/^($xs*)/;
 156                 my $addr = $1;
 157                 $addr =~ s/ /0/g;
 158                 $addr = "0x$addr";
 159
 160                 my $intro = "$addr $func [$file]:";
 161                 my $padlen = 56 - length($intro);
 162                 while ($padlen > 0) {
 163                         $intro .= '     ';
 164                         $padlen -= 8;
 165                 }
 166                 push @stack, "$intro$size\n";
 167         }
 168 }
 169
 170 # Sort output by size (last field)
 171 print sort { ($b =~ /:\t*(\d+)$/)[0] <=> ($a =~ /:\t*(\d+)$/)[0] } @stack;