config-scripts/cups-defaults.m4

   1 dnl
   2 dnl "$Id: cups-defaults.m4 7959 2008-09-17 19:30:58Z mike $"
   3 dnl
   4 dnl   Default cupsd configuration settings for CUPS.
   5 dnl
   6 dnl   Copyright 2007-2011 by Apple Inc.
   7 dnl   Copyright 2006-2007 by Easy Software Products, all rights reserved.
   8 dnl
   9 dnl   These coded instructions, statements, and computer programs are the
  10 dnl   property of Apple Inc. and are protected by Federal copyright
  11 dnl   law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  12 dnl   which should have been included with this file.  If this file is
  13 dnl   file is missing or damaged, see the license at "http://www.cups.org/".
  14 dnl
  15
  16 dnl Default languages...
  17 LANGUAGES="`ls -1 locale/cups_*.po | sed -e '1,$s/locale\/cups_//' -e '1,$s/\.po//' | tr '\n' ' '`"
  18
  19 AC_ARG_WITH(languages, [  --with-languages        set installed languages, default=all ],[
  20         case "$withval" in
  21                 none | no) LANGUAGES="" ;;
  22                 all) ;;
  23                 *) LANGUAGES="$withval" ;;
  24         esac])
  25 AC_SUBST(LANGUAGES)
  26
  27 dnl Mac OS X bundle-based localization support
  28 AC_ARG_WITH(bundledir, [  --with-bundledir     set Mac OS X localization bundle directory ],
  29         CUPS_BUNDLEDIR="$withval",
  30         if test "x$uname" = xDarwin -a $uversion -ge 100; then
  31                 CUPS_BUNDLEDIR="/System/Library/Frameworks/ApplicationServices.framework/Versions/A/Frameworks/PrintCore.framework/Versions/A"
  32                 LANGUAGES=""
  33         else
  34                 CUPS_BUNDLEDIR=""
  35         fi)
  36
  37 AC_SUBST(CUPS_BUNDLEDIR)
  38 if test "x$CUPS_BUNDLEDIR" != x; then
  39         AC_DEFINE_UNQUOTED(CUPS_BUNDLEDIR, "$CUPS_BUNDLEDIR")
  40 fi
  41
  42 dnl Default ConfigFilePerm
  43 AC_ARG_WITH(config_file_perm, [  --with-config-file-perm set default ConfigFilePerm value, default=0640],
  44         CUPS_CONFIG_FILE_PERM="$withval",
  45         if test "x$uname" = xDarwin; then
  46                 CUPS_CONFIG_FILE_PERM="644"
  47         else
  48                 CUPS_CONFIG_FILE_PERM="640"
  49         fi)
  50 AC_SUBST(CUPS_CONFIG_FILE_PERM)
  51 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_CONFIG_FILE_PERM, 0$CUPS_CONFIG_FILE_PERM)
  52
  53 dnl Default LogFilePerm
  54 AC_ARG_WITH(log_file_perm, [  --with-log-file-perm    set default LogFilePerm value, default=0644],
  55         CUPS_LOG_FILE_PERM="$withval",
  56         CUPS_LOG_FILE_PERM="644")
  57 AC_SUBST(CUPS_LOG_FILE_PERM)
  58 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LOG_FILE_PERM, 0$CUPS_LOG_FILE_PERM)
  59
  60 dnl Default FatalErrors
  61 AC_ARG_WITH(fatal_errors, [  --with-fatal-errors     set default FatalErrors value, default=config],
  62         CUPS_FATAL_ERRORS="$withval",
  63         CUPS_FATAL_ERRORS="config")
  64 AC_SUBST(CUPS_FATAL_ERRORS)
  65 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_FATAL_ERRORS, "$CUPS_FATAL_ERRORS")
  66
  67
  68 dnl Default LogLevel
  69 AC_ARG_WITH(log_level, [  --with-log-level        set default LogLevel value, default=warn],
  70         CUPS_LOG_LEVEL="$withval",
  71         CUPS_LOG_LEVEL="warn")
  72 AC_SUBST(CUPS_LOG_LEVEL)
  73 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LOG_LEVEL, "$CUPS_LOG_LEVEL")
  74
  75 dnl Default AccessLogLevel
  76 AC_ARG_WITH(access_log_level, [  --with-access-log-level set default AccessLogLevel value, default=actions],
  77         CUPS_ACCESS_LOG_LEVEL="$withval",
  78         CUPS_ACCESS_LOG_LEVEL="actions")
  79 AC_SUBST(CUPS_ACCESS_LOG_LEVEL)
  80 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_ACCESS_LOG_LEVEL, "$CUPS_ACCESS_LOG_LEVEL")
  81
  82 dnl Default Browsing
  83 AC_ARG_ENABLE(browsing, [  --disable-browsing      disable Browsing by default])
  84 if test "x$enable_browsing" = xno; then
  85         CUPS_BROWSING="No"
  86         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 0)
  87 else
  88         CUPS_BROWSING="Yes"
  89         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 1)
  90 fi
  91 AC_SUBST(CUPS_BROWSING)
  92
  93 dnl Default BrowseLocalProtocols
  94 AC_ARG_WITH(local_protocols, [  --with-local-protocols  set default BrowseLocalProtocols, default="CUPS"],
  95         default_local_protocols="$withval",
  96         default_local_protocols="default")
  97
  98 if test x$with_local_protocols != xno; then
  99         if test "x$default_local_protocols" = "xdefault"; then
 100                 if test "x$DNSSDLIBS" != "x"; then
 101                 CUPS_BROWSE_LOCAL_PROTOCOLS="CUPS dnssd"
 102         else
 103                 CUPS_BROWSE_LOCAL_PROTOCOLS="CUPS"
 104                 fi
 105         else
 106                 CUPS_BROWSE_LOCAL_PROTOCOLS="$default_local_protocols"
 107         fi
 108 else
 109         CUPS_BROWSE_LOCAL_PROTOCOLS=""
 110 fi
 111
 112 AC_SUBST(CUPS_BROWSE_LOCAL_PROTOCOLS)
 113 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_LOCAL_PROTOCOLS,
 114         "$CUPS_BROWSE_LOCAL_PROTOCOLS")
 115
 116 dnl Default BrowseRemoteProtocols
 117 AC_ARG_WITH(remote_protocols, [  --with-remote-protocols set default BrowseRemoteProtocols, default="CUPS"],
 118         default_remote_protocols="$withval",
 119         default_remote_protocols="default")
 120
 121 if test x$with_remote_protocols != xno; then
 122         if test "x$default_remote_protocols" = "xdefault"; then
 123                 if test "$uname" = "Darwin" -a $uversion -ge 90; then
 124                         CUPS_BROWSE_REMOTE_PROTOCOLS=""
 125                 else
 126                         CUPS_BROWSE_REMOTE_PROTOCOLS="CUPS"
 127                 fi
 128         else
 129                 CUPS_BROWSE_REMOTE_PROTOCOLS="$default_remote_protocols"
 130         fi
 131 else
 132         CUPS_BROWSE_REMOTE_PROTOCOLS=""
 133 fi
 134
 135 AC_SUBST(CUPS_BROWSE_REMOTE_PROTOCOLS)
 136 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_REMOTE_PROTOCOLS,
 137         "$CUPS_BROWSE_REMOTE_PROTOCOLS")
 138
 139 dnl Default BrowseShortNames
 140 AC_ARG_ENABLE(browse_short, [  --disable-browse-short-names
 141                           disable BrowseShortNames by default])
 142 if test "x$enable_browse_short" = xno; then
 143         CUPS_BROWSE_SHORT_NAMES="No"
 144         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_SHORT_NAMES, 0)
 145 else
 146         CUPS_BROWSE_SHORT_NAMES="Yes"
 147         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_SHORT_NAMES, 1)
 148 fi
 149 AC_SUBST(CUPS_BROWSE_SHORT_NAMES)
 150
 151 dnl Default DefaultShared
 152 AC_ARG_ENABLE(default_shared, [  --disable-default-shared
 153                           disable DefaultShared by default])
 154 if test "x$enable_default_shared" = xno; then
 155         CUPS_DEFAULT_SHARED="No"
 156         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 0)
 157 else
 158         CUPS_DEFAULT_SHARED="Yes"
 159         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 1)
 160 fi
 161 AC_SUBST(CUPS_DEFAULT_SHARED)
 162
 163 dnl Default ImplicitClasses
 164 AC_ARG_ENABLE(implicit, [  --disable-implicit-classes
 165                           disable ImplicitClasses by default])
 166 if test "x$enable_implicit" = xno; then
 167         CUPS_IMPLICIT_CLASSES="No"
 168         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IMPLICIT_CLASSES, 0)
 169 else
 170         CUPS_IMPLICIT_CLASSES="Yes"
 171         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IMPLICIT_CLASSES, 1)
 172 fi
 173 AC_SUBST(CUPS_IMPLICIT_CLASSES)
 174
 175 dnl Default UseNetworkDefault
 176 AC_ARG_ENABLE(use_network_default, [  --enable-use-network-default
 177                           set UseNetworkDefault to Yes by default])
 178 if test "x$enable_use_network_default" != xno; then
 179         AC_MSG_CHECKING(whether to use network default printers)
 180         if test "x$enable_use_network_default" = xyes -o $uname != Darwin; then
 181                 CUPS_USE_NETWORK_DEFAULT="Yes"
 182                 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 1)
 183                 AC_MSG_RESULT(yes)
 184         else
 185                 CUPS_USE_NETWORK_DEFAULT="No"
 186                 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 0)
 187                 AC_MSG_RESULT(no)
 188         fi
 189 else
 190         CUPS_USE_NETWORK_DEFAULT="No"
 191         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 0)
 192 fi
 193 AC_SUBST(CUPS_USE_NETWORK_DEFAULT)
 194
 195 dnl Determine the correct username and group for this OS...
 196 AC_ARG_WITH(cups_user, [  --with-cups-user        set default user for CUPS],
 197         CUPS_USER="$withval",
 198         AC_MSG_CHECKING(for default print user)
 199         if test x$uname = xDarwin; then
 200                 if test x`id -u _lp 2>/dev/null` = x; then
 201                         CUPS_USER="lp";
 202                 else
 203                         CUPS_USER="_lp";
 204                 fi
 205                 AC_MSG_RESULT($CUPS_USER)
 206         elif test -f /etc/passwd; then
 207                 CUPS_USER=""
 208                 for user in lp lpd guest daemon nobody; do
 209                         if test "`grep \^${user}: /etc/passwd`" != ""; then
 210                                 CUPS_USER="$user"
 211                                 AC_MSG_RESULT($user)
 212                                 break;
 213                         fi
 214                 done
 215
 216                 if test x$CUPS_USER = x; then
 217                         CUPS_USER="nobody"
 218                         AC_MSG_RESULT(not found, using "$CUPS_USER")
 219                 fi
 220         else
 221                 CUPS_USER="nobody"
 222                 AC_MSG_RESULT(no password file, using "$CUPS_USER")
 223         fi)
 224
 225 if test "x$CUPS_USER" = "xroot" -o "x$CUPS_USER" = "x0"; then
 226         AC_MSG_ERROR([The default user for CUPS cannot be root!])
 227 fi
 228
 229 AC_ARG_WITH(cups_group, [  --with-cups-group       set default group for CUPS],
 230         CUPS_GROUP="$withval",
 231         AC_MSG_CHECKING(for default print group)
 232         if test x$uname = xDarwin; then
 233                 if test x`id -g _lp 2>/dev/null` = x; then
 234                         CUPS_GROUP="lp";
 235                 else
 236                         CUPS_GROUP="_lp";
 237                 fi
 238                 AC_MSG_RESULT($CUPS_GROUP)
 239         elif test -f /etc/group; then
 240                 GROUP_LIST="_lp lp nobody"
 241                 CUPS_GROUP=""
 242                 for group in $GROUP_LIST; do
 243                         if test "`grep \^${group}: /etc/group`" != ""; then
 244                                 CUPS_GROUP="$group"
 245                                 AC_MSG_RESULT($group)
 246                                 break;
 247                         fi
 248                 done
 249
 250                 if test x$CUPS_GROUP = x; then
 251                         CUPS_GROUP="nobody"
 252                         AC_MSG_RESULT(not found, using "$CUPS_GROUP")
 253                 fi
 254         else
 255                 CUPS_GROUP="nobody"
 256                 AC_MSG_RESULT(no group file, using "$CUPS_GROUP")
 257         fi)
 258
 259 if test "x$CUPS_GROUP" = "xroot" -o "x$CUPS_GROUP" = "xwheel" -o "x$CUPS_GROUP" = "x0"; then
 260         AC_MSG_ERROR([The default group for CUPS cannot be root!])
 261 fi
 262
 263 AC_ARG_WITH(system_groups, [  --with-system-groups    set default system groups for CUPS],
 264         CUPS_SYSTEM_GROUPS="$withval",
 265         if test x$uname = xDarwin; then
 266                 CUPS_SYSTEM_GROUPS="admin"
 267         else
 268                 AC_MSG_CHECKING(for default system groups)
 269                 if test -f /etc/group; then
 270                         CUPS_SYSTEM_GROUPS=""
 271                         GROUP_LIST="lpadmin sys system root"
 272                         for group in $GROUP_LIST; do
 273                                 if test "`grep \^${group}: /etc/group`" != ""; then
 274                                         if test "x$CUPS_SYSTEM_GROUPS" = x; then
 275                                                 CUPS_SYSTEM_GROUPS="$group"
 276                                         else
 277                                                 CUPS_SYSTEM_GROUPS="$CUPS_SYSTEM_GROUPS $group"
 278                                         fi
 279                                 fi
 280                         done
 281
 282                         if test "x$CUPS_SYSTEM_GROUPS" = x; then
 283                                 CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 284                                 AC_MSG_RESULT(no groups found, using "$CUPS_SYSTEM_GROUPS")
 285                         else
 286                                 AC_MSG_RESULT("$CUPS_SYSTEM_GROUPS")
 287                         fi
 288                 else
 289                         CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 290                         AC_MSG_RESULT(no group file, using "$CUPS_SYSTEM_GROUPS")
 291                 fi
 292         fi)
 293
 294 CUPS_PRIMARY_SYSTEM_GROUP="`echo $CUPS_SYSTEM_GROUPS | awk '{print $1}'`"
 295
 296 for group in $CUPS_SYSTEM_GROUPS; do
 297         if test "x$CUPS_GROUP" = "x$group"; then
 298                 AC_MSG_ERROR([The default system groups cannot contain the default CUPS group!])
 299         fi
 300 done
 301
 302 AC_SUBST(CUPS_USER)
 303 AC_SUBST(CUPS_GROUP)
 304 AC_SUBST(CUPS_SYSTEM_GROUPS)
 305 AC_SUBST(CUPS_PRIMARY_SYSTEM_GROUP)
 306
 307 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USER, "$CUPS_USER")
 308 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_GROUP, "$CUPS_GROUP")
 309 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SYSTEM_GROUPS, "$CUPS_SYSTEM_GROUPS")
 310
 311 dnl Default printcap file...
 312 AC_ARG_WITH(printcap, [  --with-printcap         set default printcap file],
 313         default_printcap="$withval",
 314         default_printcap="default")
 315
 316 if test x$default_printcap != xno; then
 317         if test "x$default_printcap" = "xdefault"; then
 318                 case $uname in
 319                         Darwin*)
 320                                 if test $uversion -ge 90; then
 321                                         CUPS_DEFAULT_PRINTCAP="/Library/Preferences/org.cups.printers.plist"
 322                                 else
 323                                         CUPS_DEFAULT_PRINTCAP="/etc/printcap"
 324                                 fi
 325                                 ;;
 326                         SunOS*)
 327                                 CUPS_DEFAULT_PRINTCAP="/etc/printers.conf"
 328                                 ;;
 329                         *)
 330                                 CUPS_DEFAULT_PRINTCAP="/etc/printcap"
 331                                 ;;
 332                 esac
 333         else
 334                 CUPS_DEFAULT_PRINTCAP="$default_printcap"
 335         fi
 336 else
 337         CUPS_DEFAULT_PRINTCAP=""
 338 fi
 339
 340 AC_SUBST(CUPS_DEFAULT_PRINTCAP)
 341 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_PRINTCAP, "$CUPS_DEFAULT_PRINTCAP")
 342
 343 dnl Default LPD config file...
 344 AC_ARG_WITH(lpdconfigfile, [  --with-lpdconfigfile    set default LPDConfigFile URI],
 345         default_lpdconfigfile="$withval",
 346         default_lpdconfigfile="default")
 347
 348 if test x$default_lpdconfigfile != xno; then
 349         if test "x$default_lpdconfigfile" = "xdefault"; then
 350                 case $uname in
 351                         Darwin*)
 352                                 CUPS_DEFAULT_LPD_CONFIG_FILE="launchd:///System/Library/LaunchDaemons/org.cups.cups-lpd.plist"
 353                                 ;;
 354                         *)
 355                                 if test "x$XINETD" != x; then
 356                                         CUPS_DEFAULT_LPD_CONFIG_FILE="xinetd://$XINETD/cups-lpd"
 357                                 else
 358                                         CUPS_DEFAULT_LPD_CONFIG_FILE=""
 359                                 fi
 360                                 ;;
 361                 esac
 362         else
 363                 CUPS_DEFAULT_LPD_CONFIG_FILE="$default_lpdconfigfile"
 364         fi
 365 else
 366         CUPS_DEFAULT_LPD_CONFIG_FILE=""
 367 fi
 368
 369 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LPD_CONFIG_FILE, "$CUPS_DEFAULT_LPD_CONFIG_FILE")
 370
 371 dnl Default SMB config file...
 372 AC_ARG_WITH(smbconfigfile, [  --with-smbconfigfile    set default SMBConfigFile URI],
 373         default_smbconfigfile="$withval",
 374         default_smbconfigfile="default")
 375
 376 if test x$default_smbconfigfile != xno; then
 377         if test "x$default_smbconfigfile" = "xdefault"; then
 378                 if test -f /etc/smb.conf; then
 379                         CUPS_DEFAULT_SMB_CONFIG_FILE="samba:///etc/smb.conf"
 380                 else
 381                         CUPS_DEFAULT_SMB_CONFIG_FILE=""
 382                 fi
 383         else
 384                 CUPS_DEFAULT_SMB_CONFIG_FILE="$default_smbconfigfile"
 385         fi
 386 else
 387         CUPS_DEFAULT_SMB_CONFIG_FILE=""
 388 fi
 389
 390 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SMB_CONFIG_FILE, "$CUPS_DEFAULT_SMB_CONFIG_FILE")
 391
 392 dnl Default MaxCopies value...
 393 AC_ARG_WITH(max-copies, [  --with-max-copies       set default max copies value, default=9999 ],
 394         CUPS_MAX_COPIES="$withval",
 395         CUPS_MAX_COPIES="9999")
 396
 397 AC_SUBST(CUPS_MAX_COPIES)
 398 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_MAX_COPIES, $CUPS_MAX_COPIES)
 399
 400 dnl Default raw printing state
 401 AC_ARG_ENABLE(raw_printing, [  --disable-raw-printing  do not allow raw printing by default])
 402 if test "x$enable_raw_printing" != xno; then
 403         DEFAULT_RAW_PRINTING=""
 404 else
 405         DEFAULT_RAW_PRINTING="#"
 406 fi
 407 AC_SUBST(DEFAULT_RAW_PRINTING)
 408
 409 dnl Default SNMP options...
 410 AC_ARG_WITH(snmp-address, [  --with-snmp-address     set SNMP query address, default=auto ],
 411         if test "x$withval" = x; then
 412                 CUPS_SNMP_ADDRESS=""
 413         else
 414                 CUPS_SNMP_ADDRESS="Address $withval"
 415         fi,
 416         if test "x$uname" = xDarwin; then
 417                 CUPS_SNMP_ADDRESS=""
 418         else
 419                 CUPS_SNMP_ADDRESS="Address @LOCAL"
 420         fi)
 421
 422 AC_ARG_WITH(snmp-community, [  --with-snmp-community   set SNMP community, default=public ],
 423         CUPS_SNMP_COMMUNITY="Community $withval",
 424         CUPS_SNMP_COMMUNITY="Community public")
 425
 426 AC_SUBST(CUPS_SNMP_ADDRESS)
 427 AC_SUBST(CUPS_SNMP_COMMUNITY)
 428
 429 dnl New default port definition for IPP...
 430 AC_ARG_WITH(ipp-port, [  --with-ipp-port         set port number for IPP, default=631 ],
 431         DEFAULT_IPP_PORT="$withval",
 432         DEFAULT_IPP_PORT="631")
 433
 434 AC_SUBST(DEFAULT_IPP_PORT)
 435 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IPP_PORT,$DEFAULT_IPP_PORT)
 436
 437 dnl Web interface...
 438 AC_ARG_ENABLE(webif, [  --enable-webif          enable the web interface by default, default=no for Mac OS X])
 439 case "x$enable_webif" in
 440         xno)
 441                 CUPS_WEBIF=No
 442                 CUPS_DEFAULT_WEBIF=0
 443                 ;;
 444         xyes)
 445                 CUPS_WEBIF=Yes
 446                 CUPS_DEFAULT_WEBIF=1
 447                 ;;
 448         *)
 449                 if test $uname = Darwin; then
 450                         CUPS_WEBIF=No
 451                         CUPS_DEFAULT_WEBIF=0
 452                 else
 453                         CUPS_WEBIF=Yes
 454                         CUPS_DEFAULT_WEBIF=1
 455                 fi
 456                 ;;
 457 esac
 458
 459 AC_SUBST(CUPS_WEBIF)
 460 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_WEBIF, $CUPS_DEFAULT_WEBIF)
 461
 462 dnl
 463 dnl End of "$Id: cups-defaults.m4 7959 2008-09-17 19:30:58Z mike $".
 464 dnl