configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([kmod],
   3         [20],
   4         [linux-modules@vger.kernel.org],
   5         [kmod],
   6         [http://git.kernel.org/?p=utils/kernel/kmod/kmod.git])
   7
   8 AC_CONFIG_SRCDIR([libkmod/libkmod.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AC_CONFIG_HEADERS(config.h)
  11 AC_CONFIG_AUX_DIR([build-aux])
  12
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AC_SYS_LARGEFILE
  15 AC_PREFIX_DEFAULT([/usr])
  16 AM_MAINTAINER_MODE([enable])
  17 AM_INIT_AUTOMAKE([check-news foreign 1.11 silent-rules tar-pax no-dist-gzip dist-xz subdir-objects color-tests parallel-tests])
  18 AM_SILENT_RULES([yes])
  19 LT_INIT([disable-static pic-only])
  20 DOLT
  21
  22 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by kmod])])
  23 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by kmod])])
  24
  25 #####################################################################
  26 # Program checks and configurations
  27 #####################################################################
  28
  29 AC_PROG_SED
  30 AC_PROG_MKDIR_P
  31 AC_PROG_LN_S
  32 PKG_PROG_PKG_CONFIG
  33 AC_PATH_PROG([XSLTPROC], [xsltproc])
  34
  35 AC_PROG_CC_C99
  36
  37 #####################################################################
  38 # Function and structure checks
  39 #####################################################################
  40
  41 AC_CHECK_FUNCS_ONCE(__xstat)
  42 AC_CHECK_FUNCS_ONCE([__secure_getenv secure_getenv])
  43 AC_CHECK_FUNCS_ONCE([finit_module])
  44
  45 CC_CHECK_FUNC_BUILTIN([__builtin_clz])
  46 CC_CHECK_FUNC_BUILTIN([__builtin_types_compatible_p])
  47 CC_CHECK_FUNC_BUILTIN([__builtin_uaddl_overflow], [ ], [ ])
  48 CC_CHECK_FUNC_BUILTIN([__builtin_uaddll_overflow], [ ], [ ])
  49
  50 # dietlibc doesn't have st.st_mtim struct member
  51 AC_CHECK_MEMBERS([struct stat.st_mtim], [], [], [#include <sys/stat.h>])
  52
  53 # musl 1.0 and bionic 4.4 don't have strndupa
  54 AC_CHECK_DECLS_ONCE([strndupa])
  55
  56 # RHEL 5 and older do not have be32toh
  57 AC_CHECK_DECLS_ONCE([be32toh])
  58
  59 # Check kernel headers
  60 AC_CHECK_HEADERS_ONCE([linux/module.h])
  61
  62 AC_MSG_CHECKING([whether _Static_assert() is supported])
  63 AC_COMPILE_IFELSE(
  64         [AC_LANG_SOURCE([[_Static_assert(1, "Test");]])],
  65         [AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define if _Static_assert() is available])
  66          AC_MSG_RESULT([yes])],
  67         [AC_MSG_RESULT([no])])
  68
  69 AC_MSG_CHECKING([whether _Noreturn is supported])
  70 AC_COMPILE_IFELSE(
  71         [AC_LANG_SOURCE([[_Noreturn int foo(void) { exit(0); }]])],
  72         [AC_DEFINE([HAVE_NORETURN], [1], [Define if _Noreturn is available])
  73          AC_MSG_RESULT([yes])],
  74         [AC_MSG_RESULT([no])])
  75
  76
  77 #####################################################################
  78 # --with-
  79 #####################################################################
  80
  81 AC_ARG_WITH([rootlibdir],
  82         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
  83         [], [with_rootlibdir=$libdir])
  84 AC_SUBST([rootlibdir], [$with_rootlibdir])
  85
  86 AC_ARG_WITH([xz],
  87         AS_HELP_STRING([--with-xz], [handle Xz-compressed modules @<:@default=disabled@:>@]),
  88         [], [with_xz=no])
  89 AS_IF([test "x$with_xz" != "xno"], [
  90         PKG_CHECK_MODULES([liblzma], [liblzma >= 4.99])
  91         AC_DEFINE([ENABLE_XZ], [1], [Enable Xz for modules.])
  92 ], [
  93         AC_MSG_NOTICE([Xz support not requested])
  94 ])
  95
  96 AC_ARG_WITH([zlib],
  97         AS_HELP_STRING([--with-zlib], [handle gzipped modules @<:@default=disabled@:>@]),
  98         [], [with_zlib=no])
  99 AS_IF([test "x$with_zlib" != "xno"], [
 100         PKG_CHECK_MODULES([zlib], [zlib])
 101         AC_DEFINE([ENABLE_ZLIB], [1], [Enable zlib for modules.])
 102 ], [
 103         AC_MSG_NOTICE([zlib support not requested])
 104 ])
 105
 106 AC_ARG_WITH([bashcompletiondir],
 107         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 108         [],
 109         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 110                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 111         ] , [
 112                 with_bashcompletiondir=${datadir}/bash-completion/completions
 113         ])])
 114 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 115
 116 #####################################################################
 117 # --enable-
 118 #####################################################################
 119
 120 AC_ARG_ENABLE([experimental],
 121         AS_HELP_STRING([--enable-experimental], [enable experimental tools and features. Do not enable it unless you know what you are doing. @<:@default=disabled@:>@]),
 122         [], enable_experimental=no)
 123 AM_CONDITIONAL([BUILD_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
 124 AS_IF([test "x$enable_experimental" = "xyes"], [
 125         AC_DEFINE(ENABLE_EXPERIMENTAL, [1], [Experimental features.])
 126 ])
 127
 128 AC_ARG_ENABLE([tools],
 129         AS_HELP_STRING([--disable-tools], [disable building tools that provide same functionality as module-init-tools @<:@default=enabled@:>@]),
 130         [], enable_tools=yes)
 131 AM_CONDITIONAL([BUILD_TOOLS], [test "x$enable_tools" = "xyes"])
 132
 133 AC_ARG_ENABLE([manpages],
 134         AS_HELP_STRING([--disable-manpages], [disable manpages @<:@default=enabled@:>@]),
 135         [], enable_manpages=yes)
 136 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" = "xyes"])
 137
 138 AC_ARG_ENABLE([test-modules],
 139         AS_HELP_STRING([--disable-test-modules], [disable building test modules during make check: cached modules will be used @<:@default=enabled@:>@]),
 140         [], enable_test_modules=yes)
 141 AM_CONDITIONAL([BUILD_MODULES], [test "x$enable_test_modules" = "xyes"])
 142
 143 AC_ARG_ENABLE([logging],
 144         AS_HELP_STRING([--disable-logging], [disable system logging @<:@default=enabled@:>@]),
 145         [], enable_logging=yes)
 146 AS_IF([test "x$enable_logging" = "xyes"], [
 147         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
 148 ])
 149
 150 AC_ARG_ENABLE([debug],
 151         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
 152         [], [enable_debug=no])
 153 AS_IF([test "x$enable_debug" = "xyes"], [
 154         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
 155 ])
 156
 157 AC_ARG_ENABLE([python],
 158         AS_HELP_STRING([--enable-python], [enable Python libkmod bindings @<:@default=disabled@:>@]),
 159         [], [enable_python=no])
 160 AS_IF([test "x$enable_python" = "xyes"], [
 161         AM_PATH_PYTHON(,,[:])
 162         AC_PATH_PROG([CYTHON], [cython], [:])
 163
 164         PKG_CHECK_MODULES([PYTHON], [python-${PYTHON_VERSION}],
 165                           [have_python=yes],
 166                           [PKG_CHECK_MODULES([PYTHON], [python],
 167                                              [have_python=yes],
 168                                              [have_python=no])])
 169
 170         AS_IF([test "x$have_python" = xno],
 171               [AC_MSG_ERROR([*** python support requested but libraries not found])])
 172 ])
 173 AM_CONDITIONAL([BUILD_PYTHON], [test "x$enable_python" = "xyes"])
 174
 175 AC_ARG_ENABLE([coverage],
 176         AS_HELP_STRING([--enable-coverage], [enable test coverage @<:@default=disabled@:>@]),
 177         [], [enable_coverage=no])
 178 AS_IF([test "x$enable_coverage" = "xyes"], [
 179         AC_CHECK_PROG(have_coverage, [lcov], [yes], [no])
 180         AS_IF([test "x$have_coverage" = xno],[
 181                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 182         ], [
 183                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 184                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 185                 AS_IF([test "$lcov_version_major" -lt 1 -o "$lcov_version_minor" -lt 10], [
 186                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 187                 ], [
 188                         have_coverage=yes
 189                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 190                         -fprofile-arcs \
 191                         -ftest-coverage])
 192                 ])
 193         ])
 194 ])
 195 AM_CONDITIONAL([ENABLE_COVERAGE], [test "x$enable_coverage" = "xyes"])
 196
 197 m4_ifdef([GTK_DOC_CHECK], [
 198 GTK_DOC_CHECK([1.14],[--flavour no-tmpl-flat])
 199 ], [
 200 AM_CONDITIONAL([ENABLE_GTK_DOC], false)])
 201
 202
 203 #####################################################################
 204 # Default CFLAGS and LDFLAGS
 205 #####################################################################
 206
 207 CC_CHECK_FLAGS_APPEND(with_cflags, [CFLAGS], [\
 208                        -pipe \
 209                        -DANOTHER_BRICK_IN_THE \
 210                        -Wall \
 211                        -W \
 212                        -Wextra \
 213                        -Wno-inline \
 214                        -Wvla \
 215                        -Wundef \
 216                        -Wformat=2 \
 217                        -Wlogical-op \
 218                        -Wsign-compare \
 219                        -Wformat-security \
 220                        -Wmissing-include-dirs \
 221                        -Wformat-nonliteral \
 222                        -Wold-style-definition \
 223                        -Wpointer-arith \
 224                        -Winit-self \
 225                        -Wdeclaration-after-statement \
 226                        -Wfloat-equal \
 227                        -Wmissing-prototypes \
 228                        -Wstrict-prototypes \
 229                        -Wredundant-decls \
 230                        -Wmissing-declarations \
 231                        -Wmissing-noreturn \
 232                        -Wshadow \
 233                        -Wendif-labels \
 234                        -Wstrict-aliasing=3 \
 235                        -Wwrite-strings \
 236                        -Wno-long-long \
 237                        -Wno-overlength-strings \
 238                        -Wno-unused-parameter \
 239                        -Wno-missing-field-initializers \
 240                        -Wno-unused-result \
 241                        -Wnested-externs \
 242                        -Wchar-subscripts \
 243                        -Wtype-limits \
 244                        -Wuninitialized \
 245                        -fno-common \
 246                        -fdiagnostics-show-option \
 247                        -fvisibility=hidden \
 248                        -ffunction-sections \
 249                        -fdata-sections])
 250 AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 251
 252
 253 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [ \
 254                        -Wl,--as-needed \
 255                        -Wl,--no-undefined \
 256                        -Wl,--gc-sections])
 257 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 258
 259 #####################################################################
 260 # Generate files from *.in
 261 #####################################################################
 262
 263 AC_CONFIG_FILES([
 264         Makefile
 265         man/Makefile
 266         libkmod/docs/Makefile
 267         libkmod/docs/version.xml
 268 ])
 269
 270
 271 #####################################################################
 272
 273 AC_OUTPUT
 274 AC_MSG_RESULT([
 275         $PACKAGE $VERSION
 276         =======
 277
 278         prefix:                 ${prefix}
 279         sysconfdir:             ${sysconfdir}
 280         libdir:                 ${libdir}
 281         rootlibdir:             ${rootlibdir}
 282         includedir:             ${includedir}
 283         bindir:                 ${bindir}
 284         Bash completions dir:   ${with_bashcompletiondir}
 285
 286         compiler:               ${CC}
 287         cflags:                 ${with_cflags} ${CFLAGS}
 288         ldflags:                ${with_ldflags} ${LDFLAGS}
 289
 290         experimental features:  ${enable_experimental}
 291         tools:                  ${enable_tools}
 292         python bindings:        ${enable_python}
 293         logging:                ${enable_logging}
 294         compression:            xz=${with_xz}  zlib=${with_zlib}
 295         debug:                  ${enable_debug}
 296         coverage:               ${enable_coverage}
 297         doc:                    ${enable_gtk_doc}
 298         man:                    ${enable_manpages}
 299         test-modules:           ${enable_test_modules}
 300 ])