config/firewall/rules.pl

   1 #!/usr/bin/perl -w
   2 ###############################################################################
   3 #                                                                             #
   4 # IPFire.org - A linux based firewall                                         #
   5 # Copyright (C) 2013 Alexander Marx <amarx@ipfire.org>                        #
   6 #                                                                             #
   7 # This program is free software: you can redistribute it and/or modify        #
   8 # it under the terms of the GNU General Public License as published by        #
   9 # the Free Software Foundation, either version 3 of the License, or           #
  10 # (at your option) any later version.                                         #
  11 #                                                                             #
  12 # This program is distributed in the hope that it will be useful,             #
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  15 # GNU General Public License for more details.                                #
  16 #                                                                             #
  17 # You should have received a copy of the GNU General Public License           #
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  19 #                                                                             #
  20 ###############################################################################
  21
  22 use strict;
  23
  24 require '/var/ipfire/general-functions.pl';
  25 require "${General::swroot}/lang.pl";
  26 require "/usr/lib/firewall/firewall-lib.pl";
  27
  28 # Set to one to enable debugging mode.
  29 my $DEBUG = 0;
  30
  31 my $IPTABLES = "iptables --wait";
  32
  33 # iptables chains
  34 my $CHAIN_INPUT           = "INPUTFW";
  35 my $CHAIN_FORWARD         = "FORWARDFW";
  36 my $CHAIN_OUTPUT          = "OUTGOINGFW";
  37 my $CHAIN                 = $CHAIN_FORWARD;
  38 my $CHAIN_NAT_SOURCE      = "NAT_SOURCE";
  39 my $CHAIN_NAT_DESTINATION = "NAT_DESTINATION";
  40 my $CHAIN_MANGLE_NAT_DESTINATION_FIX = "NAT_DESTINATION";
  41 my @VALID_CHAINS          = ($CHAIN_INPUT, $CHAIN_FORWARD, $CHAIN_OUTPUT);
  42 my @ANY_ADDRESSES         = ("0.0.0.0/0.0.0.0", "0.0.0.0/0", "0/0");
  43
  44 my @PROTOCOLS = ("tcp", "udp", "icmp", "igmp", "ah", "esp", "gre", "ipv6", "ipip");
  45 my @PROTOCOLS_WITH_PORTS = ("tcp", "udp");
  46
  47 my @VALID_TARGETS = ("ACCEPT", "DROP", "REJECT");
  48
  49 my %fwdfwsettings=();
  50 my %defaultNetworks=();
  51 my %configfwdfw=();;
  52 my %customgrp=();
  53 my %configinputfw=();
  54 my %configoutgoingfw=();
  55 my %confignatfw=();
  56 my %aliases=();
  57 my @p2ps=();
  58
  59 my $configfwdfw         = "${General::swroot}/firewall/config";
  60 my $configinput     = "${General::swroot}/firewall/input";
  61 my $configoutgoing  = "${General::swroot}/firewall/outgoing";
  62 my $p2pfile                     = "${General::swroot}/firewall/p2protocols";
  63 my $configgrp           = "${General::swroot}/fwhosts/customgroups";
  64 my $netsettings         = "${General::swroot}/ethernet/settings";
  65
  66 &General::readhash("${General::swroot}/firewall/settings", \%fwdfwsettings);
  67 &General::readhash("$netsettings", \%defaultNetworks);
  68 &General::readhasharray($configfwdfw, \%configfwdfw);
  69 &General::readhasharray($configinput, \%configinputfw);
  70 &General::readhasharray($configoutgoing, \%configoutgoingfw);
  71 &General::readhasharray($configgrp, \%customgrp);
  72 &General::get_aliases(\%aliases);
  73
  74 my @log_limit_options = &make_log_limit_options();
  75
  76 # MAIN
  77 &main();
  78
  79 sub main {
  80         # Flush all chains.
  81         &flush();
  82
  83         # Reload firewall rules.
  84         &preparerules();
  85
  86         # Load P2P block rules.
  87         &p2pblock();
  88
  89         # Reload firewall policy.
  90         run("/usr/sbin/firewall-policy");
  91 }
  92
  93 sub run {
  94         # Executes or prints the given shell command.
  95         my $command = shift;
  96
  97         if ($DEBUG) {
  98                 print "$command\n";
  99         } else {
 100                 system "$command";
 101
 102                 if ($?) {
 103                         print_error("ERROR: $command");
 104                 }
 105         }
 106 }
 107
 108 sub print_error {
 109         my $message = shift;
 110
 111         print STDERR "$message\n";
 112 }
 113
 114 sub print_rule {
 115         my $hash = shift;
 116
 117         print "\nRULE:";
 118
 119         my $i = 0;
 120         foreach (@$hash) {
 121                 printf("  %2d: %s", $i++, $_);
 122         }
 123         print "\n";
 124 }
 125
 126 sub flush {
 127         run("$IPTABLES -F $CHAIN_INPUT");
 128         run("$IPTABLES -F $CHAIN_FORWARD");
 129         run("$IPTABLES -F $CHAIN_OUTPUT");
 130         run("$IPTABLES -t nat -F $CHAIN_NAT_SOURCE");
 131         run("$IPTABLES -t nat -F $CHAIN_NAT_DESTINATION");
 132         run("$IPTABLES -t mangle -F $CHAIN_MANGLE_NAT_DESTINATION_FIX");
 133 }
 134
 135 sub preparerules {
 136         if (! -z  "${General::swroot}/firewall/config"){
 137                 &buildrules(\%configfwdfw);
 138         }
 139         if (! -z  "${General::swroot}/firewall/input"){
 140                 &buildrules(\%configinputfw);
 141         }
 142         if (! -z  "${General::swroot}/firewall/outgoing"){
 143                 &buildrules(\%configoutgoingfw);
 144         }
 145 }
 146
 147 sub buildrules {
 148         my $hash = shift;
 149
 150         foreach my $key (sort {$a <=> $b} keys %$hash) {
 151                 # Skip disabled rules.
 152                 next unless ($$hash{$key}[2] eq 'ON');
 153
 154                 if ($DEBUG) {
 155                         print_rule($$hash{$key});
 156                 }
 157
 158                 # Check if the target is valid.
 159                 my $target = $$hash{$key}[0];
 160                 if (!$target ~~ @VALID_TARGETS) {
 161                         print_error("Invalid target '$target' for rule $key");
 162                         next;
 163                 }
 164
 165                 # Check if the chain is valid.
 166                 my $chain = $$hash{$key}[1];
 167                 if (!$chain ~~ @VALID_CHAINS) {
 168                         print_error("Invalid chain '$chain' in rule $key");
 169                         next;
 170                 }
 171
 172                 # Collect all sources.
 173                 my @sources = &get_addresses($hash, $key, "src");
 174
 175                 # Collect all destinations.
 176                 my @destinations = &get_addresses($hash, $key, "tgt");
 177
 178                 # Check if logging should be enabled.
 179                 my $LOG = ($$hash{$key}[17] eq 'ON');
 180
 181                 # Check if NAT is enabled and initialize variables, that we use for that.
 182                 my $NAT = ($$hash{$key}[28] eq 'ON');
 183                 my $NAT_MODE;
 184                 if ($NAT) {
 185                         $NAT_MODE = uc($$hash{$key}[31]);
 186                 }
 187
 188                 # Set up time constraints.
 189                 my @time_options = ();
 190                 if ($$hash{$key}[18] eq 'ON') {
 191                         push(@time_options, ("-m", "time"));
 192
 193                         # Select all days of the week this match is active.
 194                         my @weekdays = ();
 195                         if ($$hash{$key}[19] ne '') {
 196                                 push (@weekdays, "Mon");
 197                         }
 198                         if ($$hash{$key}[20] ne '') {
 199                                 push (@weekdays, "Tue");
 200                         }
 201                         if ($$hash{$key}[21] ne '') {
 202                                 push (@weekdays, "Wed");
 203                         }
 204                         if ($$hash{$key}[22] ne '') {
 205                                 push (@weekdays, "Thu");
 206                         }
 207                         if ($$hash{$key}[23] ne '') {
 208                                 push (@weekdays, "Fri");
 209                         }
 210                         if ($$hash{$key}[24] ne '') {
 211                                 push (@weekdays, "Sat");
 212                         }
 213                         if ($$hash{$key}[25] ne '') {
 214                                 push (@weekdays, "Sun");
 215                         }
 216                         if (@weekdays) {
 217                                 push(@time_options, ("--weekdays", join(",", @weekdays)));
 218                         }
 219
 220                         # Convert start time.
 221                         my $time_start = &format_time($$hash{$key}[26]);
 222                         if ($time_start) {
 223                                 push(@time_options, ("--timestart", $time_start));
 224                         }
 225
 226                         # Convert end time.
 227                         my $time_stop = &format_time($$hash{$key}[27]);
 228                         if ($time_stop) {
 229                                 push(@time_options, ("--timestop", $time_stop));
 230                         }
 231                 }
 232
 233                 # Check which protocols are used in this rule and so that we can
 234                 # later group rules by protocols.
 235                 my @protocols = &get_protocols($hash, $key);
 236                 if (!@protocols) {
 237                         print_error("Invalid protocol configuration for rule $key");
 238                         next;
 239                 }
 240
 241                 foreach my $protocol (@protocols) {
 242                         # Check if the given protocol is supported.
 243                         if (($protocol ne "all") && (!$protocol ~~ @PROTOCOLS)) {
 244                                 print_error("Protocol $protocol is not supported (rule $key)");
 245                                 next;
 246                         }
 247
 248                         # Prepare protocol options (like ICMP types, ports, etc...).
 249                         my @protocol_options = &get_protocol_options($hash, $key, $protocol);
 250
 251                         # Check if this protocol knows ports.
 252                         my $protocol_has_ports = ($protocol ~~ @PROTOCOLS_WITH_PORTS);
 253
 254                         foreach my $source (@sources) {
 255                                 foreach my $destination (@destinations) {
 256                                         # Skip invalid rules.
 257                                         next if (!$source || !$destination || ($destination eq "none"));
 258
 259                                         # Sanitize source.
 260                                         if ($source ~~ @ANY_ADDRESSES) {
 261                                                 $source = "";
 262                                         }
 263
 264                                         # Sanitize destination.
 265                                         if ($destination ~~ @ANY_ADDRESSES) {
 266                                                 $destination = "";
 267                                         }
 268
 269                                         # Array with iptables arguments.
 270                                         my @options = ();
 271
 272                                         # Append protocol.
 273                                         if ($protocol ne "all") {
 274                                                 push(@options, ("-p", $protocol));
 275                                                 push(@options, @protocol_options);
 276                                         }
 277
 278                                         # Prepare source options.
 279                                         my @source_options = ();
 280                                         if ($source =~ /mac/) {
 281                                                 push(@source_options, $source);
 282                                         } elsif ($source) {
 283                                                 push(@source_options, ("-s", $source));
 284                                         }
 285
 286                                         # Prepare destination options.
 287                                         my @destination_options = ();
 288                                         if ($destination) {
 289                                                 push(@destination_options, ("-d", $destination));
 290                                         }
 291
 292                                         # Add time constraint options.
 293                                         push(@options, @time_options);
 294
 295                                         my $firewall_is_in_source_subnet = 0;
 296                                         if ($source) {
 297                                                 $firewall_is_in_source_subnet = &firewall_is_in_subnet($source);
 298                                         }
 299
 300                                         # Process NAT rules.
 301                                         if ($NAT) {
 302                                                 my $nat_address = &get_nat_address($$hash{$key}[29]);
 303
 304                                                 # Skip NAT rules if the NAT address is unknown
 305                                                 # (i.e. no internet connection has been established, yet).
 306                                                 next unless ($nat_address);
 307
 308                                                 # Destination NAT
 309                                                 if ($NAT_MODE eq "DNAT") {
 310                                                         # Make port-forwardings useable from the internal networks.
 311                                                         &add_dnat_mangle_rules($nat_address, @options);
 312
 313                                                         my @nat_options = @options;
 314                                                         push(@nat_options, @source_options);
 315                                                         push(@nat_options, ("-d", $nat_address));
 316
 317                                                         my ($dnat_address, $dnat_mask) = split("/", $destination);
 318                                                         @destination_options = ("-d", $dnat_address);
 319
 320                                                         if ($protocol_has_ports) {
 321                                                                 my $dnat_port = &get_dnat_target_port($hash, $key);
 322
 323                                                                 if ($dnat_port) {
 324                                                                         $dnat_address .= ":$dnat_port";
 325                                                                 }
 326                                                         }
 327
 328                                                         if ($LOG) {
 329                                                                 run("$IPTABLES -t nat -A $CHAIN_NAT_DESTINATION @nat_options @log_limit_options -j LOG --log-prefix 'DNAT '");
 330                                                         }
 331                                                         run("$IPTABLES -t nat -A $CHAIN_NAT_DESTINATION @nat_options -j DNAT --to-destination $dnat_address");
 332
 333                                                 # Source NAT
 334                                                 } elsif ($NAT_MODE eq "SNAT") {
 335                                                         my @nat_options = @options;
 336
 337                                                         push(@nat_options, @source_options);
 338                                                         push(@nat_options, @destination_options);
 339
 340                                                         if ($LOG) {
 341                                                                 run("$IPTABLES -t nat -A $CHAIN_NAT_SOURCE @nat_options @log_limit_options -j LOG --log-prefix 'SNAT '");
 342                                                         }
 343                                                         run("$IPTABLES -t nat -A $CHAIN_NAT_SOURCE @nat_options -j SNAT --to-source $nat_address");
 344                                                 }
 345                                         }
 346
 347                                         push(@options, @source_options);
 348
 349                                         if ($firewall_is_in_source_subnet && ($fwdfwsettings{"POLICY"} eq "MODE1") && ($chain eq $CHAIN_FORWARD)) {
 350                                                 if ($LOG && !$NAT) {
 351                                                         run("$IPTABLES -A $CHAIN_INPUT @options @log_limit_options -j LOG --log-prefix '$CHAIN_INPUT '");
 352                                                 }
 353                                                 run("$IPTABLES -A $CHAIN_INPUT @options -j $target");
 354                                         }
 355
 356                                         push(@options, @destination_options);
 357
 358                                         # Insert firewall rule.
 359                                         if ($LOG && !$NAT) {
 360                                                 run("$IPTABLES -A $chain @options @log_limit_options -j LOG --log-prefix '$chain '");
 361                                         }
 362                                         run("$IPTABLES -A $chain @options -j $target");
 363                                 }
 364                         }
 365                 }
 366         }
 367 }
 368
 369 sub get_external_interface() {
 370         open(IFACE, "/var/ipfire/red/iface") or return "";
 371         my $iface = <IFACE>;
 372         close(IFACE);
 373
 374         return $iface;
 375 }
 376
 377 sub get_external_address() {
 378         open(ADDR, "/var/ipfire/red/local-ipaddress") or return "";
 379         my $address = <ADDR>;
 380         close(ADDR);
 381
 382         return $address;
 383 }
 384
 385 sub get_alias {
 386         my $id = shift;
 387
 388         foreach my $alias (sort keys %aliases) {
 389                 if ($id eq $alias) {
 390                         return $aliases{$alias};
 391                 }
 392         }
 393 }
 394
 395 sub get_nat_address {
 396         my $zone = shift;
 397
 398         # Any static address of any zone.
 399         if ($zone eq "RED" || $zone eq "GREEN" || $zone eq "ORANGE" || $zone eq "BLUE") {
 400                 return $defaultNetworks{$zone . "_ADDRESS"};
 401
 402         } elsif ($zone eq "Default IP") {
 403                 return &get_external_address();
 404
 405         } else {
 406                 return &get_alias($zone);
 407         }
 408
 409         print_error("Could not find NAT address");
 410 }
 411
 412 # Formats the given timestamp into the iptables format which is "hh:mm" UTC.
 413 sub format_time {
 414         my $val = shift;
 415
 416         # Convert the given time into minutes.
 417         my $minutes = &time_convert_to_minutes($val);
 418
 419         # Move the timestamp into UTC.
 420         $minutes += &time_utc_offset();
 421
 422         # Make sure $minutes is between 00:00 and 23:59.
 423         if ($minutes < 0) {
 424                 $minutes += 1440;
 425         }
 426
 427         if ($minutes > 1440) {
 428                 $minutes -= 1440;
 429         }
 430
 431         # Format as hh:mm.
 432         return sprintf("%02d:%02d", $minutes / 60, $minutes % 60);
 433 }
 434
 435 # Calculates the offsets in minutes from the local timezone to UTC.
 436 sub time_utc_offset {
 437         my @localtime = localtime(time);
 438         my @gmtime = gmtime(time);
 439
 440         return ($gmtime[2] * 60 + $gmtime[1] % 60) - ($localtime[2] * 60 + $localtime[1] % 60);
 441 }
 442
 443 # Takes a timestamp like "14:00" and converts it into minutes since midnight.
 444 sub time_convert_to_minutes {
 445         my ($hrs, $min) = split(":", shift);
 446
 447         return ($hrs * 60) + $min;
 448 }
 449
 450 sub p2pblock {
 451         my $P2PSTRING = "";
 452         my $DO;
 453         open( FILE, "< $p2pfile" ) or die "Unable to read $p2pfile";
 454         @p2ps = <FILE>;
 455         close FILE;
 456         my $CMD = "-m ipp2p";
 457         foreach my $p2pentry (sort @p2ps) {
 458                 my @p2pline = split( /\;/, $p2pentry );
 459                 if ( $fwdfwsettings{'POLICY'} eq 'MODE1' ) {
 460                         $DO = "ACCEPT";
 461                         if ("$p2pline[2]" eq "on") {
 462                                 $P2PSTRING = "$P2PSTRING --$p2pline[1]";
 463                         }
 464                 }else {
 465                         $DO = "RETURN";
 466                         if ("$p2pline[2]" eq "off") {
 467                                 $P2PSTRING = "$P2PSTRING --$p2pline[1]";
 468                         }
 469                 }
 470         }
 471
 472         if($P2PSTRING) {
 473                 run("$IPTABLES -A FORWARDFW $CMD $P2PSTRING -j $DO");
 474         }
 475 }
 476
 477 sub get_addresses {
 478         my $hash = shift;
 479         my $key  = shift;
 480         my $type = shift;
 481
 482         my @addresses = ();
 483         my $addr_type;
 484         my $value;
 485         my $group_name;
 486
 487         if ($type eq "src") {
 488                 $addr_type = $$hash{$key}[3];
 489                 $value = $$hash{$key}[4];
 490
 491         } elsif ($type eq "tgt") {
 492                 $addr_type = $$hash{$key}[5];
 493                 $value = $$hash{$key}[6];
 494         }
 495
 496         if ($addr_type ~~ ["cust_grp_src", "cust_grp_tgt"]) {
 497                 foreach my $grp (sort {$a <=> $b} keys %customgrp) {
 498                         if ($customgrp{$grp}[0] eq $value) {
 499                                 my @address = &get_address($customgrp{$grp}[3], $customgrp{$grp}[2], $type);
 500
 501                                 if (@address) {
 502                                         push(@addresses, @address);
 503                                 }
 504                         }
 505                 }
 506         } else {
 507                 my @address = &get_address($addr_type, $value, $type);
 508
 509                 if (@address) {
 510                         push(@addresses, @address);
 511                 }
 512         }
 513
 514         return @addresses;
 515 }
 516
 517 sub get_address {
 518         my $key   = shift;
 519         my $value = shift;
 520         my $type  = shift;
 521
 522         my @ret = ();
 523
 524         # If the user manually typed an address, we just check if it is a MAC
 525         # address. Otherwise, we assume that it is an IP address.
 526         if ($key ~~ ["src_addr", "tgt_addr"]) {
 527                 if (&General::validmac($value)) {
 528                         push(@ret, "-m mac --mac-source $value");
 529                 } else {
 530                         push(@ret, $value);
 531                 }
 532
 533         # If a default network interface (GREEN, BLUE, etc.) is selected, we
 534         # try to get the corresponding address of the network.
 535         } elsif ($key ~~ ["std_net_src", "std_net_tgt", "Standard Network"]) {
 536                 my $external_interface = &get_external_interface();
 537
 538                 my $network_address = &fwlib::get_std_net_ip($value, $external_interface);
 539                 if ($network_address) {
 540                         push(@ret, $network_address);
 541                 }
 542
 543         # Custom networks.
 544         } elsif ($key ~~ ["cust_net_src", "cust_net_tgt", "Custom Network"]) {
 545                 my $network_address = &fwlib::get_net_ip($value);
 546                 if ($network_address) {
 547                         push(@ret, $network_address);
 548                 }
 549
 550         # Custom hosts.
 551         } elsif ($key ~~ ["cust_host_src", "cust_host_tgt", "Custom Host"]) {
 552                 my $host_address = &fwlib::get_host_ip($value, $type);
 553                 if ($host_address) {
 554                         push(@ret, $host_address);
 555                 }
 556
 557         # OpenVPN networks.
 558         } elsif ($key ~~ ["ovpn_net_src", "ovpn_net_tgt", "OpenVPN static network"]) {
 559                 my $network_address = &fwlib::get_ovpn_net_ip($value, 1);
 560                 if ($network_address) {
 561                         push(@ret, $network_address);
 562                 }
 563
 564         # OpenVPN hosts.
 565         } elsif ($key ~~ ["ovpn_host_src", "ovpn_host_tgt", "OpenVPN static host"]) {
 566                 my $host_address = &fwlib::get_ovpn_host_ip($value, 33);
 567                 if ($host_address) {
 568                         push(@ret, $host_address);
 569                 }
 570
 571         # OpenVPN N2N.
 572         } elsif ($key ~~ ["ovpn_n2n_src", "ovpn_n2n_tgt", "OpenVPN N-2-N"]) {
 573                 my $network_address = &fwlib::get_ovpn_n2n_ip($value, 11);
 574                 if ($network_address) {
 575                         push(@ret, $network_address);
 576                 }
 577
 578         # IPsec networks.
 579         } elsif ($key ~~ ["ipsec_net_src", "ipsec_net_tgt", "IpSec Network"]) {
 580                 my $network_address = &fwlib::get_ipsec_net_ip($value, 11);
 581                 if ($network_address) {
 582                         push(@ret, $network_address);
 583                 }
 584
 585         # The firewall's own IP addresses.
 586         } elsif ($key ~~ ["ipfire", "ipfire_src"]) {
 587                 # ALL
 588                 if ($value eq "ALL") {
 589                         push(@ret, "0/0");
 590
 591                 # GREEN
 592                 } elsif ($value eq "GREEN") {
 593                         push(@ret, $defaultNetworks{"GREEN_ADDRESS"});
 594
 595                 # BLUE
 596                 } elsif ($value eq "BLUE") {
 597                         push(@ret, $defaultNetworks{"BLUE_ADDRESS"});
 598
 599                 # ORANGE
 600                 } elsif ($value eq "ORANGE") {
 601                         push(@ret, $defaultNetworks{"ORANGE_ADDRESS"});
 602
 603                 # RED
 604                 } elsif ($value ~~ ["RED", "RED1"]) {
 605                         my $address = &get_external_address();
 606                         if ($address) {
 607                                 push(@ret, $address);
 608                         }
 609
 610                 # Aliases
 611                 } else {
 612                         my %alias = &get_alias($value);
 613                         if (%alias) {
 614                                 push(@ret, $alias{"IPT"});
 615                         }
 616                 }
 617
 618         # If nothing was selected, we assume "any".
 619         } else {
 620                 push(@ret, "0/0");
 621         }
 622
 623         return @ret;
 624 }
 625
 626 sub get_protocols {
 627         my $hash = shift;
 628         my $key = shift;
 629
 630         my $uses_source_ports = ($$hash{$key}[7] eq "ON");
 631         my $uses_services = ($$hash{$key}[11] eq "ON");
 632
 633         my @protocols = ();
 634
 635         # Rules which don't have source ports or services (like ICMP, ESP, ...).
 636         if (!$uses_source_ports && !$uses_services) {
 637                 push(@protocols, $$hash{$key}[8]);
 638
 639         # Rules which either use ports or services.
 640         } elsif ($uses_source_ports || $uses_services) {
 641                 # Check if service group or service
 642                 if ($$hash{$key}[14] eq 'cust_srv') {
 643                         push(@protocols, &fwlib::get_srv_prot($$hash{$key}[15]));
 644
 645                 } elsif($$hash{$key}[14] eq 'cust_srvgrp'){
 646                         my $protos = &fwlib::get_srvgrp_prot($$hash{$key}[15]);
 647                         push(@protocols, split(",", $protos));
 648
 649                 } else {
 650                         # Fetch the protocol for this rule.
 651                         my $protocol = lc($$hash{$key}[8]);
 652
 653                         # Fetch source and destination ports for this rule.
 654                         my $source_ports = $$hash{$key}[10];
 655                         my $destination_ports = $$hash{$key}[15];
 656
 657                         # Check if ports are set for protocols which do not support ports.
 658                         if (!($protocol ~~ @PROTOCOLS_WITH_PORTS) && ($source_ports || $destination_ports)) {
 659                                 print_error("$protocol does not support ports");
 660                                 return ();
 661                         }
 662
 663                         push(@protocols, $protocol);
 664                 }
 665         }
 666
 667         # Remove all empty elements
 668         @protocols = map { $_ ? $_ : () } @protocols;
 669
 670         # If no protocol has been defined, we assume "all".
 671         if (!@protocols) {
 672                 push(@protocols, "all");
 673         }
 674
 675         # Make all protocol names lowercase.
 676         @protocols = map { lc } @protocols;
 677
 678         return @protocols;
 679 }
 680
 681 sub get_protocol_options {
 682         my $hash = shift;
 683         my $key  = shift;
 684         my $protocol = shift;
 685         my @options = ();
 686
 687         # Process source ports.
 688         my $use_src_ports = ($$hash{$key}[7] eq "ON");
 689         my $src_ports     = $$hash{$key}[10];
 690
 691         if ($use_src_ports && $src_ports) {
 692                 push(@options, &format_ports($src_ports, "src"));
 693         }
 694
 695         # Process destination ports.
 696         my $use_dst_ports  = ($$hash{$key}[11] eq "ON");
 697         my $use_dnat       = (($$hash{$key}[28] eq "ON") && ($$hash{$key}[31] eq "dnat"));
 698
 699         if ($use_dst_ports) {
 700                 my $dst_ports_mode = $$hash{$key}[14];
 701                 my $dst_ports      = $$hash{$key}[15];
 702
 703                 if (($dst_ports_mode eq "TGT_PORT") && $dst_ports) {
 704                         if ($use_dnat && $$hash{$key}[30]) {
 705                                 $dst_ports = $$hash{$key}[30];
 706                         }
 707                         push(@options, &format_ports($dst_ports, "dst"));
 708
 709                 } elsif ($dst_ports_mode eq "cust_srv") {
 710                         if ($protocol eq "ICMP") {
 711                                 push(@options, ("--icmp-type", &fwlib::get_srv_port($dst_ports, 3, "ICMP")));
 712                         } else {
 713                                 $dst_ports = &fwlib::get_srv_port($dst_ports, 1, uc($protocol));
 714                                 push(@options, &format_ports($dst_ports, "dst"));
 715                         }
 716
 717                 } elsif ($dst_ports_mode eq "cust_srvgrp") {
 718                         push(@options, &fwlib::get_srvgrp_port($dst_ports, uc($protocol)));
 719                 }
 720         }
 721
 722         # Check if a single ICMP type is selected.
 723         if (!$use_src_ports && !$use_dst_ports && $protocol eq "icmp") {
 724                 my $icmp_type = $$hash{$key}[9];
 725
 726                 if (($icmp_type ne "All ICMP-Types") && $icmp_type) {
 727                         push(@options, ("--icmp-type", $icmp_type));
 728                 }
 729         }
 730
 731         return @options;
 732 }
 733
 734 sub format_ports {
 735         my $ports = shift;
 736         my $type = shift;
 737
 738         my $arg;
 739         if ($type eq "src") {
 740                 $arg = "--sport";
 741         } elsif ($type eq "dst") {
 742                 $arg = "--dport";
 743         }
 744
 745         my @options = ();
 746
 747         if ($ports =~ /\|/) {
 748                 $ports =~ s/\|/,/g;
 749                 push(@options, ("-m", "multiport"));
 750         }
 751
 752         if ($ports) {
 753                 push(@options, ($arg, $ports));
 754         }
 755
 756         return @options;
 757 }
 758
 759 sub get_dnat_target_port {
 760         my $hash = shift;
 761         my $key  = shift;
 762
 763         if ($$hash{$key}[14] eq "TGT_PORT") {
 764                 my $port = $$hash{$key}[15];
 765                 my $external_port = $$hash{$key}[30];
 766
 767                 if ($external_port && ($port ne $external_port)) {
 768                         return $$hash{$key}[15];
 769                 }
 770         }
 771 }
 772
 773 sub add_dnat_mangle_rules {
 774         my $nat_address = shift;
 775         my @options = @_;
 776
 777         my $mark = 0;
 778         foreach my $zone ("GREEN", "BLUE", "ORANGE") {
 779                 $mark++;
 780
 781                 # Skip rule if not all required information exists.
 782                 next unless (exists $defaultNetworks{$zone . "_NETADDRESS"});
 783                 next unless (exists $defaultNetworks{$zone . "_NETMASK"});
 784
 785                 my @mangle_options = @options;
 786
 787                 my $netaddress = $defaultNetworks{$zone . "_NETADDRESS"};
 788                 $netaddress .= "/" . $defaultNetworks{$zone . "_NETMASK"};
 789
 790                 push(@mangle_options, ("-s", $netaddress, "-d", $nat_address));
 791                 push(@mangle_options, ("-j", "MARK", "--set-mark", $mark));
 792
 793                 run("$IPTABLES -t mangle -A $CHAIN_MANGLE_NAT_DESTINATION_FIX @mangle_options");
 794         }
 795 }
 796
 797 sub make_log_limit_options {
 798         my @options = ("-m", "limit");
 799
 800         # Maybe we should get this from the configuration.
 801         my $limit = 10;
 802
 803         # We limit log messages to $limit messages per minute.
 804         push(@options, ("--limit", "$limit/min"));
 805
 806         # And we allow bursts of 2x $limit.
 807         push(@options, ("--limit-burst", $limit * 2));
 808
 809         return @options;
 810 }
 811
 812 sub firewall_is_in_subnet {
 813         my $subnet = shift;
 814
 815         my ($net_address, $net_mask) = split("/", $subnet);
 816         if (!$net_mask) {
 817                 return 0;
 818         }
 819
 820         # ORANGE is missing here, because nothing may ever access
 821         # the firewall from this network.
 822         foreach my $zone ("GREEN", "BLUE") {
 823                 next unless (exists $defaultNetworks{$zone . "_ADDRESS"});
 824
 825                 my $zone_address = $defaultNetworks{$zone . "_ADDRESS"};
 826
 827                 if (&General::IpInSubnet($zone_address, $net_address, $net_mask)) {
 828                         return 1;
 829                 }
 830         }
 831
 832         return 0;
 833 }