configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT([kmod],
   3         [19],
   4         [linux-modules@vger.kernel.org],
   5         [kmod],
   6         [http://git.kernel.org/?p=utils/kernel/kmod/kmod.git])
   7
   8 AC_CONFIG_SRCDIR([libkmod/libkmod.c])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AM_INIT_AUTOMAKE([check-news foreign 1.11 silent-rules
  11         tar-pax no-dist-gzip dist-xz subdir-objects color-tests parallel-tests])
  12 AC_PROG_CC_STDC
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AC_SYS_LARGEFILE
  15 AC_CONFIG_MACRO_DIR([m4])
  16 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  17 AM_SILENT_RULES([yes])
  18 LT_INIT([disable-static pic-only])
  19 AC_PREFIX_DEFAULT([/usr])
  20 AM_MAINTAINER_MODE([enable])
  21
  22 AS_IF([test "x$enable_static" = "xyes"],
  23       [AC_MSG_ERROR([--enable-static is not supported by kmod])])
  24
  25
  26 #####################################################################
  27 # Program checks and configurations
  28 #####################################################################
  29
  30 AC_PROG_CC
  31 AC_PROG_CC_C99
  32 AM_PROG_CC_C_O
  33 AC_PROG_GCC_TRADITIONAL
  34 AC_C_BIGENDIAN
  35
  36 AC_PROG_SED
  37 AC_PROG_MKDIR_P
  38 PKG_PROG_PKG_CONFIG
  39 AC_PATH_PROG([XSLTPROC], [xsltproc])
  40
  41
  42 #####################################################################
  43 # Function and structure checks
  44 #####################################################################
  45
  46 AC_CHECK_FUNCS_ONCE(__xstat)
  47 AC_CHECK_FUNCS_ONCE([__secure_getenv secure_getenv])
  48 AC_CHECK_FUNCS_ONCE([finit_module])
  49
  50 CC_CHECK_FUNC_BUILTIN([__builtin_clz])
  51 CC_CHECK_FUNC_BUILTIN([__builtin_types_compatible_p])
  52
  53 # dietlibc doesn't have st.st_mtim struct member
  54 AC_CHECK_MEMBERS([struct stat.st_mtim], [], [], [#include <sys/stat.h>])
  55
  56 # musl 1.0 and bionic 4.4 don't have strndupa
  57 AC_CHECK_DECLS_ONCE([strndupa])
  58
  59 # RHEL 5 and older do not have be32toh
  60 AC_CHECK_DECLS_ONCE([be32toh])
  61
  62 # Check kernel headers
  63 AC_CHECK_HEADERS_ONCE([linux/module.h])
  64
  65 AC_MSG_CHECKING([whether _Static_assert() is supported])
  66 AC_COMPILE_IFELSE(
  67         [AC_LANG_SOURCE([[_Static_assert(1, "Test");]])],
  68         [AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define if _Static_assert() is available])
  69          AC_MSG_RESULT([yes])],
  70         [AC_MSG_RESULT([no])])
  71
  72 #####################################################################
  73 # --with-
  74 #####################################################################
  75
  76 AC_ARG_WITH([rootlibdir],
  77         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
  78         [], [with_rootlibdir=$libdir])
  79 AC_SUBST([rootlibdir], [$with_rootlibdir])
  80
  81 AC_ARG_WITH([xz],
  82         AS_HELP_STRING([--with-xz], [handle Xz-compressed modules @<:@default=disabled@:>@]),
  83         [], [with_xz=no])
  84 AS_IF([test "x$with_xz" != "xno"], [
  85         PKG_CHECK_MODULES([liblzma], [liblzma >= 4.99])
  86         AC_DEFINE([ENABLE_XZ], [1], [Enable Xz for modules.])
  87 ], [
  88         AC_MSG_NOTICE([Xz support not requested])
  89 ])
  90
  91 AC_ARG_WITH([zlib],
  92         AS_HELP_STRING([--with-zlib], [handle gzipped modules @<:@default=disabled@:>@]),
  93         [], [with_zlib=no])
  94 AS_IF([test "x$with_zlib" != "xno"], [
  95         PKG_CHECK_MODULES([zlib], [zlib])
  96         AC_DEFINE([ENABLE_ZLIB], [1], [Enable zlib for modules.])
  97 ], [
  98         AC_MSG_NOTICE([zlib support not requested])
  99 ])
 100
 101 AC_ARG_WITH([bashcompletiondir],
 102         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 103         [],
 104         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 105                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 106         ] , [
 107                 with_bashcompletiondir=${datadir}/bash-completion/completions
 108         ])])
 109 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 110
 111 #####################################################################
 112 # --enable-
 113 #####################################################################
 114
 115 AC_ARG_ENABLE([tools],
 116         AS_HELP_STRING([--disable-tools], [disable building tools that provide same functionality as module-init-tools @<:@default=enabled@:>@]),
 117         [], enable_tools=yes)
 118 AM_CONDITIONAL([BUILD_TOOLS], [test "x$enable_tools" = "xyes"])
 119
 120 AC_ARG_ENABLE([manpages],
 121         AS_HELP_STRING([--disable-manpages], [disable manpages @<:@default=enabled@:>@]),
 122         [], enable_manpages=yes)
 123 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" = "xyes"])
 124
 125 AC_ARG_ENABLE([logging],
 126         AS_HELP_STRING([--disable-logging], [disable system logging @<:@default=enabled@:>@]),
 127         [], enable_logging=yes)
 128 AS_IF([test "x$enable_logging" = "xyes"], [
 129         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
 130 ])
 131
 132 AC_ARG_ENABLE([debug],
 133         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
 134         [], [enable_debug=no])
 135 AS_IF([test "x$enable_debug" = "xyes"], [
 136         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
 137 ])
 138
 139 AC_ARG_ENABLE([python],
 140         AS_HELP_STRING([--enable-python], [enable Python libkmod bindings @<:@default=disabled@:>@]),
 141         [], [enable_python=no])
 142 AS_IF([test "x$enable_python" = "xyes"], [
 143         AM_PATH_PYTHON(,,[:])
 144         AC_PATH_PROG([CYTHON], [cython], [:])
 145
 146         PKG_CHECK_MODULES([PYTHON], [python-${PYTHON_VERSION}],
 147                           [have_python=yes],
 148                           [PKG_CHECK_MODULES([PYTHON], [python],
 149                                              [have_python=yes],
 150                                              [have_python=no])])
 151
 152         AS_IF([test "x$have_python" = xno],
 153               [AC_MSG_ERROR([*** python support requested but libraries not found])])
 154 ])
 155 AM_CONDITIONAL([BUILD_PYTHON], [test "x$enable_python" = "xyes"])
 156
 157 AC_ARG_ENABLE([coverage],
 158         AS_HELP_STRING([--enable-coverage], [enable test coverage @<:@default=disabled@:>@]),
 159         [], [enable_coverage=no])
 160 AS_IF([test "x$enable_coverage" = "xyes"], [
 161         AC_CHECK_PROG(have_coverage, [lcov], [yes], [no])
 162         AS_IF([test "x$have_coverage" = xno],[
 163                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 164         ], [
 165                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 166                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 167                 AS_IF([test "$lcov_version_major" -lt 1 -o "$lcov_version_minor" -lt 10], [
 168                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 169                 ], [
 170                         have_coverage=yes
 171                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 172                         -fprofile-arcs \
 173                         -ftest-coverage])
 174                 ])
 175         ])
 176 ])
 177 AM_CONDITIONAL([ENABLE_COVERAGE], [test "x$enable_coverage" = "xyes"])
 178
 179 m4_ifdef([GTK_DOC_CHECK], [
 180 GTK_DOC_CHECK([1.14],[--flavour no-tmpl-flat])
 181 ], [
 182 AM_CONDITIONAL([ENABLE_GTK_DOC], false)])
 183
 184
 185 #####################################################################
 186 # Default CFLAGS and LDFLAGS
 187 #####################################################################
 188
 189 CC_CHECK_FLAGS_APPEND(with_cflags, [CFLAGS], [\
 190                        -pipe \
 191                        -DANOTHER_BRICK_IN_THE \
 192                        -Wall \
 193                        -W \
 194                        -Wextra \
 195                        -Wno-inline \
 196                        -Wvla \
 197                        -Wundef \
 198                        -Wformat=2 \
 199                        -Wlogical-op \
 200                        -Wsign-compare \
 201                        -Wformat-security \
 202                        -Wmissing-include-dirs \
 203                        -Wformat-nonliteral \
 204                        -Wold-style-definition \
 205                        -Wpointer-arith \
 206                        -Winit-self \
 207                        -Wdeclaration-after-statement \
 208                        -Wfloat-equal \
 209                        -Wmissing-prototypes \
 210                        -Wstrict-prototypes \
 211                        -Wredundant-decls \
 212                        -Wmissing-declarations \
 213                        -Wmissing-noreturn \
 214                        -Wshadow \
 215                        -Wendif-labels \
 216                        -Wstrict-aliasing=3 \
 217                        -Wwrite-strings \
 218                        -Wno-long-long \
 219                        -Wno-overlength-strings \
 220                        -Wno-unused-parameter \
 221                        -Wno-missing-field-initializers \
 222                        -Wno-unused-result \
 223                        -Wnested-externs \
 224                        -Wchar-subscripts \
 225                        -Wtype-limits \
 226                        -Wuninitialized \
 227                        -fno-common \
 228                        -fdiagnostics-show-option \
 229                        -fvisibility=hidden \
 230                        -ffunction-sections \
 231                        -fdata-sections])
 232 AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 233
 234
 235 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [ \
 236                        -Wl,--as-needed \
 237                        -Wl,--no-undefined \
 238                        -Wl,--gc-sections])
 239 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 240
 241 #####################################################################
 242 # Generate files from *.in
 243 #####################################################################
 244
 245 AC_CONFIG_HEADERS(config.h)
 246 AC_CONFIG_FILES([
 247         Makefile
 248         man/Makefile
 249         libkmod/docs/Makefile
 250         libkmod/docs/version.xml
 251 ])
 252
 253
 254 #####################################################################
 255
 256 AC_OUTPUT
 257 AC_MSG_RESULT([
 258         $PACKAGE $VERSION
 259         =======
 260
 261         prefix:                 ${prefix}
 262         sysconfdir:             ${sysconfdir}
 263         libdir:                 ${libdir}
 264         rootlibdir:             ${rootlibdir}
 265         includedir:             ${includedir}
 266         bindir:                 ${bindir}
 267         Bash completions dir:   ${with_bashcompletiondir}
 268
 269         compiler:               ${CC}
 270         cflags:                 ${with_cflags} ${CFLAGS}
 271         ldflags:                ${with_ldflags} ${LDFLAGS}
 272
 273         tools:                  ${enable_tools}
 274         python bindings:        ${enable_python}
 275         logging:                ${enable_logging}
 276         compression:            xz=${with_xz}  zlib=${with_zlib}
 277         debug:                  ${enable_debug}
 278         coverage:               ${enable_coverage}
 279         doc:                    ${enable_gtk_doc}
 280         man:                    ${enable_manpages}
 281 ])