configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT([kmod],
   3         [3],
   4         [linux-modules@vger.kernel.org],
   5         [kmod],
   6         [http://git.profusion.mobi/cgit.cgi/kmod.git/])
   7
   8 AC_CONFIG_SRCDIR([libkmod/libkmod.c])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AM_INIT_AUTOMAKE([check-news foreign 1.11 silent-rules
  11         tar-pax no-dist-gzip dist-xz subdir-objects])
  12 AC_PROG_CC_STDC
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AC_SYS_LARGEFILE
  15 AC_CONFIG_MACRO_DIR([m4])
  16 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  17 AM_SILENT_RULES([yes])
  18 LT_INIT([disable-static pic-only])
  19 AC_PREFIX_DEFAULT([/usr])
  20
  21 AC_PROG_CC
  22 AC_PROG_CC_C99
  23 AC_C_TYPEOF
  24 AM_PROG_CC_C_O
  25 AC_PROG_GCC_TRADITIONAL
  26 AC_C_BIGENDIAN
  27
  28 AC_PROG_SED
  29 AC_PROG_MKDIR_P
  30 PKG_PROG_PKG_CONFIG
  31
  32 AC_ARG_WITH([rootprefix],
  33         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
  34         [], [with_rootprefix=""])
  35 AC_SUBST([rootprefix], [$with_rootprefix])
  36
  37 AC_ARG_WITH([rootlibdir],
  38         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
  39         [], [with_rootlibdir=$libdir])
  40 AC_SUBST([rootlibdir], [$with_rootlibdir])
  41
  42 AC_ARG_ENABLE([tools],
  43         AS_HELP_STRING([--disable-tools], [disable building tools that provide same functionality as module-init-tools @<:@default=enabled@:>@]),
  44         [], enable_tools=yes)
  45 AM_CONDITIONAL([BUILD_TOOLS], [test "x$enable_tools" = "xyes"])
  46
  47 AC_ARG_ENABLE([logging],
  48         AS_HELP_STRING([--disable-logging], [disable system logging @<:@default=enabled@:>@]),
  49         [], enable_logging=yes)
  50 AS_IF([test "x$enable_logging" = "xyes"], [
  51         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
  52 ])
  53
  54 AC_ARG_WITH([xz],
  55         AS_HELP_STRING([--with-xz], [handle Xz-compressed modules @<:@default=disabled@:>@]),
  56         [], [with_xz=no])
  57 AS_IF([test "x$with_xz" != "xno"], [
  58         PKG_CHECK_MODULES([liblzma], [liblzma >= 4.99])
  59         AC_DEFINE([ENABLE_XZ], [1], [Enable Xz for modules.])
  60 ], [
  61         AC_MSG_NOTICE([Xz support not requested])
  62 ])
  63
  64 AC_ARG_WITH([zlib],
  65         AS_HELP_STRING([--with-zlib], [handle gzipped modules @<:@default=disabled@:>@]),
  66         [], [with_zlib=no])
  67 AS_IF([test "x$with_zlib" != "xno"], [
  68         PKG_CHECK_MODULES([zlib], [zlib])
  69         AC_DEFINE([ENABLE_ZLIB], [1], [Enable zlib for modules.])
  70 ], [
  71         AC_MSG_NOTICE([zlib support not requested])
  72 ])
  73
  74 AC_ARG_ENABLE([debug],
  75         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  76         [], [enable_debug=no])
  77 AS_IF([test "x$enable_debug" = "xyes"], [
  78         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  79 ])
  80
  81 CC_CHECK_CFLAGS_APPEND([ \
  82                         -pipe \
  83                         -DANOTHER_BRICK_IN_THE \
  84                         -Wall \
  85                         -W \
  86                         -Wextra \
  87                         -Wno-inline \
  88                         -Wvla \
  89                         -Wundef \
  90                         -Wformat=2 \
  91                         -Wlogical-op \
  92                         -Wsign-compare \
  93                         -Wformat-security \
  94                         -Wmissing-include-dirs \
  95                         -Wformat-nonliteral \
  96                         -Wold-style-definition \
  97                         -Wpointer-arith \
  98                         -Winit-self \
  99                         -Wdeclaration-after-statement \
 100                         -Wfloat-equal \
 101                         -Wmissing-prototypes \
 102                         -Wstrict-prototypes \
 103                         -Wredundant-decls \
 104                         -Wmissing-declarations \
 105                         -Wmissing-noreturn \
 106                         -Wshadow \
 107                         -Wendif-labels \
 108                         -Wstrict-aliasing=2 \
 109                         -Wwrite-strings \
 110                         -Wno-long-long \
 111                         -Wno-overlength-strings \
 112                         -Wno-unused-parameter \
 113                         -Wno-missing-field-initializers \
 114                         -Wno-unused-result \
 115                         -Wnested-externs \
 116                         -Wchar-subscripts \
 117                         -Wtype-limits \
 118                         -Wuninitialized \
 119                         -fno-common \
 120                         -fdiagnostics-show-option \
 121                         -fvisibility=hidden \
 122                         -ffunction-sections \
 123                         -fdata-sections \
 124                         -Wl,--as-needed \
 125                         -Wl,--gc-sections])
 126
 127
 128 AC_CONFIG_HEADERS(config.h)
 129 AC_CONFIG_FILES([
 130         Makefile
 131         libkmod/docs/Makefile
 132         libkmod/docs/version.xml
 133 ])
 134
 135 m4_ifdef([GTK_DOC_CHECK], [
 136 GTK_DOC_CHECK([1.14],[--flavour no-tmpl-flat])
 137 ], [
 138 AM_CONDITIONAL([ENABLE_GTK_DOC], false)])
 139
 140 AC_OUTPUT
 141 AC_MSG_RESULT([
 142         $PACKAGE $VERSION
 143         ======
 144
 145         prefix:                 ${prefix}
 146         rootprefix:             ${rootprefix}
 147         sysconfdir:             ${sysconfdir}
 148         libdir:                 ${libdir}
 149         rootlibdir:             ${rootlibdir}
 150         includedir:             ${includedir}
 151         bindir:                 ${bindir}
 152
 153         compiler:               ${CC}
 154         cflags:                 ${CFLAGS}
 155         ldflags:                ${LDFLAGS}
 156
 157         tools:                  ${enable_tools}
 158         logging:                ${enable_logging}
 159         compression:            xz=${with_xz}  zlib=${with_zlib}
 160         debug:                  ${enable_debug}
 161         doc:                    ${enable_gtk_doc}
 162 ])