config-scripts/cups-defaults.m4

   1 dnl
   2 dnl "$Id: cups-defaults.m4 6656 2007-07-12 23:56:23Z mike $"
   3 dnl
   4 dnl   Default cupsd configuration settings for the Common UNIX Printing System
   5 dnl   (CUPS).
   6 dnl
   7 dnl   Copyright 2007 by Apple Inc.
   8 dnl   Copyright 2006-2007 by Easy Software Products, all rights reserved.
   9 dnl
  10 dnl   These coded instructions, statements, and computer programs are the
  11 dnl   property of Apple Inc. and are protected by Federal copyright
  12 dnl   law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  13 dnl   which should have been included with this file.  If this file is
  14 dnl   file is missing or damaged, see the license at "http://www.cups.org/".
  15 dnl
  16
  17 dnl Default languages...
  18 LANGUAGES="`ls -1 locale/*.po | sed -e '1,$s/locale\/cups_//' -e '1,$s/\.po//' | tr '\n' ' '`"
  19
  20 AC_ARG_WITH(languages, [  --with-languages        set installed languages, default=all ],[
  21         case "$withval" in
  22                 none | no) LANGUAGES="" ;;
  23                 all) ;;
  24                 *) LANGUAGES="$withval" ;;
  25         esac])
  26 AC_SUBST(LANGUAGES)
  27
  28 dnl Default ConfigFilePerm
  29 AC_ARG_WITH(config_file_perm, [  --with-config-file-perm set default ConfigFilePerm value, default=0640],
  30         CUPS_CONFIG_FILE_PERM="$withval",
  31         if test "x$uname" = xDarwin; then
  32                 CUPS_CONFIG_FILE_PERM="644"
  33         else
  34                 CUPS_CONFIG_FILE_PERM="640"
  35         fi)
  36 AC_SUBST(CUPS_CONFIG_FILE_PERM)
  37 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_CONFIG_FILE_PERM, 0$CUPS_CONFIG_FILE_PERM)
  38
  39 dnl Default LogFilePerm
  40 AC_ARG_WITH(log_file_perm, [  --with-log-file-perm    set default LogFilePerm value, default=0644],
  41         CUPS_LOG_FILE_PERM="$withval",
  42         CUPS_LOG_FILE_PERM="644")
  43 AC_SUBST(CUPS_LOG_FILE_PERM)
  44 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LOG_FILE_PERM, 0$CUPS_LOG_FILE_PERM)
  45
  46 dnl Default Browsing
  47 AC_ARG_ENABLE(browsing, [  --enable-browsing       enable Browsing by default, default=yes])
  48 if test "x$enable_browsing" = xno; then
  49         CUPS_BROWSING="No"
  50         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 0)
  51 else
  52         CUPS_BROWSING="Yes"
  53         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 1)
  54 fi
  55 AC_SUBST(CUPS_BROWSING)
  56
  57 dnl Default BrowseLocalProtocols
  58 AC_ARG_WITH(local_protocols, [  --with-local-protocols  set default BrowseLocalProtocols, default="CUPS"],
  59         default_local_protocols="$withval",
  60         default_local_protocols="default")
  61
  62 if test x$with_local_protocols != xno; then
  63         if test "x$default_local_protocols" = "xdefault"; then
  64                 if test "x$DNSSDLIBS" != "x"; then
  65                 CUPS_BROWSE_LOCAL_PROTOCOLS="CUPS dnssd"
  66         else
  67                 CUPS_BROWSE_LOCAL_PROTOCOLS="CUPS"
  68                 fi
  69         else
  70                 CUPS_BROWSE_LOCAL_PROTOCOLS="$default_local_protocols"
  71         fi
  72 else
  73         CUPS_BROWSE_LOCAL_PROTOCOLS=""
  74 fi
  75
  76 AC_SUBST(CUPS_BROWSE_LOCAL_PROTOCOLS)
  77 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_LOCAL_PROTOCOLS,
  78         "$CUPS_BROWSE_LOCAL_PROTOCOLS")
  79
  80 dnl Default BrowseRemoteProtocols
  81 AC_ARG_WITH(remote_protocols, [  --with-remote-protocols set default BrowseRemoteProtocols, default="CUPS"],
  82         default_remote_protocols="$withval",
  83         default_remote_protocols="default")
  84
  85 if test x$with_remote_protocols != xno; then
  86         if test "x$default_remote_protocols" = "xdefault"; then
  87                 if test "$uname" = "Darwin" -a $uversion -ge 90; then
  88                         CUPS_BROWSE_REMOTE_PROTOCOLS=""
  89                 else
  90                         CUPS_BROWSE_REMOTE_PROTOCOLS="CUPS"
  91                 fi
  92         else
  93                 CUPS_BROWSE_REMOTE_PROTOCOLS="$default_remote_protocols"
  94         fi
  95 else
  96         CUPS_BROWSE_REMOTE_PROTOCOLS=""
  97 fi
  98
  99 AC_SUBST(CUPS_BROWSE_REMOTE_PROTOCOLS)
 100 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_REMOTE_PROTOCOLS,
 101         "$CUPS_BROWSE_REMOTE_PROTOCOLS")
 102
 103 dnl Default BrowseShortNames
 104 AC_ARG_ENABLE(browse_short, [  --enable-browse-short-names
 105                           enable BrowseShortNames by default, default=yes])
 106 if test "x$enable_browse_short" = xno; then
 107         CUPS_BROWSE_SHORT_NAMES="No"
 108         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_SHORT_NAMES, 0)
 109 else
 110         CUPS_BROWSE_SHORT_NAMES="Yes"
 111         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_SHORT_NAMES, 1)
 112 fi
 113 AC_SUBST(CUPS_BROWSE_SHORT_NAMES)
 114
 115 dnl Default DefaultShared
 116 AC_ARG_ENABLE(default_shared, [  --enable-default-shared enable DefaultShared by default, default=yes])
 117 if test "x$enable_default_shared" = xno; then
 118         CUPS_DEFAULT_SHARED="No"
 119         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 0)
 120 else
 121         CUPS_DEFAULT_SHARED="Yes"
 122         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 1)
 123 fi
 124 AC_SUBST(CUPS_DEFAULT_SHARED)
 125
 126 dnl Default ImplicitClasses
 127 AC_ARG_ENABLE(implicit, [  --enable-implicit-classes
 128                           enable ImplicitClasses by default, default=yes])
 129 if test "x$enable_implicit" = xno; then
 130         CUPS_IMPLICIT_CLASSES="No"
 131         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IMPLICIT_CLASSES, 0)
 132 else
 133         CUPS_IMPLICIT_CLASSES="Yes"
 134         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IMPLICIT_CLASSES, 1)
 135 fi
 136 AC_SUBST(CUPS_IMPLICIT_CLASSES)
 137
 138 dnl Default UseNetworkDefault
 139 AC_ARG_ENABLE(use_network_default, [  --enable-use-network-default
 140                           enable UseNetworkDefault by default, default=auto])
 141 if test "x$enable_use_network_default" != xno; then
 142         AC_MSG_CHECKING(whether to use network default printers)
 143         if test "x$enable_use_network_default" = xyes -o $uname != Darwin; then
 144                 CUPS_USE_NETWORK_DEFAULT="Yes"
 145                 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 1)
 146                 AC_MSG_RESULT(yes)
 147         else
 148                 CUPS_USE_NETWORK_DEFAULT="No"
 149                 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 0)
 150                 AC_MSG_RESULT(no)
 151         fi
 152 else
 153         CUPS_USE_NETWORK_DEFAULT="No"
 154         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 0)
 155 fi
 156 AC_SUBST(CUPS_USE_NETWORK_DEFAULT)
 157
 158 dnl Determine the correct username and group for this OS...
 159 AC_ARG_WITH(cups_user, [  --with-cups-user        set default user for CUPS],
 160         CUPS_USER="$withval",
 161         AC_MSG_CHECKING(for default print user)
 162         if test -f /etc/passwd; then
 163                 CUPS_USER=""
 164                 for user in lp lpd guest daemon nobody; do
 165                         if test "`grep \^${user}: /etc/passwd`" != ""; then
 166                                 CUPS_USER="$user"
 167                                 AC_MSG_RESULT($user)
 168                                 break;
 169                         fi
 170                 done
 171
 172                 if test x$CUPS_USER = x; then
 173                         CUPS_USER="nobody"
 174                         AC_MSG_RESULT(not found, using "$CUPS_USER")
 175                 fi
 176         else
 177                 CUPS_USER="nobody"
 178                 AC_MSG_RESULT(no password file, using "$CUPS_USER")
 179         fi)
 180
 181 AC_ARG_WITH(cups_group, [  --with-cups-group       set default group for CUPS],
 182         CUPS_GROUP="$withval",
 183         AC_MSG_CHECKING(for default print group)
 184         if test -f /etc/group; then
 185                 GROUP_LIST="lp nobody"
 186                 CUPS_GROUP=""
 187                 for group in $GROUP_LIST; do
 188                         if test "`grep \^${group}: /etc/group`" != ""; then
 189                                 CUPS_GROUP="$group"
 190                                 AC_MSG_RESULT($group)
 191                                 break;
 192                         fi
 193                 done
 194
 195                 if test x$CUPS_GROUP = x; then
 196                         CUPS_GROUP="nobody"
 197                         AC_MSG_RESULT(not found, using "$CUPS_GROUP")
 198                 fi
 199         else
 200                 CUPS_GROUP="nobody"
 201                 AC_MSG_RESULT(no group file, using "$CUPS_GROUP")
 202         fi)
 203
 204 AC_ARG_WITH(system_groups, [  --with-system-groups    set default system groups for CUPS],
 205         CUPS_SYSTEM_GROUPS="$withval",
 206         if test x$uname = xDarwin; then
 207                 CUPS_SYSTEM_GROUPS="lpadmin admin"
 208         else
 209                 AC_MSG_CHECKING(for default system groups)
 210                 if test -f /etc/group; then
 211                         CUPS_SYSTEM_GROUPS=""
 212                         GROUP_LIST="lpadmin sys system root"
 213                         for group in $GROUP_LIST; do
 214                                 if test "`grep \^${group}: /etc/group`" != ""; then
 215                                         if test "x$CUPS_SYSTEM_GROUPS" = x; then
 216                                                 CUPS_SYSTEM_GROUPS="$group"
 217                                         else
 218                                                 CUPS_SYSTEM_GROUPS="$CUPS_SYSTEM_GROUPS $group"
 219                                         fi
 220                                 fi
 221                         done
 222
 223                         if test "x$CUPS_SYSTEM_GROUPS" = x; then
 224                                 CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 225                                 AC_MSG_RESULT(no groups found, using "$CUPS_SYSTEM_GROUPS")
 226                         else
 227                                 AC_MSG_RESULT("$CUPS_SYSTEM_GROUPS")
 228                         fi
 229                 else
 230                         CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 231                         AC_MSG_RESULT(no group file, using "$CUPS_SYSTEM_GROUPS")
 232                 fi
 233         fi)
 234
 235
 236 CUPS_PRIMARY_SYSTEM_GROUP="`echo $CUPS_SYSTEM_GROUPS | awk '{print $1}'`"
 237
 238 AC_SUBST(CUPS_USER)
 239 AC_SUBST(CUPS_GROUP)
 240 AC_SUBST(CUPS_SYSTEM_GROUPS)
 241 AC_SUBST(CUPS_PRIMARY_SYSTEM_GROUP)
 242
 243 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USER, "$CUPS_USER")
 244 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_GROUP, "$CUPS_GROUP")
 245 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SYSTEM_GROUPS, "$CUPS_SYSTEM_GROUPS")
 246
 247 dnl Default printcap file...
 248 AC_ARG_WITH(printcap, [  --with-printcap         set default printcap file],
 249         default_printcap="$withval",
 250         default_printcap="default")
 251
 252 if test x$default_printcap != xno; then
 253         if test "x$default_printcap" = "xdefault"; then
 254                 case $uname in
 255                         Darwin*)
 256                                 if test $uversion -ge 90; then
 257                                         CUPS_DEFAULT_PRINTCAP=""
 258                                 else
 259                                         CUPS_DEFAULT_PRINTCAP="/etc/printcap"
 260                                 fi
 261                                 ;;
 262                         SunOS*)
 263                                 CUPS_DEFAULT_PRINTCAP="/etc/printers.conf"
 264                                 ;;
 265                         *)
 266                                 CUPS_DEFAULT_PRINTCAP="/etc/printcap"
 267                                 ;;
 268                 esac
 269         else
 270                 CUPS_DEFAULT_PRINTCAP="$default_printcap"
 271         fi
 272 else
 273         CUPS_DEFAULT_PRINTCAP=""
 274 fi
 275
 276 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_PRINTCAP, "$CUPS_DEFAULT_PRINTCAP")
 277
 278 dnl Default MaxCopies value...
 279 AC_ARG_WITH(max-copies, [  --with-max-copies       set max copies value, default=100 ],
 280         CUPS_MAX_COPIES="$withval",
 281         if test "x$uname" = xDarwin; then
 282                 CUPS_MAX_COPIES="999"
 283         else
 284                 CUPS_MAX_COPIES="100"
 285         fi)
 286
 287 AC_SUBST(CUPS_MAX_COPIES)
 288 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_MAX_COPIES, $CUPS_MAX_COPIES)
 289
 290 dnl Default raw printing state
 291 AC_ARG_ENABLE(raw_printing, [  --enable-raw-printing   enable raw printing by default, default=auto])
 292 if test "x$enable_raw_printing" != xno; then
 293         AC_MSG_CHECKING(whether to enable raw printing)
 294         if test "x$enable_raw_printing" = xyes -o $uname = Darwin; then
 295                 DEFAULT_RAW_PRINTING=""
 296                 AC_MSG_RESULT(yes)
 297         else
 298                 DEFAULT_RAW_PRINTING="#"
 299                 AC_MSG_RESULT(no)
 300         fi
 301 else
 302         DEFAULT_RAW_PRINTING="#"
 303 fi
 304 AC_SUBST(DEFAULT_RAW_PRINTING)
 305
 306 dnl Default SNMP options...
 307 AC_ARG_WITH(snmp-address, [  --with-snmp-address     set SNMP query address, default=auto ],
 308         if test "x$withval" = x; then
 309                 CUPS_SNMP_ADDRESS=""
 310         else
 311                 CUPS_SNMP_ADDRESS="Address $withval"
 312         fi,
 313         if test "x$uname" = xDarwin; then
 314                 CUPS_SNMP_ADDRESS=""
 315         else
 316                 CUPS_SNMP_ADDRESS="Address @LOCAL"
 317         fi)
 318
 319 AC_ARG_WITH(snmp-community, [  --with-snmp-community   set SNMP community, default=public ],
 320         CUPS_SNMP_COMMUNITY="Community $withval",
 321         CUPS_SNMP_COMMUNITY="Community public")
 322
 323 AC_SUBST(CUPS_SNMP_ADDRESS)
 324 AC_SUBST(CUPS_SNMP_COMMUNITY)
 325
 326 dnl
 327 dnl End of "$Id: cups-defaults.m4 6656 2007-07-12 23:56:23Z mike $".
 328 dnl