configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_DISABLE_OPTION_CHECKING
  35
  36 progname=$0
  37 # if PWD already has a value, it is probably wrong.
  38 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  39
  40 # Export original configure arguments for use by sub-configures.
  41 # Quote arguments with shell meta charatcers.
  42 TOPLEVEL_CONFIGURE_ARGUMENTS=
  43 set -- "$progname" "$@"
  44 for ac_arg
  45 do
  46   case "$ac_arg" in
  47   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  48     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  49     # if the argument is of the form -foo=baz, quote the baz part only
  50     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  51   *) ;;
  52   esac
  53   # Add the quoted argument to the list.
  54   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  55 done
  56 if test "$silent" = yes; then
  57   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  58 fi
  59 # Remove the initial space we just introduced and, as these will be
  60 # expanded by make, quote '$'.
  61 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  62 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  63
  64 # Find the build, host, and target systems.
  65 ACX_NONCANONICAL_BUILD
  66 ACX_NONCANONICAL_HOST
  67 ACX_NONCANONICAL_TARGET
  68
  69 dnl Autoconf 2.5x and later will set a default program prefix if
  70 dnl --target was used, even if it was the same as --host.  Disable
  71 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  72 dnl to take effect.
  73 test "$host_noncanonical" = "$target_noncanonical" &&
  74   test "$program_prefix$program_suffix$program_transform_name" = \
  75     NONENONEs,x,x, &&
  76   program_transform_name=s,y,y,
  77
  78 AC_CANONICAL_SYSTEM
  79 AC_ARG_PROGRAM
  80
  81 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  82 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  83
  84 # Get 'install' or 'install-sh' and its variants.
  85 AC_PROG_INSTALL
  86 ACX_PROG_LN
  87 AC_PROG_LN_S
  88 AC_PROG_SED
  89 AC_PROG_AWK
  90
  91 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  92
  93 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  94 # a relative path.
  95 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  96   INSTALL="${srcpwd}/install-sh -c"
  97 fi
  98
  99 # Set srcdir to "." if that's what it is.
 100 # This is important for multilib support.
 101 pwd=`${PWDCMD-pwd}`
 102 if test "${pwd}" = "${srcpwd}" ; then
 103   srcdir=.
 104 fi
 105
 106 topsrcdir=$srcpwd
 107
 108 extra_host_args=
 109
 110 ### To add a new directory to the tree, first choose whether it is a target
 111 ### or a host dependent tool.  Then put it into the appropriate list
 112 ### (library or tools, host or target), doing a dependency sort.
 113
 114 # Subdirs will be configured in the order listed in build_configdirs,
 115 # configdirs, or target_configdirs; see the serialization section below.
 116
 117 # Dependency sorting is only needed when *configuration* must be done in
 118 # a particular order.  In all cases a dependency should be specified in
 119 # the Makefile, whether or not it's implicitly specified here.
 120
 121 # Double entries in build_configdirs, configdirs, or target_configdirs may
 122 # cause circular dependencies and break everything horribly.
 123
 124 # these library is used by various programs built for the build
 125 # environment
 126 #
 127 build_libs="build-libiberty build-libcpp"
 128
 129 # these tools are built for the build environment
 130 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 131
 132 # these libraries are used by various programs built for the host environment
 133 #f
 134 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 135
 136 # these tools are built for the host environment
 137 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 138 # know that we are building the simulator.
 139 # binutils, gas and ld appear in that order because it makes sense to run
 140 # "make check" in that particular order.
 141 # If --enable-gold is used, "gold" may replace "ld".
 142 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 143
 144 # these libraries are built for the target environment, and are built after
 145 # the host libraries and the host tools (which may be a cross compiler)
 146 # Note that libiberty is not a target library.
 147 target_libraries="target-libgcc \
 148                 target-libbacktrace \
 149                 target-libgloss \
 150                 target-newlib \
 151                 target-libgomp \
 152                 target-liboffloadmic \
 153                 target-libhsail-rt \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 # Handle --enable-gold, --enable-ld.
 303 # --disable-gold [--enable-ld]
 304 #     Build only ld.  Default option.
 305 # --enable-gold [--enable-ld]
 306 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 307 #     as "ld.bfd" and "ld".
 308 # --enable-gold=default [--enable-ld]
 309 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 310 #     install ld as "ld.bfd".
 311 # --enable-gold[=default] --disable-ld
 312 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 313 # --enable-gold --enable-ld=default
 314 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 315 #     and ld.bfd).
 316 #     In other words, ld is default
 317 # --enable-gold=default --enable-ld=default
 318 #     Error.
 319
 320 default_ld=
 321 AC_ARG_ENABLE(gold,
 322 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 323                 [build gold @<:@ARG={default,yes,no}@:>@])],
 324 ENABLE_GOLD=$enableval,
 325 ENABLE_GOLD=no)
 326 case "${ENABLE_GOLD}" in
 327   yes|default)
 328     # Check for ELF target.
 329     is_elf=no
 330     case "${target}" in
 331       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 332       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 333       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 334       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 335         case "${target}" in
 336           *-*-linux*aout* | *-*-linux*oldld*)
 337             ;;
 338           *)
 339             is_elf=yes
 340             ;;
 341         esac
 342     esac
 343
 344     if test "$is_elf" = "yes"; then
 345       # Check for target supported by gold.
 346       case "${target}" in
 347         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 348         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 349           configdirs="$configdirs gold"
 350           if test x${ENABLE_GOLD} = xdefault; then
 351             default_ld=gold
 352           fi
 353           ENABLE_GOLD=yes
 354           ;;
 355       esac
 356     fi
 357     ;;
 358   no)
 359     ;;
 360   *)
 361     AC_MSG_ERROR([invalid --enable-gold argument])
 362     ;;
 363 esac
 364
 365 AC_ARG_ENABLE(ld,
 366 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 367                 [build ld @<:@ARG={default,yes,no}@:>@])],
 368 ENABLE_LD=$enableval,
 369 ENABLE_LD=yes)
 370
 371 case "${ENABLE_LD}" in
 372   default)
 373     if test x${default_ld} != x; then
 374       AC_MSG_ERROR([either gold or ld can be the default ld])
 375     fi
 376     ;;
 377   yes)
 378     ;;
 379   no)
 380     if test x${ENABLE_GOLD} != xyes; then
 381       AC_MSG_WARN([neither ld nor gold are enabled])
 382     fi
 383     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 384     ;;
 385   *)
 386     AC_MSG_ERROR([invalid --enable-ld argument])
 387     ;;
 388 esac
 389
 390 # PR gas/19109
 391 # Decide the default method for compressing debug sections.
 392 # Provide a configure time option to override our default.
 393 AC_ARG_ENABLE(compressed_debug_sections,
 394 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 395                 [Enable compressed debug sections for gas, gold or ld by
 396                  default])],
 397 [
 398   if test x"$enable_compressed_debug_sections" = xyes; then
 399     AC_MSG_ERROR([no program with compressed debug sections specified])
 400   fi
 401 ], [enable_compressed_debug_sections=])
 402
 403 # Configure extra directories which are host specific
 404
 405 case "${host}" in
 406   *-cygwin*)
 407     configdirs="$configdirs libtermcap" ;;
 408 esac
 409
 410 # A target can indicate whether a language isn't supported for some reason.
 411 # Only spaces may be used in this macro; not newlines or tabs.
 412 unsupported_languages=
 413
 414 # Remove more programs from consideration, based on the host or
 415 # target this usually means that a port of the program doesn't
 416 # exist yet.
 417
 418 case "${host}" in
 419   i[[3456789]]86-*-msdosdjgpp*)
 420     noconfigdirs="$noconfigdirs tcl tk itcl"
 421     ;;
 422 esac
 423
 424
 425 AC_ARG_ENABLE(libquadmath,
 426 AS_HELP_STRING([--disable-libquadmath],
 427   [do not build libquadmath directory]),
 428 ENABLE_LIBQUADMATH=$enableval,
 429 ENABLE_LIBQUADMATH=yes)
 430 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 431   noconfigdirs="$noconfigdirs target-libquadmath"
 432 fi
 433
 434
 435 AC_ARG_ENABLE(libquadmath-support,
 436 AS_HELP_STRING([--disable-libquadmath-support],
 437   [disable libquadmath support for Fortran]),
 438 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 439 ENABLE_LIBQUADMATH_SUPPORT=yes)
 440 enable_libquadmath_support=
 441 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 442   enable_libquadmath_support=no
 443 fi
 444
 445
 446 AC_ARG_ENABLE(libada,
 447 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 448 ENABLE_LIBADA=$enableval,
 449 ENABLE_LIBADA=yes)
 450 if test "${ENABLE_LIBADA}" != "yes" ; then
 451   noconfigdirs="$noconfigdirs gnattools"
 452 fi
 453
 454 AC_ARG_ENABLE(libssp,
 455 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 456 ENABLE_LIBSSP=$enableval,
 457 ENABLE_LIBSSP=yes)
 458
 459 AC_ARG_ENABLE(libstdcxx,
 460 AS_HELP_STRING([--disable-libstdcxx],
 461   [do not build libstdc++-v3 directory]),
 462 ENABLE_LIBSTDCXX=$enableval,
 463 ENABLE_LIBSTDCXX=default)
 464 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 465   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 466 fi]
 467
 468 # If this is accelerator compiler and its target is intelmic we enable
 469 # target liboffloadmic by default.  If this is compiler with offloading
 470 # for intelmic we enable host liboffloadmic by default.  Otherwise
 471 # liboffloadmic is disabled by default.
 472 AC_ARG_ENABLE([liboffloadmic],
 473 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 474                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 475 [case "$enableval" in
 476   no | host | target)
 477     enable_liboffloadmic=$enableval ;;
 478   *)
 479     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 480 esac],
 481 [if test x"$enable_as_accelerator_for" != x; then
 482   case "${target}" in
 483     *-intelmic-* | *-intelmicemul-*)
 484       enable_liboffloadmic=target
 485       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 486       ;;
 487     *)
 488       enable_liboffloadmic=no
 489       ;;
 490   esac
 491 else
 492   case "${enable_offload_targets}" in
 493     *-intelmic-* | *-intelmicemul-*)
 494       enable_liboffloadmic=host
 495       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 496       ;;
 497     *)
 498       enable_liboffloadmic=no
 499       ;;
 500     esac
 501 fi])
 502 AC_SUBST(extra_liboffloadmic_configure_flags)
 503
 504 # Enable libgomp by default on hosted POSIX systems, and a few others.
 505 if test x$enable_libgomp = x ; then
 506     case "${target}" in
 507     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 508         ;;
 509     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 510         ;;
 511     *-*-solaris2* | *-*-hpux11*)
 512         ;;
 513     *-*-darwin* | *-*-aix*)
 514         ;;
 515     nvptx*-*-* | amdgcn*-*-*)
 516         ;;
 517     *)
 518         noconfigdirs="$noconfigdirs target-libgomp"
 519         ;;
 520     esac
 521 fi
 522
 523 # Disable libatomic on unsupported systems.
 524 if test -d ${srcdir}/libatomic; then
 525     if test x$enable_libatomic = x; then
 526         AC_MSG_CHECKING([for libatomic support])
 527         if (srcdir=${srcdir}/libatomic; \
 528                 . ${srcdir}/configure.tgt; \
 529                 test -n "$UNSUPPORTED")
 530         then
 531             AC_MSG_RESULT([no])
 532             noconfigdirs="$noconfigdirs target-libatomic"
 533         else
 534             AC_MSG_RESULT([yes])
 535         fi
 536     fi
 537 fi
 538
 539 # Disable liboffloadmic on unsupported systems.
 540 if test -d ${srcdir}/liboffloadmic; then
 541     if test x$enable_liboffloadmic != xno; then
 542         AC_MSG_CHECKING([for liboffloadmic support])
 543         if (srcdir=${srcdir}/liboffloadmic; \
 544                 . ${srcdir}/configure.tgt; \
 545                 test -n "$UNSUPPORTED")
 546         then
 547             AC_MSG_RESULT([no])
 548             noconfigdirs="$noconfigdirs target-liboffloadmic"
 549         else
 550             AC_MSG_RESULT([yes])
 551         fi
 552     fi
 553 fi
 554
 555 # Disable libitm on unsupported systems.
 556 if test -d ${srcdir}/libitm; then
 557     if test x$enable_libitm = x; then
 558         AC_MSG_CHECKING([for libitm support])
 559         if (srcdir=${srcdir}/libitm; \
 560                 . ${srcdir}/configure.tgt; \
 561                 test -n "$UNSUPPORTED")
 562         then
 563             AC_MSG_RESULT([no])
 564             noconfigdirs="$noconfigdirs target-libitm"
 565         else
 566             AC_MSG_RESULT([yes])
 567         fi
 568     fi
 569 fi
 570
 571 # Disable libsanitizer on unsupported systems.
 572 if test -d ${srcdir}/libsanitizer; then
 573     if test x$enable_libsanitizer = x; then
 574         AC_MSG_CHECKING([for libsanitizer support])
 575         if (srcdir=${srcdir}/libsanitizer; \
 576                 . ${srcdir}/configure.tgt; \
 577                 test -n "$UNSUPPORTED")
 578         then
 579             AC_MSG_RESULT([no])
 580             noconfigdirs="$noconfigdirs target-libsanitizer"
 581         else
 582             AC_MSG_RESULT([yes])
 583         fi
 584     fi
 585 fi
 586
 587 # Disable libvtv on unsupported systems.
 588 if test -d ${srcdir}/libvtv; then
 589     if test x$enable_libvtv = x; then
 590         AC_MSG_CHECKING([for libvtv support])
 591         if (srcdir=${srcdir}/libvtv; \
 592                 . ${srcdir}/configure.tgt; \
 593                 test "$VTV_SUPPORTED" != "yes")
 594         then
 595             AC_MSG_RESULT([no])
 596             noconfigdirs="$noconfigdirs target-libvtv"
 597         else
 598             AC_MSG_RESULT([yes])
 599         fi
 600     fi
 601 fi
 602
 603
 604 # Disable libhsail-rt on unsupported systems.
 605 if test -d ${srcdir}/libhsail-rt; then
 606     if test x$enable_libhsail_rt = x; then
 607         AC_MSG_CHECKING([for libhsail-rt support])
 608         if (srcdir=${srcdir}/libhsail-rt; \
 609                 . ${srcdir}/configure.tgt; \
 610                 test -n "$UNSUPPORTED")
 611         then
 612             AC_MSG_RESULT([no])
 613             unsupported_languages="$unsupported_languages brig"
 614             # This implicitly disables also target-libhsail-rt as it won't
 615             # get added to the build without BRIG FE.
 616         else
 617             AC_MSG_RESULT([yes])
 618         fi
 619     fi
 620 fi
 621
 622
 623 # Disable libquadmath for some systems.
 624 case "${target}" in
 625   avr-*-*)
 626     noconfigdirs="$noconfigdirs target-libquadmath"
 627     ;;
 628   # libquadmath is unused on AIX and libquadmath build process use of
 629   # LD_LIBRARY_PATH can break AIX bootstrap.
 630   powerpc-*-aix* | rs6000-*-aix*)
 631     noconfigdirs="$noconfigdirs target-libquadmath"
 632     ;;
 633 esac
 634
 635 # Disable libssp for some systems.
 636 case "${target}" in
 637   avr-*-*)
 638     # No hosted I/O support.
 639     noconfigdirs="$noconfigdirs target-libssp"
 640     ;;
 641   bpf-*-*)
 642     noconfigdirs="$noconfigdirs target-libssp"
 643     ;;
 644   powerpc-*-aix* | rs6000-*-aix*)
 645     noconfigdirs="$noconfigdirs target-libssp"
 646     ;;
 647   pru-*-*)
 648     # No hosted I/O support.
 649     noconfigdirs="$noconfigdirs target-libssp"
 650     ;;
 651   rl78-*-*)
 652     # libssp uses a misaligned load to trigger a fault, but the RL78
 653     # doesn't fault for those - instead, it gives a build-time error
 654     # for explicit misaligned loads.
 655     noconfigdirs="$noconfigdirs target-libssp"
 656     ;;
 657   visium-*-*)
 658     # No hosted I/O support.
 659     noconfigdirs="$noconfigdirs target-libssp"
 660     ;;
 661 esac
 662
 663 # Disable libstdc++-v3 for some systems.
 664 # Allow user to override this if they pass --enable-libstdc++-v3
 665 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 666   case "${target}" in
 667     *-*-vxworks*)
 668       # VxWorks uses the Dinkumware C++ library.
 669       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 670       ;;
 671     amdgcn*-*-*)
 672       # Not ported/fails to build when using newlib.
 673       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 674       ;;
 675     arm*-wince-pe*)
 676       # the C++ libraries don't build on top of CE's C libraries
 677       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 678       ;;
 679     avr-*-*)
 680       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 681       ;;
 682     bpf-*-*)
 683       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 684       ;;
 685     ft32-*-*)
 686       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 687       ;;
 688   esac
 689 fi
 690
 691 # Disable C++ on systems where it is known to not work.
 692 # For testing, you can override this with --enable-languages=c++.
 693 case ,${enable_languages}, in
 694   *,c++,*)
 695     ;;
 696   *)
 697       case "${target}" in
 698         bpf-*-*)
 699           unsupported_languages="$unsupported_languages c++"
 700           ;;
 701       esac
 702       ;;
 703 esac
 704
 705 # Disable Objc on systems where it is known to not work.
 706 # For testing, you can override this with --enable-languages=objc.
 707 case ,${enable_languages}, in
 708   *,objc,*)
 709     ;;
 710   *)
 711       case "${target}" in
 712         bpf-*-*)
 713           unsupported_languages="$unsupported_languages objc"
 714           ;;
 715       esac
 716       ;;
 717 esac
 718
 719 # Disable D on systems where it is known to not work.
 720 # For testing, you can override this with --enable-languages=d.
 721 case ,${enable_languages}, in
 722   *,d,*)
 723     ;;
 724   *)
 725     case "${target}" in
 726       *-*-darwin*)
 727         unsupported_languages="$unsupported_languages d"
 728         ;;
 729       bpf-*-*)
 730         unsupported_languages="$unsupported_languages d"
 731         ;;
 732     esac
 733     ;;
 734 esac
 735
 736 # Disable libphobos on unsupported systems.
 737 # For testing, you can override this with --enable-libphobos.
 738 if test -d ${srcdir}/libphobos; then
 739     if test x$enable_libphobos = x; then
 740         AC_MSG_CHECKING([for libphobos support])
 741         if (srcdir=${srcdir}/libphobos; \
 742                 . ${srcdir}/configure.tgt; \
 743                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 744         then
 745             AC_MSG_RESULT([no])
 746             noconfigdirs="$noconfigdirs target-libphobos"
 747         else
 748             AC_MSG_RESULT([yes])
 749         fi
 750     fi
 751 fi
 752
 753 # Disable Fortran for some systems.
 754 case "${target}" in
 755   mmix-*-*)
 756     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 757     unsupported_languages="$unsupported_languages fortran"
 758     ;;
 759   bpf-*-*)
 760     unsupported_languages="$unsupported_languages fortran"
 761     ;;
 762 esac
 763
 764 # Disable libffi for some systems.
 765 case "${target}" in
 766   powerpc-*-darwin*)
 767     ;;
 768   i[[3456789]]86-*-darwin*)
 769     ;;
 770   x86_64-*-darwin[[912]]*)
 771     ;;
 772   *-*-darwin*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   *-*-netware*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   *-*-phoenix*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   *-*-rtems*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   *-*-tpf*)
 785     noconfigdirs="$noconfigdirs target-libffi"
 786     ;;
 787   *-*-uclinux*)
 788     noconfigdirs="$noconfigdirs target-libffi"
 789     ;;
 790   *-*-vxworks*)
 791     noconfigdirs="$noconfigdirs target-libffi"
 792     ;;
 793   aarch64*-*-freebsd*)
 794     noconfigdirs="$noconfigdirs target-libffi"
 795     ;;
 796   alpha*-*-*vms*)
 797     noconfigdirs="$noconfigdirs target-libffi"
 798     ;;
 799   arm*-*-freebsd*)
 800     noconfigdirs="$noconfigdirs target-libffi"
 801     ;;
 802   arm-wince-pe)
 803     noconfigdirs="$noconfigdirs target-libffi"
 804     ;;
 805   arm*-*-symbianelf*)
 806     noconfigdirs="$noconfigdirs target-libffi"
 807     ;;
 808   bpf-*-*)
 809     noconfigdirs="$noconfigdirs target-libffi"
 810     ;;
 811   cris-*-* | crisv32-*-*)
 812     case "${target}" in
 813       *-*-linux*)
 814         ;;
 815       *) # See PR46792 regarding target-libffi.
 816         noconfigdirs="$noconfigdirs target-libffi";;
 817     esac
 818     ;;
 819   hppa*64*-*-hpux*)
 820     noconfigdirs="$noconfigdirs target-libffi"
 821     ;;
 822   hppa*-hp-hpux11*)
 823     ;;
 824   hppa*-*-hpux*)
 825     noconfigdirs="$noconfigdirs target-libffi"
 826     ;;
 827   ia64*-*-*vms*)
 828     noconfigdirs="$noconfigdirs target-libffi"
 829     ;;
 830   i[[3456789]]86-w64-mingw*)
 831     noconfigdirs="$noconfigdirs target-libffi"
 832     ;;
 833   i[[3456789]]86-*-mingw*)
 834     noconfigdirs="$noconfigdirs target-libffi"
 835     ;;
 836   x86_64-*-mingw*)
 837     noconfigdirs="$noconfigdirs target-libffi"
 838     ;;
 839   mmix-*-*)
 840     noconfigdirs="$noconfigdirs target-libffi"
 841     ;;
 842   powerpc-*-aix*)
 843     ;;
 844   rs6000-*-aix*)
 845     ;;
 846   ft32-*-*)
 847     noconfigdirs="$noconfigdirs target-libffi"
 848     ;;
 849   *-*-lynxos*)
 850     noconfigdirs="$noconfigdirs target-libffi"
 851     ;;
 852 esac
 853
 854 # Disable the go frontend on systems where it is known to not work. Please keep
 855 # this in sync with contrib/config-list.mk.
 856 case "${target}" in
 857 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 858     unsupported_languages="$unsupported_languages go"
 859     ;;
 860 esac
 861
 862 # Only allow gdbserver on some systems.
 863 if test -d ${srcdir}/gdbserver; then
 864     if test x$enable_gdbserver = x; then
 865         AC_MSG_CHECKING([for gdbserver support])
 866         if (srcdir=${srcdir}/gdbserver; \
 867                 . ${srcdir}/configure.srv; \
 868                 test -n "$UNSUPPORTED")
 869         then
 870             AC_MSG_RESULT([no])
 871             noconfigdirs="$noconfigdirs gdbserver"
 872         else
 873             AC_MSG_RESULT([yes])
 874         fi
 875     fi
 876 fi
 877
 878 # Disable libgo for some systems where it is known to not work.
 879 # For testing, you can easily override this with --enable-libgo.
 880 if test x$enable_libgo = x; then
 881     case "${target}" in
 882     *-*-darwin*)
 883         # PR 46986
 884         noconfigdirs="$noconfigdirs target-libgo"
 885         ;;
 886     *-*-cygwin* | *-*-mingw*)
 887         noconfigdirs="$noconfigdirs target-libgo"
 888         ;;
 889     bpf-*-*)
 890         noconfigdirs="$noconfigdirs target-libgo"
 891         ;;
 892     esac
 893 fi
 894
 895 # Default libgloss CPU subdirectory.
 896 libgloss_dir="$target_cpu"
 897
 898 case "${target}" in
 899   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 900     libgloss_dir=wince
 901     ;;
 902   aarch64*-*-* )
 903     libgloss_dir=aarch64
 904     ;;
 905   arm*-*-*)
 906     libgloss_dir=arm
 907     ;;
 908   cris-*-* | crisv32-*-*)
 909     libgloss_dir=cris
 910     ;;
 911   hppa*-*-*)
 912     libgloss_dir=pa
 913     ;;
 914   i[[3456789]]86-*-*)
 915     libgloss_dir=i386
 916     ;;
 917   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 918     libgloss_dir=m68hc11
 919     ;;
 920   m68*-*-* | fido-*-*)
 921     libgloss_dir=m68k
 922     ;;
 923   mips*-*-*)
 924     libgloss_dir=mips
 925     ;;
 926   powerpc*-*-*)
 927     libgloss_dir=rs6000
 928     ;;
 929   pru-*-*)
 930     libgloss_dir=pru
 931     ;;
 932   sparc*-*-*)
 933     libgloss_dir=sparc
 934     ;;
 935 esac
 936
 937 # Disable newlib and libgloss for various target OSes.
 938 case "${target}" in
 939   alpha*-dec-osf*)
 940     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 941     ;;
 942   i[[3456789]]86-*-linux*)
 943     # This section makes it possible to build newlib natively on linux.
 944     # If we are using a cross compiler then don't configure newlib.
 945     if test x${is_cross_compiler} != xno ; then
 946       noconfigdirs="$noconfigdirs target-newlib"
 947     fi
 948     noconfigdirs="$noconfigdirs target-libgloss"
 949     # If we are not using a cross compiler, do configure newlib.
 950     # Note however, that newlib will only be configured in this situation
 951     # if the --with-newlib option has been given, because otherwise
 952     # 'target-newlib' will appear in skipdirs.
 953     ;;
 954   i[[3456789]]86-*-rdos*)
 955     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 956     ;;
 957   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 958     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 959     ;;
 960   sparc-*-sunos4*)
 961     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 962     ;;
 963   bpf-*-*)
 964     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 965     ;;
 966   *-*-aix*)
 967     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 968     ;;
 969   *-*-beos*)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   *-*-chorusos)
 973     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 974     ;;
 975   *-*-dragonfly*)
 976     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 977     ;;
 978   *-*-freebsd*)
 979     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 980     ;;
 981   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 982     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 983     ;;
 984   *-*-lynxos*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   *-*-mingw*)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990   *-*-netbsd*)
 991     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 992     ;;
 993   *-*-netware*)
 994     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 995     ;;
 996   *-*-tpf*)
 997     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 998     ;;
 999   *-*-uclinux*)
