configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #######################
   5 ### Base configuration
   6
   7 # Configure autoconf
   8 AC_PREREQ([2.64])
   9
  10 AC_INIT([lldpd],
  11         [m4_esyscmd_s([./get-version])],
  12         [https://github.com/vincentbernat/lldpd/issues],
  13         [lldpd],
  14         [http://vincentbernat.github.io/lldpd/])
  15
  16 AC_CONFIG_SRCDIR([src/log.c])
  17 AC_CONFIG_HEADER([config.h])
  18 AC_CONFIG_FILES([Makefile
  19                  src/Makefile
  20                  src/compat/Makefile
  21                  src/daemon/Makefile
  22                  src/lib/Makefile
  23                  src/client/Makefile
  24                  tests/Makefile
  25                  osx/Makefile])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  28
  29 # Configure automake
  30 AM_INIT_AUTOMAKE([foreign subdir-objects -Wall -Werror tar-ustar])
  31 AM_MAINTAINER_MODE
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  33
  34 # Automake 1.12...
  35 m4_pattern_allow([AM_PROG_AR])
  36 AM_PROG_AR
  37
  38 # Configure libtool
  39 LT_INIT
  40 gl_LD_VERSION_SCRIPT
  41
  42 #######################
  43 ### Checks
  44
  45 # Checks for programs.
  46 AC_PROG_CC
  47 AC_PROG_CC_C99
  48 if test x"$ac_cv_prog_cc_c99" = x"no"; then
  49   AC_MSG_FAILURE([*** C99 support is mandatory])
  50 fi
  51 AM_PROG_CC_C_O
  52 AC_PROG_LIBTOOL
  53 AC_PROG_LN_S
  54 AC_PROG_EGREP
  55 AC_PROG_AWK
  56
  57 # Doxygen
  58 DX_HTML_FEATURE(ON)
  59 DX_DOT_FEATURE(OFF)
  60 DX_CHM_FEATURE(OFF)
  61 DX_CHI_FEATURE(OFF)
  62 DX_MAN_FEATURE(OFF)
  63 DX_RTF_FEATURE(OFF)
  64 DX_XML_FEATURE(OFF)
  65 DX_PDF_FEATURE(ON)
  66 DX_PS_FEATURE(OFF)
  67 DX_INIT_DOXYGEN([lldpd], [doxygen.cfg], [doxygen])
  68
  69 # Check some compiler flags
  70 AX_CFLAGS_GCC_OPTION([-Wunknown-warning-option], [LLDP_CFLAGS])
  71 AX_CFLAGS_GCC_OPTION([-fdiagnostics-show-option], [LLDP_CFLAGS])
  72 AX_CFLAGS_GCC_OPTION([-fdiagnostics-color=auto], [LLDP_CFLAGS])
  73 AX_CFLAGS_GCC_OPTION([-pipe], [LLDP_CFLAGS])
  74 AX_CFLAGS_GCC_OPTION([-Wall], [LLDP_CFLAGS])
  75 AX_CFLAGS_GCC_OPTION([-W], [LLDP_CFLAGS])
  76 AX_CFLAGS_GCC_OPTION([-Wextra], [LLDP_CFLAGS])
  77 AX_CFLAGS_GCC_OPTION([-Wformat], [LLDP_CFLAGS])
  78 AX_CFLAGS_GCC_OPTION([-Wformat-security], [LLDP_CFLAGS])
  79 AX_CFLAGS_GCC_OPTION([-Wimplicit-fallthrough], [LLDP_CFLAGS])
  80 AX_CFLAGS_GCC_OPTION([-Wfatal-errors], [LLDP_CFLAGS])
  81 AX_CFLAGS_GCC_OPTION([-Wheader-guard], [LLDP_CFLAGS])
  82 AX_CFLAGS_GCC_OPTION([-Wdocumentation], [LLDP_CFLAGS])
  83 AX_CFLAGS_GCC_OPTION([-Winline], [LLDP_CFLAGS])
  84 AX_CFLAGS_GCC_OPTION([-Wpointer-arith], [LLDP_CFLAGS])
  85 AX_CFLAGS_GCC_OPTION([-fno-omit-frame-pointer], [LLDP_CFLAGS])
  86 AX_CFLAGS_GCC_OPTION([-Wno-cast-align], [LLDP_CFLAGS]) dnl clang is bad at this
  87 AX_CFLAGS_GCC_OPTION([-Wno-unused-parameter], [LLDP_CFLAGS])
  88 AX_CFLAGS_GCC_OPTION([-Wno-missing-field-initializers], [LLDP_CFLAGS])
  89 AX_CFLAGS_GCC_OPTION([-Wno-sign-compare], [LLDP_CFLAGS]) dnl Should be fixed later
  90 AX_LDFLAGS_OPTION([-Wl,-z,relro], [LLDP_LDFLAGS])
  91 AX_LDFLAGS_OPTION([-Wl,-z,now], [LLDP_LDFLAGS])
  92
  93 AC_C_TYPEOF
  94
  95 # Hardening
  96 AC_ARG_ENABLE([hardening],
  97   [AS_HELP_STRING([--enable-hardening],
  98     [Enable compiler and linker options to frustrate memory corruption exploits @<:@default=yes@:>@])],
  99   [hardening="$enableval"],
 100   [hardening="yes"])
 101 AC_ARG_ENABLE([pie],
 102   [AS_HELP_STRING([--enable-pie],
 103     [Enable PIE (position independant executable) @<:@default=no@:>@])],
 104   [pie="$enableval"],
 105   [pie="no"])
 106
 107 if test x"$hardening" != x"no"; then
 108   AX_CFLAGS_GCC_OPTION([-fstack-protector], [LLDP_CFLAGS])
 109   AX_CFLAGS_GCC_OPTION([-fstack-protector-all], [LLDP_CFLAGS])
 110   AX_CFLAGS_GCC_OPTION([-fstack-protector-strong], [LLDP_CFLAGS])
 111   AX_CFLAGS_GCC_OPTION([-fstack-protector-strong], [LLDP_CFLAGS])
 112   AX_CFLAGS_GCC_OPTION([-fstack-clash-protection], [LLDP_CFLAGS])
 113   AX_CFLAGS_GCC_OPTION([-D_FORTIFY_SOURCE=2], [LLDP_CPPFLAGS])
 114 fi
 115 if test x"$pie" = x"yes"; then
 116   AX_CFLAGS_GCC_OPTION([-fPIE], [LLDP_CFLAGS])
 117   AX_LDFLAGS_OPTION([-fPIE -pie], [LLDP_BIN_LDFLAGS],
 118     [AX_LDFLAGS_OPTION([-fPIE -Wl,-pie], [LLDP_BIN_LDFLAGS])])
 119 fi
 120
 121 # Sanitizers
 122 AC_ARG_ENABLE([sanitizers],
 123   AS_HELP_STRING([--enable-sanitizers],
 124     [Enable code instrumentation with selected sanitizers @<:@default=no@:>@]),
 125   [
 126 case "$enableval" in
 127     no) sanitizers= ;;
 128     yes) sanitizers="-fsanitize=address,undefined" ;;
 129     *) sanitizers="-fsanitize=$enableval" ;;
 130 esac
 131 if test x"$sanitizers" != x; then
 132   LLDP_CFLAGS="$LLDP_CFLAGS $sanitizers"
 133   LLDP_LDFLAGS="$LLDP_LDFLAGS $sanitizers"
 134   AC_DEFINE([HAVE_ADDRESS_SANITIZER], 1, [Define if have both address and leak sanitizer])
 135 elif test x"$hardening" != x"no"; then
 136   AX_LDFLAGS_OPTION([-fsanitize=safe-stack], [LLDP_BIN_LDFLAGS])
 137   if test x"$ax_cv_ld_check_flag__fsanitize_safe_stack" != x"no"; then
 138     AX_CFLAGS_GCC_OPTION([-fsanitize=safe-stack], [LLDP_CFLAGS])
 139   fi
 140 fi
 141   ])
 142
 143 # Code coverage
 144 AC_ARG_ENABLE([gcov],
 145   AS_HELP_STRING([--enable-gcov],
 146     [Enable coverage instrumentation @<:@default=no@:>@]),
 147     [gcov="$enableval"],
 148     [gcov="no"])
 149 if test x"$gcov" != x"no"; then
 150   LLDP_CFLAGS="$LLDP_CFLAGS --coverage"
 151   LLDP_LDFLAGS="$LLDP_LDFLAGS --coverage"
 152 fi
 153
 154 # OS
 155 lldp_CHECK_OS
 156 lldp_CFLAGS_OS
 157
 158 AC_CACHE_SAVE
 159
 160 # Checks for header files.
 161 AC_HEADER_RESOLV
 162 AC_CHECK_HEADERS([valgrind/valgrind.h])
 163 lldp_CHECK_STDINT
 164
 165 AC_CACHE_SAVE
 166
 167 # Checks for typedefs, structures, and compiler characteristics.
 168 lldp_CHECK___PROGNAME
 169 lldp_CHECK_ALIGNOF
 170
 171 # Checks for library functions.
 172 AC_CONFIG_LIBOBJ_DIR([src/compat])
 173 AC_FUNC_MALLOC
 174 AC_FUNC_REALLOC
 175 AC_FUNC_FORK
 176
 177 # Some functions can be in libbsd
 178 AC_ARG_WITH([libbsd],
 179   AS_HELP_STRING(
 180     [--with-libbsd],
 181     [Use libbsd @<:@default=auto@:>@]),
 182   [],
 183   [with_libbsd=auto])
 184 if test x"$with_libbsd" != x"no"; then
 185   PKG_CHECK_MODULES([libbsd], [libbsd-overlay], [
 186     _save_CFLAGS="$CFLAGS"
 187     _save_LIBS="$LIBS"
 188     CFLAGS="$CFLAGS $libbsd_CFLAGS"
 189     LIBS="$LIBS $libbsd_LIBS"
 190     AC_MSG_CHECKING([if libbsd can be linked correctly])
 191     AC_TRY_LINK([
 192   @%:@include <sys/time.h>
 193   @%:@include <sys/types.h>
 194   ],[],
 195       [
 196         AC_MSG_RESULT(yes)
 197         LLDP_CFLAGS="$LLDP_CFLAGS $libbsd_CFLAGS"
 198         LLDP_LDFLAGS="$LLDP_LDFLAGS $libbsd_LIBS"
 199         with_libbsd=yes
 200       ],[
 201         AC_MSG_RESULT(no)
 202         CFLAGS="$_save_CFLAGS"
 203         LIBS="$_save_LIBS"
 204         if test x"$with_libbsd" = x"yes"; then
 205            AC_MSG_FAILURE([*** no libbsd support found])
 206         fi
 207         with_libbsd=no
 208       ])
 209   ], [
 210     if test x"$with_libbsd" = x"yes"; then
 211        AC_MSG_FAILURE([*** no libbsd support found])
 212     fi
 213     with_libbsd=no
 214   ])
 215 fi
 216
 217 # setproctitle may have an _init function
 218 AC_REPLACE_FUNCS([setproctitle])
 219 AC_CHECK_FUNCS([setproctitle_init])
 220 # Other functions
 221 AC_REPLACE_FUNCS([strlcpy
 222                   strnlen
 223                   strndup
 224                   strtonum
 225                   getline
 226                   asprintf
 227                   vsyslog
 228                   daemon])
 229 # Optional functions
 230 AC_CHECK_FUNCS([setresuid setresgid])
 231
 232 # Check for res_init. On OSX, res_init is a symbol in libsystem_info
 233 # and a macro in resolv.h. We need to ensure we test with resolv.h.
 234 m4_pushdef([AC_LANG_CALL(C)], [
 235   AC_LANG_PROGRAM([$1
 236 @%:@include <resolv.h>], [return $2 ();])])
 237 AC_SEARCH_LIBS([res_init], resolv bind,
 238                AC_DEFINE([HAVE_RES_INIT], 1,
 239                [Define to indicate that res_init() exists]))
 240 m4_popdef([AC_LANG_CALL(C)])
 241
 242 AC_CACHE_SAVE
 243
 244 ## Unit tests wich check
 245 PKG_CHECK_MODULES([check], [check >= 0.9.4], [have_check=yes], [have_check=no])
 246
 247 # Third-party libraries
 248 lldp_CHECK_LIBEVENT
 249 lldp_CHECK_LIBCAP
 250
 251 # Compatibility with pkg.m4 < 0.27
 252 m4_ifdef([PKG_INSTALLDIR], [PKG_INSTALLDIR],
 253          [AC_ARG_WITH([pkgconfigdir],
 254                       [AS_HELP_STRING([--with-pkgconfigdir],
 255                       [install directory for *.pc pkg-config file])],
 256                       [],[with_pkgconfigdir='$(libdir)/pkgconfig'])
 257           AC_SUBST([pkgconfigdir], [${with_pkgconfigdir}])])
 258
 259 #######################
 260 ### Options
 261
 262 # Readline
 263 AC_ARG_WITH([readline],
 264   AS_HELP_STRING(
 265     [--with-readline],
 266     [Enable the use of readline-like library @<:@default=auto@:>@]),
 267   [],
 268   [with_readline=auto])
 269 if test x"$with_readline" != x"no"; then
 270    AX_LIB_READLINE
 271    if test x"$with_readline" != x"check" -a x"$with_readline" != x"auto"; then
 272      if test x"$ax_cv_lib_readline" = x"no"; then
 273        AC_MSG_FAILURE([*** no readline support found])
 274      fi
 275    fi
 276 else
 277    ax_cv_lib_readline="no"
 278 fi
 279
 280 # SNMP
 281 AC_ARG_WITH([snmp],
 282   AS_HELP_STRING(
 283     [--with-snmp],
 284     [Enable the use of SNMP @<:@default=no@:>@]),
 285   [],
 286   [with_snmp=no])
 287 lldp_CHECK_SNMP
 288
 289 # XML
 290 AC_ARG_WITH([xml],
 291   AS_HELP_STRING(
 292     [--with-xml],
 293     [Enable XML output via libxml2 @<:@default=auto@:>@]),
 294   [],
 295   [with_xml=auto])
 296 lldp_CHECK_XML2
 297
 298 # JSON (built-in)
 299 lldp_ARG_ENABLE([json0], [use of pre-0.9.2 JSON/json-c format], [no])
 300
 301 # Seccomp
 302 AC_ARG_WITH([seccomp],
 303   AS_HELP_STRING(
 304     [--with-seccomp],
 305     [Enable seccomp support (with libseccomp, experimental) @<:@default=no@:>@]),
 306   [],
 307   [with_seccomp=no])
 308 lldp_CHECK_SECCOMP
 309
 310 # OS X launchd support
 311 lldp_ARG_WITH([launchddaemonsdir], [Directory for launchd configuration file (OSX)],
 312                                    [/Library/LaunchDaemons])
 313 AC_SUBST([launchddaemonsdir], [$with_launchddaemonsdir])
 314 AM_CONDITIONAL(HAVE_LAUNCHDDAEMONSDIR,
 315     [test -n "$with_launchddaemonsdir" -a "x$with_launchddaemonsdir" != xno ])
 316
 317 # Systemd
 318 lldp_ARG_WITH([systemdsystemunitdir], [Directory for systemd service files],
 319               [$($PKG_CONFIG --variable=systemdsystemunitdir systemd 2> /dev/null)])
 320 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 321 AM_CONDITIONAL(HAVE_SYSTEMDSYSTEMUNITDIR,
 322     [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
 323
 324 # sysusers
 325 lldp_ARG_WITH([sysusersdir], [Directory for sysusers files],
 326               [$($PKG_CONFIG --variable=sysusersdir systemd 2> /dev/null)])
 327 AC_SUBST([sysusersdir], [$with_sysusersdir])
 328 AM_CONDITIONAL(HAVE_SYSUSERSDIR,
 329     [test -n "$with_sysusersdir" -a "x$with_sysusersdir" != xno ])
 330
 331 # AppArmor
 332 lldp_ARG_WITH([apparmordir], [Directory for AppArmor profiles (Linux)],
 333                              [no])
 334 AC_SUBST([apparmordir], [$with_apparmordir])
 335 AM_CONDITIONAL(HAVE_APPARMORDIR,
 336     [test -n "$with_apparmordir" -a "x$with_apparmordir" != xno ])
 337
 338 # Systemtap/DTrace
 339 lldp_SYSTEMTAP
 340
 341 # Privsep settings
 342 lldp_ARG_ENABLE([privsep], [Privilege separation], [yes])
 343 lldp_ARG_WITH([privsep-user], [Which user to use for privilege separation], [_lldpd])
 344 lldp_ARG_WITH([privsep-group], [Which group to use for privilege separation], [_lldpd])
 345
 346 # Directories
 347 dnl On autoconf 2.69 and before, runstatedir is not configurable, let be able to use it anyway
 348 if test "x$runstatedir" = x; then
 349     AC_SUBST([runstatedir], ['${localstatedir}/run'])
 350 fi
 351 lldp_ARG_WITH([privsep-chroot], [Which directory to use to chroot lldpd], [${runstatedir}/lldpd])
 352 lldp_ARG_WITH([lldpd-ctl-socket], [Path to socket for communication with lldpd], [${runstatedir}/lldpd.socket])
 353 lldp_ARG_WITH([lldpd-pid-file], [Path to lldpd PID file], [${runstatedir}/lldpd.pid])
 354
 355 # Netlink
 356 lldp_ARG_WITH_UNQUOTED([netlink-max-receive-bufsize], [Netlink maximum receive buffer size], [1024*1024])
 357 lldp_ARG_WITH_UNQUOTED([netlink-receive-bufsize], [Netlink initial receive buffer size], [0])
 358 lldp_ARG_WITH_UNQUOTED([netlink-send-bufsize], [Netlink send buffer size], [0])
 359
 360 # CDP/FDP/EDP/SONMP
 361 lldp_ARG_ENABLE([cdp], [Cisco Discovery Protocol], [yes])
 362 lldp_ARG_ENABLE([fdp], [Foundry Discovery Protocol], [yes])
 363 lldp_ARG_ENABLE([edp], [Extreme Discovery Protocol], [yes])
 364 lldp_ARG_ENABLE([sonmp], [SynOptics Network Management Protocol], [yes])
 365
 366 # LLDPMED/Dot1/Dot3
 367 lldp_ARG_ENABLE([lldpmed], [LLDP-MED extension], [yes])
 368 lldp_ARG_ENABLE([dot1], [Dot1 extension (VLAN stuff)], [yes])
 369 lldp_ARG_ENABLE([dot3], [Dot3 extension (PHY stuff)], [yes])
 370 lldp_ARG_ENABLE([custom], [Custom TLV support], [yes])
 371
 372 # Oldies
 373 MIN_LINUX_KERNEL_VERSION=2.6.39
 374 lldp_ARG_ENABLE([oldies], [compatibility with Linux kernel older than 2.6.39], [no])
 375 if test x"$os" = x"Linux"; then
 376     if test x"$enable_oldies" = x"no"; then
 377       AC_DEFINE_UNQUOTED(MIN_LINUX_KERNEL_VERSION, "[$MIN_LINUX_KERNEL_VERSION]", [Minimal Linux kernel version required])
 378     else
 379       AC_DEFINE(MIN_LINUX_KERNEL_VERSION, "2.6.11", [Minimal kernel version required])
 380     fi
 381 fi
 382
 383 AX_BUILD_DATE_EPOCH(BUILD_DATE, "%FT%TZ", [BUILD_DATE="(unknown)"])
 384 AC_DEFINE_UNQUOTED(BUILD_DATE, "[$BUILD_DATE]", [Build date and time])
 385 AC_DEFINE_UNQUOTED(LLDP_CC, "[$CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS]", [C compiler command])
 386 AC_DEFINE_UNQUOTED(LLDP_LD, "[$LD $LLDP_LDFLAGS $LLDP_BIN_LDFLAGS $LDFLAGS $LIBS]", [Linker compiler command])
 387
 388 #######################
 389 # Output results
 390 AC_SUBST([LLDP_CFLAGS])
 391 AC_SUBST([LLDP_CPPFLAGS])
 392 AC_SUBST([LLDP_LDFLAGS])
 393 AC_SUBST([LLDP_BIN_LDFLAGS])
 394 AM_CONDITIONAL([HAVE_CHECK], [test x"$have_check" = x"yes"])
 395 AM_CONDITIONAL([USE_SNMP], [test x"$with_snmp" = x"yes"])
 396 AM_CONDITIONAL([USE_XML], [test x"$with_xml" = x"yes"])
 397 AM_CONDITIONAL([USE_SECCOMP], [test x"$with_seccomp" = x"yes"])
 398 dnl If old default of AR_FLAGS is otherwise being used (because of older automake),
 399 dnl replace it with one without 'u'
 400 if test "x$AR_FLAGS" = "xcru" ; then
 401   AR_FLAGS="cr"
 402 fi
 403 AC_OUTPUT
 404
 405 if test x"$LIBEVENT_EMBEDDED" = x; then
 406    libevent=system
 407 else
 408    libevent=embedded
 409 fi
 410
 411 cat <<EOF
 412
 413 ------------------ Summary ------------------
 414  $PACKAGE_NAME version $PACKAGE_VERSION
 415   OS.............: $os
 416   Prefix.........: $prefix
 417   C Compiler.....: $CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS
 418   Linker.........: $LD $LLDP_LDFLAGS $LLDP_BIN_LDFLAGS $LDFLAGS $LIBS
 419   Libevent.......: $libevent
 420   Readline.......: ${ax_cv_lib_readline}
 421
 422  Optional features:
 423   SNMP support...: ${with_snmp-no}
 424   CDP............: $enable_cdp
 425   FDP............: $enable_fdp
 426   EDP............: $enable_edp
 427   SONMP..........: $enable_sonmp
 428   LLDPMED........: $enable_lldpmed
 429   DOT1...........: $enable_dot1
 430   DOT3...........: $enable_dot3
 431   CUSTOM.........: $enable_custom
 432   XML output.....: ${with_xml-no}
 433   Oldies support.: $enable_oldies
 434   seccomp........: ${with_seccomp-no}
 435   libbsd.........: ${with_libbsd-no}
 436
 437  Privilege separation:
 438   Enabled........: $enable_privsep
 439   User/group.....: ${with_privsep_user}/${with_privsep_group}
 440   Chroot.........: ${with_privsep_chroot}
 441
 442  Instrumentation (for devs only):
 443   Sanitizers.....: ${sanitizers:-none}
 444   Coverage.......: ${gcov}
 445 ------------- Compiler version --------------
 446 $($CC --version || true)
 447 -------------- Linker version ---------------
 448 $($LD --version || true)
 449 ---------------------------------------------
 450
 451 Check the above options and compile with:
 452  ${MAKE-make}
 453
 454 EOF