config-scripts/cups-image.m4

   1 dnl
   2 dnl "$Id: cups-image.m4 5311 2006-03-19 13:21:42Z mike $"
   3 dnl
   4 dnl   Image library/filter stuff for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 1997-2006 by Easy Software Products, all rights reserved.
   7 dnl
   8 dnl   These coded instructions, statements, and computer programs are the
   9 dnl   property of Easy Software Products and are protected by Federal
  10 dnl   copyright law.  Distribution and use rights are outlined in the file
  11 dnl   "LICENSE.txt" which should have been included with this file.  If this
  12 dnl   file is missing or damaged please contact Easy Software Products
  13 dnl   at:
  14 dnl
  15 dnl       Attn: CUPS Licensing Information
  16 dnl       Easy Software Products
  17 dnl       44141 Airport View Drive, Suite 204
  18 dnl       Hollywood, Maryland 20636 USA
  19 dnl
  20 dnl       Voice: (301) 373-9600
  21 dnl       EMail: cups-info@cups.org
  22 dnl         WWW: http://www.cups.org
  23 dnl
  24
  25 dnl See if we want the image filters included at all...
  26 AC_ARG_ENABLE(image, [  --enable-image          turn on image filters, default=auto])
  27
  28 IMGFILTERS=""
  29 if test "x$enable_image" != xno; then
  30         AC_MSG_CHECKING(whether to build image filters)
  31         if test "x$enable_image" = xyes -o $uname != Darwin; then
  32                 IMGFILTERS="imagetops imagetoraster"
  33                 AC_MSG_RESULT(yes)
  34         else
  35                 AC_MSG_RESULT(no)
  36         fi
  37 fi
  38
  39 AC_SUBST(IMGFILTERS)
  40
  41 dnl Save the current libraries since we don't want the image libraries
  42 dnl included with every program...
  43 SAVELIBS="$LIBS"
  44
  45 dnl Check for image libraries...
  46 AC_ARG_ENABLE(jpeg, [  --enable-jpeg           turn on JPEG support, default=yes])
  47 AC_ARG_ENABLE(png, [  --enable-png            turn on PNG support, default=yes])
  48 AC_ARG_ENABLE(tiff, [  --enable-tiff           turn on TIFF support, default=yes])
  49
  50 LIBJPEG=""
  51 LIBPNG=""
  52 LIBTIFF=""
  53 LIBZ=""
  54
  55 AC_SUBST(LIBJPEG)
  56 AC_SUBST(LIBPNG)
  57 AC_SUBST(LIBTIFF)
  58 AC_SUBST(LIBZ)
  59
  60 if test x$enable_jpeg != xno; then
  61     AC_CHECK_HEADER(jpeglib.h,
  62         AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
  63             AC_DEFINE(HAVE_LIBJPEG)
  64             LIBJPEG="-ljpeg"
  65             LIBS="$LIBS -ljpeg"))
  66 else
  67     AC_MSG_NOTICE([JPEG support disabled with --disable-jpeg.])
  68 fi
  69
  70 AC_CHECK_HEADER(zlib.h,
  71     AC_CHECK_LIB(z, gzgets,
  72         AC_DEFINE(HAVE_LIBZ)
  73         LIBZ="-lz"
  74         LIBS="$LIBS -lz"))
  75
  76 dnl PNG library uses math library functions...
  77 AC_CHECK_LIB(m, pow)
  78
  79 if test x$enable_png != xno; then
  80     AC_CHECK_HEADER(png.h,
  81         AC_CHECK_LIB(png, png_set_tRNS_to_alpha,
  82             AC_DEFINE(HAVE_LIBPNG)
  83             LIBPNG="-lpng -lm"))
  84 else
  85     AC_MSG_NOTICE([PNG support disabled with --disable-png.])
  86 fi
  87
  88 if test x$enable_tiff != xno; then
  89     AC_CHECK_HEADER(tiff.h,
  90         AC_CHECK_LIB(tiff, TIFFReadScanline,
  91         AC_DEFINE(HAVE_LIBTIFF)
  92         LIBTIFF="-ltiff"))
  93 else
  94     AC_MSG_NOTICE([TIFF support disabled with --disable-tiff.])
  95 fi
  96
  97 dnl Restore original LIBS settings...
  98 LIBS="$SAVELIBS"
  99
 100 EXPORT_LIBJPEG="$LIBJPEG"
 101 EXPORT_LIBPNG="$LIBPNG"
 102 EXPORT_LIBTIFF="$LIBTIFF"
 103 EXPORT_LIBZ="$LIBZ"
 104
 105 AC_SUBST(EXPORT_LIBJPEG)
 106 AC_SUBST(EXPORT_LIBPNG)
 107 AC_SUBST(EXPORT_LIBTIFF)
 108 AC_SUBST(EXPORT_LIBZ)
 109
 110 AC_CHECK_HEADER(stdlib.h,AC_DEFINE(HAVE_STDLIB_H))
 111
 112 dnl
 113 dnl End of "$Id: cups-image.m4 5311 2006-03-19 13:21:42Z mike $".
 114 dnl