config-scripts/cups-network.m4

   1 dnl
   2 dnl "$Id: cups-network.m4 177 2006-06-21 00:20:03Z jlovell $"
   3 dnl
   4 dnl   Networking stuff for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 1997-2005 by Easy Software Products, all rights reserved.
   7 dnl
   8 dnl   These coded instructions, statements, and computer programs are the
   9 dnl   property of Easy Software Products and are protected by Federal
  10 dnl   copyright law.  Distribution and use rights are outlined in the file
  11 dnl   "LICENSE.txt" which should have been included with this file.  If this
  12 dnl   file is missing or damaged please contact Easy Software Products
  13 dnl   at:
  14 dnl
  15 dnl       Attn: CUPS Licensing Information
  16 dnl       Easy Software Products
  17 dnl       44141 Airport View Drive, Suite 204
  18 dnl       Hollywood, Maryland 20636 USA
  19 dnl
  20 dnl       Voice: (301) 373-9600
  21 dnl       EMail: cups-info@cups.org
  22 dnl         WWW: http://www.cups.org
  23 dnl
  24
  25 AC_SEARCH_LIBS(socket, socket)
  26 AC_SEARCH_LIBS(gethostbyaddr, nsl)
  27 AC_SEARCH_LIBS(getaddrinfo, nsl, AC_DEFINE(HAVE_GETADDRINFO))
  28 AC_SEARCH_LIBS(getifaddrs, nsl, AC_DEFINE(HAVE_GETIFADDRS))
  29 AC_SEARCH_LIBS(getnameinfo, nsl, AC_DEFINE(HAVE_GETNAMEINFO))
  30 AC_SEARCH_LIBS(hstrerror, nsl socket resolv, AC_DEFINE(HAVE_HSTRERROR))
  31 AC_SEARCH_LIBS(rresvport_af, nsl, AC_DEFINE(HAVE_RRESVPORT_AF))
  32
  33 AC_CHECK_MEMBER(struct sockaddr.sa_len,,, [#include <sys/socket.h>])
  34 AC_CHECK_HEADER(sys/sockio.h, AC_DEFINE(HAVE_SYS_SOCKIO_H))
  35
  36 if test "$uname" = "SunOS"; then
  37         case "$uversion" in
  38                 55* | 56*)
  39                         maxfiles=1024
  40                         ;;
  41                 *)
  42                         maxfiles=4096
  43                         ;;
  44         esac
  45 else
  46         maxfiles=4096
  47 fi
  48
  49 AC_ARG_WITH(maxfiles, [  --with-maxfiles=N       set maximum number of file descriptors for scheduler ],
  50         maxfiles=$withval)
  51
  52 AC_DEFINE_UNQUOTED(CUPS_MAX_FDS, $maxfiles)
  53
  54 CUPS_DEFAULT_DOMAINSOCKET=""
  55
  56 dnl Domain socket support...
  57 AC_ARG_WITH(domainsocket, [  --with-domainsocket     set unix domain socket name],
  58         default_domainsocket="$withval",
  59         default_domainsocket="")
  60
  61 if test x$enable_domainsocket != xno -a x$default_domainsocket != xno; then
  62         if test "x$default_domainsocket" = x; then
  63                 case "$uname" in
  64                         Darwin*)
  65                                 # Darwin and MaxOS X do their own thing...
  66                                 CUPS_DEFAULT_DOMAINSOCKET="$localstatedir/run/cupsd"
  67                                 ;;
  68                         *)
  69                                 # All others use FHS standard...
  70                                 CUPS_DEFAULT_DOMAINSOCKET="$CUPS_STATEDIR/cups.sock"
  71                                 ;;
  72                 esac
  73         else
  74                 CUPS_DEFAULT_DOMAINSOCKET="$default_domainsocket"
  75         fi
  76
  77         CUPS_LISTEN_DOMAINSOCKET="Listen $CUPS_DEFAULT_DOMAINSOCKET"
  78
  79         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DOMAINSOCKET, "$CUPS_DEFAULT_DOMAINSOCKET")
  80 else
  81         CUPS_LISTEN_DOMAINSOCKET=""
  82 fi
  83
  84 AC_SUBST(CUPS_DEFAULT_DOMAINSOCKET)
  85 AC_SUBST(CUPS_LISTEN_DOMAINSOCKET)
  86
  87 dnl
  88 dnl End of "$Id: cups-network.m4 177 2006-06-21 00:20:03Z jlovell $".
  89 dnl