config-scripts/cups-gssapi.m4

   1 dnl
   2 dnl   "$Id$"
   3 dnl
   4 dnl   GSSAPI/Kerberos library detection.
   5 dnl
   6 dnl   Copyright 2006-2007 by Easy Software Products.
   7 dnl
   8 dnl   This file contains Kerberos support code, copyright 2006 by
   9 dnl   Jelmer Vernooij.
  10 dnl
  11 dnl   These coded instructions, statements, and computer programs are the
  12 dnl   property of Easy Software Products and are protected by Federal
  13 dnl   copyright law.  Distribution and use rights are outlined in the file
  14 dnl   "LICENSE.txt" which should have been included with this file.  If this
  15 dnl   file is missing or damaged please contact Easy Software Products
  16 dnl   at:
  17 dnl
  18 dnl       Attn: CUPS Licensing Information
  19 dnl       Easy Software Products
  20 dnl       44141 Airport View Drive, Suite 204
  21 dnl       Hollywood, Maryland 20636 USA
  22 dnl
  23 dnl       Voice: (301) 373-9600
  24 dnl       EMail: cups-info@cups.org
  25 dnl         WWW: http://www.cups.org
  26 dnl
  27
  28 AC_ARG_ENABLE(gssapi, [  --enable-gssapi         turn on GSSAPI support, default=yes])
  29
  30 LIBGSSAPI=""
  31
  32 if test x$enable_gssapi != xno; then
  33         AC_PATH_PROG(KRB5CONFIG, krb5-config)
  34         if test "x$KRB5CONFIG" != x; then
  35                 CFLAGS="`$KRB5CONFIG --cflags gssapi` $CFLAGS"
  36                 CPPFLAGS="`$KRB5CONFIG --cflags gssapi` $CPPFLAGS"
  37                 LIBGSSAPI="`$KRB5CONFIG --libs gssapi`"
  38                 AC_DEFINE(HAVE_GSSAPI, 1, [Whether GSSAPI is available])
  39         else
  40                 # Solaris provides its own GSSAPI implementation...
  41                 AC_CHECK_LIB(gss, gss_display_status,
  42                         AC_DEFINE(HAVE_GSSAPI, 1, [Whether GSSAPI is available])
  43                         LIBGSSAPI="-lgss")
  44         fi
  45
  46         if test "x$LIBGSSAPI" != x; then
  47                 AC_CHECK_HEADER(krb5.h, AC_DEFINE(HAVE_KRB5_H))
  48                 AC_CHECK_HEADER(gssapi.h, AC_DEFINE(HAVE_GSSAPI_H))
  49                 AC_CHECK_HEADER(gssapi/gssapi.h, AC_DEFINE(HAVE_GSSAPI_GSSAPI_H))
  50                 AC_CHECK_HEADER(gssapi/gssapi_generic.h, AC_DEFINE(HAVE_GSSAPI_GSSAPI_GENERIC_H))
  51                 AC_CHECK_HEADER(gssapi/gssapi_krb5.h, AC_DEFINE(HAVE_GSSAPI_GSSAPI_KRB5_H))
  52
  53                 SAVELIBS="$LIBS"
  54                 LIBS="$LIBS $LIBGSSAPI"
  55
  56                 AC_CHECK_FUNC(gsskrb5_register_acceptor_identity,
  57                               AC_DEFINE(HAVE_GSSKRB5_REGISTER_ACCEPTOR_IDENTITY))
  58
  59                 AC_MSG_CHECKING(for GSS_C_NT_HOSTBASED_SERVICE)
  60                 if test $ac_cv_header_gssapi_gssapi_h = yes; then
  61                         AC_TRY_COMPILE([ #include <gssapi/gssapi.h> ],
  62                                        [ gss_OID foo = GSS_C_NT_HOSTBASED_SERVICE; ],
  63                                        AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE)
  64                                        AC_MSG_RESULT(yes),
  65                                        AC_MSG_RESULT(no))
  66                 else
  67                         AC_TRY_COMPILE([ #include <gssapi.h> ],
  68                                        [ gss_OID foo = GSS_C_NT_HOSTBASED_SERVICE; ],
  69                                        AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE)
  70                                        AC_MSG_RESULT(yes),
  71                                        AC_MSG_RESULT(no))
  72                 fi
  73
  74                 LIBS="$SAVELIBS"
  75
  76                 AC_MSG_CHECKING(for Heimdal Kerberos)
  77                 AC_TRY_COMPILE([ #include <krb5.h> ],
  78                                [ char *tmp = heimdal_version; ],
  79                                AC_DEFINE(HAVE_HEIMDAL)
  80                                AC_MSG_RESULT(yes),
  81                                AC_MSG_RESULT(no))
  82         fi
  83 fi
  84
  85 dnl Default GSS service name...
  86 AC_ARG_WITH(gssservicename, [  --with-gssservicename   set default gss service name],
  87         default_gssservicename="$withval",
  88         default_gssservicename="default")
  89
  90 if test x$default_gssservicename != xno; then
  91         if test "x$default_gssservicename" = "xdefault"; then
  92                 CUPS_DEFAULT_GSSSERVICENAME="IPP"
  93         else
  94                 CUPS_DEFAULT_GSSSERVICENAME="$default_gssservicename"
  95         fi
  96 else
  97         CUPS_DEFAULT_GSSSERVICENAME=""
  98 fi
  99
 100 AC_SUBST(LIBGSSAPI)
 101 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_GSSSERVICENAME, "$CUPS_DEFAULT_GSSSERVICENAME")
 102
 103 dnl
 104 dnl End of "$Id$".
 105 dnl