config-scripts/cups-defaults.m4

   1 dnl
   2 dnl "$Id$"
   3 dnl
   4 dnl   Default cupsd configuration settings for the Common UNIX Printing System
   5 dnl   (CUPS).
   6 dnl
   7 dnl   Copyright 2006 by Easy Software Products, all rights reserved.
   8 dnl
   9 dnl   These coded instructions, statements, and computer programs are the
  10 dnl   property of Easy Software Products and are protected by Federal
  11 dnl   copyright law.  Distribution and use rights are outlined in the file
  12 dnl   "LICENSE.txt" which should have been included with this file.  If this
  13 dnl   file is missing or damaged please contact Easy Software Products
  14 dnl   at:
  15 dnl
  16 dnl       Attn: CUPS Licensing Information
  17 dnl       Easy Software Products
  18 dnl       44141 Airport View Drive, Suite 204
  19 dnl       Hollywood, Maryland 20636 USA
  20 dnl
  21 dnl       Voice: (301) 373-9600
  22 dnl       EMail: cups-info@cups.org
  23 dnl         WWW: http://www.cups.org
  24 dnl
  25
  26 dnl Default langugages...
  27 AC_ARG_WITH(languages, [  --with-languages        set installed languages, default="es ja" ],
  28         LANGUAGES="$withval",
  29         LANGUAGES="es ja")
  30 AC_SUBST(LANGUAGES)
  31
  32 dnl Default ConfigFilePerm
  33 AC_ARG_WITH(config_perm, [  --with-config-file-perm set default ConfigFilePerm value, default=0640],
  34         CUPS_CONFIG_FILE_PERM="$withval",
  35         if test "x$uname" = xDarwin; then
  36                 CUPS_CONFIG_FILE_PERM="644"
  37         else
  38                 CUPS_CONFIG_FILE_PERM="640"
  39         fi)
  40 AC_SUBST(CUPS_CONFIG_FILE_PERM)
  41 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_CONFIG_FILE_PERM, 0$CUPS_CONFIG_FILE_PERM)
  42
  43 dnl Default LogFilePerm
  44 AC_ARG_WITH(log_perm, [  --with-log-file-perm    set default LogFilePerm value, default=0644],
  45         CUPS_LOG_FILE_PERM="$withval",
  46         CUPS_LOG_FILE_PERM="644")
  47 AC_SUBST(CUPS_LOG_FILE_PERM)
  48 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LOG_FILE_PERM, 0$CUPS_LOG_FILE_PERM)
  49
  50 dnl Default Browsing
  51 AC_ARG_ENABLE(browsing, [  --enable-browsing       enable Browsing by default, default=yes])
  52 if test "x$enable_browsing" = xno; then
  53         CUPS_BROWSING="No"
  54         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 0)
  55 else
  56         CUPS_BROWSING="Yes"
  57         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 1)
  58 fi
  59 AC_SUBST(CUPS_BROWSING)
  60
  61 dnl Default BrowseLocalProtocols
  62 AC_ARG_WITH(browse_local, [  --with-local-protocols  set default BrowseLocalProtocols, default="CUPS"],
  63         CUPS_BROWSE_LOCAL_PROTOCOLS="$withval",
  64         CUPS_BROWSE_LOCAL_PROTOCOLS="CUPS")
  65 AC_SUBST(CUPS_BROWSE_LOCAL_PROTOCOLS)
  66 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_LOCAL_PROTOCOLS,
  67         "$CUPS_BROWSE_LOCAL_PROTOCOLS")
  68
  69 dnl Default BrowseRemoteProtocols
  70 AC_ARG_WITH(browse_remote, [  --with-remote-protocols set default BrowseRemoteProtocols, default="CUPS"],
  71         CUPS_BROWSE_REMOTE_PROTOCOLS="$withval",
  72         CUPS_BROWSE_REMOTE_PROTOCOLS="CUPS")
  73 AC_SUBST(CUPS_BROWSE_REMOTE_PROTOCOLS)
  74 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_REMOTE_PROTOCOLS,
  75         "$CUPS_BROWSE_REMOTE_PROTOCOLS")
  76
  77 dnl Default BrowseShortNames
  78 AC_ARG_ENABLE(browse_short, [  --enable-browse-short-names
  79                           enable BrowseShortNames by default, default=yes])
  80 if test "x$enable_browse_short" = xno; then
  81         CUPS_BROWSE_SHORT_NAMES="No"
  82         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_SHORT_NAMES, 0)
  83 else
  84         CUPS_BROWSE_SHORT_NAMES="Yes"
  85         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_SHORT_NAMES, 1)
  86 fi
  87 AC_SUBST(CUPS_BROWSE_SHORT_NAMES)
  88
  89 dnl Default DefaultShared
  90 AC_ARG_ENABLE(default_shared, [  --enable-default-shared enable DefaultShared by default, default=yes])
  91 if test "x$enable_default_shared" = xno; then
  92         CUPS_DEFAULT_SHARED="No"
  93         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 0)
  94 else
  95         CUPS_DEFAULT_SHARED="Yes"
  96         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 1)
  97 fi
  98 AC_SUBST(CUPS_DEFAULT_SHARED)
  99
 100 dnl Default ImplicitClasses
 101 AC_ARG_ENABLE(implicit, [  --enable-implicit-classes
 102                           enable ImplicitClasses by default, default=yes])
 103 if test "x$enable_implicit" = xno; then
 104         CUPS_IMPLICIT_CLASSES="No"
 105         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IMPLICIT_CLASSES, 0)
 106 else
 107         CUPS_IMPLICIT_CLASSES="Yes"
 108         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IMPLICIT_CLASSES, 1)
 109 fi
 110 AC_SUBST(CUPS_IMPLICIT_CLASSES)
 111
 112 dnl Default UseNetworkDefault
 113 AC_ARG_ENABLE(network_default, [  --enable-use-network-default
 114                           enable UseNetworkDefault by default, default=yes])
 115 if test "x$enable_network_default" = xno; then
 116         CUPS_USE_NETWORK_DEFAULT="No"
 117         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 0)
 118 else
 119         CUPS_USE_NETWORK_DEFAULT="Yes"
 120         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 1)
 121 fi
 122 AC_SUBST(CUPS_USE_NETWORK_DEFAULT)
 123
 124 dnl Determine the correct username and group for this OS...
 125 AC_ARG_WITH(cups-user, [  --with-cups-user        set default user for CUPS],
 126         CUPS_USER="$withval",
 127         AC_MSG_CHECKING(for default print user)
 128         if test -f /etc/passwd; then
 129                 CUPS_USER=""
 130                 for user in lp lpd guest daemon nobody; do
 131                         if test "`grep \^${user}: /etc/passwd`" != ""; then
 132                                 CUPS_USER="$user"
 133                                 AC_MSG_RESULT($user)
 134                                 break;
 135                         fi
 136                 done
 137
 138                 if test x$CUPS_USER = x; then
 139                         CUPS_USER="nobody"
 140                         AC_MSG_RESULT(not found, using "$CUPS_USER")
 141                 fi
 142         else
 143                 CUPS_USER="nobody"
 144                 AC_MSG_RESULT(no password file, using "$CUPS_USER")
 145         fi)
 146
 147 AC_ARG_WITH(cups-group, [  --with-cups-group       set default group for CUPS],
 148         CUPS_GROUP="$withval",
 149         AC_MSG_CHECKING(for default print group)
 150         if test -f /etc/group; then
 151                 if test x$uname = xDarwin; then
 152                         GROUP_LIST="nobody"
 153                 else
 154                         GROUP_LIST="lp nobody"
 155                 fi
 156
 157                 CUPS_GROUP=""
 158                 for group in $GROUP_LIST; do
 159                         if test "`grep \^${group}: /etc/group`" != ""; then
 160                                 CUPS_GROUP="$group"
 161                                 AC_MSG_RESULT($group)
 162                                 break;
 163                         fi
 164                 done
 165
 166                 if test x$CUPS_GROUP = x; then
 167                         CUPS_GROUP="nobody"
 168                         AC_MSG_RESULT(not found, using "$CUPS_GROUP")
 169                 fi
 170         else
 171                 CUPS_GROUP="nobody"
 172                 AC_MSG_RESULT(no group file, using "$CUPS_GROUP")
 173         fi)
 174
 175 AC_ARG_WITH(system-groups, [  --with-system-groups    set default system groups for CUPS],
 176         CUPS_SYSTEM_GROUPS="$withval",
 177         if test x$uname = xDarwin; then
 178                 GROUP_LIST="admin"
 179         else
 180                 GROUP_LIST="lpadmin sys system root"
 181         fi
 182
 183         AC_MSG_CHECKING(for default system groups)
 184         if test -f /etc/group; then
 185                 CUPS_SYSTEM_GROUPS=""
 186                 for group in $GROUP_LIST; do
 187                         if test "`grep \^${group}: /etc/group`" != ""; then
 188                                 if test "x$CUPS_SYSTEM_GROUPS" = x; then
 189                                         CUPS_SYSTEM_GROUPS="$group"
 190                                 else
 191                                         CUPS_SYSTEM_GROUPS="$CUPS_SYSTEM_GROUPS $group"
 192                                 fi
 193                         fi
 194                 done
 195
 196                 if test "x$CUPS_SYSTEM_GROUPS" = x; then
 197                         CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 198                         AC_MSG_RESULT(no groups found, using "$CUPS_SYSTEM_GROUPS")
 199                 else
 200                         AC_MSG_RESULT("$CUPS_SYSTEM_GROUPS")
 201                 fi
 202         else
 203                 CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 204                 AC_MSG_RESULT(no group file, using "$CUPS_SYSTEM_GROUPS")
 205         fi)
 206
 207 CUPS_PRIMARY_SYSTEM_GROUP="`echo $CUPS_SYSTEM_GROUPS | awk '{print $1}'`"
 208
 209 AC_SUBST(CUPS_USER)
 210 AC_SUBST(CUPS_GROUP)
 211 AC_SUBST(CUPS_SYSTEM_GROUPS)
 212 AC_SUBST(CUPS_PRIMARY_SYSTEM_GROUP)
 213
 214 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USER, "$CUPS_USER")
 215 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_GROUP, "$CUPS_GROUP")
 216 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SYSTEM_GROUPS, "$CUPS_SYSTEM_GROUPS")
 217
 218
 219 dnl
 220 dnl End of "$Id$".
 221 dnl