guardian.in

   1 #!/usr/bin/perl
   2 ###############################################################################
   3 #                                                                             #
   4 # IPFire.org - A linux based firewall                                         #
   5 # Copyright (C) 2015-2016  IPFire Development Team                            #
   6 #                                                                             #
   7 # This program is free software: you can redistribute it and/or modify        #
   8 # it under the terms of the GNU General Public License as published by        #
   9 # the Free Software Foundation, either version 3 of the License, or           #
  10 # (at your option) any later version.                                         #
  11 #                                                                             #
  12 # This program is distributed in the hope that it will be useful,             #
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  15 # GNU General Public License for more details.                                #
  16 #                                                                             #
  17 # You should have received a copy of the GNU General Public License           #
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  19 #                                                                             #
  20 ###############################################################################
  21
  22 use strict;
  23 use threads;
  24 use threads::shared;
  25 use Getopt::Long;
  26 use Thread::Queue;
  27 use Linux::Inotify2;
  28 use Time::HiRes qw[ time sleep ];
  29
  30 require Guardian::Base;
  31 require Guardian::Config;
  32 require Guardian::Daemon;
  33 require Guardian::Events;
  34 require Guardian::Logger;
  35 require Guardian::Parser;
  36 require Guardian::Socket;
  37
  38 use warnings;
  39
  40 # Disable warnings of unjoined threads when stopping guardian.
  41 no warnings 'threads';
  42
  43 # Define version.
  44 my $version ="@PACKAGE_VERSION@";
  45
  46 # Get and store the given command line arguments in a hash.
  47 my %cmdargs = ();
  48
  49 &GetOptions (\%cmdargs,
  50         'foreground|f',
  51         'config|c=s',
  52         'help|h',
  53         'version|v',
  54 );
  55
  56 # Show help / version information.
  57 if (defined($cmdargs{"help"})) {
  58         print "Guardian $version \n";
  59         print "Usage: guardian <optional arguments>\n";
  60         print " -c, --config\t\tspecifiy a configuration file other than the default (/etc/guardian/guardian.conf)\n";
  61         print " -f, --foreground\turn in the foreground (doesn't fork, any output goes to STDOUT)\n";
  62         print " -h, --help\t\tshows this help\n";
  63         print " -v, --version\t\tdisplay programm version and exit.\n";
  64         exit;
  65 } elsif (defined($cmdargs{"version"})) {
  66         print "Guardian $version \n";
  67         exit;
  68 }
  69
  70 # Check if another instance of guardian is allready running.
  71 if (&Guardian::Daemon::IsRunning()) {
  72         die "Another instance of Guardian is already running...\n";
  73 }
  74
  75 # Read-in the configuration file and store the settings.
  76 # Push the may be given config file argument.
  77 my %mainsettings = &Guardian::Config::UseConfig($cmdargs{"config"});
  78
  79 # Initialize Logger.
  80 my $logger = Guardian::Logger->Init(%mainsettings);
  81 $logger->Log("debug", "Logger successfully initialized...");
  82
  83 # Add the logger object to the mainsettings for passing
  84 # it to the modules.
  85 $mainsettings{Logger} = $logger;
  86
  87 # Redirect perls "die" messages to the logger before exiting.
  88 $SIG{__DIE__} = sub { $logger->Log("err", "@_"); };
  89
  90 # Initialize the parser module.
  91 my $parser = Guardian::Parser->Init(%mainsettings);
  92
  93 # Initialize the event handler.
  94 my $events = Guardian::Events->Init(%mainsettings);
  95
  96 # Hash to store the currently monitored files and their configured
  97 # parsers.
  98 my %monitored_files = ();
  99
 100 # Shared hash between the main process and all threads. It will store the
 101 # monitored files and their current file position.
 102 my %file_positions :shared = ();
 103
 104 # Create the main queue. It is used to store and process all events which are
 105 # reported and enqueued by the worker threads.
 106 my $queue :shared = new Thread::Queue or die "Could not create new, empty queue. $!";;
 107
 108 # Hash to store all currently running worker objects and their corresponding files.
 109 # (Does not include the socket thread)
 110 my %running_workers;
 111
 112 # Variable to store if the workers should pause or compute.
 113 my $workers_pause :shared = 0;
 114
 115 # Check if guardian should be daemonized or keep in the foreground.
 116 unless (defined($cmdargs{"foreground"})) {
 117         # Fork into background.
 118         &Guardian::Daemon::Daemonize();
 119 } else {
 120         # Write PID (process-id).
 121         &Guardian::Daemon::WritePID();
 122 }
 123
 124 # Call Init function to initzialize guardian.
 125 &Init();
 126
 127 # Log successfully started process.
 128 $logger->Log("info", "Guardian $version successfully started...");
 129
 130 # Infinite main loop, which processes all queued events.
 131 while(1) {
 132         # Get the amount of elements in our queue.
 133         # "undef" will be returned if it is empty.
 134         my $current_events = $queue->pending();
 135
 136         # If there is at least one element enqued
 137         if($current_events > 0) {
 138                 # Grab the data of the top enqueued event.
 139                 my $event = $queue->peek();
 140
 141                 # Log processed event.
 142                 $logger->Log("debug", "QUEUE - Processed event: $event");
 143
 144                 # Send event data to the events parser to determine
 145                 # if any action is required.
 146                 $events->CheckAction($event);
 147
 148                 # Drop processed event from queue.
 149                 $queue->dequeue();
 150         }
 151
 152         # Call RemoveBlocks routine from the Events module to check
 153         # if items from the block list can be dropped.
 154         $events->RemoveBlocks();
 155
 156         # Sleep 50ms to reduce the load of the main process.
 157         sleep(0.05);
 158 }
 159
 160 #
 161 ## Init function.
 162 #
 163 ## This function contains code which has to be executed while guardian
 164 ## is starting.
 165 #
 166 sub Init () {
 167         # Setup signal handler.
 168         &SignalHandler();
 169
 170         # Setup IPC mechanism via Socket in an own thread.
 171         threads->create(\&Socket);
 172
 173         # Generate hash of monitored files.
 174         %monitored_files = &Guardian::Base::GenerateMonitoredFiles(\%mainsettings, \%monitored_files);
 175
 176         # Start worker threads.
 177         &StartWorkers();
 178 }
 179
 180 #
 181 ## Worker function.
 182 #
 183 ## This function is responsible for monitoring modifications of the given logfile,
 184 ## read them and pass them to the message parser.
 185 #
 186 ## To get file modifications the inotify subsystem of the linux kernel is used.
 187 #
 188 ## In order to prevent from permanently read and keep files opened, or dealing
 189 ## with huge logfiles, at initialization time of the worker process, the file will
 190 ## be opened once and the cursor position of the end of file (EOF) get stored. When
 191 ## reading any newly added lines from the file, we directly can jump to the last
 192 ## known position and get these lines. Afterwards, we store the current cursor position
 193 ## again, so we can do it in this way over and over again.
 194 #
 195 ## All read lines get stored in an array, which will be passed to the Parser.
 196 #
 197 ## If any response (action) from the parser is received, it will be put into the
 198 ## shared event queue.
 199 #
 200 sub Worker ($) {
 201         my $file = $_[0];
 202
 203         # Obtain the parser name which should be used to parse any
 204         # messages of this file.
 205         my $use_parser = $monitored_files{$file};
 206
 207         # Signal handler to kill worker.
 208         $SIG{'KILL'} = sub { threads->exit(); };
 209
 210         # Create inotify watcher.
 211         my $watcher = new Linux::Inotify2 or die "Could not use inotify. $!";
 212
 213         # Monitor the specified file.
 214         $watcher->watch("$file", IN_MODIFY) or die "Could not monitor $file. $!";
 215
 216         # Switch watcher into non-blocking mode.
 217         $watcher->blocking(0);
 218
 219         # Log successfully spawned worker.
 220         $logger->Log("debug", "Spawned worker thread for: $file");
 221
 222         # Infinite loop.
 223         while(1) {
 224                 # Check if the workers should pause or perform their desired work.
 225                 if ($workers_pause) {
 226                         # Wait 1 second until the next check.
 227                         sleep(1);
 228                 } else {
 229                         # Check for any events and perform them, if there
 230                         # is a least one.
 231                         if ($watcher->read) {
 232                                 my @message = ();
 233
 234                                 # Obtain fileposition from hash.
 235                                 my $fileposition = $file_positions{$file};
 236
 237                                 # Open the file.
 238                                 open (FILE, $file) or die "Could not open $file. $!";
 239
 240                                 # Seek to the last known position.
 241                                 seek (FILE, $fileposition, 0);
 242
 243                                 # Get the log message.
 244                                 while (my $line = <FILE>) {
 245                                         # Remove any newlines.
 246                                         chomp $line;
 247
 248                                         # Add all lines to the message array.
 249                                         push (@message, $line);
 250                                 }
 251
 252                                 {
 253                                         # Lock shared hash.
 254                                         lock(%file_positions);
 255
 256                                         # Update fileposition.
 257                                         $file_positions{$file} = tell(FILE);
 258                                 }
 259
 260                                 # Close file.
 261                                 close(FILE);
 262
 263                                 # Send filename and message to the parser,
 264                                 # which will return if any actions have to be performed.
 265                                 my @actions = $parser->Parser("$use_parser", @message);
 266
 267                                 # Send the action to the main process and put it into
 268                                 # the queue.
 269                                 if (@actions) {
 270                                         # Lock the queue.
 271                                         lock($queue);
 272
 273                                         # Loop through the actions array, and perform
 274                                         # every single action.
 275                                         foreach my $action (@actions) {
 276                                                 # Prevent from enqueuing empty actions.
 277                                                 if (defined($action)) {
 278                                                         # Put the required action into the queue.
 279                                                         $queue->enqueue($action);
 280                                                 }
 281                                         }
 282                                 }
 283                         } else {
 284                                 # Sleep for 100ms until the next round of the loop will start.
 285                                 sleep(0.1);
 286                         }
 287                 }
 288         }
 289 }
 290
 291 #
 292 ## Socket function.
 293 #
 294 ## This function uses the Socket module to create and listen to an UNIX socket.
 295 ## It automatically accepts all incoming connections and pass the received
 296 ## data messages to the the Message_Parser function which is also part of the
 297 ## socket module.
 298 #
 299 ## If a valid command has been sent through the socket, the corresponding event
 300 ## will be enqueued into the shared event queue.
 301 #
 302 sub Socket () {
 303         # Create the Server socket by calling the responsible function.
 304         my $server = &Guardian::Socket::Server($mainsettings{SocketOwner});
 305
 306         # Log successfull creation of socket.
 307         $logger->Log("debug", "Listening to Socket...");
 308
 309         # Accept incoming connections from the socket.
 310         while (my $connection = $server->accept()) {
 311                 # Autoflush the socket after the data
 312                 # has been received.
 313                 $connection->autoflush(1);
 314
 315                 # Gather all data from the connection.
 316                 while (my $message = <$connection>) {
 317                         # Remove any newlines.
 318                         chomp($message);
 319
 320                         # Log received socket command.
 321                         $logger->Log("debug", "Socket - Recieved message: $message");
 322
 323                         # Send the received data message to the
 324                         # socket parser.
 325                         my $action = &Guardian::Socket::Message_Parser($message);
 326
 327                         # If the parser returns to perform an action,
 328                         # add it to the main event queue.
 329                         if ($action) {
 330                                 # Lock the queue.
 331                                 lock($queue);
 332
 333                                 # Enqueue the returned action.
 334                                 $queue->enqueue($action);
 335                         }
 336                 }
 337         }
 338 }
 339
 340 #
 341 ## Function for capturing process signals.
 342 #
 343 ## This function captures any sent process signals and will call various
 344 ## actions, based on the captured signal.
 345 #
 346 sub SignalHandler {
 347         $SIG{INT} = \&Shutdown;
 348         $SIG{TERM} = \&Shutdown;
 349         $SIG{QUIT} = \&Shutdown;
 350         $SIG{HUP} = \&Reload;
 351         $SIG{USR1} = \&ReloadIgnoreList;
 352 }
 353
 354 #
 355 ## Function to start the workers (threads) for all monitored files.
 356 #
 357 ## This function will loop through the hash of monitored files and will
 358 ## spawn an own thread based worker for each file. Every created worker will
 359 ## be added to the array of running workers.
 360 #
 361 sub StartWorkers () {
 362         # Init/Update hash which contains the cursor position of EOF.
 363         %file_positions = &Guardian::Base::FilePositions(\%monitored_files, \%file_positions);
 364
 365         # Loop through the hash which contains the monitored files and start
 366         # a worker thread for each single one.
 367         foreach my $file (keys %monitored_files) {
 368                 # Check if an worker is already running for this file.
 369                 # If not, start the worker.
 370                 unless (exists($running_workers{$file})) {
 371                         $logger->Log("debug", "Starting worker thread for $file");
 372
 373                         # Create worker thread for the file.
 374                         $running_workers{$file} = threads->create(\&Worker,$file);
 375                 }
 376         }
 377 }
 378
 379 #
 380 ## Function to stop all running workers.
 381 #
 382 ## This function is used to stop all currently running workers and will be
 383 ## called when reloading or shutting down guardian.
 384 #
 385 sub StopWorkers () {
 386         # Loop through all running workers.
 387         foreach my $worker (keys %running_workers) {
 388                 # Determine if the worker should be stopped.
 389                 # This happens if the file should not be longer monitored.
 390                 unless(exists($monitored_files{$worker})) {
 391                         $logger->Log("debug", "Stopping worker thread for $worker");
 392
 393                         # Send a "KILL" signal to the worker.
 394                         $running_workers{$worker}->kill('KILL');
 395
 396                         # Remove worker from hash of running workers.
 397                         delete($running_workers{$worker});
 398                 }
 399         }
 400
 401         # Get amount of currently running worker threads.
 402         if (! keys(%running_workers)) {
 403                 $logger->Log("debug", "All workers have been stopped...");
 404         }
 405
 406         # Return nothing.
 407         return;
 408 }
 409
 410 #
 411 ## Function to pause all running workers.
 412 #
 413 ## This function is used to pause all currently running workers.
 414 #
 415 sub PauseWorkers() {
 416         # Set workers_pause variable to "1".
 417         # All workers will sleep until the variable has been set to "0".
 418         $workers_pause = 1;
 419
 420         # Log paused workers.
 421         $logger->Log("debug", "All workers have been paused...");
 422
 423         # Return nothing.
 424         return;
 425 }
 426
 427 #
 428 ## Function to continue all running workers.
 429 #
 430 ## This function is used to continue all paused workers.
 431 #
 432 sub ResumeWorkers() {
 433         # Set workers_suspend variable to "0" - they will continue their work
 434         # again.
 435         $workers_pause = 0;
 436
 437         # Log continued workers.
 438         $logger->Log("debug", "All workers are working again...");
 439
 440         # Return nothing.
 441         return;
 442 }
 443
 444 #
 445 ## Reload function.
 446 #
 447 ## This function will get called if the signal handler receives a "SIGHUP" signal,
 448 ## or the reload command will be sent via socket connection. It is responsible for
 449 ## reloading all configure options and stopping/starting the worker threads.
 450 #
 451 sub Reload () {
 452         # Log reload.
 453         $logger->Log("info", "Reload configuration...");
 454
 455         # Pause all running workers.
 456         &PauseWorkers();
 457
 458         # Re-read configuration file.
 459         %mainsettings = &Guardian::Config::UseConfig($cmdargs{"config"});
 460
 461         # Update Logger settings.
 462         $logger = Guardian::Logger->Init(%mainsettings);
 463
 464         # Update logger object in mainsettings hash.
 465         $mainsettings{Logger} = $logger;
 466
 467         # Update Parser handler.
 468         $parser->Update(\%mainsettings);
 469
 470         # Update Event handler.
 471         $events->Update(\%mainsettings);
 472
 473         # Update ignore list.
 474         &ReloadIgnoreList();
 475
 476         # Re-generate hash of monitored files.
 477         %monitored_files = &Guardian::Base::GenerateMonitoredFiles(\%mainsettings, \%monitored_files);
 478
 479         # Stop workers if they are not needed anymore.
 480         &StopWorkers();
 481
 482         # Start new worker threads if required.
 483         &StartWorkers();
 484
 485         # Resume workers.
 486         &ResumeWorkers();
 487
 488         # Return nothing.
 489         return;
 490 }
 491
 492 #
 493 ## ReloadIgnoreList function.
 494 #
 495 ## This function will be called if the signal handler receives a "SIGUSR1" signal,
 496 ## or the reload-ignore-list command will be sent via the socket connection. It just
 497 ## performs a simple check if an ignore file has been configured and calls the responsible
 498 ## function on the events module.
 499 #
 500 sub ReloadIgnoreList () {
 501         # Update ignore list, if an ignorefile has been specified.
 502         if (exists($mainsettings{IgnoreFile})) {
 503                 # Log reload of the ignore list.
 504                 $logger->Log("info", "Reloading ignore list...");
 505
 506                 # Call responsible function from the events module.
 507                 &Guardian::Events::GenerateIgnoreList($mainsettings{IgnoreFile});
 508         }
 509 }
 510
 511 #
 512 ## Logrotate function.
 513 #
 514 ## This function only get called when the logrotate command will be sent via
 515 ## the socket connection. It is responsible for validating and altering the current
 516 ## cursor positions of the monitored files and stopping/starting the worker threads.
 517 #
 518 sub Logrotate () {
 519         # Stop all running workers.
 520         &PauseWorkers();
 521
 522         {
 523         # Lock shared hash.
 524         lock(%file_positions);
 525
 526         # Loop through the hash which contains the current
 527         # file positions.
 528         foreach my $file (keys(%file_positions)) {
 529                 # Obtain stored value from hash.
 530                 my $stored_position = $file_positions{$file};
 531
 532                 # Call function to get the current position.
 533                 my $current_position = &Guardian::Base::GetFileposition($file);
 534
 535                 # Compare if the current position still matches
 536                 # the stored one.
 537                 if ($current_position ne $stored_position) {
 538                         # Update to the new position, because
 539                         # they has changed during file rotation.
 540                         $file_positions{$file} = $current_position;
 541
 542                         # Log notice about rotated file.
 543                         $logger->Log("debug", "$file have been rotated - Using new file position.");
 544                 }
 545         }
 546
 547         # After this bracket, the lock of the hash will be released.
 548         }
 549
 550         # Restart all worker threads.
 551         &ResumeWorkers();
 552
 553         # Return nothing.
 554         return;
 555 }
 556
 557 #
 558 ## Shutdown function.
 559 #
 560 ## This function is used to do a clean shutdown of guardian. It will be called
 561 ## by the signal handler when receiving INT (2), QUIT (3) and TERM (15) signals.
 562 #
 563 sub Shutdown () {
 564         # Log shutdown.
 565         $logger->Log("info", "Shutting down...");
 566
 567         # Reset hash of monitored files.
 568         %monitored_files = ();
 569
 570         # Stop all workers.
 571         &StopWorkers();
 572
 573         # Unblock all blocked hosts.
 574         &Guardian::Events::CallFlush();
 575
 576         # Remove socket file on exit.
 577         &Guardian::Socket::RemoveSocketFile();
 578
 579         # Remove pid file on exit.
 580         &Guardian::Daemon::RemovePIDFile();
 581
 582         # Sleep for one second to give perl some
 583         # time to proper clean up everything before
 584         # exiting.
 585         sleep(1);
 586
 587         # Log good bye message.
 588         $logger->Log("debug", "Good Bye!");
 589
 590         # Exit guardian.
 591         exit;
 592 }