config-scripts/cups-largefile.m4

   1 dnl
   2 dnl "$Id: cups-largefile.m4 4732 2005-09-30 23:23:25Z mike $"
   3 dnl
   4 dnl   Large file support stuff for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 1997-2005 by Easy Software Products, all rights reserved.
   7 dnl
   8 dnl   These coded instructions, statements, and computer programs are the
   9 dnl   property of Easy Software Products and are protected by Federal
  10 dnl   copyright law.  Distribution and use rights are outlined in the file
  11 dnl   "LICENSE.txt" which should have been included with this file.  If this
  12 dnl   file is missing or damaged please contact Easy Software Products
  13 dnl   at:
  14 dnl
  15 dnl       Attn: CUPS Licensing Information
  16 dnl       Easy Software Products
  17 dnl       44141 Airport View Drive, Suite 204
  18 dnl       Hollywood, Maryland 20636 USA
  19 dnl
  20 dnl       Voice: (301) 373-9600
  21 dnl       EMail: cups-info@cups.org
  22 dnl         WWW: http://www.cups.org
  23 dnl
  24
  25 dnl Check for largefile support...
  26 AC_SYS_LARGEFILE
  27
  28 dnl Define largefile options as needed...
  29 LARGEFILE=""
  30 if test x$enable_largefile != xno; then
  31         LARGEFILE="-D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
  32
  33         if test $ac_cv_sys_large_files = 1; then
  34                 LARGEFILE="$LARGEFILE -D_LARGE_FILES"
  35         fi
  36
  37         if test $ac_cv_sys_file_offset_bits = 64; then
  38                 LARGEFILE="$LARGEFILE -D_FILE_OFFSET_BITS=64"
  39         fi
  40 fi
  41 AC_SUBST(LARGEFILE)
  42
  43 dnl Check for "long long" support...
  44 AC_CACHE_CHECK(for long long int, ac_cv_c_long_long,
  45         [if test "$GCC" = yes; then
  46                 ac_cv_c_long_long=yes
  47         else
  48                 AC_TRY_COMPILE(,[long long int i;],
  49                         ac_cv_c_long_long=yes,
  50                         ac_cv_c_long_long=no)
  51         fi])
  52
  53 if test $ac_cv_c_long_long = yes; then
  54         AC_DEFINE(HAVE_LONG_LONG)
  55 fi
  56
  57 AC_CHECK_FUNC(strtoll, AC_DEFINE(HAVE_STRTOLL))
  58
  59 dnl
  60 dnl End of "$Id: cups-largefile.m4 4732 2005-09-30 23:23:25Z mike $".
  61 dnl