configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [206],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  48 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  49
  50 # i18n stuff for the PolicyKit policy files
  51 IT_PROG_INTLTOOL([0.40.0])
  52
  53 GETTEXT_PACKAGE=systemd
  54 AC_SUBST(GETTEXT_PACKAGE)
  55
  56 AC_PROG_MKDIR_P
  57 AC_PROG_LN_S
  58 AC_PROG_SED
  59 AC_PROG_GREP
  60 AC_PROG_AWK
  61
  62 AC_PROG_CC
  63 AC_PROG_CC_C99
  64 AM_PROG_CC_C_O
  65 AC_PROG_GCC_TRADITIONAL
  66
  67 AC_PATH_PROG([M4], [m4])
  68 AC_PATH_PROG([XSLTPROC], [xsltproc])
  69
  70 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  71 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  72
  73 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  74
  75 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  76
  77 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
  78
  79 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec])
  80
  81 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  82 m4_ifdef([GTK_DOC_CHECK], [
  83 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  84          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  85           enable_gtk_doc=no])
  86
  87 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  88         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  89 ])
  90
  91 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  92 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  93 ], [
  94    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  95    enable_introspection=no])
  96
  97 AC_CHECK_TOOL(OBJCOPY, objcopy)
  98 AC_CHECK_TOOL(STRINGS, strings)
  99 AC_CHECK_TOOL(GPERF, gperf)
 100 if test -z "$GPERF" ; then
 101         AC_MSG_ERROR([*** gperf not found])
 102 fi
 103
 104 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 105         -pipe \
 106         -Wall \
 107         -Wextra \
 108         -Wno-inline \
 109         -Wundef \
 110         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 111         -Wlogical-op \
 112         -Wsign-compare \
 113         -Wmissing-include-dirs \
 114         -Wold-style-definition \
 115         -Wpointer-arith \
 116         -Winit-self \
 117         -Wdeclaration-after-statement \
 118         -Wfloat-equal \
 119         -Wmissing-prototypes \
 120         -Wstrict-prototypes \
 121         -Wredundant-decls \
 122         -Wmissing-declarations \
 123         -Wmissing-noreturn \
 124         -Wshadow \
 125         -Wendif-labels \
 126         -Wcast-align \
 127         -Wstrict-aliasing=2 \
 128         -Wwrite-strings \
 129         -Wno-long-long \
 130         -Wno-overlength-strings \
 131         -Wno-unused-parameter \
 132         -Wno-missing-field-initializers \
 133         -Wno-unused-result \
 134         -Werror=overflow \
 135         -ffast-math \
 136         -fno-common \
 137         -fdiagnostics-show-option \
 138         -fdiagnostics-color \
 139         -fno-strict-aliasing \
 140         -fvisibility=hidden \
 141         -ffunction-sections \
 142         -fdata-sections \
 143         -fstack-protector \
 144         --param=ssp-buffer-size=4])
 145 AC_SUBST([OUR_CFLAGS], $with_cflags)
 146
 147 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
 148         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 149                -Wp,-D_FORTIFY_SOURCE=2])],
 150         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 151 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 152
 153 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 154         -Wl,--as-needed \
 155         -Wl,--no-undefined \
 156         -Wl,--gc-sections \
 157         -Wl,-z,relro \
 158         -Wl,-z,now])
 159 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 160
 161 # ------------------------------------------------------------------------------
 162 # we use python to build the man page index, and for systemd-python
 163 have_python=no
 164 AC_ARG_WITH([python],
 165         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 166
 167 AS_IF([test "x$with_python" != "xno"], [
 168         AM_PATH_PYTHON(,, [:])
 169         AS_IF([test "$PYTHON" != :], [have_python=yes])
 170 ])
 171 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 172 AS_IF([test "x$PYTHON_BINARY" = "x"],
 173       [AS_IF([test "x$have_python" = "xyes"],
 174              [PYTHON_BINARY="$(which "$PYTHON")"],
 175              [PYTHON_BINARY=/usr/bin/python])])
 176 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 177
 178 have_python_devel=no
 179 AC_ARG_ENABLE(python_devel, AS_HELP_STRING([--disable-python-devel], [Do not build python modules]))
 180 AS_IF([test "x$enable_python_devel" != "xno"], [
 181       PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}],
 182             [have_python_devel=yes],
 183             [PKG_CHECK_MODULES([PYTHON_DEVEL], [python],
 184                   [have_python_devel=yes],
 185                   [have_python_devel=no])])
 186       AS_IF([test "x$have_python_devel" = xno -a "x$enable_python_devel" = xyes],
 187             [AC_MSG_ERROR([*** python-devel support requested but libraries not found])])
 188 ])
 189 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 190
 191 # ------------------------------------------------------------------------------
 192
 193 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 194 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 195
 196 # unconditionally pull-in librt with old glibc versions
 197 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 198
 199 save_LIBS="$LIBS"
 200 LIBS=
 201 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 202 CAP_LIBS="$LIBS"
 203 AC_SUBST(CAP_LIBS)
 204
 205 LIBS=
 206 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 207 RT_LIBS="$LIBS"
 208 AC_SUBST(RT_LIBS)
 209 LIBS="$save_LIBS"
 210
 211 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 212 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 213 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 214 #include <unistd.h>
 215 #include <sys/mount.h>
 216 #include <fcntl.h>]])
 217
 218 # This makes sure pkg.m4 is available.
 219 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 220
 221 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 222
 223 # ------------------------------------------------------------------------------
 224 have_coverage=no
 225 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 226 if test "x$enable_coverage" = "xyes" ; then
 227         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 228         if test "x$lcov_found" = xno ; then
 229                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 230         else
 231                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 232                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 233                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 234                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 235                 else
 236                         have_coverage=yes
 237                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 238                         -fprofile-arcs \
 239                         -ftest-coverage])
 240                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 241                 fi
 242         fi
 243 fi
 244 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 245
 246 # ------------------------------------------------------------------------------
 247 have_kmod=no
 248 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 249 if test "x$enable_kmod" != "xno"; then
 250         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 251         if test "x$have_kmod" = "xyes"; then
 252                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 14 ],
 253                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 254                         AC_MSG_ERROR([*** kmod version >= 14 not found]))
 255         fi
 256         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 257                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 258         fi
 259 fi
 260 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 261
 262 # ------------------------------------------------------------------------------
 263 have_blkid=no
 264 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 265 if test "x$enable_blkid" != "xno"; then
 266         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 267                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 268         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 269                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 270         fi
 271 fi
 272 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 273
 274 # ------------------------------------------------------------------------------
 275 have_ima=yes
 276 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 277                 [case "${enableval}" in
 278                         yes) have_ima=yes ;;
 279                         no) have_ima=no ;;
 280                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 281                 esac],
 282                 [have_ima=yes])
 283
 284 if test "x${have_ima}" != xno ; then
 285         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 286 fi
 287
 288 # ------------------------------------------------------------------------------
 289 have_chkconfig=yes
 290 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 291                 [case "${enableval}" in
 292                         yes) have_chkconfig=yes ;;
 293                         no) have_chkconfig=no ;;
 294                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 295                 esac],
 296                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 297                 if test -z "$CHKCONFIG"; then
 298                         have_chkconfig=no
 299                 else
 300                         have_chkconfig=yes
 301                 fi])
 302
 303 if test "x${have_chkconfig}" != xno ; then
 304         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 305 fi
 306
 307 # ------------------------------------------------------------------------------
 308 have_selinux=no
 309 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 310 if test "x$enable_selinux" != "xno"; then
 311         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 312                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 313         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 314                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 315         fi
 316 fi
 317 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 318
 319 AC_ARG_WITH(debug-shell,
 320         AS_HELP_STRING([--with-debug-shell=PATH],
 321                 [Path to debug shell binary]),
 322         [SUSHELL="$withval"],[
 323         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 324
 325 AC_SUBST(SUSHELL)
 326
 327 AC_ARG_WITH([debug-tty],
 328         AS_HELP_STRING([--with-debug-tty=PATH],
 329                 [Specify the tty device for debug shell]),
 330         [DEBUGTTY="$withval"],
 331         [DEBUGTTY=/dev/tty9])
 332
 333 AC_SUBST(DEBUGTTY)
 334
 335 # ------------------------------------------------------------------------------
 336 have_xz=no
 337 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 338 if test "x$enable_xz" != "xno"; then
 339         PKG_CHECK_MODULES(XZ, [ liblzma ],
 340                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 341         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 342                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 343         fi
 344 fi
 345 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 346
 347 # ------------------------------------------------------------------------------
 348 AC_ARG_ENABLE([tcpwrap],
 349         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 350                 [case "${enableval}" in
 351                         yes) have_tcpwrap=yes ;;
 352                         no) have_tcpwrap=no ;;
 353                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 354                 esac],
 355                 [have_tcpwrap=auto])
 356
 357 if test "x${have_tcpwrap}" != xno ; then
 358         ACX_LIBWRAP
 359         if test "x${LIBWRAP_LIBS}" = x ; then
 360                 if test "x$have_tcpwrap" = xyes ; then
 361                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 362                 fi
 363                 have_tcpwrap=no
 364         else
 365                 have_tcpwrap=yes
 366         fi
 367 else
 368         LIBWRAP_LIBS=
 369 fi
 370 AC_SUBST(LIBWRAP_LIBS)
 371
 372 # ------------------------------------------------------------------------------
 373 AC_ARG_ENABLE([pam],
 374         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 375                 [case "${enableval}" in
 376                         yes) have_pam=yes ;;
 377                         no) have_pam=no ;;
 378                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 379                 esac],
 380                 [have_pam=auto])
 381
 382 if test "x${have_pam}" != xno ; then
 383         AC_CHECK_HEADERS(
 384                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 385                 [have_pam=yes],
 386                 [if test "x$have_pam" = xyes ; then
 387                         AC_MSG_ERROR([*** PAM headers not found.])
 388                 fi])
 389
 390         AC_CHECK_LIB(
 391                 [pam],
 392                 [pam_syslog],
 393                 [have_pam=yes],
 394                 [if test "x$have_pam" = xyes ; then
 395                         AC_MSG_ERROR([*** libpam not found.])
 396                 fi])
 397
 398         if test "x$have_pam" = xyes ; then
 399                 PAM_LIBS="-lpam -lpam_misc"
 400                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 401         else
 402                 have_pam=no
 403         fi
 404 else
 405         PAM_LIBS=
 406 fi
 407 AC_SUBST(PAM_LIBS)
 408 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 409
 410 # ------------------------------------------------------------------------------
 411 AC_ARG_ENABLE([acl],
 412         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 413                 [case "${enableval}" in
 414                         yes) have_acl=yes ;;
 415                         no) have_acl=no ;;
 416                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 417                 esac],
 418                 [have_acl=auto])
 419
 420 if test "x${have_acl}" != xno ; then
 421         AC_CHECK_HEADERS(
 422                 [sys/acl.h acl/libacl.h],
 423                 [have_acl=yes],
 424                 [if test "x$have_acl" = xyes ; then
 425                         AC_MSG_ERROR([*** ACL headers not found.])
 426                 fi])
 427
 428         AC_CHECK_LIB(
 429                 [acl],
 430                 [acl_get_file],
 431                 [have_acl=yes],
 432                 [if test "x$have_acl" = xyes ; then
 433                         AC_MSG_ERROR([*** libacl not found.])
 434                 fi])
 435
 436         if test "x$have_acl" = xyes ; then
 437                 ACL_LIBS="-lacl"
 438                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 439         else
 440                 have_acl=no
 441         fi
 442 else
 443         ACL_LIBS=
 444 fi
 445 AC_SUBST(ACL_LIBS)
 446 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 447
 448 # ------------------------------------------------------------------------------
 449 AC_ARG_ENABLE([xattr],
 450         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 451                 [case "${enableval}" in
 452                         yes) have_xattr=yes ;;
 453                         no) have_xattr=no ;;
 454                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 455                 esac],
 456                 [have_xattr=auto])
 457
 458 if test "x${have_xattr}" != xno ; then
 459         AC_CHECK_HEADERS(
 460                 [attr/xattr.h],
 461                 [have_xattr=yes],
 462                 [if test "x$have_xattr" = xyes ; then
 463                         AC_MSG_ERROR([*** XATTR headers not found.])
 464                 fi])
 465
 466         AC_CHECK_LIB(
 467                 [attr],
 468                 [fsetxattr],
 469                 [have_xattr=yes],
 470                 [if test "x$have_xattr" = xyes ; then
 471                         AC_MSG_ERROR([*** libattr not found.])
 472                 fi])
 473
 474         if test "x$have_xattr" = xyes ; then
 475                 XATTR_LIBS="-lattr"
 476                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 477         else
 478                 have_xattr=no
 479         fi
 480 else
 481         XATTR_LIBS=
 482 fi
 483 AC_SUBST(XATTR_LIBS)
 484 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 485
 486 # ------------------------------------------------------------------------------
 487 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 488                 [case "${enableval}" in
 489                         yes) have_smack=yes ;;
 490                         no) have_smack=no ;;
 491                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 492                 esac],
 493                 [have_smack=auto])
 494
 495 if test "x${have_xattr}" = xno; then
 496         if test "x${have_smack}" = xyes; then
 497                 AC_MSG_ERROR(SMACK requires xattr support)
 498         else
 499                 have_smack=no
 500         fi
 501 else
 502         if test "x${have_smack}" = xauto; then
 503                 have_smack=yes
 504         fi
 505 fi
 506
 507 if test "x${have_smack}" = xyes ; then
 508         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 509 fi
 510
 511 # ------------------------------------------------------------------------------
 512 AC_ARG_ENABLE([gcrypt],
 513         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 514                 [case "${enableval}" in
 515                         yes) have_gcrypt=yes ;;
 516                         no) have_gcrypt=no ;;
 517                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 518                 esac],
 519                 [have_gcrypt=auto])
 520
 521 if test "x${have_gcrypt}" != xno ; then
 522         AM_PATH_LIBGCRYPT(
 523                 [1.4.5],
 524                 [have_gcrypt=yes],
 525                 [if test "x$have_gcrypt" = xyes ; then
 526                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 527                 fi])
 528
 529         if test "x$have_gcrypt" = xyes ; then
 530                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 531                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 532                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 533         else
 534                 have_gcrypt=no
 535         fi
 536 else
 537         GCRYPT_LIBS=
 538         GCRYPT_CFLAGS=
 539 fi
 540 AC_SUBST(GCRYPT_LIBS)
 541 AC_SUBST(GCRYPT_CFLAGS)
 542 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 543
 544 # ------------------------------------------------------------------------------
 545 AC_ARG_ENABLE([audit],
 546         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 547                 [case "${enableval}" in
 548                         yes) have_audit=yes ;;
 549                         no) have_audit=no ;;
 550                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 551                 esac],
 552                 [have_audit=auto])
 553
 554 if test "x${have_audit}" != xno ; then
 555         AC_CHECK_HEADERS(
 556                 [libaudit.h],
 557                 [have_audit=yes],
 558                 [if test "x$have_audit" = xyes ; then
 559                         AC_MSG_ERROR([*** AUDIT headers not found.])
 560                 fi])
 561
 562         AC_CHECK_LIB(
 563                 [audit],
 564                 [audit_open],
 565                 [have_audit=yes],
 566                 [if test "x$have_audit" = xyes ; then
 567                         AC_MSG_ERROR([*** libaudit not found.])
 568                 fi])
 569
 570         if test "x$have_audit" = xyes ; then
 571                 AUDIT_LIBS="-laudit"
 572                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 573         else
 574                 have_audit=no
 575         fi
 576 else
 577         AUDIT_LIBS=
 578 fi
 579 AC_SUBST(AUDIT_LIBS)
 580
 581 # ------------------------------------------------------------------------------
 582 have_libcryptsetup=no
 583 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 584 if test "x$enable_libcryptsetup" != "xno"; then
 585         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 586                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 587         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 588                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 589         fi
 590 fi
 591 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 592
 593 # ------------------------------------------------------------------------------
 594 have_qrencode=no
 595 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 596 if test "x$enable_qrencode" != "xno"; then
 597         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 598                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 599         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 600                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 601         fi
 602 fi
 603 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 604
 605 # ------------------------------------------------------------------------------
 606 have_microhttpd=no
 607 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 608 if test "x$enable_microhttpd" != "xno"; then
 609         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 610                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 611         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 612                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 613         fi
 614 fi
 615 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 616
 617 # ------------------------------------------------------------------------------
 618 have_binfmt=no
 619 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 620 if test "x$enable_binfmt" != "xno"; then
 621         have_binfmt=yes
 622 fi
 623 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 624
 625 # ------------------------------------------------------------------------------
 626 have_vconsole=no
 627 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 628 if test "x$enable_vconsole" != "xno"; then
 629         have_vconsole=yes
 630 fi
 631 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 632
 633 # ------------------------------------------------------------------------------
 634 have_readahead=no
 635 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 636 if test "x$enable_readahead" != "xno"; then
 637         have_readahead=yes
 638 fi
 639 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 640
 641 # ------------------------------------------------------------------------------
 642 have_bootchart=no
 643 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 644 if test "x$enable_bootchart" != "xno"; then
 645         have_bootchart=yes
 646 fi
 647 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 648
 649 # ------------------------------------------------------------------------------
 650 have_quotacheck=no
 651 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 652 if test "x$enable_quotacheck" != "xno"; then
 653         have_quotacheck=yes
 654 fi
 655 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 656
 657 # ------------------------------------------------------------------------------
 658 have_tmpfiles=no
 659 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 660 if test "x$enable_tmpfiles" != "xno"; then
 661         have_tmpfiles=yes
 662 fi
 663 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 664
 665 # ------------------------------------------------------------------------------
 666 have_randomseed=no
 667 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 668 if test "x$enable_randomseed" != "xno"; then
 669         have_randomseed=yes
 670 fi
 671 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 672
 673 # ------------------------------------------------------------------------------
 674 have_logind=no
 675 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 676 if test "x$enable_logind" != "xno"; then
 677         have_logind=yes
 678 fi
 679 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 680 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 681
 682 # ------------------------------------------------------------------------------
 683 have_machined=no
 684 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 685 if test "x$enable_machined" != "xno"; then
 686         have_machined=yes
 687 fi
 688 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 689 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 690
 691 # ------------------------------------------------------------------------------
 692 have_hostnamed=no
 693 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 694 if test "x$enable_hostnamed" != "xno"; then
 695         have_hostnamed=yes
 696 fi
 697 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 698
 699 # ------------------------------------------------------------------------------
 700 have_timedated=no
 701 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 702 if test "x$enable_timedated" != "xno"; then
 703         have_timedated=yes
 704 fi
 705 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 706
 707 # ------------------------------------------------------------------------------
 708 have_localed=no
 709 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 710 if test "x$enable_localed" != "xno"; then
 711         have_localed=yes
 712 fi
 713 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 714
 715 # ------------------------------------------------------------------------------
 716 have_coredump=no
 717 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 718 if test "x$enable_coredump" != "xno"; then
 719         have_coredump=yes
 720 fi
 721 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 722
 723 # ------------------------------------------------------------------------------
 724 have_polkit=no
 725 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 726 if test "x$enable_polkit" != "xno"; then
 727         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 728         have_polkit=yes
 729 fi
 730 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 731
 732 # ------------------------------------------------------------------------------
 733 have_efi=no
 734 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 735 if test "x$enable_efi" != "xno"; then
 736         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 737         have_efi=yes
 738 fi
 739 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 740
 741 # ------------------------------------------------------------------------------
 742 AC_ARG_WITH(rc-local-script-path-start,
 743         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 744                 [Path to /etc/rc.local]),
 745         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 746         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 747
 748 AC_ARG_WITH(rc-local-script-path-stop,
 749         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 750                 [Path to /usr/sbin/halt.local]),
 751         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 752         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 753
 754 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 755 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 756
 757 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 758 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 759
 760 # ------------------------------------------------------------------------------
 761 AC_ARG_WITH(kbd-loadkeys,
 762         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 763                 [Path to loadkeys]),
 764         [KBD_LOADKEYS="$withval"],
 765         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 766
 767 AC_ARG_WITH(kbd-setfont,
 768         AS_HELP_STRING([--with-kbd-setfont=PATH],
 769                 [Path to setfont]),
 770         [KBD_SETFONT="$withval"],
 771         [KBD_SETFONT="/usr/bin/setfont"])
 772
 773 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 774 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 775
 776 AC_SUBST(KBD_LOADKEYS)
 777 AC_SUBST(KBD_SETFONT)
 778
 779 AC_ARG_WITH(telinit,
 780         AS_HELP_STRING([--with-telinit=PATH],
 781                 [Path to telinit]),
 782         [TELINIT="$withval"],
 783         [TELINIT="/lib/upstart/telinit"])
 784
 785 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 786
 787 AC_SUBST(TELINIT)
 788
 789 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 790
 791 # ------------------------------------------------------------------------------
 792 have_myhostname=no
 793 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 794 if test "x$enable_myhostname" != "xno"; then
 795         AC_HEADER_STDC
 796         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 797
 798         AC_C_CONST
 799         AC_TYPE_SIZE_T
 800         AC_HEADER_TIME
 801
 802         AC_FUNC_MALLOC
 803         AC_FUNC_SELECT_ARGTYPES
 804         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 805
 806         have_myhostname=yes
 807 fi
 808 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 809
 810 # ------------------------------------------------------------------------------
 811 AC_ARG_WITH(firmware-path,
 812        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 813           [Firmware search path (default="")]),
 814        [], [with_firmware_path=""])
 815 OLD_IFS=$IFS
 816 IFS=:
 817 for i in $with_firmware_path; do
 818        if test "x${FIRMWARE_PATH}" = "x"; then
 819               FIRMWARE_PATH="\\\"${i}/\\\""
 820        else
 821               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 822        fi
 823 done
 824 IFS=$OLD_IFS
 825 AC_SUBST(FIRMWARE_PATH)
 826 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 827 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 828
 829 # ------------------------------------------------------------------------------
 830 AC_ARG_ENABLE([gudev],
 831        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 832        [], [enable_gudev=yes])
 833 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 834 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 835 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 836
 837 # ------------------------------------------------------------------------------
 838 have_manpages=no
 839 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 840 AS_IF([test "x$enable_manpages" != xno], [
 841         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 842                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 843         ])
 844         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 845 ])
 846 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 847
 848 # ------------------------------------------------------------------------------
 849
 850 # Location of the init scripts as mandated by LSB
 851 SYSTEM_SYSVINIT_PATH=/etc/init.d
 852 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 853 M4_DEFINES=
 854
 855 AC_ARG_WITH([sysvinit-path],
 856         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 857                 [Specify the path to where the SysV init scripts are located])],
 858         [SYSTEM_SYSVINIT_PATH="$withval"],
 859         [])
 860
 861 AC_ARG_WITH([sysvrcnd-path],
 862         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 863                 [Specify the path to the base directory for the SysV rcN.d directories])],
 864         [SYSTEM_SYSVRCND_PATH="$withval"],
 865         [])
 866
 867 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 868         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 869         SYSTEM_SYSV_COMPAT="yes"
 870         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 871 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 872         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 873 else
 874         SYSTEM_SYSV_COMPAT="no"
 875 fi
 876
 877 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 878 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 879 AC_SUBST(M4_DEFINES)
 880
 881 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 882
 883 AC_ARG_WITH([tty-gid],
 884         [AS_HELP_STRING([--with-tty-gid=GID],
 885                 [Specify the numeric GID of the 'tty' group])],
 886         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 887         [])
 888
 889 AC_ARG_WITH([dbuspolicydir],
 890         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 891         [],
 892         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 893
 894 AC_ARG_WITH([dbussessionservicedir],
 895         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 896         [],
 897         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 898
 899 AC_ARG_WITH([dbussystemservicedir],
 900         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 901         [],
 902         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 903
 904 AC_ARG_WITH([dbusinterfacedir],
 905         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 906         [],
 907         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 908
 909 AC_ARG_WITH([bashcompletiondir],
 910         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 911         [],
 912         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 913                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 914         ] , [
 915                 with_bashcompletiondir=${datadir}/bash-completion/completions
 916         ])])
 917
 918 AC_ARG_WITH([zshcompletiondir],
 919         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 920         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 921
 922 AC_ARG_WITH([rootprefix],
 923         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 924         [], [with_rootprefix=${ac_default_prefix}])
 925
 926 AC_ARG_WITH([rootlibdir],
 927         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 928         [],
 929         [with_rootlibdir=${libdir}])
 930
 931 AC_ARG_WITH([pamlibdir],
 932         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 933         [],
 934         [with_pamlibdir=${with_rootlibdir}/security])
 935
 936 AC_ARG_ENABLE([split-usr],
 937         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 938         [],
 939         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 940                 enable_split_usr=yes
 941         ], [
 942                 enable_split_usr=no
 943         ])])
 944
 945 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 946         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 947 ])
 948
 949 # Work around intltoolize and gtk-doc problems in VPATH builds
 950 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 951                                        [Define to do gtk-doc tests])
 952 AS_IF([test "x$0" != "x./configure"], [
 953         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 954 ])
 955
 956 AC_ARG_ENABLE(tests,
 957        [AC_HELP_STRING([--disable-tests], [disable tests])],
 958        enable_tests=$enableval, enable_tests=yes)
 959 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 960
 961 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 962 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 963 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 964 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 965 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 966 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 967 AC_SUBST([pamlibdir], [$with_pamlibdir])
 968 AC_SUBST([rootprefix], [$with_rootprefix])
 969 AC_SUBST([rootlibdir], [$with_rootlibdir])
 970
 971 AC_CONFIG_FILES([
 972         Makefile po/Makefile.in
 973         docs/libudev/Makefile
 974         docs/libudev/version.xml
 975         docs/gudev/Makefile
 976         docs/gudev/version.xml
 977 ])
 978
 979 AC_OUTPUT
 980 AC_MSG_RESULT([
 981         $PACKAGE_NAME $VERSION
 982
 983         libcryptsetup:           ${have_libcryptsetup}
 984         tcpwrap:                 ${have_tcpwrap}
 985         PAM:                     ${have_pam}
 986         AUDIT:                   ${have_audit}
 987         IMA:                     ${have_ima}
 988         SELinux:                 ${have_selinux}
 989         SMACK:                   ${have_smack}
 990         XZ:                      ${have_xz}
 991         ACL:                     ${have_acl}
 992         XATTR:                   ${have_xattr}
 993         GCRYPT:                  ${have_gcrypt}
 994         QRENCODE:                ${have_qrencode}
 995         MICROHTTPD:              ${have_microhttpd}
 996         CHKCONFIG:               ${have_chkconfig}
 997         binfmt:                  ${have_binfmt}
 998         vconsole:                ${have_vconsole}
 999         readahead:               ${have_readahead}
1000         bootchart:               ${have_bootchart}
1001         quotacheck:              ${have_quotacheck}
1002         tmpfiles:                ${have_tmpfiles}
1003         randomseed:              ${have_randomseed}
1004         logind:                  ${have_logind}
1005         machined:                ${have_machined}
1006         hostnamed:               ${have_hostnamed}
1007         timedated:               ${have_timedated}
1008         localed:                 ${have_localed}
1009         coredump:                ${have_coredump}
1010         polkit:                  ${have_polkit}
1011         efi:                     ${have_efi}
1012         kmod:                    ${have_kmod}
1013         blkid:                   ${have_blkid}
1014         nss-myhostname:          ${have_myhostname}
1015         gudev:                   ${enable_gudev}
1016         gintrospection:          ${enable_introspection}
1017         Python:                  ${have_python}
1018         Python Headers:          ${have_python_devel}
1019         man pages:               ${have_manpages}
1020         gtk-doc:                 ${enable_gtk_doc}
1021         test coverage:           ${have_coverage}
1022         Split /usr:              ${enable_split_usr}
1023         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1024
1025         prefix:                  ${prefix}
1026         rootprefix:              ${with_rootprefix}
1027         sysconf dir:             ${sysconfdir}
1028         datarootdir:             ${datarootdir}
1029         includedir:              ${includedir}
1030         include_prefix:          ${INCLUDE_PREFIX}
1031         lib dir:                 ${libdir}
1032         rootlib dir:             ${with_rootlibdir}
1033         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1034         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1035         Build Python:            ${PYTHON}
1036         Installation Python:     ${PYTHON_BINARY}
1037         firmware path:           ${FIRMWARE_PATH}
1038         PAM modules dir:         ${with_pamlibdir}
1039         D-Bus policy dir:        ${with_dbuspolicydir}
1040         D-Bus session dir:       ${with_dbussessionservicedir}
1041         D-Bus system dir:        ${with_dbussystemservicedir}
1042         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1043         Bash completions dir:    ${with_bashcompletiondir}
1044         Zsh completions dir:     ${with_zshcompletiondir}
1045         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1046         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1047         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1048
1049         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1050         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1051         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1052         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
1053         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
1054 ])