config-scripts/cups-defaults.m4

   1 dnl
   2 dnl Default cupsd configuration settings for CUPS.
   3 dnl
   4 dnl Copyright 2007-2015 by Apple Inc.
   5 dnl Copyright 2006-2007 by Easy Software Products, all rights reserved.
   6 dnl
   7 dnl These coded instructions, statements, and computer programs are the
   8 dnl property of Apple Inc. and are protected by Federal copyright
   9 dnl law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  10 dnl which should have been included with this file.  If this file is
  11 dnl file is missing or damaged, see the license at "http://www.cups.org/".
  12 dnl
  13
  14 dnl Default languages...
  15 LANGUAGES="`ls -1 locale/cups_*.po 2>/dev/null | sed -e '1,$s/locale\/cups_//' -e '1,$s/\.po//' | tr '\n' ' '`"
  16
  17 AC_ARG_WITH(languages, [  --with-languages        set installed languages, default=all ],[
  18         case "$withval" in
  19                 none | no) LANGUAGES="" ;;
  20                 all) ;;
  21                 *) LANGUAGES="$withval" ;;
  22         esac])
  23 AC_SUBST(LANGUAGES)
  24
  25 dnl macOS bundle-based localization support
  26 AC_ARG_WITH(bundledir, [  --with-bundledir        set macOS localization bundle directory ],
  27         CUPS_BUNDLEDIR="$withval",
  28         if test "x$uname" = xDarwin -a $uversion -ge 100; then
  29                 CUPS_BUNDLEDIR="/System/Library/Frameworks/ApplicationServices.framework/Versions/A/Frameworks/PrintCore.framework/Versions/A"
  30                 LANGUAGES=""
  31         else
  32                 CUPS_BUNDLEDIR=""
  33         fi)
  34
  35 AC_SUBST(CUPS_BUNDLEDIR)
  36 if test "x$CUPS_BUNDLEDIR" != x; then
  37         AC_DEFINE_UNQUOTED(CUPS_BUNDLEDIR, "$CUPS_BUNDLEDIR")
  38 fi
  39
  40 dnl Default ConfigFilePerm
  41 AC_ARG_WITH(config_file_perm, [  --with-config-file-perm set default ConfigFilePerm value, default=0640],
  42         CUPS_CONFIG_FILE_PERM="$withval",
  43         if test "x$uname" = xDarwin; then
  44                 CUPS_CONFIG_FILE_PERM="644"
  45         else
  46                 CUPS_CONFIG_FILE_PERM="640"
  47         fi)
  48 AC_SUBST(CUPS_CONFIG_FILE_PERM)
  49 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_CONFIG_FILE_PERM, 0$CUPS_CONFIG_FILE_PERM)
  50
  51 dnl Default permissions for cupsd
  52 AC_ARG_WITH(cupsd_file_perm, [  --with-cupsd-file-perm  set default cupsd permissions, default=0500],
  53         CUPS_CUPSD_FILE_PERM="$withval",
  54         CUPS_CUPSD_FILE_PERM="500")
  55 AC_SUBST(CUPS_CUPSD_FILE_PERM)
  56
  57 dnl Default LogFilePerm
  58 AC_ARG_WITH(log_file_perm, [  --with-log-file-perm    set default LogFilePerm value, default=0644],
  59         CUPS_LOG_FILE_PERM="$withval",
  60         CUPS_LOG_FILE_PERM="644")
  61 AC_SUBST(CUPS_LOG_FILE_PERM)
  62 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LOG_FILE_PERM, 0$CUPS_LOG_FILE_PERM)
  63
  64 dnl Default FatalErrors
  65 AC_ARG_WITH(fatal_errors, [  --with-fatal-errors     set default FatalErrors value, default=config],
  66         CUPS_FATAL_ERRORS="$withval",
  67         CUPS_FATAL_ERRORS="config")
  68 AC_SUBST(CUPS_FATAL_ERRORS)
  69 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_FATAL_ERRORS, "$CUPS_FATAL_ERRORS")
  70
  71 dnl Default LogLevel
  72 AC_ARG_WITH(log_level, [  --with-log-level        set default LogLevel value, default=warn],
  73         CUPS_LOG_LEVEL="$withval",
  74         CUPS_LOG_LEVEL="warn")
  75 AC_SUBST(CUPS_LOG_LEVEL)
  76 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LOG_LEVEL, "$CUPS_LOG_LEVEL")
  77
  78 dnl Default AccessLogLevel
  79 AC_ARG_WITH(access_log_level, [  --with-access-log-level set default AccessLogLevel value, default=none],
  80         CUPS_ACCESS_LOG_LEVEL="$withval",
  81         CUPS_ACCESS_LOG_LEVEL="none")
  82 AC_SUBST(CUPS_ACCESS_LOG_LEVEL)
  83 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_ACCESS_LOG_LEVEL, "$CUPS_ACCESS_LOG_LEVEL")
  84
  85 dnl Default PageLogFormat
  86 AC_ARG_ENABLE(page_logging, [  --enable-page-logging   enable page_log by default])
  87 if test "x$enable_page_logging" = xyes; then
  88         CUPS_PAGE_LOG_FORMAT=""
  89 else
  90         CUPS_PAGE_LOG_FORMAT="PageLogFormat"
  91 fi
  92 AC_SUBST(CUPS_PAGE_LOG_FORMAT)
  93
  94 dnl Default Browsing
  95 AC_ARG_ENABLE(browsing, [  --disable-browsing      disable Browsing by default])
  96 if test "x$enable_browsing" = xno; then
  97         CUPS_BROWSING="No"
  98         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 0)
  99 else
 100         CUPS_BROWSING="Yes"
 101         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 1)
 102 fi
 103 AC_SUBST(CUPS_BROWSING)
 104
 105 dnl Default BrowseLocalProtocols
 106 AC_ARG_WITH(local_protocols, [  --with-local-protocols  set default BrowseLocalProtocols, default=""],
 107         default_local_protocols="$withval",
 108         default_local_protocols="default")
 109
 110 if test x$with_local_protocols != xno; then
 111         if test "x$default_local_protocols" = "xdefault"; then
 112                 if test "x$DNSSD_BACKEND" != "x"; then
 113                         CUPS_BROWSE_LOCAL_PROTOCOLS="dnssd"
 114                 else
 115                         CUPS_BROWSE_LOCAL_PROTOCOLS=""
 116                 fi
 117         else
 118                 CUPS_BROWSE_LOCAL_PROTOCOLS="$default_local_protocols"
 119         fi
 120 else
 121         CUPS_BROWSE_LOCAL_PROTOCOLS=""
 122 fi
 123
 124 AC_SUBST(CUPS_BROWSE_LOCAL_PROTOCOLS)
 125 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_LOCAL_PROTOCOLS,
 126         "$CUPS_BROWSE_LOCAL_PROTOCOLS")
 127
 128 dnl Default DefaultShared
 129 AC_ARG_ENABLE(default_shared, [  --disable-default-shared
 130                           disable DefaultShared by default])
 131 if test "x$enable_default_shared" = xno; then
 132         CUPS_DEFAULT_SHARED="No"
 133         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 0)
 134 else
 135         CUPS_DEFAULT_SHARED="Yes"
 136         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 1)
 137 fi
 138 AC_SUBST(CUPS_DEFAULT_SHARED)
 139
 140 dnl Determine the correct username and group for this OS...
 141 AC_ARG_WITH(cups_user, [  --with-cups-user        set default user for CUPS],
 142         CUPS_USER="$withval",
 143         AC_MSG_CHECKING(for default print user)
 144         if test x$uname = xDarwin; then
 145                 if test x`id -u _lp 2>/dev/null` = x; then
 146                         CUPS_USER="lp";
 147                 else
 148                         CUPS_USER="_lp";
 149                 fi
 150                 AC_MSG_RESULT($CUPS_USER)
 151         elif test -f /etc/passwd; then
 152                 CUPS_USER=""
 153                 for user in lp lpd guest daemon nobody; do
 154                         if test "`grep \^${user}: /etc/passwd`" != ""; then
 155                                 CUPS_USER="$user"
 156                                 AC_MSG_RESULT($user)
 157                                 break;
 158                         fi
 159                 done
 160
 161                 if test x$CUPS_USER = x; then
 162                         CUPS_USER="nobody"
 163                         AC_MSG_RESULT(not found, using "$CUPS_USER")
 164                 fi
 165         else
 166                 CUPS_USER="nobody"
 167                 AC_MSG_RESULT(no password file, using "$CUPS_USER")
 168         fi)
 169
 170 if test "x$CUPS_USER" = "xroot" -o "x$CUPS_USER" = "x0"; then
 171         AC_MSG_ERROR([The default user for CUPS cannot be root!])
 172 fi
 173
 174 AC_ARG_WITH(cups_group, [  --with-cups-group       set default group for CUPS],
 175         CUPS_GROUP="$withval",
 176         AC_MSG_CHECKING(for default print group)
 177         if test x$uname = xDarwin; then
 178                 if test x`id -g _lp 2>/dev/null` = x; then
 179                         CUPS_GROUP="lp";
 180                 else
 181                         CUPS_GROUP="_lp";
 182                 fi
 183                 AC_MSG_RESULT($CUPS_GROUP)
 184         elif test -f /etc/group; then
 185                 GROUP_LIST="_lp lp nobody"
 186                 CUPS_GROUP=""
 187                 for group in $GROUP_LIST; do
 188                         if test "`grep \^${group}: /etc/group`" != ""; then
 189                                 CUPS_GROUP="$group"
 190                                 AC_MSG_RESULT($group)
 191                                 break;
 192                         fi
 193                 done
 194
 195                 if test x$CUPS_GROUP = x; then
 196                         CUPS_GROUP="nobody"
 197                         AC_MSG_RESULT(not found, using "$CUPS_GROUP")
 198                 fi
 199         else
 200                 CUPS_GROUP="nobody"
 201                 AC_MSG_RESULT(no group file, using "$CUPS_GROUP")
 202         fi)
 203
 204 if test "x$CUPS_GROUP" = "xroot" -o "x$CUPS_GROUP" = "xwheel" -o "x$CUPS_GROUP" = "x0"; then
 205         AC_MSG_ERROR([The default group for CUPS cannot be root!])
 206 fi
 207
 208 AC_ARG_WITH(system_groups, [  --with-system-groups    set default system groups for CUPS],
 209         CUPS_SYSTEM_GROUPS="$withval",
 210         if test x$uname = xDarwin; then
 211                 CUPS_SYSTEM_GROUPS="admin"
 212         else
 213                 AC_MSG_CHECKING(for default system groups)
 214                 if test -f /etc/group; then
 215                         CUPS_SYSTEM_GROUPS=""
 216                         GROUP_LIST="lpadmin sys system root"
 217                         for group in $GROUP_LIST; do
 218                                 if test "`grep \^${group}: /etc/group`" != ""; then
 219                                         if test "x$CUPS_SYSTEM_GROUPS" = x; then
 220                                                 CUPS_SYSTEM_GROUPS="$group"
 221                                         else
 222                                                 CUPS_SYSTEM_GROUPS="$CUPS_SYSTEM_GROUPS $group"
 223                                         fi
 224                                 fi
 225                         done
 226
 227                         if test "x$CUPS_SYSTEM_GROUPS" = x; then
 228                                 CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 229                                 AC_MSG_RESULT(no groups found, using "$CUPS_SYSTEM_GROUPS")
 230                         else
 231                                 AC_MSG_RESULT("$CUPS_SYSTEM_GROUPS")
 232                         fi
 233                 else
 234                         CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 235                         AC_MSG_RESULT(no group file, using "$CUPS_SYSTEM_GROUPS")
 236                 fi
 237         fi)
 238
 239 CUPS_PRIMARY_SYSTEM_GROUP="`echo $CUPS_SYSTEM_GROUPS | awk '{print $1}'`"
 240
 241 for group in $CUPS_SYSTEM_GROUPS; do
 242         if test "x$CUPS_GROUP" = "x$group"; then
 243                 AC_MSG_ERROR([The default system groups cannot contain the default CUPS group!])
 244         fi
 245 done
 246
 247 AC_SUBST(CUPS_USER)
 248 AC_SUBST(CUPS_GROUP)
 249 AC_SUBST(CUPS_SYSTEM_GROUPS)
 250 AC_SUBST(CUPS_PRIMARY_SYSTEM_GROUP)
 251
 252 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USER, "$CUPS_USER")
 253 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_GROUP, "$CUPS_GROUP")
 254 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SYSTEM_GROUPS, "$CUPS_SYSTEM_GROUPS")
 255
 256 dnl Default printcap file...
 257 AC_ARG_WITH(printcap, [  --with-printcap         set default printcap file],
 258         default_printcap="$withval",
 259         default_printcap="default")
 260
 261 if test x$default_printcap != xno; then
 262         if test "x$default_printcap" = "xdefault"; then
 263                 case $uname in
 264                         Darwin*)
 265                                 if test $uversion -ge 90; then
 266                                         CUPS_DEFAULT_PRINTCAP="/Library/Preferences/org.cups.printers.plist"
 267                                 else
 268                                         CUPS_DEFAULT_PRINTCAP="/etc/printcap"
 269                                 fi
 270                                 ;;
 271                         SunOS*)
 272                                 CUPS_DEFAULT_PRINTCAP="/etc/printers.conf"
 273                                 ;;
 274                         *)
 275                                 CUPS_DEFAULT_PRINTCAP="/etc/printcap"
 276                                 ;;
 277                 esac
 278         else
 279                 CUPS_DEFAULT_PRINTCAP="$default_printcap"
 280         fi
 281 else
 282         CUPS_DEFAULT_PRINTCAP=""
 283 fi
 284
 285 AC_SUBST(CUPS_DEFAULT_PRINTCAP)
 286 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_PRINTCAP, "$CUPS_DEFAULT_PRINTCAP")
 287
 288 dnl Default LPD config file...
 289 AC_ARG_WITH(lpdconfigfile, [  --with-lpdconfigfile    set default LPDConfigFile URI],
 290         default_lpdconfigfile="$withval",
 291         default_lpdconfigfile="default")
 292
 293 if test x$default_lpdconfigfile != xno; then
 294         if test "x$default_lpdconfigfile" = "xdefault"; then
 295                 case $uname in
 296                         Darwin*)
 297                                 CUPS_DEFAULT_LPD_CONFIG_FILE="launchd:///System/Library/LaunchDaemons/org.cups.cups-lpd.plist"
 298                                 ;;
 299                         *)
 300                                 if test "x$XINETD" != x; then
 301                                         CUPS_DEFAULT_LPD_CONFIG_FILE="xinetd://$XINETD/cups-lpd"
 302                                 else
 303                                         CUPS_DEFAULT_LPD_CONFIG_FILE=""
 304                                 fi
 305                                 ;;
 306                 esac
 307         else
 308                 CUPS_DEFAULT_LPD_CONFIG_FILE="$default_lpdconfigfile"
 309         fi
 310 else
 311         CUPS_DEFAULT_LPD_CONFIG_FILE=""
 312 fi
 313
 314 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LPD_CONFIG_FILE, "$CUPS_DEFAULT_LPD_CONFIG_FILE")
 315 AC_SUBST(CUPS_DEFAULT_LPD_CONFIG_FILE)
 316
 317 dnl Default SMB config file...
 318 AC_ARG_WITH(smbconfigfile, [  --with-smbconfigfile    set default SMBConfigFile URI],
 319         default_smbconfigfile="$withval",
 320         default_smbconfigfile="default")
 321
 322 if test x$default_smbconfigfile != xno; then
 323         if test "x$default_smbconfigfile" = "xdefault"; then
 324                 if test -f /etc/smb.conf; then
 325                         CUPS_DEFAULT_SMB_CONFIG_FILE="samba:///etc/smb.conf"
 326                 else
 327                         CUPS_DEFAULT_SMB_CONFIG_FILE=""
 328                 fi
 329         else
 330                 CUPS_DEFAULT_SMB_CONFIG_FILE="$default_smbconfigfile"
 331         fi
 332 else
 333         CUPS_DEFAULT_SMB_CONFIG_FILE=""
 334 fi
 335
 336 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SMB_CONFIG_FILE, "$CUPS_DEFAULT_SMB_CONFIG_FILE")
 337 AC_SUBST(CUPS_DEFAULT_SMB_CONFIG_FILE)
 338
 339 dnl Default MaxCopies value...
 340 AC_ARG_WITH(max-copies, [  --with-max-copies       set default max copies value, default=9999 ],
 341         CUPS_MAX_COPIES="$withval",
 342         CUPS_MAX_COPIES="9999")
 343
 344 AC_SUBST(CUPS_MAX_COPIES)
 345 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_MAX_COPIES, $CUPS_MAX_COPIES)
 346
 347 dnl Default raw printing state
 348 AC_ARG_ENABLE(raw_printing, [  --disable-raw-printing  do not allow raw printing by default])
 349 if test "x$enable_raw_printing" != xno; then
 350         DEFAULT_RAW_PRINTING=""
 351 else
 352         DEFAULT_RAW_PRINTING="#"
 353 fi
 354 AC_SUBST(DEFAULT_RAW_PRINTING)
 355
 356 dnl Default SNMP options...
 357 AC_ARG_WITH(snmp-address, [  --with-snmp-address     set SNMP query address, default=auto ],
 358         if test "x$withval" = x; then
 359                 CUPS_SNMP_ADDRESS=""
 360         else
 361                 CUPS_SNMP_ADDRESS="Address $withval"
 362         fi,
 363         if test "x$uname" = xDarwin; then
 364                 CUPS_SNMP_ADDRESS=""
 365         else
 366                 CUPS_SNMP_ADDRESS="Address @LOCAL"
 367         fi)
 368
 369 AC_ARG_WITH(snmp-community, [  --with-snmp-community   set SNMP community, default=public ],
 370         CUPS_SNMP_COMMUNITY="Community $withval",
 371         CUPS_SNMP_COMMUNITY="Community public")
 372
 373 AC_SUBST(CUPS_SNMP_ADDRESS)
 374 AC_SUBST(CUPS_SNMP_COMMUNITY)
 375
 376 dnl New default port definition for IPP...
 377 AC_ARG_WITH(ipp-port, [  --with-ipp-port         set port number for IPP, default=631 ],
 378         DEFAULT_IPP_PORT="$withval",
 379         DEFAULT_IPP_PORT="631")
 380
 381 AC_SUBST(DEFAULT_IPP_PORT)
 382 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IPP_PORT,$DEFAULT_IPP_PORT)
 383
 384 dnl Web interface...
 385 AC_ARG_ENABLE(webif, [  --enable-webif          enable the web interface by default, default=no for macOS])
 386 case "x$enable_webif" in
 387         xno)
 388                 CUPS_WEBIF=No
 389                 CUPS_DEFAULT_WEBIF=0
 390                 ;;
 391         xyes)
 392                 CUPS_WEBIF=Yes
 393                 CUPS_DEFAULT_WEBIF=1
 394                 ;;
 395         *)
 396                 if test $uname = Darwin; then
 397                         CUPS_WEBIF=No
 398                         CUPS_DEFAULT_WEBIF=0
 399                 else
 400                         CUPS_WEBIF=Yes
 401                         CUPS_DEFAULT_WEBIF=1
 402                 fi
 403                 ;;
 404 esac
 405
 406 AC_SUBST(CUPS_WEBIF)
 407 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_WEBIF, $CUPS_DEFAULT_WEBIF)