1000     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1001     ;;
1002   *-*-vxworks*)
1003     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1004     ;;
1005 esac
1006
1007 case "${target}" in
1008   *-*-chorusos)
1009     ;;
1010   aarch64-*-darwin*)
1011     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1012     noconfigdirs="$noconfigdirs sim target-rda"
1013     ;;
1014   amdgcn*-*-*)
1015     ;;
1016   arm-*-darwin*)
1017     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1018     noconfigdirs="$noconfigdirs sim target-rda"
1019     ;;
1020   powerpc-*-darwin*)
1021     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1022     noconfigdirs="$noconfigdirs sim target-rda"
1023     ;;
1024   i[[3456789]]86-*-darwin*)
1025     noconfigdirs="$noconfigdirs ld gprof"
1026     noconfigdirs="$noconfigdirs sim target-rda"
1027     ;;
1028   x86_64-*-darwin[[912]]*)
1029     noconfigdirs="$noconfigdirs ld gas gprof"
1030     noconfigdirs="$noconfigdirs sim target-rda"
1031     ;;
1032   *-*-darwin*)
1033     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1034     noconfigdirs="$noconfigdirs sim target-rda"
1035     ;;
1036   *-*-dragonfly*)
1037     ;;
1038   *-*-freebsd*)
1039     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1040         && test -f /usr/local/include/gmp.h; then
1041       with_gmp=/usr/local
1042     fi
1043     ;;
1044   *-*-kaos*)
1045     # Remove unsupported stuff on all kaOS configurations.
1046     noconfigdirs="$noconfigdirs target-libgloss"
1047     ;;
1048   *-*-netbsd*)
1049     ;;
1050   *-*-netware*)
1051     ;;
1052   *-*-phoenix*)
1053     noconfigdirs="$noconfigdirs target-libgloss"
1054     ;;
1055   *-*-rtems*)
1056     noconfigdirs="$noconfigdirs target-libgloss"
1057     ;;
1058     # The tpf target doesn't support gdb yet.
1059   *-*-tpf*)
1060     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1061     ;;
1062   *-*-uclinux*)
1063     noconfigdirs="$noconfigdirs target-rda"
1064     ;;
1065   *-*-vxworks*)
1066     ;;
1067   alpha*-dec-osf*)
1068     # ld works, but does not support shared libraries.
1069     # gas doesn't generate exception information.
1070     noconfigdirs="$noconfigdirs gas ld"
1071     ;;
1072   alpha*-*-*vms*)
1073     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1074     ;;
1075   alpha*-*-*)
1076     # newlib is not 64 bit ready
1077     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1078     ;;
1079   bpf-*-*)
1080     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1081     ;;
1082   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1083     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1084     ;;
1085   arc*-*-*)
1086     noconfigdirs="$noconfigdirs sim"
1087     ;;
1088   arm-*-pe*)
1089     noconfigdirs="$noconfigdirs target-libgloss"
1090     ;;
1091   arm-*-riscix*)
1092     noconfigdirs="$noconfigdirs ld target-libgloss"
1093     ;;
1094   avr-*-*)
1095     if test x${with_avrlibc} != xno; then
1096       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1097     fi
1098     ;;
1099   c4x-*-* | tic4x-*-*)
1100     noconfigdirs="$noconfigdirs target-libgloss"
1101     ;;
1102   tic54x-*-*)
1103     noconfigdirs="$noconfigdirs target-libgloss gdb"
1104     ;;
1105   d10v-*-*)
1106     noconfigdirs="$noconfigdirs target-libgloss"
1107     ;;
1108   d30v-*-*)
1109     noconfigdirs="$noconfigdirs gdb"
1110     ;;
1111   fr30-*-elf*)
1112     noconfigdirs="$noconfigdirs gdb"
1113     ;;
1114   ft32-*-*)
1115     noconfigdirs="$noconfigdirs target-rda gprof"
1116     ;;
1117   moxie-*-*)
1118     noconfigdirs="$noconfigdirs"
1119     ;;
1120   h8300*-*-*)
1121     noconfigdirs="$noconfigdirs target-libgloss"
1122     ;;
1123   h8500-*-*)
1124     noconfigdirs="$noconfigdirs target-libgloss"
1125     ;;
1126   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1127     ;;
1128   hppa*64*-*-hpux*)
1129     noconfigdirs="$noconfigdirs gdb"
1130     ;;
1131   hppa*-*-hpux11*)
1132     noconfigdirs="$noconfigdirs gdb ld"
1133     ;;
1134   hppa*64*-*-linux*)
1135     ;;
1136   hppa*-*-linux*)
1137     ;;
1138   hppa*-*-*elf* | \
1139   hppa*-*-lites* | \
1140   hppa*-*-openbsd* | \
1141   hppa*64*-*-*)
1142     ;;
1143   hppa*-*-pro*)
1144     ;;
1145   hppa*-*-*)
1146     noconfigdirs="$noconfigdirs ld"
1147     ;;
1148   i960-*-*)
1149     noconfigdirs="$noconfigdirs gdb"
1150     ;;
1151   ia64*-*-elf*)
1152     # No gdb support yet.
1153     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1154     ;;
1155   ia64*-**-hpux*)
1156     # No ld support yet.
1157     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1158     ;;
1159   ia64*-*-*vms*)
1160     # No ld support yet.
1161     noconfigdirs="$noconfigdirs libgui itcl ld"
1162     ;;
1163   i[[3456789]]86-w64-mingw*)
1164     ;;
1165   i[[3456789]]86-*-mingw*)
1166     target_configdirs="$target_configdirs target-winsup"
1167     ;;
1168   *-*-cygwin*)
1169     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1170     noconfigdirs="$noconfigdirs target-libgloss"
1171     # always build newlib if winsup directory is present.
1172     if test -d "$srcdir/winsup/cygwin"; then
1173       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1174     elif test -d "$srcdir/newlib"; then
1175       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1176     fi
1177     ;;
1178   i[[3456789]]86-*-pe)
1179     noconfigdirs="$noconfigdirs target-libgloss"
1180     ;;
1181   i[[3456789]]86-*-sco3.2v5*)
1182     # The linker does not yet know about weak symbols in COFF,
1183     # and is not configured to handle mixed ELF and COFF.
1184     noconfigdirs="$noconfigdirs ld target-libgloss"
1185     ;;
1186   i[[3456789]]86-*-sco*)
1187     noconfigdirs="$noconfigdirs gprof target-libgloss"
1188     ;;
1189   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1190     noconfigdirs="$noconfigdirs target-libgloss"
1191     ;;
1192   i[[3456789]]86-*-sysv4*)
1193     noconfigdirs="$noconfigdirs target-libgloss"
1194     ;;
1195   i[[3456789]]86-*-beos*)
1196     noconfigdirs="$noconfigdirs gdb"
1197     ;;
1198   i[[3456789]]86-*-rdos*)
1199     noconfigdirs="$noconfigdirs gdb"
1200     ;;
1201   mmix-*-*)
1202     noconfigdirs="$noconfigdirs gdb"
1203     ;;
1204   mt-*-*)
1205     noconfigdirs="$noconfigdirs sim"
1206     ;;
1207   nfp-*-*)
1208     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1209     noconfigdirs="$noconfigdirs $target_libraries"
1210     ;;
1211   pdp11-*-*)
1212     noconfigdirs="$noconfigdirs gdb gprof"
1213     ;;
1214   powerpc-*-aix*)
1215     # copied from rs6000-*-* entry
1216     noconfigdirs="$noconfigdirs gprof"
1217     ;;
1218   powerpc*-*-winnt* | powerpc*-*-pe*)
1219     target_configdirs="$target_configdirs target-winsup"
1220     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1221     # always build newlib.
1222     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1223     ;;
1224     # This is temporary until we can link against shared libraries
1225   powerpcle-*-solaris*)
1226     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1227     ;;
1228   powerpc-*-beos*)
1229     noconfigdirs="$noconfigdirs gdb"
1230     ;;
1231   rs6000-*-lynxos*)
1232     noconfigdirs="$noconfigdirs gprof"
1233     ;;
1234   rs6000-*-aix*)
1235     noconfigdirs="$noconfigdirs gprof"
1236     ;;
1237   rs6000-*-*)
1238     noconfigdirs="$noconfigdirs gprof"
1239     ;;
1240   m68k-apollo-*)
1241     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1242     ;;
1243   microblaze*)
1244     noconfigdirs="$noconfigdirs gprof"
1245     ;;
1246   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1247     if test x$with_newlib = xyes; then
1248       noconfigdirs="$noconfigdirs gprof"
1249     fi
1250     ;;
1251   mips*-*-irix5*)
1252     noconfigdirs="$noconfigdirs gprof target-libgloss"
1253     ;;
1254   mips*-*-irix6*)
1255     noconfigdirs="$noconfigdirs gprof target-libgloss"
1256     ;;
1257   mips*-*-bsd*)
1258     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1259     ;;
1260   mips*-*-linux*)
1261     ;;
1262   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1263   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1264     noconfigdirs="$noconfigdirs ld gas gprof"
1265     ;;
1266   mips*-*-*)
1267     noconfigdirs="$noconfigdirs gprof"
1268     ;;
1269   nvptx*-*-*)
1270     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1271     ;;
1272   sh-*-*)
1273     case "${target}" in
1274       sh*-*-elf)
1275          ;;
1276       *)
1277          noconfigdirs="$noconfigdirs target-libgloss" ;;
1278     esac
1279     ;;
1280   sparc-*-sunos4*)
1281     if test x${is_cross_compiler} = xno ; then
1282            use_gnu_ld=no
1283     fi
1284     ;;
1285   tic6x-*-*)
1286     noconfigdirs="$noconfigdirs sim"
1287     ;;
1288   tilepro*-*-* | tilegx*-*-*)
1289     noconfigdirs="$noconfigdirs sim"
1290     ;;
1291   v810-*-*)
1292     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1293     ;;
1294   vax-*-*)
1295     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1296     ;;
1297   wasm32-*-*)
1298     noconfigdirs="$noconfigdirs ld"
1299     ;;
1300 esac
1301
1302 # If we aren't building newlib, then don't build libgloss, since libgloss
1303 # depends upon some newlib header files.
1304 case "${noconfigdirs}" in
1305   *target-libgloss*) ;;
1306   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1307 esac
1308
1309 # Work in distributions that contain no compiler tools, like Autoconf.
1310 host_makefile_frag=/dev/null
1311 if test -d ${srcdir}/config ; then
1312 case "${host}" in
1313   i[[3456789]]86-*-msdosdjgpp*)
1314     host_makefile_frag="config/mh-djgpp"
1315     ;;
1316   *-cygwin*)
1317     ACX_CHECK_CYGWIN_CAT_WORKS
1318     host_makefile_frag="config/mh-cygwin"
1319     ;;
1320   *-mingw*)
1321     host_makefile_frag="config/mh-mingw"
1322     ;;
1323   alpha*-linux*)
1324     host_makefile_frag="config/mh-alpha-linux"
1325     ;;
1326   hppa*-hp-hpux10*)
1327     host_makefile_frag="config/mh-pa-hpux10"
1328     ;;
1329   hppa*-hp-hpux*)
1330     host_makefile_frag="config/mh-pa"
1331     ;;
1332   hppa*-*)
1333     host_makefile_frag="config/mh-pa"
1334     ;;
1335   *-*-darwin*)
1336     host_makefile_frag="config/mh-darwin"
1337     ;;
1338   powerpc-*-aix*)
1339     host_makefile_frag="config/mh-ppc-aix"
1340     ;;
1341   rs6000-*-aix*)
1342     host_makefile_frag="config/mh-ppc-aix"
1343     ;;
1344 esac
1345 fi
1346
1347 if test "${build}" != "${host}" ; then
1348   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1349   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1350   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1351   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1352   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1353   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1354   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1355   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1356   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1357   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1358   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1359   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1360   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1361 else
1362   AR_FOR_BUILD="\$(AR)"
1363   AS_FOR_BUILD="\$(AS)"
1364   CC_FOR_BUILD="\$(CC)"
1365   CXX_FOR_BUILD="\$(CXX)"
1366   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1367   GOC_FOR_BUILD="\$(GOC)"
1368   GDC_FOR_BUILD="\$(GDC)"
1369   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1370   LD_FOR_BUILD="\$(LD)"
1371   NM_FOR_BUILD="\$(NM)"
1372   RANLIB_FOR_BUILD="\$(RANLIB)"
1373   WINDRES_FOR_BUILD="\$(WINDRES)"
1374   WINDMC_FOR_BUILD="\$(WINDMC)"
1375 fi
1376
1377 AC_PROG_CC
1378 AC_PROG_CXX
1379
1380 # We must set the default linker to the linker used by gcc for the correct
1381 # operation of libtool.  If LD is not defined and we are using gcc, try to
1382 # set the LD default to the ld used by gcc.
1383 if test -z "$LD"; then
1384   if test "$GCC" = yes; then
1385     case $build in
1386     *-*-mingw*)
1387       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1388     *)
1389       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1390     esac
1391     case $gcc_prog_ld in
1392     # Accept absolute paths.
1393     [[\\/]* | [A-Za-z]:[\\/]*)]
1394       LD="$gcc_prog_ld" ;;
1395     esac
1396   fi
1397 fi
1398
1399 # Check whether -static-libstdc++ -static-libgcc is supported.
1400 have_static_libs=no
1401 if test "$GCC" = yes; then
1402   saved_LDFLAGS="$LDFLAGS"
1403
1404   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1405   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1406   AC_LANG_PUSH(C++)
1407   AC_LINK_IFELSE([AC_LANG_SOURCE([
1408 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1409 #error -static-libstdc++ not implemented
1410 #endif
1411 int main() {}])],
1412     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1413     [AC_MSG_RESULT([no])])
1414   AC_LANG_POP(C++)
1415
1416   LDFLAGS="$saved_LDFLAGS"
1417 fi
1418
1419 ACX_PROG_GNAT
1420 ACX_PROG_CMP_IGNORE_INITIAL
1421
1422 AC_ARG_ENABLE([bootstrap],
1423 [AS_HELP_STRING([--enable-bootstrap],
1424                 [enable bootstrapping @<:@yes if native build@:>@])],,
1425 enable_bootstrap=default)
1426
1427 # Issue errors and warnings for invalid/strange bootstrap combinations.
1428 if test -r $srcdir/gcc/configure; then
1429   have_compiler=yes
1430 else
1431   have_compiler=no
1432 fi
1433
1434 case "$have_compiler:$host:$target:$enable_bootstrap" in
1435   *:*:*:no) ;;
1436
1437   # Default behavior.  Enable bootstrap if we have a compiler
1438   # and we are in a native configuration.
1439   yes:$build:$build:default)
1440     enable_bootstrap=yes ;;
1441
1442   *:*:*:default)
1443     enable_bootstrap=no ;;
1444
1445   # We have a compiler and we are in a native configuration, bootstrap is ok
1446   yes:$build:$build:yes)
1447     ;;
1448
1449   # Other configurations, but we have a compiler.  Assume the user knows
1450   # what he's doing.
1451   yes:*:*:yes)
1452     AC_MSG_WARN([trying to bootstrap a cross compiler])
1453     ;;
1454
1455   # No compiler: if they passed --enable-bootstrap explicitly, fail
1456   no:*:*:yes)
1457     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1458
1459   # Fail if wrong command line
1460   *)
1461     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1462     ;;
1463 esac
1464
1465 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1466 # C++11 compiler can still start the bootstrap.
1467 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1468   CXX="$CXX -std=c++11"
1469 fi
1470
1471 # Used for setting $lt_cv_objdir
1472 _LT_CHECK_OBJDIR
1473
1474 # Check for GMP, MPFR and MPC
1475 gmplibs="-lmpc -lmpfr -lgmp"
1476 gmpinc=
1477 have_gmp=no
1478
1479 # Specify a location for mpc
1480 # check for this first so it ends up on the link line before mpfr.
1481 AC_ARG_WITH(mpc,
1482 [AS_HELP_STRING([--with-mpc=PATH],
1483                 [specify prefix directory for installed MPC package.
1484                  Equivalent to --with-mpc-include=PATH/include
1485                  plus --with-mpc-lib=PATH/lib])])
1486 AC_ARG_WITH(mpc-include,
1487 [AS_HELP_STRING([--with-mpc-include=PATH],
1488                 [specify directory for installed MPC include files])])
1489 AC_ARG_WITH(mpc-lib,
1490 [AS_HELP_STRING([--with-mpc-lib=PATH],
1491                 [specify directory for the installed MPC library])])
1492
1493 if test "x$with_mpc" != x; then
1494   gmplibs="-L$with_mpc/lib $gmplibs"
1495   gmpinc="-I$with_mpc/include $gmpinc"
1496 fi
1497 if test "x$with_mpc_include" != x; then
1498   gmpinc="-I$with_mpc_include $gmpinc"
1499 fi
1500 if test "x$with_mpc_lib" != x; then
1501   gmplibs="-L$with_mpc_lib $gmplibs"
1502 fi
1503 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1504   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1505   gmpinc='-I$$s/mpc/src '"$gmpinc"
1506   # Do not test the mpc version.  Assume that it is sufficient, since
1507   # it is in the source tree, and the library has not been built yet
1508   # but it would be included on the link line in the version check below
1509   # hence making the test fail.
1510   have_gmp=yes
1511 fi
1512
1513 # Specify a location for mpfr
1514 # check for this first so it ends up on the link line before gmp.
1515 AC_ARG_WITH(mpfr-dir,
1516 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1517 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1518 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1519
1520 AC_ARG_WITH(mpfr,
1521 [AS_HELP_STRING([--with-mpfr=PATH],
1522                 [specify prefix directory for installed MPFR package.
1523                  Equivalent to --with-mpfr-include=PATH/include
1524                  plus --with-mpfr-lib=PATH/lib])])
1525 AC_ARG_WITH(mpfr-include,
1526 [AS_HELP_STRING([--with-mpfr-include=PATH],
1527                 [specify directory for installed MPFR include files])])
1528 AC_ARG_WITH(mpfr-lib,
1529 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1530                 [specify directory for the installed MPFR library])])
1531
1532 if test "x$with_mpfr" != x; then
1533   gmplibs="-L$with_mpfr/lib $gmplibs"
1534   gmpinc="-I$with_mpfr/include $gmpinc"
1535 fi
1536 if test "x$with_mpfr_include" != x; then
1537   gmpinc="-I$with_mpfr_include $gmpinc"
1538 fi
1539 if test "x$with_mpfr_lib" != x; then
1540   gmplibs="-L$with_mpfr_lib $gmplibs"
1541 fi
1542 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1543   # MPFR v3.1.0 moved the sources into a src sub-directory.
1544   if ! test -d ${srcdir}/mpfr/src; then
1545     AC_MSG_ERROR([dnl
1546 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1547   fi
1548   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1549   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1550   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1551   # Do not test the mpfr version.  Assume that it is sufficient, since
1552   # it is in the source tree, and the library has not been built yet
1553   # but it would be included on the link line in the version check below
1554   # hence making the test fail.
1555   have_gmp=yes
1556 fi
1557
1558 # Specify a location for gmp
1559 AC_ARG_WITH(gmp-dir,
1560 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1561 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1562 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1563
1564 AC_ARG_WITH(gmp,
1565 [AS_HELP_STRING([--with-gmp=PATH],
1566                 [specify prefix directory for the installed GMP package.
1567                  Equivalent to --with-gmp-include=PATH/include
1568                  plus --with-gmp-lib=PATH/lib])])
1569 AC_ARG_WITH(gmp-include,
1570 [AS_HELP_STRING([--with-gmp-include=PATH],
1571                 [specify directory for installed GMP include files])])
1572 AC_ARG_WITH(gmp-lib,
1573 [AS_HELP_STRING([--with-gmp-lib=PATH],
1574                 [specify directory for the installed GMP library])])
1575
1576
1577 if test "x$with_gmp" != x; then
1578   gmplibs="-L$with_gmp/lib $gmplibs"
1579   gmpinc="-I$with_gmp/include $gmpinc"
1580 fi
1581 if test "x$with_gmp_include" != x; then
1582   gmpinc="-I$with_gmp_include $gmpinc"
1583 fi
1584 if test "x$with_gmp_lib" != x; then
1585   gmplibs="-L$with_gmp_lib $gmplibs"
1586 fi
1587 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1588   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1589   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1590   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1591   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1592   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1593   # Do not test the gmp version.  Assume that it is sufficient, since
1594   # it is in the source tree, and the library has not been built yet
1595   # but it would be included on the link line in the version check below
1596   # hence making the test fail.
1597   have_gmp=yes
1598 fi
1599
1600 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1601   have_gmp=yes
1602   saved_CFLAGS="$CFLAGS"
1603   CFLAGS="$CFLAGS $gmpinc"
1604   # Check for the recommended and required versions of GMP.
1605   AC_MSG_CHECKING([for the correct version of gmp.h])
1606   AC_TRY_COMPILE([#include "gmp.h"],[
1607   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1608   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1609   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1610   choke me
1611   #endif
1612   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1613   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1614   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1615   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1616   choke me
1617   #endif
1618   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1619    [AC_MSG_RESULT([no]); have_gmp=no])
1620
1621   # If we have GMP, check the MPFR version.
1622   if test x"$have_gmp" = xyes; then
1623     # Check for the recommended and required versions of MPFR.
1624     AC_MSG_CHECKING([for the correct version of mpfr.h])
1625     AC_TRY_COMPILE([#include <gmp.h>
1626     #include <mpfr.h>],[
1627     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1628     choke me
1629     #endif
1630     ], [AC_TRY_COMPILE([#include <gmp.h>
1631     #include <mpfr.h>],[
1632     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1633     choke me
1634     #endif
1635     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1636      [AC_MSG_RESULT([no]); have_gmp=no])
1637   fi
1638
1639   # Check for the MPC header version.
1640   if test x"$have_gmp" = xyes ; then
1641     # Check for the recommended and required versions of MPC.
1642     AC_MSG_CHECKING([for the correct version of mpc.h])
1643     AC_TRY_COMPILE([#include <mpc.h>],[
1644     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1645     choke me
1646     #endif
1647     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1648     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1649     choke me
1650     #endif
1651     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1652      [AC_MSG_RESULT([no]); have_gmp=no])
1653   fi
1654
1655   # Now check the MPFR library.
1656   if test x"$have_gmp" = xyes; then
1657     saved_LIBS="$LIBS"
1658     LIBS="$LIBS $gmplibs"
1659     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1660     AC_TRY_LINK([#include <mpc.h>],[
1661     mpfr_t n;
1662     mpfr_t x;
1663     mpc_t c;
1664     int t;
1665     mpfr_init (n);
1666     mpfr_init (x);
1667     mpfr_atan2 (n, n, x, MPFR_RNDN);
1668     mpfr_erfc (n, x, MPFR_RNDN);
1669     mpfr_subnormalize (x, t, MPFR_RNDN);
1670     mpfr_clear(n);
1671     mpfr_clear(x);
1672     mpc_init2 (c, 53);
1673     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1674     mpc_cosh (c, c, MPC_RNDNN);
1675     mpc_pow (c, c, c, MPC_RNDNN);
1676     mpc_acosh (c, c, MPC_RNDNN);
1677     mpc_clear (c);
1678     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1679     LIBS="$saved_LIBS"
1680   fi
1681
1682   CFLAGS="$saved_CFLAGS"
1683
1684 # The library versions listed in the error message below should match
1685 # the HARD-minimums enforced above.
1686   if test x$have_gmp != xyes; then
1687     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1688 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1689 their locations.  Source code for these libraries can be found at
1690 their respective hosting sites as well as at
1691 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1692 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1693 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1694 make sure that you have installed both the libraries and the header
1695 files.  They may be located in separate packages.])
1696   fi
1697 fi
1698
1699 # Flags needed for both GMP, MPFR and/or MPC.
1700 AC_SUBST(gmplibs)
1701 AC_SUBST(gmpinc)
1702 AC_SUBST(extra_mpfr_configure_flags)
1703 AC_SUBST(extra_mpc_gmp_configure_flags)
1704 AC_SUBST(extra_mpc_mpfr_configure_flags)
1705 AC_SUBST(extra_isl_gmp_configure_flags)
1706
1707 # Libraries to use for stage1 or when not bootstrapping.
1708 AC_ARG_WITH(stage1-libs,
1709 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1710 [if test "$withval" = "no" -o "$withval" = "yes"; then
1711    stage1_libs=
1712  else
1713    stage1_libs=$withval
1714  fi],
1715 [stage1_libs=])
1716 AC_SUBST(stage1_libs)
1717
1718 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1719 # default is yes if gcc is being built; no otherwise.  The reason for
1720 # this default is that gdb is sometimes linked against GNU Source
1721 # Highlight, which is a shared library that uses C++ exceptions.  In
1722 # this case, -static-libstdc++ will cause crashes.
1723 AC_ARG_WITH(static-standard-libraries,
1724 [AS_HELP_STRING([--with-static-standard-libraries],
1725                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1726 [], [with_static_standard_libraries=auto])
1727 if test "$with_static_standard_libraries" = auto; then
1728   with_static_standard_libraries=$have_compiler
1729 fi
1730
1731 # Linker flags to use for stage1 or when not bootstrapping.
1732 AC_ARG_WITH(stage1-ldflags,
1733 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1734 [if test "$withval" = "no" -o "$withval" = "yes"; then
1735    stage1_ldflags=
1736  else
1737    stage1_ldflags=$withval
1738  fi],
1739 [stage1_ldflags=
1740  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1741  # if supported.  But if the user explicitly specified the libraries to use,
1742  # trust that they are doing what they want.
1743  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1744      -a "$have_static_libs" = yes; then
1745    stage1_ldflags="-static-libstdc++ -static-libgcc"
1746  fi])
1747 AC_SUBST(stage1_ldflags)
1748
1749 # Libraries to use for stage2 and later builds.
1750 AC_ARG_WITH(boot-libs,
1751 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1752 [if test "$withval" = "no" -o "$withval" = "yes"; then
1753    poststage1_libs=
1754  else
1755    poststage1_libs=$withval
1756  fi],
1757 [poststage1_libs=])
1758 AC_SUBST(poststage1_libs)
1759
1760 # Linker flags to use for stage2 and later builds.
1761 AC_ARG_WITH(boot-ldflags,
1762 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1763                 [linker flags for stage2 and later])],
1764 [if test "$withval" = "no" -o "$withval" = "yes"; then
1765    poststage1_ldflags=
1766  else
1767    poststage1_ldflags=$withval
1768  fi],
1769 [poststage1_ldflags=
1770  # In stages 2 and 3, default to linking libstdc++ and libgcc
1771  # statically.  But if the user explicitly specified the libraries to
1772  # use, trust that they are doing what they want.
1773  if test "$poststage1_libs" = ""; then
1774    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1775  fi])
1776 AC_SUBST(poststage1_ldflags)
1777
1778 # GCC GRAPHITE dependency isl.
1779 # Basic setup is inlined here, actual checks are in config/isl.m4
1780
1781 AC_ARG_WITH(isl,
1782   [AS_HELP_STRING(
1783    [--with-isl=PATH],
1784    [Specify prefix directory for the installed isl package.
1785     Equivalent to --with-isl-include=PATH/include
1786     plus --with-isl-lib=PATH/lib])])
1787
1788 # Treat --without-isl as a request to disable
1789 # GRAPHITE support and skip all following checks.
1790 if test "x$with_isl" != "xno"; then
1791   # Check for isl
1792   dnl Provide configure switches and initialize islinc & isllibs
1793   dnl with user input.
1794   ISL_INIT_FLAGS
1795   dnl The versions of isl that work for Graphite
1796   ISL_CHECK_VERSION()
1797   dnl Only execute fail-action, if isl has been requested.
1798   ISL_IF_FAILED([
1799     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1800 fi
1801
1802 # If the isl check failed, disable builds of in-tree variant of isl
1803 if test "x$with_isl" = xno ||
1804    test "x$gcc_cv_isl" = xno; then
1805   noconfigdirs="$noconfigdirs isl"
1806   islinc=
1807 fi
1808
1809 AC_SUBST(isllibs)
1810 AC_SUBST(islinc)
1811
1812 # Check for LTO support.
1813 AC_ARG_ENABLE(lto,
1814 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1815 enable_lto=$enableval,
1816 enable_lto=yes; default_enable_lto=yes)
1817
1818 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1819   build_lto_plugin=yes
1820 ],[if test x"$default_enable_lto" = x"yes" ; then
1821     case $target in
1822       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1823       # On other non-ELF platforms, LTO has yet to be validated.
1824       *) enable_lto=no ;;
1825     esac
1826   else
1827   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1828   # It would also be nice to check the binutils support, but we don't
1829   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1830   # warn during gcc/ subconfigure; unless you're bootstrapping with
1831   # -flto it won't be needed until after installation anyway.
1832     case $target in
1833       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1834       *) if test x"$enable_lto" = x"yes"; then
1835         AC_MSG_ERROR([LTO support is not enabled for this target.])
1836         fi
1837       ;;
1838     esac
1839   fi
1840   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1841   # Build it unless LTO was explicitly disabled.
1842   case $target in
1843     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1844     *) ;;
1845   esac
1846 ])
1847
1848 AC_ARG_ENABLE(linker-plugin-configure-flags,
1849   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1850     [additional flags for configuring linker plugins @<:@none@:>@])],
1851   extra_linker_plugin_configure_flags=$enableval,
1852   extra_linker_plugin_configure_flags=)
1853 AC_SUBST(extra_linker_plugin_configure_flags)
1854 AC_ARG_ENABLE(linker-plugin-flags,
1855   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1856     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1857   extra_linker_plugin_flags=$enableval,
1858   extra_linker_plugin_flags=)
1859 AC_SUBST(extra_linker_plugin_flags)
1860
1861 # Enable --enable-host-shared.
1862 # Checked early to determine whether jit is an 'all' language
1863 AC_ARG_ENABLE(host-shared,
1864 [AS_HELP_STRING([--enable-host-shared],
1865                 [build host code as shared libraries])],
1866 [host_shared=$enableval], [host_shared=no])
1867 AC_SUBST(host_shared)
1868
1869 # By default, C and C++ are the only stage 1 languages.
1870 stage1_languages=,c,
1871
1872 # Target libraries that we bootstrap.
1873 bootstrap_target_libs=,target-libgcc,
1874
1875 # Figure out what language subdirectories are present.
1876 # Look if the user specified --enable-languages="..."; if not, use
1877 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1878 # go away some day.
1879 # NB:  embedded tabs in this IF block -- do not untabify
1880 if test -d ${srcdir}/gcc; then
1881   if test x"${enable_languages+set}" != xset; then
1882     if test x"${LANGUAGES+set}" = xset; then
1883       enable_languages="${LANGUAGES}"
1884         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1885     else
1886       enable_languages=default
1887     fi
1888   else
1889     if test x"${enable_languages}" = x ||
1890        test x"${enable_languages}" = xyes;
1891        then
1892       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1893       exit 1
1894     fi
1895   fi
1896   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1897
1898   # 'f95' is the old name for the 'fortran' language. We issue a warning
1899   # and make the substitution.
1900   case ,${enable_languages}, in
1901     *,f95,*)
1902       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1903       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1904       ;;
1905   esac
1906
1907   # If bootstrapping, C++ must be enabled.
1908   case ",$enable_languages,:$enable_bootstrap" in
1909     *,c++,*:*) ;;
1910     *:yes)
1911       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1912         enable_languages="${enable_languages},c++"
1913       else
1914         AC_MSG_ERROR([bootstrapping requires c++ sources])
1915       fi
1916       ;;
1917   esac
1918
1919   # First scan to see if an enabled language requires some other language.
1920   # We assume that a given config-lang.in will list all the language
1921   # front ends it requires, even if some are required indirectly.
1922   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1923     case ${lang_frag} in
1924       ..) ;;
1925       # The odd quoting in the next line works around
1926       # an apparent bug in bash 1.12 on linux.
1927       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1928       *)
1929         # From the config-lang.in, get $language, $lang_requires, and
1930         # $lang_requires_boot_languages.
1931         language=
1932         lang_requires=
1933         lang_requires_boot_languages=
1934         # set srcdir during sourcing lang_frag to the gcc dir.
1935         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1936         # polutes this shell
1937         saved_srcdir=${srcdir}
1938         srcdir=${srcdir}/gcc . ${lang_frag}
1939         srcdir=${saved_srcdir}
1940         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1941           case ,${enable_languages}, in
1942             *,$other,*) ;;
1943             *,default,*) ;;
1944             *,all,*) ;;
1945             *,$language,*)
1946               echo " \`$other' language required by \`$language'; enabling" 1>&2
1947               enable_languages="${enable_languages},${other}"
1948               ;;
1949           esac
1950         done
1951         for other in ${lang_requires_boot_languages} ; do
1952           if test "$other" != "c"; then
1953             case ,${enable_stage1_languages}, in
1954               *,$other,*) ;;
1955               *,default,*) ;;
1956               *,all,*) ;;
1957               *)
1958                 case ,${enable_languages}, in
1959                   *,$language,*)
1960                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1961                     enable_stage1_languages="$enable_stage1_languages,${other}"
1962                     ;;
1963                 esac
1964                 ;;
1965             esac
1966           fi
1967         done
1968         ;;
1969     esac
1970   done
1971
1972   new_enable_languages=,c,
1973
1974   # If LTO is enabled, add the LTO front end.
1975   if test "$enable_lto" = "yes" ; then
1976     case ,${enable_languages}, in
1977       *,lto,*) ;;
1978       *) enable_languages="${enable_languages},lto" ;;
1979     esac
1980     if test "${build_lto_plugin}" = "yes" ; then
1981       configdirs="$configdirs lto-plugin"
1982     fi
1983   fi
1984
1985   # If we're building an offloading compiler, add the LTO front end.
1986   if test x"$enable_as_accelerator_for" != x ; then
1987     case ,${enable_languages}, in
1988       *,lto,*) ;;
1989       *) enable_languages="${enable_languages},lto" ;;
1990     esac
1991   fi
1992
1993   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1994   potential_languages=,c,
1995
1996   enabled_target_libs=
1997   disabled_target_libs=
1998
1999   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2000     case ${lang_frag} in
2001       ..) ;;
2002       # The odd quoting in the next line works around
2003       # an apparent bug in bash 1.12 on linux.
2004       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2005       *)
2006         # From the config-lang.in, get $language, $target_libs,
2007         # $lang_dirs, $boot_language, and $build_by_default
2008         language=
2009         target_libs=
2010         lang_dirs=
2011         subdir_requires=
2012         boot_language=no
2013         build_by_default=yes
2014         # set srcdir during sourcing.  See above about save & restore
2015         saved_srcdir=${srcdir}
2016         srcdir=${srcdir}/gcc . ${lang_frag}
2017         srcdir=${saved_srcdir}
2018         if test x${language} = x; then
2019           echo "${lang_frag} doesn't set \$language." 1>&2
2020           exit 1
2021         fi
2022
2023         if test "$language" = "c++"; then
2024           boot_language=yes
2025         fi
2026
2027         add_this_lang=no
2028         # C is always enabled, so no need to add it again
2029         if test "$language" != "c"; then
2030           case ,${enable_languages}, in
2031             *,${language},*)
2032               # Language was explicitly selected; include it
2033               add_this_lang=yes
2034               ;;
2035             *,all,*)
2036               # All languages are enabled
2037               add_this_lang=all
2038               ;;
2039             *,default,*)
2040               # 'default' was selected, select it if it is a default language
2041               add_this_lang=${build_by_default}
2042               ;;
2043           esac
2044         fi
2045
2046         # Disable languages that need other directories if these aren't available.
2047         for i in $subdir_requires; do
2048           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2049           case ${add_this_lang} in
2050             yes)
2051               # Specifically requested language; tell them.
2052               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2053               ;;
2054             all)
2055               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2056               add_this_lang=unsupported
2057               ;;
2058             *)
2059               # Silently disable.
2060               add_this_lang=unsupported
2061               ;;
2062           esac
2063         done
2064
2065         # Disable Ada if no preexisting GNAT is available.
2066         case ${add_this_lang}:${language}:${have_gnat} in
2067           yes:ada:no)
2068             # Specifically requested language; tell them.
2069             AC_MSG_ERROR([GNAT is required to build $language])
2070             ;;
2071           all:ada:no)
2072             AC_MSG_WARN([GNAT is required to build $language])
2073             add_this_lang=unsupported
2074             ;;
2075           *:ada:no)
2076             # Silently disable.
2077             add_this_lang=unsupported
2078             ;;
2079         esac
2080
2081         # Disable jit if -enable-host-shared not specified
2082         # but not if building for Mingw. All code in Windows
2083         # is position independent code (PIC).
2084         case $target in
2085           *mingw*) ;;
2086           *)
2087           case ${add_this_lang}:${language}:${host_shared} in
2088             yes:jit:no)
2089                    # PR jit/64780: explicitly specify --enable-host-shared
2090             AC_MSG_ERROR([
2091 Enabling language "jit" requires --enable-host-shared.
2092
2093 --enable-host-shared typically slows the rest of the compiler down by
2094 a few %, so you must explicitly enable it.
2095
2096 If you want to build both the jit and the regular compiler, it is often
2097 best to do this via two separate configure/builds, in separate
2098 directories, to avoid imposing the performance cost of
2099 --enable-host-shared on the regular compiler.])
2100                     ;;
2101             all:jit:no)
2102               AC_MSG_WARN([--enable-host-shared required to build $language])
2103               add_this_lang=unsupported
2104               ;;
2105             *:jit:no)
2106               # Silently disable.
2107               add_this_lang=unsupported
2108               ;;
2109                 esac
2110           ;;
2111         esac
2112
2113         # Disable a language that is unsupported by the target.
2114         case "${add_this_lang}: $unsupported_languages " in
2115           no:*) ;;
2116           unsupported:*) ;;
2117           *:*" $language "*)
2118             AC_MSG_WARN([${language} not supported for this target])
2119             add_this_lang=unsupported
2120             ;;
2121         esac
2122
2123         case $add_this_lang in
2124           unsupported)
2125             # Remove language-dependent dirs.
2126             disabled_target_libs="$disabled_target_libs $target_libs"
2127             noconfigdirs="$noconfigdirs $lang_dirs"
2128             ;;
2129           no)
2130             # Remove language-dependent dirs; still show language as supported.
2131             disabled_target_libs="$disabled_target_libs $target_libs"
2132             noconfigdirs="$noconfigdirs $lang_dirs"
2133             potential_languages="${potential_languages}${language},"
2134             ;;
2135           all|yes)
2136             new_enable_languages="${new_enable_languages}${language},"
2137             potential_languages="${potential_languages}${language},"
2138             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2139             enabled_target_libs="$enabled_target_libs $target_libs"
2140             case "${boot_language}:,$enable_stage1_languages," in
2141               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2142                 # Add to (comma-separated) list of stage 1 languages.
2143                 case ",$stage1_languages," in
2144                   *,$language,* | ,yes, | ,all,) ;;
2145                   *) stage1_languages="${stage1_languages}${language}," ;;
2146                 esac
2147                 # We need to bootstrap any supporting libraries.
2148                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2149                 ;;
2150             esac
2151             ;;
2152         esac
2153         ;;
2154     esac
2155   done
2156
2157   # Add target libraries which are only needed for disabled languages
2158   # to noconfigdirs.
2159   if test -n "$disabled_target_libs"; then
2160     for dir in $disabled_target_libs; do
2161       case " $enabled_target_libs " in
2162       *" ${dir} "*) ;;
2163       *) noconfigdirs="$noconfigdirs $dir" ;;
2164       esac
2165     done
2166   fi
2167
2168   AC_ARG_ENABLE(stage1-languages,
2169   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2170                   [choose additional languages to build during
2171                   stage1.  Mostly useful for compiler development])],
2172   [case ,${enable_stage1_languages}, in
2173     ,no,|,,)
2174       # Set it to something that will have no effect in the loop below
2175       enable_stage1_languages=c ;;
2176     ,yes,)
2177       enable_stage1_languages=`echo $new_enable_languages | \
2178         sed -e "s/^,//" -e "s/,$//" ` ;;
2179     *,all,*)
2180       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2181         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2182   esac
2183
2184   # Add "good" languages from enable_stage1_languages to stage1_languages,
2185   # while "bad" languages go in missing_languages.  Leave no duplicates.
2186   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2187     case $potential_languages in
2188       *,$i,*)
2189         case $stage1_languages in
2190           *,$i,*) ;;
2191           *) stage1_languages="$stage1_languages$i," ;;
2192         esac ;;
2193       *)
2194         case $missing_languages in
2195           *,$i,*) ;;
2196           *) missing_languages="$missing_languages$i," ;;
2197         esac ;;
2198      esac
2199   done])
2200
2201   # Remove leading/trailing commas that were added for simplicity
2202   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2203   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2204   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2205   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2206
2207   if test "x$missing_languages" != x; then
2208     AC_MSG_ERROR([
2209 The following requested languages could not be built: ${missing_languages}
2210 Supported languages are: ${potential_languages}])
2211   fi
2212   if test "x$new_enable_languages" != "x$enable_languages"; then
2213     echo The following languages will be built: ${new_enable_languages}
2214     enable_languages="$new_enable_languages"
2215   fi
2216
2217   AC_SUBST(stage1_languages)
2218   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2219 fi
2220
2221 # Handle --disable-<component> generically.
2222 for dir in $configdirs $build_configdirs $target_configdirs ; do
2223   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2224   varname=`echo $dirname | sed -e s/+/_/g`
2225   if eval test x\${enable_${varname}} "=" xno ; then
2226     noconfigdirs="$noconfigdirs $dir"
2227   fi
2228 done
2229
2230 # Check for Boehm's garbage collector
2231 AC_ARG_ENABLE(objc-gc,
2232 [AS_HELP_STRING([--enable-objc-gc],
2233                 [enable use of Boehm's garbage collector with the
2234                  GNU Objective-C runtime])])
2235 AC_ARG_WITH([target-bdw-gc],
2236 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2237                 [specify prefix directory for installed bdw-gc package.
2238                  Equivalent to --with-target-bdw-gc-include=PATH/include
2239                  plus --with-target-bdw-gc-lib=PATH/lib])])
2240 AC_ARG_WITH([target-bdw-gc-include],
2241 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2242                 [specify directories for installed bdw-gc include files])])
2243 AC_ARG_WITH([target-bdw-gc-lib],
2244 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2245                 [specify directories for installed bdw-gc library])])
2246
2247 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2248   AC_MSG_CHECKING([for bdw garbage collector])
2249   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2250     dnl no bdw-gw options, assume default locations
2251     AC_MSG_RESULT([using bdw-gc in default locations])
2252   else
2253     dnl bdw-gw options, first error checking, complete checking in libobjc
2254     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2255       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2256     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2257       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2258     else
2259       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2260     fi
2261   fi
2262 esac
2263
2264 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2265 case ,${enable_languages}, in
2266   *,c++,*)
2267     # Disable libitm, libsanitizer if we're not building libstdc++
2268     case "${noconfigdirs}" in
2269       *target-libstdc++-v3*)
2270         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2271         ;;
2272       *) ;;
2273     esac
2274     ;;
2275   *)
2276     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2277     ;;
2278 esac
2279
2280 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2281 # $build_configdirs and $target_configdirs.
2282 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2283
2284 notsupp=""
2285 for dir in . $skipdirs $noconfigdirs ; do
2286   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2287   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2288     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2289     if test -r $srcdir/$dirname/configure ; then
2290       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2291         true
2292       else
2293         notsupp="$notsupp $dir"
2294       fi
2295     fi
2296   fi
2297   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2298     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2299     if test -r $srcdir/$dirname/configure ; then
2300       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2301         true
2302       else
2303         notsupp="$notsupp $dir"
2304       fi
2305     fi
2306   fi
2307   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2308     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2309     if test -r $srcdir/$dirname/configure ; then
2310       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2311         true
2312       else
2313         notsupp="$notsupp $dir"
2314       fi
2315     fi
2316   fi
2317 done
2318
2319 # Quietly strip out all directories which aren't configurable in this tree.
2320 # This relies on all configurable subdirectories being autoconfiscated, which
2321 # is now the case.
2322 build_configdirs_all="$build_configdirs"
2323 build_configdirs=
2324 for i in ${build_configdirs_all} ; do
2325   j=`echo $i | sed -e s/build-//g`
2326   if test -f ${srcdir}/$j/configure ; then
2327     build_configdirs="${build_configdirs} $i"
2328   fi
2329 done
2330
2331 configdirs_all="$configdirs"
2332 configdirs=
2333 for i in ${configdirs_all} ; do
2334   if test -f ${srcdir}/$i/configure ; then
2335     configdirs="${configdirs} $i"
2336   fi
2337 done
2338
2339 target_configdirs_all="$target_configdirs"
2340 target_configdirs=
2341 for i in ${target_configdirs_all} ; do
2342   j=`echo $i | sed -e s/target-//g`
2343   if test -f ${srcdir}/$j/configure ; then
2344     target_configdirs="${target_configdirs} $i"
2345   fi
2346 done
2347
2348 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2349 # so we have to add it after the preceding checks.
2350 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2351 then
2352   case " $configdirs " in
2353     *" libiberty "*)
2354       # If we can build libiberty, we can also build libiberty-linker-plugin.
2355       configdirs="$configdirs libiberty-linker-plugin"
2356       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2357         --with-libiberty=../libiberty-linker-plugin";;
2358     *)
2359       AC_MSG_ERROR([libiberty missing]);;
2360   esac
2361 fi
2362
2363 # Sometimes we have special requirements for the host libiberty.
2364 extra_host_libiberty_configure_flags=
2365 extra_host_zlib_configure_flags=
2366 case " $configdirs " in
2367   *" lto-plugin "* | *" libcc1 "*)
2368     # When these are to be built as shared libraries, the same applies to
2369     # libiberty.
2370     extra_host_libiberty_configure_flags=--enable-shared
2371     ;;
2372   *" bfd "*)
2373     # When bfd is to be built as a shared library, the same applies to
2374     # zlib.
2375     if test "$enable_shared" = "yes"; then
2376       extra_host_zlib_configure_flags=--enable-host-shared
2377     fi
2378     ;;
2379 esac
2380 AC_SUBST(extra_host_libiberty_configure_flags)
2381 AC_SUBST(extra_host_zlib_configure_flags)
2382
2383 # Produce a warning message for the subdirs we can't configure.
2384 # This isn't especially interesting in the Cygnus tree, but in the individual
2385 # FSF releases, it's important to let people know when their machine isn't
2386 # supported by the one or two programs in a package.
2387
2388 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2389   # If $appdirs is non-empty, at least one of those directories must still
2390   # be configured, or we error out.  (E.g., if the gas release supports a
2391   # specified target in some subdirs but not the gas subdir, we shouldn't
2392   # pretend that all is well.)
2393   if test -n "$appdirs" ; then
2394     for dir in $appdirs ; do
2395       if test -r $dir/Makefile.in ; then
2396         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2397           appdirs=""
2398           break
2399         fi
2400         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2401           appdirs=""
2402           break
2403         fi
2404       fi
2405     done
2406     if test -n "$appdirs" ; then
2407       echo "*** This configuration is not supported by this package." 1>&2
2408       exit 1
2409     fi
2410   fi
2411   # Okay, some application will build, or we don't care to check.  Still
2412   # notify of subdirs not getting built.
2413   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2414   echo "    ${notsupp}" 1>&2
2415   echo "    (Any other directories should still work fine.)" 1>&2
2416 fi
2417
2418 case "$host" in
2419   *msdosdjgpp*)
2420     enable_gdbtk=no ;;
2421 esac
2422
2423 # To find our prefix, in gcc_cv_tool_prefix.
2424 ACX_TOOL_DIRS
2425
2426 copy_dirs=
2427
2428 AC_ARG_WITH([build-sysroot],
2429   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2430                   [use sysroot as the system root during the build])],
2431   [if test x"$withval" != x ; then
2432      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2433    fi],
2434   [SYSROOT_CFLAGS_FOR_TARGET=])
2435 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2436
2437 AC_ARG_WITH([debug-prefix-map],
2438   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2439                   [map A to B, C to D ... in debug information])],
2440   [if test x"$withval" != x; then
2441      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2442      for debug_map in $withval; do
2443        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2444      done
2445    fi],
2446   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2447 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2448
2449 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2450 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2451 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2452 # We want to ensure that TARGET libraries (which we know are built with
2453 # gcc) are built with "-O2 -g", so include those options when setting
2454 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2455 if test "x$CFLAGS_FOR_TARGET" = x; then
2456   if test "x${is_cross_compiler}" = xyes; then
2457     CFLAGS_FOR_TARGET="-g -O2"
2458   else
2459     CFLAGS_FOR_TARGET=$CFLAGS
2460     case " $CFLAGS " in
2461       *" -O2 "*) ;;
2462       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2463     esac
2464     case " $CFLAGS " in
2465       *" -g "* | *" -g3 "*) ;;
2466       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2467     esac
2468   fi
2469 fi
2470 AC_SUBST(CFLAGS_FOR_TARGET)
2471
2472 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2473   if test "x${is_cross_compiler}" = xyes; then
2474     CXXFLAGS_FOR_TARGET="-g -O2"
2475   else
2476     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2477     case " $CXXFLAGS " in
2478       *" -O2 "*) ;;
2479       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2480     esac
2481     case " $CXXFLAGS " in
2482       *" -g "* | *" -g3 "*) ;;
2483       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2484     esac
2485   fi
2486 fi
2487 AC_SUBST(CXXFLAGS_FOR_TARGET)
2488
2489 AC_SUBST(LDFLAGS_FOR_TARGET)
2490
2491 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2492 # the named directory are copied to $(tooldir)/sys-include.
2493 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2494   if test x${is_cross_compiler} = xno ; then
2495     echo 1>&2 '***' --with-headers is only supported when cross compiling
2496     exit 1
2497   fi
2498   if test x"${with_headers}" != xyes ; then
2499     x=${gcc_cv_tool_prefix}
2500     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2501   fi
2502 fi
2503
2504 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2505 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2506 # are permitted.
2507 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2508   if test x${is_cross_compiler} = xno ; then
2509     echo 1>&2 '***' --with-libs is only supported when cross compiling
2510     exit 1
2511   fi
2512   if test x"${with_libs}" != xyes ; then
2513     # Copy the libraries in reverse order, so that files in the first named
2514     # library override files in subsequent libraries.
2515     x=${gcc_cv_tool_prefix}
2516     for l in ${with_libs}; do
2517       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2518     done
2519   fi
2520 fi
2521
2522 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2523 #
2524 # This is done by determining whether or not the appropriate directory
2525 # is available, and by checking whether or not specific configurations
2526 # have requested that this magic not happen.
2527 #
2528 # The command line options always override the explicit settings in
2529 # configure.ac, and the settings in configure.ac override this magic.
2530 #
2531 # If the default for a toolchain is to use GNU as and ld, and you don't
2532 # want to do that, then you should use the --without-gnu-as and
2533 # --without-gnu-ld options for the configure script.  Similarly, if
2534 # the default is to use the included zlib and you don't want to do that,
2535 # you should use the --with-system-zlib option for the configure script.
2536
2537 if test x${use_gnu_as} = x &&
2538    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2539   with_gnu_as=yes
2540   extra_host_args="$extra_host_args --with-gnu-as"
2541 fi
2542
2543 if test x${use_gnu_ld} = x &&
2544    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2545   with_gnu_ld=yes
2546   extra_host_args="$extra_host_args --with-gnu-ld"
2547 fi
2548
2549 if test x${use_included_zlib} = x &&
2550    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2551   :
2552 else
2553   with_system_zlib=yes
2554   extra_host_args="$extra_host_args --with-system-zlib"
2555 fi
2556
2557 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2558 # can detect this case.
2559
2560 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2561   with_newlib=yes
2562   extra_host_args="$extra_host_args --with-newlib"
2563 fi
2564
2565 # Handle ${copy_dirs}
2566 set fnord ${copy_dirs}
2567 shift
2568 while test $# != 0 ; do
2569   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2570     :
2571   else
2572     echo Copying $1 to $2
2573
2574     # Use the install script to create the directory and all required
2575     # parent directories.
2576     if test -d $2 ; then
2577       :
2578     else
2579       echo >config.temp
2580       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2581     fi
2582
2583     # Copy the directory, assuming we have tar.
2584     # FIXME: Should we use B in the second tar?  Not all systems support it.
2585     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2586
2587     # It is the responsibility of the user to correctly adjust all
2588     # symlinks.  If somebody can figure out how to handle them correctly
2589     # here, feel free to add the code.
2590
2591     echo $1 > $2/COPIED
2592   fi
2593   shift; shift
2594 done
2595
2596 # Determine a target-dependent exec_prefix that the installed
2597 # gcc will search in.  Keep this list sorted by triplet, with
2598 # the *-*-osname triplets last.
2599 md_exec_prefix=
2600 case "${target}" in
2601   i[[34567]]86-pc-msdosdjgpp*)
2602     md_exec_prefix=/dev/env/DJDIR/bin
2603     ;;
2604   *-*-hpux* | \
2605   *-*-nto-qnx* | \
2606   *-*-solaris2*)
2607     md_exec_prefix=/usr/ccs/bin
2608     ;;
2609 esac
2610
2611 extra_arflags_for_target=
2612 extra_nmflags_for_target=
2613 extra_ranlibflags_for_target=
2614 target_makefile_frag=/dev/null
2615 case "${target}" in
2616   spu-*-*)
2617     target_makefile_frag="config/mt-spu"
2618     ;;
2619   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2620     target_makefile_frag="config/mt-sde"
2621     ;;
2622   mipsisa*-*-elfoabi*)
2623     target_makefile_frag="config/mt-mips-elfoabi"
2624     ;;
2625   mips*-*-*linux* | mips*-*-gnu*)
2626     target_makefile_frag="config/mt-mips-gnu"
2627     ;;
2628   nios2-*-elf*)
2629     target_makefile_frag="config/mt-nios2-elf"
2630     ;;
2631   *-*-linux-android*)
2632     target_makefile_frag="config/mt-android"
2633     ;;
2634   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2635     target_makefile_frag="config/mt-gnu"
2636     ;;
2637   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2638     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2639     # commands to handle both 32-bit and 64-bit objects.  These flags are
2640     # harmless if we're using GNU nm or ar.
2641     extra_arflags_for_target=" -X32_64"
2642     extra_nmflags_for_target=" -B -X32_64"
2643     ;;
2644 esac
2645
2646 alphaieee_frag=/dev/null
2647 case $target in
2648   alpha*-*-*)
2649     # This just makes sure to use the -mieee option to build target libs.
2650     # This should probably be set individually by each library.
2651     alphaieee_frag="config/mt-alphaieee"
2652     ;;
2653 esac
2654
2655 # If --enable-target-optspace always use -Os instead of -O2 to build
2656 # the target libraries, similarly if it is not specified, use -Os
2657 # on selected platforms.
2658 ospace_frag=/dev/null
2659 case "${enable_target_optspace}:${target}" in
2660   yes:*)
2661     ospace_frag="config/mt-ospace"
2662     ;;
2663   :d30v-*)
2664     ospace_frag="config/mt-d30v"
2665     ;;
2666   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2667     ospace_frag="config/mt-ospace"
2668     ;;
2669   no:* | :*)
2670     ;;
2671   *)
2672     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2673     ;;
2674 esac
2675
2676 # Some systems (e.g., one of the i386-aix systems the gas testers are
2677 # using) don't handle "\$" correctly, so don't use it here.
2678 tooldir='${exec_prefix}'/${target_noncanonical}
2679 build_tooldir=${tooldir}
2680
2681 # Create a .gdbinit file which runs the one in srcdir
2682 # and tells GDB to look there for source files.
2683
2684 if test -r ${srcdir}/.gdbinit ; then
2685   case ${srcdir} in
2686     .) ;;
2687     *) cat > ./.gdbinit <<EOF
2688 # ${NO_EDIT}
2689 dir ${srcdir}
2690 dir .
2691 source ${srcdir}/.gdbinit
2692 EOF
2693     ;;
2694   esac
2695 fi
2696
2697 # Make sure that the compiler is able to generate an executable.  If it
2698 # can't, we are probably in trouble.  We don't care whether we can run the
2699 # executable--we might be using a cross compiler--we only care whether it
2700 # can be created.  At this point the main configure script has set CC.
2701 we_are_ok=no
2702 echo "int main () { return 0; }" > conftest.c
2703 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2704 if test $? = 0 ; then
2705   if test -s conftest || test -s conftest.exe ; then
2706     we_are_ok=yes
2707   fi
2708 fi
2709 case $we_are_ok in
2710   no)
2711     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2712     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2713     rm -f conftest*
2714     exit 1
2715     ;;
2716 esac
2717 rm -f conftest*
2718
2719 # Decide which environment variable is used to find dynamic libraries.
2720 case "${host}" in
2721   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2722   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2723   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2724   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2725 esac
2726
2727 # On systems where the dynamic library environment variable is PATH,
2728 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2729 # built executables to PATH.
2730 if test "$RPATH_ENVVAR" = PATH; then
2731   GCC_SHLIB_SUBDIR=/shlib
2732 else
2733   GCC_SHLIB_SUBDIR=
2734 fi
2735
2736 # Adjust the toplevel makefile according to whether bootstrap was selected.
2737 case $enable_bootstrap in
2738   yes)
2739     bootstrap_suffix=bootstrap
2740     BUILD_CONFIG=bootstrap-debug
2741     ;;
2742   no)
2743     bootstrap_suffix=no-bootstrap
2744     BUILD_CONFIG=
2745     ;;
2746 esac
2747
2748 AC_MSG_CHECKING(for default BUILD_CONFIG)
2749
2750 AC_ARG_WITH([build-config],
2751   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2752                   [use config/NAME.mk build configuration])],
2753   [case $with_build_config in
2754    yes) with_build_config= ;;
2755    no) with_build_config= BUILD_CONFIG= ;;
2756    esac])
2757
2758 if test "x${with_build_config}" != x; then
2759   BUILD_CONFIG=$with_build_config
2760 else
2761   case $BUILD_CONFIG in
2762   bootstrap-debug)
2763     if echo "int f (void) { return 0; }" > conftest.c &&
2764        ${CC} -c conftest.c &&
2765        mv conftest.o conftest.o.g0 &&
2766        ${CC} -c -g conftest.c &&
2767        mv conftest.o conftest.o.g &&
2768        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2769       :
2770     else
2771       BUILD_CONFIG=
2772     fi
2773     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2774     ;;
2775   esac
2776 fi
2777 AC_MSG_RESULT($BUILD_CONFIG)
2778 AC_SUBST(BUILD_CONFIG)
2779
2780 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2781 AC_MSG_CHECKING([for --enable-vtable-verify])
2782 AC_ARG_ENABLE(vtable-verify,
2783 [AS_HELP_STRING([--enable-vtable-verify],
2784                 [Enable vtable verification feature])],
2785 [case "$enableval" in
2786  yes) enable_vtable_verify=yes ;;
2787  no)  enable_vtable_verify=no ;;
2788  *)   enable_vtable_verify=no;;
2789  esac],
2790 [enable_vtable_verify=no])
2791 AC_MSG_RESULT($enable_vtable_verify)
2792
2793 # Record target_configdirs and the configure arguments for target and
2794 # build configuration in Makefile.
2795 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2796 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2797 bootstrap_fixincludes=no
2798
2799 # If we are building libgomp, bootstrap it.
2800 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2801   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2802 fi
2803
2804 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2805 # or bootstrap-ubsan, bootstrap it.
2806 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2807   case "$BUILD_CONFIG" in
2808     *bootstrap-asan* | *bootstrap-ubsan* )
2809       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2810       bootstrap_fixincludes=yes
2811       ;;
2812   esac
2813 fi
2814
2815 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2816 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2817    test "$enable_vtable_verify" != no; then
2818   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2819 fi
2820
2821 # Determine whether gdb needs tk/tcl or not.
2822 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2823 # and in that case we want gdb to be built without tk.  Ugh!
2824 # In fact I believe gdb is the *only* package directly dependent on tk,
2825 # so we should be able to put the 'maybe's in unconditionally and
2826 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2827 # 100% sure that that's safe though.
2828
2829 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2830 case "$enable_gdbtk" in
2831   no)
2832     GDB_TK="" ;;
2833   yes)
2834     GDB_TK="${gdb_tk}" ;;
2835   *)
2836     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2837     # distro.  Eventually someone will fix this and move Insight, nee
2838     # gdbtk to a separate directory.
2839     if test -d ${srcdir}/gdb/gdbtk ; then
2840       GDB_TK="${gdb_tk}"
2841     else
2842       GDB_TK=""
2843     fi
2844     ;;
2845 esac
2846 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2847 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2848
2849 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2850 # else does, only include them if one of these is built.  The Makefile
2851 # provides the ordering, so it's enough here to add to the list.
2852 case " ${configdirs} " in
2853   *\ gdb\ *)
2854     configdirs="${configdirs} gnulib gdbsupport"
2855     ;;
2856   *\ gdbserver\ *)
2857     configdirs="${configdirs} gnulib gdbsupport"
2858     ;;
2859 esac
2860
2861 # Strip out unwanted targets.
2862
2863 # While at that, we remove Makefiles if we were started for recursive
2864 # configuration, so that the top-level Makefile reconfigures them,
2865 # like we used to do when configure itself was recursive.
2866
2867 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2868 # but now we're fixing up the Makefile ourselves with the additional
2869 # commands passed to AC_CONFIG_FILES.  Use separate variables
2870 # extrasub-{build,host,target} not because there is any reason to split
2871 # the substitutions up that way, but only to remain below the limit of
2872 # 99 commands in a script, for HP-UX sed.
2873
2874 # Do not nest @if/@endif or @unless/@endunless pairs, because
2875 # configure will not warn you at all.
2876
2877 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2878   yes:yes:*\ gold\ *:*,c++,*) ;;
2879   yes:yes:*\ gold\ *:*)
2880     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2881     ;;
2882 esac
2883
2884 extrasub_build=
2885 for module in ${build_configdirs} ; do
2886   if test -z "${no_recursion}" \
2887      && test -f ${build_subdir}/${module}/Makefile; then
2888     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2889     rm -f ${build_subdir}/${module}/Makefile
2890   fi
2891   extrasub_build="$extrasub_build
2892 /^@if build-$module\$/d
2893 /^@endif build-$module\$/d
2894 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2895 /^@if build-$module-$bootstrap_suffix\$/d
2896 /^@endif build-$module-$bootstrap_suffix\$/d
2897 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2898 done
2899 extrasub_host=
2900 for module in ${configdirs} ; do
2901   if test -z "${no_recursion}"; then
2902     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2903       if test -f ${file}; then
2904         echo 1>&2 "*** removing ${file} to force reconfigure"
2905         rm -f ${file}
2906       fi
2907     done
2908   fi
2909   case ${module},${bootstrap_fixincludes} in
2910     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2911     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2912   esac
2913   extrasub_host="$extrasub_host
2914 /^@if $module\$/d
2915 /^@endif $module\$/d
2916 /^@unless $module\$/,/^@endunless $module\$/d
2917 /^@if $module-$host_bootstrap_suffix\$/d
2918 /^@endif $module-$host_bootstrap_suffix\$/d
2919 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2920 done
2921 extrasub_target=
2922 for module in ${target_configdirs} ; do
2923   if test -z "${no_recursion}" \
2924      && test -f ${target_subdir}/${module}/Makefile; then
2925     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2926     rm -f ${target_subdir}/${module}/Makefile
2927   fi
2928
2929   # We only bootstrap target libraries listed in bootstrap_target_libs.
2930   case $bootstrap_target_libs in
2931     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2932     *) target_bootstrap_suffix=no-bootstrap ;;
2933   esac
2934
2935   extrasub_target="$extrasub_target
2936 /^@if target-$module\$/d
2937 /^@endif target-$module\$/d
2938 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2939 /^@if target-$module-$target_bootstrap_suffix\$/d
2940 /^@endif target-$module-$target_bootstrap_suffix\$/d
2941 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2942 done
2943
2944 # Do the final fixup along with target modules.
2945 extrasub_target="$extrasub_target
2946 /^@if /,/^@endif /d
2947 /^@unless /d
2948 /^@endunless /d"
2949
2950 # Create the serialization dependencies.  This uses a temporary file.
2951
2952 AC_ARG_ENABLE([serial-configure],
2953 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2954                 [force sequential configuration of
2955                  sub-packages for the host, target or build
2956                  machine, or all sub-packages])])
2957
2958 case ${enable_serial_configure} in
2959   yes)
2960     enable_serial_build_configure=yes
2961     enable_serial_host_configure=yes
2962     enable_serial_target_configure=yes
2963     ;;
2964 esac
2965
2966 # These force 'configure's to be done one at a time, to avoid problems
2967 # with contention over a shared config.cache.
2968 rm -f serdep.tmp
2969 echo '# serdep.tmp' > serdep.tmp
2970 olditem=
2971 test "x${enable_serial_build_configure}" = xyes &&
2972 for item in ${build_configdirs} ; do
2973   case ${olditem} in
2974     "") ;;
2975     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2976   esac
2977   olditem=${item}
2978 done
2979 olditem=
2980 test "x${enable_serial_host_configure}" = xyes &&
2981 for item in ${configdirs} ; do
2982   case ${olditem} in
2983     "") ;;
2984     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2985   esac
2986   olditem=${item}
2987 done
2988 olditem=
2989 test "x${enable_serial_target_configure}" = xyes &&
2990 for item in ${target_configdirs} ; do
2991   case ${olditem} in
2992     "") ;;
2993     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2994   esac
2995   olditem=${item}
2996 done
2997 serialization_dependencies=serdep.tmp
2998 AC_SUBST_FILE(serialization_dependencies)
2999
3000 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3001 # target, nonopt, and variable assignments.  These are the ones we
3002 # might not want to pass down to subconfigures.  The exception being
3003 # --cache-file=/dev/null, which is used to turn off the use of cache
3004 # files altogether, and which should be passed on to subconfigures.
3005 # Also strip program-prefix, program-suffix, and program-transform-name,
3006 # so that we can pass down a consistent program-transform-name.
3007 baseargs=
3008 tbaseargs=
3009 keep_next=no
3010 skip_next=no
3011 eval "set -- $ac_configure_args"
3012 for ac_arg
3013 do
3014   if test X"$skip_next" = X"yes"; then
3015     skip_next=no
3016     continue
3017   fi
3018   if test X"$keep_next" = X"yes"; then
3019     case $ac_arg in
3020       *\'*)
3021         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3022     esac
3023     baseargs="$baseargs '$ac_arg'"
3024     tbaseargs="$tbaseargs '$ac_arg'"
3025     keep_next=no
3026     continue
3027   fi
3028
3029   # Handle separated arguments.  Based on the logic generated by
3030   # autoconf 2.59.
3031   case $ac_arg in
3032     *=* | --config-cache | -C | -disable-* | --disable-* \
3033       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3034       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3035       | -with-* | --with-* | -without-* | --without-* | --x)
3036       separate_arg=no
3037       ;;
3038     -*)
3039       separate_arg=yes
3040       ;;
3041     *)
3042       separate_arg=no
3043       ;;
3044   esac
3045
3046   skip_targ=no
3047   case $ac_arg in
3048 changequote(,)
3049   --with-* | --without-*)
3050     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3051
3052     case $libopt in
3053     *[-_]include)
3054       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3055       ;;
3056     *[-_]lib)
3057       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3058       ;;
3059     *)
3060       lib=$libopt
3061       ;;
3062     esac
3063 changequote([,])
3064
3065     case $lib in
3066     mpc | mpfr | gmp | isl)
3067       # If we're processing --with-$lib, --with-$lib-include or
3068       # --with-$lib-lib, for one of the libs above, and target is
3069       # different from host, don't pass the current argument to any
3070       # target library's configure.
3071       if test x$is_cross_compiler = xyes; then
3072         skip_targ=yes
3073       fi
3074       ;;
3075     esac
3076     ;;
3077   esac
3078
3079   case "$ac_arg" in
3080     --cache-file=/dev/null | \
3081     -cache-file=/dev/null )
3082       # Handled here to avoid the test to skip args below.
3083       baseargs="$baseargs '$ac_arg'"
3084       tbaseargs="$tbaseargs '$ac_arg'"
3085       # Assert: $separate_arg should always be no.
3086       keep_next=$separate_arg
3087       ;;
3088     --no*)
3089       continue
3090       ;;
3091     --c* | \
3092     --sr* | \
3093     --ho* | \
3094     --bu* | \
3095     --t* | \
3096     --program-* | \
3097     -cache_file* | \
3098     -srcdir* | \
3099     -host* | \
3100     -build* | \
3101     -target* | \
3102     -program-prefix* | \
3103     -program-suffix* | \
3104     -program-transform-name* )
3105       skip_next=$separate_arg
3106       continue
3107       ;;
3108     -*)
3109       # An option.  Add it.
3110       case $ac_arg in
3111         *\'*)
3112           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3113       esac
3114       baseargs="$baseargs '$ac_arg'"
3115       if test X"$skip_targ" = Xno; then
3116         tbaseargs="$tbaseargs '$ac_arg'"
3117       fi
3118       keep_next=$separate_arg
3119       ;;
3120     *)
3121       # Either a variable assignment, or a nonopt (triplet).  Don't
3122       # pass it down; let the Makefile handle this.
3123       continue
3124       ;;
3125   esac
3126 done
3127 # Remove the initial space we just introduced and, as these will be
3128 # expanded by make, quote '$'.
3129 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3130
3131 # Add in --program-transform-name, after --program-prefix and
3132 # --program-suffix have been applied to it.  Autoconf has already
3133 # doubled dollar signs and backslashes in program_transform_name; we want
3134 # the backslashes un-doubled, and then the entire thing wrapped in single
3135 # quotes, because this will be expanded first by make and then by the shell.
3136 # Also, because we want to override the logic in subdir configure scripts to
3137 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3138 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3139 ${program_transform_name}
3140 EOF_SED
3141 gcc_transform_name=`cat conftestsed.out`
3142 rm -f conftestsed.out
3143 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3144 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3145 if test "$silent" = yes; then
3146   baseargs="$baseargs --silent"
3147   tbaseargs="$tbaseargs --silent"
3148 fi
3149 baseargs="$baseargs --disable-option-checking"
3150 tbaseargs="$tbaseargs --disable-option-checking"
3151
3152 # Record and document user additions to sub configure arguments.
3153 AC_ARG_VAR([build_configargs],
3154            [additional configure arguments for build directories])
3155 AC_ARG_VAR([host_configargs],
3156            [additional configure arguments for host directories])
3157 AC_ARG_VAR([target_configargs],
3158            [additional configure arguments for target directories])
3159
3160 # For the build-side libraries, we just need to pretend we're native,
3161 # and not use the same cache file.  Multilibs are neither needed nor
3162 # desired.  We can't even use the same cache file for all build-side
3163 # libraries, as they're compiled differently; some with C, some with
3164 # C++ or with different feature-enabling options.
3165 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3166
3167 # For host modules, accept cache file option, or specification as blank.
3168 case "${cache_file}" in
3169 "") # empty
3170   cache_file_option="" ;;
3171 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3172   cache_file_option="--cache-file=${cache_file}" ;;
3173 *) # relative path
3174   cache_file_option="--cache-file=../${cache_file}" ;;
3175 esac
3176
3177 # Host dirs don't like to share a cache file either, horribly enough.
3178 # This seems to be due to autoconf 2.5x stupidity.
3179 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3180
3181 target_configargs="$target_configargs ${tbaseargs}"
3182
3183 # Passing a --with-cross-host argument lets the target libraries know
3184 # whether they are being built with a cross-compiler or being built
3185 # native.  However, it would be better to use other mechanisms to make the
3186 # sorts of decisions they want to make on this basis.  Please consider
3187 # this option to be deprecated.  FIXME.
3188 if test x${is_cross_compiler} = xyes ; then
3189   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3190 fi
3191
3192 # Special user-friendly check for native x86_64-linux build, if
3193 # multilib is not explicitly enabled.
3194 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3195   x86_64-*linux*:yes:$build:$build:)
3196     # Make sure we have a development environment that handles 32-bit
3197     dev64=no
3198     echo "int main () { return 0; }" > conftest.c
3199     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3200     if test $? = 0 ; then
3201       if test -s conftest || test -s conftest.exe ; then
3202         dev64=yes
3203       fi
3204     fi
3205     rm -f conftest*
3206     if test x${dev64} != xyes ; then
3207       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3208     fi
3209     ;;
3210 esac
3211
3212 # Default to --enable-multilib.
3213 if test x${enable_multilib} = x ; then
3214   target_configargs="--enable-multilib ${target_configargs}"
3215 fi
3216
3217 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3218 # changed from the earlier setting of with_newlib.
3219 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3220   target_configargs="--with-newlib ${target_configargs}"
3221 fi
3222
3223 # Different target subdirs use different values of certain variables
3224 # (notably CXX).  Worse, multilibs use *lots* of different values.
3225 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3226 # it doesn't automatically accept command-line overrides of them.
3227 # This means it's not safe for target subdirs to share a cache file,
3228 # which is disgusting, but there you have it.  Hopefully this can be
3229 # fixed in future.  It's still worthwhile to use a cache file for each
3230 # directory.  I think.
3231
3232 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3233 # We need to pass --target, as newer autoconf's requires consistency
3234 # for target_alias and gcc doesn't manage it consistently.
3235 target_configargs="--cache-file=./config.cache ${target_configargs}"
3236
3237 FLAGS_FOR_TARGET=
3238 case " $target_configdirs " in
3239  *" newlib "*)
3240   case " $target_configargs " in
3241   *" --with-newlib "*)
3242    case "$target" in
3243     *-cygwin*)
3244       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3245       ;;
3246    esac
3247
3248    # If we're not building GCC, don't discard standard headers.
3249    if test -d ${srcdir}/gcc; then
3250      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3251
3252      if test "${build}" != "${host}"; then
3253        # On Canadian crosses, CC_FOR_TARGET will have already been set
3254        # by `configure', so we won't have an opportunity to add -Bgcc/
3255        # to it.  This is right: we don't want to search that directory
3256        # for binaries, but we want the header files in there, so add
3257        # them explicitly.
3258        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3259
3260        # Someone might think of using the pre-installed headers on
3261        # Canadian crosses, in case the installed compiler is not fully
3262        # compatible with the compiler being built.  In this case, it
3263        # would be better to flag an error than risking having
3264        # incompatible object files being constructed.  We can't
3265        # guarantee that an error will be flagged, but let's hope the
3266        # compiler will do it, when presented with incompatible header
3267        # files.
3268      fi
3269    fi
3270
3271    case "${target}-${is_cross_compiler}" in
3272    i[[3456789]]86-*-linux*-no)
3273       # Here host == target, so we don't need to build gcc,
3274       # so we don't want to discard standard headers.
3275       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3276       ;;
3277    *)
3278       # If we're building newlib, use its generic headers last, but search
3279       # for any libc-related directories first (so make it the last -B
3280       # switch).
3281       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3282
3283       # If we're building libgloss, find the startup file, simulator library
3284       # and linker script.
3285       case " $target_configdirs " in
3286         *" libgloss "*)
3287         # Look for startup file, simulator library and maybe linker script.
3288         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3289         # Look for libnosys.a in case the target needs it.
3290         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3291         # Most targets have the linker script in the source directory.
3292         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3293         ;;
3294       esac
3295       ;;
3296    esac
3297    ;;
3298   esac
3299   ;;
3300 esac
3301
3302 case "$target" in
3303   x86_64-*mingw* | *-w64-mingw*)
3304   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3305   # however, use a symlink named 'mingw' in ${prefix} .
3306     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3307     ;;
3308   *-mingw*)
3309   # MinGW can't be handled as Cygwin above since it does not use newlib.
3310     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3311     ;;
3312 esac
3313
3314 # Allow the user to override the flags for
3315 # our build compiler if desired.
3316 if test x"${build}" = x"${host}" ; then
3317   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3318   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3319   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3320 fi
3321
3322 # On Canadian crosses, we'll be searching the right directories for
3323 # the previously-installed cross compiler, so don't bother to add
3324 # flags for directories within the install tree of the compiler
3325 # being built; programs in there won't even run.
3326 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3327   # Search for pre-installed headers if nothing else fits.
3328   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3329 fi
3330
3331 if test "x${use_gnu_ld}" = x &&
3332    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3333   # Arrange for us to find uninstalled linker scripts.
3334   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3335 fi
3336
3337 # Search for other target-specific linker scripts and such.
3338 case "${target}" in
3339   mep*)
3340     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3341     ;;
3342 esac
3343
3344 # Makefile fragments.
3345 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3346 do
3347   eval fragval=\$$frag
3348   if test $fragval != /dev/null; then
3349     eval $frag=${srcdir}/$fragval
3350   fi
3351 done
3352 AC_SUBST_FILE(host_makefile_frag)
3353 AC_SUBST_FILE(target_makefile_frag)
3354 AC_SUBST_FILE(alphaieee_frag)
3355 AC_SUBST_FILE(ospace_frag)
3356
3357 # Miscellanea: directories, flags, etc.
3358 AC_SUBST(RPATH_ENVVAR)
3359 AC_SUBST(GCC_SHLIB_SUBDIR)
3360 AC_SUBST(tooldir)
3361 AC_SUBST(build_tooldir)
3362 AC_SUBST(CONFIGURE_GDB_TK)
3363 AC_SUBST(GDB_TK)
3364 AC_SUBST(INSTALL_GDB_TK)
3365
3366 # Build module lists & subconfigure args.
3367 AC_SUBST(build_configargs)
3368 AC_SUBST(build_configdirs)
3369
3370 # Host module lists & subconfigure args.
3371 AC_SUBST(host_configargs)
3372 AC_SUBST(configdirs)
3373 AC_SUBST(target_configdirs)
3374
3375 # Target module lists & subconfigure args.
3376 AC_SUBST(target_configargs)
3377
3378
3379 # Build tools.
3380 AC_SUBST(AR_FOR_BUILD)
3381 AC_SUBST(AS_FOR_BUILD)
3382 AC_SUBST(CC_FOR_BUILD)
3383 AC_SUBST(CFLAGS_FOR_BUILD)
3384 AC_SUBST(CXXFLAGS_FOR_BUILD)
3385 AC_SUBST(CXX_FOR_BUILD)
3386 AC_SUBST(DLLTOOL_FOR_BUILD)
3387 AC_SUBST(GFORTRAN_FOR_BUILD)
3388 AC_SUBST(GOC_FOR_BUILD)
3389 AC_SUBST(GDC_FOR_BUILD)
3390 AC_SUBST(LDFLAGS_FOR_BUILD)
3391 AC_SUBST(LD_FOR_BUILD)
3392 AC_SUBST(NM_FOR_BUILD)
3393 AC_SUBST(RANLIB_FOR_BUILD)
3394 AC_SUBST(WINDMC_FOR_BUILD)
3395 AC_SUBST(WINDRES_FOR_BUILD)
3396
3397 # Generate default definitions for YACC, M4, LEX and other programs that run
3398 # on the build machine.  These are used if the Makefile can't locate these
3399 # programs in objdir.
3400 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3401
3402 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3403 case " $build_configdirs " in
3404   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3405 esac
3406
3407 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3408 case " $build_configdirs " in
3409   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3410 esac
3411
3412 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3413 case " $build_configdirs " in
3414   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3415 esac
3416
3417 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3418 case " $build_configdirs " in
3419   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3420   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3421 esac
3422
3423 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3424 case " $build_configdirs " in
3425   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3426 esac
3427
3428 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3429 case " $build_configdirs " in
3430   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3431   *)
3432 changequote(,)
3433     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3434     # higher, else we use the "missing" dummy.
3435     if ${MAKEINFO} --version \
3436        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3437       :
3438     else
3439       MAKEINFO="$MISSING makeinfo"
3440     fi
3441     ;;
3442 changequote([,])
3443 esac
3444
3445 # FIXME: expect and dejagnu may become build tools?
3446
3447 AC_CHECK_PROGS(EXPECT, expect, expect)
3448 case " $configdirs " in
3449   *" expect "*)
3450     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3451     ;;
3452 esac
3453
3454 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3455 case " $configdirs " in
3456   *" dejagnu "*)
3457     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3458     ;;
3459 esac
3460
3461
3462 # Host tools.
3463 NCN_STRICT_CHECK_TOOLS(AR, ar)
3464 NCN_STRICT_CHECK_TOOLS(AS, as)
3465 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3466 NCN_STRICT_CHECK_TOOLS(LD, ld)
3467 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3468 NCN_STRICT_CHECK_TOOLS(NM, nm)
3469 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3470 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3471 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3472 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3473 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3474 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3475 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3476 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3477 AC_SUBST(CC)
3478 AC_SUBST(CXX)
3479 AC_SUBST(CFLAGS)
3480 AC_SUBST(CXXFLAGS)
3481
3482 # Target tools.
3483 AC_ARG_WITH([build-time-tools],
3484   [AS_HELP_STRING([--with-build-time-tools=PATH],
3485                   [use given path to find target tools during the build])],
3486   [case x"$withval" in
3487      x/*) ;;
3488      *)
3489        with_build_time_tools=
3490        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3491        ;;
3492    esac],
3493   [with_build_time_tools=])
3494
3495 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3496 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3497 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3498 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3499 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3500 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3501
3502 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3503 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3504 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3505 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3506 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3507 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3508 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3509 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3510 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3511 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3512 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3513 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3514 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3515 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3516
3517 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3518
3519 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3520 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3521 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3522 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3523 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3524                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3525                 c++)
3526 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3527                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3528                 c++)
3529 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3530 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3531 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3532                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3533 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3534                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3535 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3536                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3537 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3538 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3539 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3540 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3541 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3542 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3543 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3544 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3545 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3546 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3547 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3548
3549 AC_SUBST(FLAGS_FOR_TARGET)
3550 AC_SUBST(RAW_CXX_FOR_TARGET)
3551
3552 # Certain tools may need extra flags.
3553 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3554 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3555 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3556
3557 # When building target libraries, except in a Canadian cross, we use
3558 # the same toolchain as the compiler we just built.
3559 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3560 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3561 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3562 if test $host = $build; then
3563   case " $configdirs " in
3564     *" gcc "*)
3565       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3566       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3567       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3568       ;;
3569   esac
3570 fi
3571
3572 AC_SUBST(COMPILER_AS_FOR_TARGET)
3573 AC_SUBST(COMPILER_LD_FOR_TARGET)
3574 AC_SUBST(COMPILER_NM_FOR_TARGET)
3575
3576 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3577 AC_ARG_ENABLE(maintainer-mode,
3578 [AS_HELP_STRING([--enable-maintainer-mode],
3579                 [enable make rules and dependencies not useful
3580                  (and sometimes confusing) to the casual installer])],
3581       USE_MAINTAINER_MODE=$enableval,
3582       USE_MAINTAINER_MODE=no)
3583 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3584 AC_SUBST(MAINTAINER_MODE_TRUE)
3585 AC_SUBST(MAINTAINER_MODE_FALSE)
3586 if test "$USE_MAINTAINER_MODE" = yes; then
3587   MAINTAINER_MODE_TRUE=
3588   MAINTAINER_MODE_FALSE='#'
3589 else
3590   MAINTAINER_MODE_TRUE='#'
3591   MAINTAINER_MODE_FALSE=
3592 fi
3593 MAINT=$MAINTAINER_MODE_TRUE
3594 AC_SUBST(MAINT)dnl
3595
3596 # ---------------------
3597 # GCC bootstrap support
3598 # ---------------------
3599
3600 # Stage specific cflags for build.
3601 stage1_cflags="-g"
3602 case $build in
3603   vax-*-*)
3604     case ${GCC} in
3605       yes) stage1_cflags="-g -Wa,-J" ;;
3606       *) stage1_cflags="-g -J" ;;
3607     esac ;;
3608 esac
3609
3610 AC_SUBST(stage1_cflags)
3611
3612 # Enable --enable-checking in stage1 of the compiler.
3613 AC_ARG_ENABLE(stage1-checking,
3614 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3615                 [choose additional checking for stage1 of the compiler])],
3616 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3617 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3618   # For --disable-checking or implicit --enable-checking=release, avoid
3619   # setting --enable-checking=gc in the default stage1 checking for LTO
3620   # bootstraps.  See PR62077.
3621   case $BUILD_CONFIG in
3622     *lto*)
3623       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3624     *)
3625       stage1_checking=--enable-checking=yes,types;;
3626   esac
3627   if test "x$enable_checking" = x && \
3628      test -d ${srcdir}/gcc && \
3629      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3630     stage1_checking=--enable-checking=yes,types,extra
3631   fi
3632 else
3633   stage1_checking=--enable-checking=$enable_checking,types
3634 fi])
3635 AC_SUBST(stage1_checking)
3636
3637 # Enable -Werror in bootstrap stage2 and later.
3638 AC_ARG_ENABLE(werror,
3639 [AS_HELP_STRING([--enable-werror],
3640                 [enable -Werror in bootstrap stage2 and later])],
3641 [
3642 case ${enable_werror} in
3643   yes) stage2_werror_flag="--enable-werror-always" ;;
3644   *) stage2_werror_flag="" ;;
3645 esac
3646 ],
3647 [
3648 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3649   case $BUILD_CONFIG in
3650   bootstrap-debug)
3651       stage2_werror_flag="--enable-werror-always" ;;
3652   "")
3653       stage2_werror_flag="--enable-werror-always" ;;
3654   esac
3655 fi
3656 ])
3657
3658 AC_SUBST(stage2_werror_flag)
3659
3660 # Specify what files to not compare during bootstrap.
3661
3662 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3663 case "$target" in
3664   hppa*64*-*-hpux*) ;;
3665   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3666   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3667 esac
3668 AC_SUBST(compare_exclusions)
3669
3670 AC_CONFIG_FILES([Makefile],
3671   [sed "$extrasub_build" Makefile |
3672    sed "$extrasub_host" |
3673    sed "$extrasub_target" > mf$$
3674    mv -f mf$$ Makefile],
3675   [extrasub_build="$extrasub_build"
3676    extrasub_host="$extrasub_host"
3677    extrasub_target="$extrasub_target"])
3678 AC_OUTPUT