configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [224],
  24         [http://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  43 AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  44 AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  45
  46 LT_PREREQ(2.2)
  47 LT_INIT([disable-static])
  48
  49 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  50 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  51
  52 SET_ARCH(X86_64, x86_64*)
  53 SET_ARCH(IA32, i*86*)
  54 SET_ARCH(MIPS, mips*)
  55 SET_ARCH(AARCH64, aarch64*)
  56
  57 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  58 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  59 AS_IF([test x"$intltool_found" != xyes],
  60       [AS_IF([test x"$enable_nls" = xyes],
  61              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  62              [AS_IF([test x"$enable_nls" != xno],
  63                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  64                      enable_nls=no])
  65              ])
  66       ])
  67
  68 AM_NLS
  69 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  70     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  71 IT_PROG_INTLTOOL([0.40.0])
  72 ])
  73
  74 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  75     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  76     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  77     AC_SUBST(INTLTOOL_POLICY_RULE)
  78 ])
  79
  80 GETTEXT_PACKAGE=systemd
  81 AC_SUBST(GETTEXT_PACKAGE)
  82 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  83
  84 AC_PROG_MKDIR_P
  85 AC_PROG_LN_S
  86 AC_PROG_SED
  87 AC_PROG_GREP
  88 AC_PROG_AWK
  89
  90 AC_PROG_CC_C99
  91
  92 AC_PATH_PROG([M4], [m4])
  93 AC_PATH_PROG([XSLTPROC], [xsltproc])
  94
  95 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  96 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
  97
  98 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap], [$PATH:/usr/sbin:/sbin])
  99
 100 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
 101
 102 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
 103
 104 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 105
 106 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 107
 108 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 109 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 110
 111 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 112
 113 M4_DEFINES=
 114
 115 AC_CHECK_TOOL(OBJCOPY, objcopy)
 116 AC_CHECK_TOOL(STRINGS, strings)
 117 AC_CHECK_TOOL(GPERF, gperf)
 118 if test -z "$GPERF" ; then
 119         AC_MSG_ERROR([*** gperf not found])
 120 fi
 121
 122 # ------------------------------------------------------------------------------
 123 address_sanitizer_cflags=
 124 address_sanitizer_cppflags=
 125 address_sanitizer_ldflags=
 126 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 127 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 128             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 129             AS_IF([test -z "$with_as_cflags"],
 130                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 131             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 132             address_sanitizer_cppflags="-DVALGRIND=1"
 133             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 134       ])
 135
 136 undefined_sanitizer_cflags=
 137 undefined_sanitizer_cppflags=
 138 undefined_sanitizer_ldflags=
 139 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 140 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 141             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 142             AS_IF([test -z "$with_us_cflags"],
 143                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 144             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 145             undefined_sanitizer_cppflags="-DVALGRIND=1"
 146             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 147       ])
 148
 149 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 150 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 151 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 152
 153 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 154         -pipe \
 155         -Wall \
 156         -Wextra \
 157         -Wundef \
 158         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 159         -Wlogical-op \
 160         -Wmissing-include-dirs \
 161         -Wold-style-definition \
 162         -Wpointer-arith \
 163         -Winit-self \
 164         -Wdeclaration-after-statement \
 165         -Wfloat-equal \
 166         -Wsuggest-attribute=noreturn \
 167         -Werror=missing-prototypes \
 168         -Werror=implicit-function-declaration \
 169         -Werror=missing-declarations \
 170         -Werror=return-type \
 171         -Werror=shadow \
 172         -Wstrict-prototypes \
 173         -Wredundant-decls \
 174         -Wmissing-noreturn \
 175         -Wshadow \
 176         -Wendif-labels \
 177         -Wstrict-aliasing=2 \
 178         -Wwrite-strings \
 179         -Wno-unused-parameter \
 180         -Wno-missing-field-initializers \
 181         -Wno-unused-result \
 182         -Wno-format-signedness \
 183         -Werror=overflow \
 184         -Wdate-time \
 185         -Wnested-externs \
 186         -ffast-math \
 187         -fno-common \
 188         -fdiagnostics-show-option \
 189         -fno-strict-aliasing \
 190         -fvisibility=hidden \
 191         -fstack-protector \
 192         -fstack-protector-strong \
 193         -fPIE \
 194         --param=ssp-buffer-size=4])
 195
 196 AS_CASE([$CC], [*clang*],
 197         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 198                -Wno-typedef-redefinition \
 199                -Wno-gnu-variable-sized-type-not-at-end \
 200         ])])
 201
 202 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 203         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 204                -flto])],
 205         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 206 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 207
 208 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 209         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 210                -Wp,-D_FORTIFY_SOURCE=2])],
 211         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 212 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 213
 214 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 215         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 216                -Wl,--gc-sections])],
 217         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 218 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 219
 220 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 221         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 222                -ffunction-sections -fdata-sections])],
 223         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 224 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 225
 226 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 227         -Wl,--as-needed \
 228         -Wl,--no-undefined \
 229         -Wl,-z,relro \
 230         -Wl,-z,now \
 231         -pie \
 232         -Wl,-fuse-ld=gold])
 233 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 234
 235 AC_CHECK_SIZEOF(pid_t)
 236 AC_CHECK_SIZEOF(uid_t)
 237 AC_CHECK_SIZEOF(gid_t)
 238 AC_CHECK_SIZEOF(time_t)
 239 AC_CHECK_SIZEOF(dev_t)
 240 AC_CHECK_SIZEOF(rlim_t,,[
 241        #include <sys/time.h>
 242        #include <sys/resource.h>
 243 ])
 244
 245 # ------------------------------------------------------------------------------
 246 # we use python to build the man page index
 247 have_python=no
 248 AC_ARG_WITH([python],
 249         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 250
 251 have_lxml=no
 252 AS_IF([test "x$with_python" != "xno"], [
 253         AM_PATH_PYTHON(,, [:])
 254         AS_IF([test "x$PYTHON" != "x:"], [
 255                 AC_MSG_CHECKING([for python lxml module])
 256                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 257                 AC_MSG_RESULT([$have_lxml])
 258                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 259                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 260         ])
 261 ])
 262 AS_IF([test "$have_python" != "yes"], [
 263       AS_IF([test "$with_python" = "yes"],
 264             [AC_MSG_ERROR([*** python support requested but python support not found])])
 265       AS_IF([test "$with_python" != "no"],
 266             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 267 ])
 268 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 269
 270 # ------------------------------------------------------------------------------
 271
 272 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 273 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 274 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 275 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 276
 277 # unconditionally pull-in librt with old glibc versions
 278 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 279
 280 save_LIBS="$LIBS"
 281 LIBS=
 282 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 283 CAP_LIBS="$LIBS"
 284 AC_SUBST(CAP_LIBS)
 285
 286 AC_CHECK_FUNCS([memfd_create])
 287 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 288 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 289                [], [], [[
 290 #include <sys/types.h>
 291 #include <unistd.h>
 292 #include <sys/mount.h>
 293 #include <fcntl.h>
 294 #include <sched.h>
 295 #include <linux/loop.h>
 296 #include <linux/random.h>
 297 ]])
 298
 299 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 300                 IFLA_MACVLAN_FLAGS,
 301                 IFLA_IPVLAN_MODE,
 302                 IFLA_VTI_REMOTE,
 303                 IFLA_PHYS_PORT_ID,
 304                 IFLA_BOND_AD_INFO,
 305                 IFLA_VLAN_PROTOCOL,
 306                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 307                 IFLA_IPTUN_ENCAP_DPORT,
 308                 IFLA_GRE_ENCAP_DPORT,
 309                 IFLA_BRIDGE_VLAN_INFO,
 310                 IFLA_BRPORT_LEARNING_SYNC,
 311                 NDA_IFINDEX,
 312                 IFA_FLAGS],
 313 [], [], [[
 314 #include <inttypes.h>
 315 #include <netinet/in.h>
 316 #include <netinet/ether.h>
 317 #include <linux/rtnetlink.h>
 318 #include <net/if.h>
 319 #include <linux/ip.h>
 320 #include <linux/if_tunnel.h>
 321 #include <linux/if_link.h>
 322 #include <linux/if_bridge.h>
 323 #include <linux/if_addr.h>
 324 #include <linux/neighbour.h>
 325 ]])
 326
 327 # This makes sure pkg.m4 is available.
 328 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 329
 330 # ------------------------------------------------------------------------------
 331 have_dbus=no
 332 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 333 AS_IF([test "x$enable_dbus" != "xno"], [
 334         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 335                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 336                 [have_dbus=no])
 337         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 338                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 339 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 340
 341 # ------------------------------------------------------------------------------
 342 have_utmp=yes
 343 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 344         AS_CASE("x${enableval}",
 345                 [xyes], [have_utmp=yes],
 346                 [xno],  [have_utmp=no],
 347                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 348 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 349 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 350
 351 # ------------------------------------------------------------------------------
 352 have_compat_libs=no
 353 AC_ARG_ENABLE([compat_libs], AS_HELP_STRING([--enable-compat-libs],[Enable creation of compatibility libraries]),
 354                 [case "${enableval}" in
 355                         yes) have_compat_libs=yes ;;
 356                         no) have_compat_libs=no ;;
 357                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libs) ;;
 358                 esac],
 359                 [have_compat_libs=no])
 360 AM_CONDITIONAL([ENABLE_COMPAT_LIBS], [test "$have_compat_libs" = "yes"])
 361
 362 # ------------------------------------------------------------------------------
 363 have_coverage=no
 364 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 365 if test "x$enable_coverage" = "xyes" ; then
 366         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 367         if test "x$lcov_found" = xno ; then
 368                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 369         else
 370                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 371                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 372                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 373                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 374                 else
 375                         have_coverage=yes
 376                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 377                         -fprofile-arcs \
 378                         -ftest-coverage])
 379                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 380                 fi
 381         fi
 382 fi
 383 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 384
 385 # ------------------------------------------------------------------------------
 386 have_kmod=no
 387 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 388 if test "x$enable_kmod" != "xno"; then
 389         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 390         if test "x$have_kmod" = "xyes"; then
 391                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 392                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 393                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 394         fi
 395         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 396                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 397         fi
 398 fi
 399 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 400
 401 # ------------------------------------------------------------------------------
 402 have_xkbcommon=no
 403 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 404 if test "x$enable_xkbcommon" != "xno"; then
 405         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 406                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 407         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 408                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 409         fi
 410 fi
 411 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 412
 413 # ------------------------------------------------------------------------------
 414 have_blkid=no
 415 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 416 if test "x$enable_blkid" != "xno"; then
 417         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 418                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 419         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 420                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 421         fi
 422 fi
 423 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 424
 425 # ------------------------------------------------------------------------------
 426 have_libmount=no
 427 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.20 ],
 428         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 429 if test "x$have_libmount" = xno; then
 430         AC_MSG_ERROR([*** libmount support required but libraries not found])
 431 fi
 432 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 433
 434 # ------------------------------------------------------------------------------
 435 have_seccomp=no
 436 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 437 if test "x$enable_seccomp" != "xno"; then
 438         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 439                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 440                 have_seccomp=yes
 441                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 442                [have_seccomp=no])
 443         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 444                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 445         fi
 446 fi
 447 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 448
 449 # ------------------------------------------------------------------------------
 450 have_ima=yes
 451 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 452                 [case "${enableval}" in
 453                         yes) have_ima=yes ;;
 454                         no) have_ima=no ;;
 455                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 456                 esac],
 457                 [have_ima=yes])
 458
 459 if test "x${have_ima}" != xno ; then
 460         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 461 fi
 462
 463 # ------------------------------------------------------------------------------
 464 have_selinux=no
 465 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 466 if test "x$enable_selinux" != "xno"; then
 467         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 468                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 469                  have_selinux=yes
 470                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 471                 [have_selinux=no])
 472         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 473                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 474         fi
 475 fi
 476 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 477
 478 have_apparmor=no
 479 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 480 if test "x$enable_apparmor" != "xno"; then
 481         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 482                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 483                  have_apparmor=yes
 484                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 485                 [have_apparmor=no])
 486         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 487                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 488         fi
 489 fi
 490 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 491
 492
 493 AC_ARG_WITH(debug-shell,
 494         AS_HELP_STRING([--with-debug-shell=PATH],
 495                 [Path to debug shell binary]),
 496         [SUSHELL="$withval"],[
 497         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 498
 499 AC_SUBST(SUSHELL)
 500
 501 AC_ARG_WITH([debug-tty],
 502         AS_HELP_STRING([--with-debug-tty=PATH],
 503                 [Specify the tty device for debug shell]),
 504         [DEBUGTTY="$withval"],
 505         [DEBUGTTY=/dev/tty9])
 506
 507 AC_SUBST(DEBUGTTY)
 508
 509 AC_ARG_WITH([certificate-root],
 510         AS_HELP_STRING([--with-certificate-root=PATH],
 511                 [Specify the prefix for TLS certificates [/etc/ssl]]),
 512         [CERTIFICATEROOT="$withval"],
 513         [CERTIFICATEROOT="/etc/ssl"])
 514
 515 AC_SUBST(CERTIFICATEROOT)
 516
 517 # ------------------------------------------------------------------------------
 518 have_xz=no
 519 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 520 if test "x$enable_xz" != "xno"; then
 521         PKG_CHECK_MODULES(XZ, [ liblzma ],
 522                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 523         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 524                 AC_MSG_ERROR([*** XZ support requested but libraries not found])
 525         fi
 526 fi
 527 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 528
 529 # ------------------------------------------------------------------------------
 530 have_zlib=no
 531 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [Disable optional ZLIB support]))
 532 if test "x$enable_zlib" != "xno"; then
 533         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 534                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available]) have_zlib=yes], have_zlib=no)
 535         if test "x$have_zlib" = xno -a "x$enable_zlib" = xyes; then
 536                 AC_MSG_ERROR([*** ZLIB support requested but libraries not found])
 537         fi
 538 fi
 539 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 540
 541 # ------------------------------------------------------------------------------
 542 have_bzip2=no
 543 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--enable-bzip2], [Disable optional BZIP2 support]))
 544 AS_IF([test "x$enable_bzip2" != "xno"], [
 545         AC_CHECK_HEADERS(bzlib.h,
 546                 [AC_DEFINE(HAVE_BZIP2, 1, [Define in BZIP2 is available])
 547                  have_bzip2=yes],
 548                 [AS_IF([test "x$have_bzip2" = xyes], [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])
 549         ])
 550 ])
 551 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 552
 553 # ------------------------------------------------------------------------------
 554 have_lz4=no
 555 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--enable-lz4], [Enable optional LZ4 support]))
 556 AS_IF([test "x$enable_lz4" = "xyes"], [
 557         AC_CHECK_HEADERS(lz4.h,
 558                [AC_DEFINE(HAVE_LZ4, 1, [Define in LZ4 is available]) have_lz4=yes],
 559                [AC_MSG_ERROR([*** LZ4 support requested but headers not found])])
 560 ])
 561 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 562
 563 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 564
 565 # ------------------------------------------------------------------------------
 566 AC_ARG_ENABLE([pam],
 567         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 568                 [case "${enableval}" in
 569                         yes) have_pam=yes ;;
 570                         no) have_pam=no ;;
 571                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 572                 esac],
 573                 [have_pam=auto])
 574
 575 if test "x${have_pam}" != xno ; then
 576         AC_CHECK_HEADERS(
 577                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 578                 [have_pam=yes],
 579                 [if test "x$have_pam" = xyes ; then
 580                         AC_MSG_ERROR([*** PAM headers not found.])
 581                 fi])
 582
 583         AC_CHECK_LIB(
 584                 [pam],
 585                 [pam_syslog],
 586                 [have_pam=yes],
 587                 [if test "x$have_pam" = xyes ; then
 588                         AC_MSG_ERROR([*** libpam not found.])
 589                 fi])
 590
 591         if test "x$have_pam" = xyes ; then
 592                 PAM_LIBS="-lpam -lpam_misc"
 593                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 594                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 595         else
 596                 have_pam=no
 597         fi
 598 else
 599         PAM_LIBS=
 600 fi
 601 AC_SUBST(PAM_LIBS)
 602 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 603
 604 # ------------------------------------------------------------------------------
 605 AC_ARG_ENABLE([acl],
 606         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 607                 [case "${enableval}" in
 608                         yes) have_acl=yes ;;
 609                         no) have_acl=no ;;
 610                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 611                 esac],
 612                 [have_acl=auto])
 613
 614 if test "x${have_acl}" != xno ; then
 615         AC_CHECK_HEADERS(
 616                 [sys/acl.h acl/libacl.h],
 617                 [have_acl=yes],
 618                 [if test "x$have_acl" = xyes ; then
 619                         AC_MSG_ERROR([*** ACL headers not found.])
 620                 fi])
 621
 622         AC_CHECK_LIB(
 623                 [acl],
 624                 [acl_get_file],
 625                 [have_acl=yes],
 626                 [if test "x$have_acl" = xyes ; then
 627                         AC_MSG_ERROR([*** libacl not found.])
 628                 fi])
 629
 630         if test "x$have_acl" = xyes ; then
 631                 ACL_LIBS="-lacl"
 632                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 633                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 634         else
 635                 have_acl=no
 636         fi
 637 else
 638         ACL_LIBS=
 639 fi
 640 AC_SUBST(ACL_LIBS)
 641 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 642
 643 # ------------------------------------------------------------------------------
 644 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 645                 [case "${enableval}" in
 646                         yes) have_smack=yes ;;
 647                         no) have_smack=no ;;
 648                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 649                 esac],
 650                 [have_smack=auto])
 651
 652 if test "x${have_smack}" = xauto; then
 653         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 654         have_smack=yes
 655 fi
 656
 657 AC_ARG_WITH(smack-run-label,
 658 AS_HELP_STRING([--with-smack-run-label=STRING],
 659         [run systemd --system itself with a specific SMACK label]),
 660         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label])],
 661         [])
 662
 663 AC_ARG_WITH(smack-default-process-label,
 664 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 665         [default SMACK label for executed processes]),
 666         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 667         [])
 668
 669 if test "x${have_smack}" = xyes ; then
 670         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 671 fi
 672
 673 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 674
 675 # ------------------------------------------------------------------------------
 676 AC_ARG_ENABLE([gcrypt],
 677         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 678                 [case "${enableval}" in
 679                         yes) have_gcrypt=yes ;;
 680                         no) have_gcrypt=no ;;
 681                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 682                 esac],
 683                 [have_gcrypt=auto])
 684
 685 if test "x${have_gcrypt}" != xno ; then
 686         AM_PATH_LIBGCRYPT(
 687                 [1.4.5],
 688                 [have_gcrypt=yes],
 689                 [if test "x$have_gcrypt" = xyes ; then
 690                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 691                 fi])
 692
 693         if test "x$have_gcrypt" = xyes ; then
 694                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 695                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 696                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 697         else
 698                 have_gcrypt=no
 699         fi
 700 else
 701         GCRYPT_LIBS=
 702         GCRYPT_CFLAGS=
 703 fi
 704 AC_SUBST(GCRYPT_LIBS)
 705 AC_SUBST(GCRYPT_CFLAGS)
 706 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 707
 708 # ------------------------------------------------------------------------------
 709 AC_ARG_ENABLE([audit],
 710         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 711                 [case "${enableval}" in
 712                         yes) have_audit=yes ;;
 713                         no) have_audit=no ;;
 714                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 715                 esac],
 716                 [have_audit=auto])
 717
 718 if test "x${have_audit}" != xno ; then
 719         AC_CHECK_HEADERS(
 720                 [libaudit.h],
 721                 [have_audit=yes],
 722                 [if test "x$have_audit" = xyes ; then
 723                         AC_MSG_ERROR([*** AUDIT headers not found.])
 724                 fi])
 725
 726         AC_CHECK_LIB(
 727                 [audit],
 728                 [audit_open],
 729                 [have_audit=yes],
 730                 [if test "x$have_audit" = xyes ; then
 731                         AC_MSG_ERROR([*** libaudit not found.])
 732                 fi])
 733
 734         if test "x$have_audit" = xyes ; then
 735                 AUDIT_LIBS="-laudit"
 736                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 737         else
 738                 have_audit=no
 739         fi
 740 else
 741         AUDIT_LIBS=
 742 fi
 743 AC_SUBST(AUDIT_LIBS)
 744 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 745
 746 # ------------------------------------------------------------------------------
 747 AC_ARG_ENABLE([elfutils],
 748         AS_HELP_STRING([--disable-elfutils],[Disable optional ELFUTILS support]),
 749                 [case "${enableval}" in
 750                         yes) have_elfutils=yes ;;
 751                         no) have_elfutils=no ;;
 752                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 753                 esac],
 754                 [have_elfutils=auto])
 755
 756 if test "x${have_elfutils}" != xno ; then
 757         AC_CHECK_HEADERS(
 758                 [elfutils/libdwfl.h],
 759                 [],
 760                 [if test "x$have_elfutils" = xyes ; then
 761                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 762                 fi])
 763
 764         AC_CHECK_LIB(
 765                 [dw],
 766                 [dwfl_begin],
 767                 [],
 768                 [if test "x$have_elfutils" = xyes ; then
 769                         AC_MSG_ERROR([*** ELFUTILS libs not found.])
 770                 fi])
 771
 772         AC_CHECK_LIB(
 773                 [dw],
 774                 [dwfl_core_file_attach],
 775                 [have_elfutils=yes],
 776                 [if test "x$have_elfutils" = xyes ; then
 777                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 778                 fi])
 779
 780         if test "x$have_elfutils" = xyes ; then
 781                 ELFUTILS_LIBS="-lelf -ldw"
 782                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 783         else
 784                 have_elfutils=no
 785         fi
 786 else
 787         ELFUTILS_LIBS=
 788 fi
 789 AC_SUBST(ELFUTILS_LIBS)
 790 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 791
 792 # ------------------------------------------------------------------------------
 793 have_libcryptsetup=no
 794 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 795 if test "x$enable_libcryptsetup" != "xno"; then
 796         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 797                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 798         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 799                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 800         fi
 801 fi
 802 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 803
 804 # ------------------------------------------------------------------------------
 805 have_qrencode=no
 806 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 807 if test "x$enable_qrencode" != "xno"; then
 808         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 809                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 810         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 811                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 812         fi
 813 fi
 814 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 815
 816 # ------------------------------------------------------------------------------
 817 have_microhttpd=no
 818 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 819 if test "x$enable_microhttpd" != "xno"; then
 820         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 821                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 822         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 823                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 824         fi
 825 fi
 826 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 827
 828 # ------------------------------------------------------------------------------
 829 have_gnutls=no
 830 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 831 if test "x$enable_gnutls" != "xno"; then
 832         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 833                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 834         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 835                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 836         fi
 837 fi
 838 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 839
 840 # ------------------------------------------------------------------------------
 841 have_libcurl=no
 842 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
 843 if test "x$enable_libcurl" != "xno"; then
 844         PKG_CHECK_MODULES(LIBCURL, [libcurl],
 845                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available]) have_libcurl=yes], have_libcurl=no)
 846         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
 847                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
 848         fi
 849 fi
 850 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 851
 852 # ------------------------------------------------------------------------------
 853 have_libidn=no
 854 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [Disable optional LIBIDN support]))
 855 if test "x$enable_libidn" != "xno"; then
 856         PKG_CHECK_MODULES(LIBIDN, [libidn],
 857                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
 858                 have_libidn=yes
 859                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
 860                [have_libidn=no])
 861         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
 862                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
 863         fi
 864 fi
 865 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
 866
 867 # ------------------------------------------------------------------------------
 868 have_libiptc=no
 869 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [Disable optional LIBIPTC support]))
 870 if test "x$enable_libiptc" != "xno"; then
 871         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
 872                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
 873                 have_libiptc=yes
 874                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
 875                [have_libiptc=no])
 876         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
 877                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
 878         fi
 879 fi
 880 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
 881
 882 # ------------------------------------------------------------------------------
 883 have_binfmt=no
 884 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 885 if test "x$enable_binfmt" != "xno"; then
 886         have_binfmt=yes
 887 fi
 888 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 889
 890 # ------------------------------------------------------------------------------
 891 have_vconsole=no
 892 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 893 if test "x$enable_vconsole" != "xno"; then
 894         have_vconsole=yes
 895 fi
 896 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 897
 898 # ------------------------------------------------------------------------------
 899 have_bootchart=no
 900 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 901 if test "x$enable_bootchart" != "xno"; then
 902         have_bootchart=yes
 903 fi
 904 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 905
 906 # ------------------------------------------------------------------------------
 907 have_quotacheck=no
 908 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 909 if test "x$enable_quotacheck" != "xno"; then
 910         have_quotacheck=yes
 911 fi
 912 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 913
 914 # ------------------------------------------------------------------------------
 915 have_tmpfiles=no
 916 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 917 if test "x$enable_tmpfiles" != "xno"; then
 918         have_tmpfiles=yes
 919 fi
 920 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 921
 922 # ------------------------------------------------------------------------------
 923 have_sysusers=no
 924 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
 925 if test "x$enable_sysusers" != "xno"; then
 926         have_sysusers=yes
 927 fi
 928 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
 929
 930 # ------------------------------------------------------------------------------
 931 have_firstboot=no
 932 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
 933 if test "x$enable_firstboot" != "xno"; then
 934         have_firstboot=yes
 935 fi
 936 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
 937
 938 # ------------------------------------------------------------------------------
 939 have_randomseed=no
 940 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 941 if test "x$enable_randomseed" != "xno"; then
 942         have_randomseed=yes
 943 fi
 944 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 945
 946 # ------------------------------------------------------------------------------
 947 have_backlight=no
 948 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
 949 if test "x$enable_backlight" != "xno"; then
 950         have_backlight=yes
 951 fi
 952 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
 953
 954 # ------------------------------------------------------------------------------
 955 have_rfkill=no
 956 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
 957 if test "x$enable_rfkill" != "xno"; then
 958         have_rfkill=yes
 959 fi
 960 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
 961
 962 # ------------------------------------------------------------------------------
 963 have_logind=no
 964 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 965 if test "x$enable_logind" != "xno"; then
 966         have_logind=yes
 967 fi
 968 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 969 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 970
 971 # ------------------------------------------------------------------------------
 972 have_machined=no
 973 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 974 if test "x$enable_machined" != "xno"; then
 975         have_machined=yes
 976 fi
 977 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 978 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 979
 980 # ------------------------------------------------------------------------------
 981 have_importd=no
 982 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
 983 if test "x$enable_importd" != "xno"; then
 984         have_importd=yes
 985 fi
 986 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
 987 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
 988
 989 # ------------------------------------------------------------------------------
 990 have_hostnamed=no
 991 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 992 if test "x$enable_hostnamed" != "xno"; then
 993         have_hostnamed=yes
 994 fi
 995 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 996
 997 # ------------------------------------------------------------------------------
 998 have_timedated=no
 999 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1000 if test "x$enable_timedated" != "xno"; then
1001         have_timedated=yes
1002 fi
1003 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1004
1005 # ------------------------------------------------------------------------------
1006 have_timesyncd=no
1007 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1008 if test "x$enable_timesyncd" != "xno"; then
1009         have_timesyncd=yes
1010         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1011 fi
1012 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1013
1014 AC_ARG_WITH(ntp-servers,
1015         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1016                 [Space-separated list of default NTP servers]),
1017         [NTP_SERVERS="$withval"],
1018         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"
1019         AC_MSG_WARN([*** Using Google NTP servers.
1020                         Do not ship OSes or devices with these default settings.
1021                         See DISTRO_PORTING for details!])])
1022
1023 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1024 AC_SUBST(NTP_SERVERS)
1025
1026 AC_ARG_WITH(time-epoch,
1027         AS_HELP_STRING([--with-time-epoch=SECONDS],
1028                 [Time epoch for time clients]),
1029         [TIME_EPOCH="$withval"],
1030         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1031
1032 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1033
1034 # ------------------------------------------------------------------------------
1035 AC_ARG_WITH(system-uid-max,
1036         AS_HELP_STRING([--with-system-uid-max=UID]
1037                 [Maximum UID for system users]),
1038         [SYSTEM_UID_MAX="$withval"],
1039         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1040
1041 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1042 AC_SUBST(SYSTEM_UID_MAX)
1043
1044 # ------------------------------------------------------------------------------
1045 AC_ARG_WITH(system-gid-max,
1046         AS_HELP_STRING([--with-system-gid-max=GID]
1047                 [Maximum GID for system groups]),
1048         [SYSTEM_GID_MAX="$withval"],
1049         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1050
1051 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1052 AC_SUBST(SYSTEM_GID_MAX)
1053
1054 # ------------------------------------------------------------------------------
1055 have_localed=no
1056 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1057 if test "x$enable_localed" != "xno"; then
1058         have_localed=yes
1059 fi
1060 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1061
1062 # ------------------------------------------------------------------------------
1063 have_coredump=no
1064 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1065 if test "x$enable_coredump" != "xno"; then
1066         have_coredump=yes
1067 fi
1068 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1069
1070 # ------------------------------------------------------------------------------
1071 have_polkit=no
1072 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1073 if test "x$enable_polkit" != "xno"; then
1074         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1075         have_polkit=yes
1076 fi
1077 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1078
1079 # ------------------------------------------------------------------------------
1080 have_resolved=no
1081 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1082 if test "x$enable_resolved" != "xno"; then
1083         have_resolved=yes
1084         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1085 fi
1086 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1087
1088 AC_ARG_WITH(dns-servers,
1089         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1090                 [Space-separated list of default DNS servers]),
1091         [DNS_SERVERS="$withval"],
1092         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1093
1094 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1095 AC_SUBST(DNS_SERVERS)
1096
1097 # ------------------------------------------------------------------------------
1098 have_networkd=no
1099 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1100 AS_IF([test "x$enable_networkd" != "xno"], [
1101         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1102         have_networkd=yes
1103         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1104 ])
1105 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1106
1107 # ------------------------------------------------------------------------------
1108 have_efi=no
1109 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
1110 if test "x$enable_efi" != "xno"; then
1111         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
1112         have_efi=yes
1113 fi
1114 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1115
1116 # ------------------------------------------------------------------------------
1117 AC_CHECK_TOOL(EFI_CC, gcc)
1118
1119 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1120
1121 AM_COND_IF(ARCH_IA32, [
1122         EFI_ARCH=ia32
1123         EFI_MACHINE_TYPE_NAME=ia32])
1124
1125 AM_COND_IF(ARCH_X86_64, [
1126         EFI_MACHINE_TYPE_NAME=x64])
1127
1128 AM_COND_IF(ARCH_AARCH64, [
1129         EFI_MACHINE_TYPE_NAME=aa64])
1130
1131 AC_SUBST([EFI_ARCH])
1132 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1133
1134 have_gnuefi=no
1135 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [Disable optional gnuefi support]))
1136 AS_IF([test "x$enable_gnuefi" != "xno"], [
1137         AC_CHECK_HEADERS(efi/${EFI_ARCH}/efibind.h,
1138                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1139                  have_gnuefi=yes],
1140                 [AS_IF([test "x$enable_gnuefi" = xyes],
1141                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1142         ])
1143
1144         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1145
1146         EFI_LIB_DIR="$efiroot"
1147         AC_ARG_WITH(efi-libdir,
1148                 AS_HELP_STRING([--with-efi-libdir=PATH], [Path to EFI lib directory]),
1149                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1150         )
1151         AC_SUBST([EFI_LIB_DIR])
1152
1153         have_efi_lds=no
1154         AC_ARG_WITH(efi-ldsdir,
1155                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [Path to EFI lds directory]),
1156                 [EFI_LDS_DIR="$withval" && AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1157                         [have_efi_lds=yes])],
1158                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1159                         [AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1160                                        [have_efi_lds=yes && break])])])
1161         AS_IF([test "x$have_efi_lds" = xyes],
1162               [AC_SUBST([EFI_LDS_DIR])],
1163               [AS_IF([test "x$enable_gnuefi" = xyes],
1164                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1165                      [have_gnuefi=no])])
1166
1167         AC_ARG_WITH(efi-includedir,
1168                 AS_HELP_STRING([--with-efi-includedir=PATH], [Path to EFI include directory]),
1169                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1170         )
1171         AC_SUBST([EFI_INC_DIR])
1172 ])
1173 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1174
1175 # ------------------------------------------------------------------------------
1176 have_kdbus=no
1177 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
1178 if test "x$enable_kdbus" != "xno"; then
1179         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
1180         have_kdbus=yes
1181         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
1182 fi
1183 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
1184
1185 # ------------------------------------------------------------------------------
1186 AC_ARG_WITH(rc-local-script-path-start,
1187         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1188                 [Path to /etc/rc.local]),
1189         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1190         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1191
1192 AC_ARG_WITH(rc-local-script-path-stop,
1193         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1194                 [Path to /usr/sbin/halt.local]),
1195         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1196         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1197
1198 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1199 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1200
1201 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1202 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1203
1204 # ------------------------------------------------------------------------------
1205 AC_ARG_WITH(kbd-loadkeys,
1206         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1207                 [Path to loadkeys]),
1208         [KBD_LOADKEYS="$withval"],
1209         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1210
1211 AC_ARG_WITH(kbd-setfont,
1212         AS_HELP_STRING([--with-kbd-setfont=PATH],
1213                 [Path to setfont]),
1214         [KBD_SETFONT="$withval"],
1215         [KBD_SETFONT="/usr/bin/setfont"])
1216
1217 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1218 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1219
1220 AC_SUBST(KBD_LOADKEYS)
1221 AC_SUBST(KBD_SETFONT)
1222
1223 AC_ARG_WITH(telinit,
1224         AS_HELP_STRING([--with-telinit=PATH],
1225                 [Path to telinit]),
1226         [TELINIT="$withval"],
1227         [TELINIT="/lib/sysvinit/telinit"])
1228
1229 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1230
1231 AC_SUBST(TELINIT)
1232
1233 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1234
1235 # ------------------------------------------------------------------------------
1236 have_myhostname=no
1237 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1238 if test "x$enable_myhostname" != "xno"; then
1239         AC_HEADER_STDC
1240         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1241
1242         AC_C_CONST
1243         AC_TYPE_SIZE_T
1244         AC_HEADER_TIME
1245
1246         AC_FUNC_MALLOC
1247         AC_FUNC_SELECT_ARGTYPES
1248         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1249
1250         have_myhostname=yes
1251 fi
1252 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1253
1254 # ------------------------------------------------------------------------------
1255 AC_ARG_ENABLE(hwdb, [AC_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1256        enable_hwdb=$enableval, enable_hwdb=yes)
1257 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1258
1259 # ------------------------------------------------------------------------------
1260 have_manpages=no
1261 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1262 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
1263 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1264
1265 # ------------------------------------------------------------------------------
1266 AC_ARG_ENABLE(hibernate,
1267        [AC_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1268        enable_hibernate=$enableval, enable_hibernate=yes)
1269 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1270
1271 # ------------------------------------------------------------------------------
1272 AC_ARG_ENABLE(ldconfig,
1273        [AC_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1274        enable_ldconfig=$enableval, enable_ldconfig=yes)
1275 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1276
1277 # ------------------------------------------------------------------------------
1278 # Location of the init scripts as mandated by LSB
1279 SYSTEM_SYSVINIT_PATH=/etc/init.d
1280 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1281
1282 AC_ARG_WITH([sysvinit-path],
1283         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1284                 [Specify the path to where the SysV init scripts are located])],
1285         [SYSTEM_SYSVINIT_PATH="$withval"],
1286         [])
1287
1288 AC_ARG_WITH([sysvrcnd-path],
1289         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1290                 [Specify the path to the base directory for the SysV rcN.d directories])],
1291         [SYSTEM_SYSVRCND_PATH="$withval"],
1292         [])
1293
1294 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1295         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1296         SYSTEM_SYSV_COMPAT="yes"
1297         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1298 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1299         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1300 else
1301         SYSTEM_SYSV_COMPAT="no"
1302 fi
1303
1304 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1305 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1306 AC_SUBST(M4_DEFINES)
1307
1308 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1309
1310 AC_ARG_WITH([tty-gid],
1311         [AS_HELP_STRING([--with-tty-gid=GID],
1312                 [Specify the numeric GID of the 'tty' group])],
1313         [TTY_GID="$withval"],
1314         [TTY_GID="5"])
1315
1316 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1317 AC_SUBST(TTY_GID)
1318
1319 AC_ARG_WITH([dbuspolicydir],
1320         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1321         [],
1322         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
1323 AX_NORMALIZE_PATH([with_dbuspolicydir])
1324
1325 AC_ARG_WITH([dbussessionservicedir],
1326         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1327         [],
1328         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1329 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1330
1331 AC_ARG_WITH([dbussystemservicedir],
1332         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1333         [],
1334         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1335 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1336
1337 AC_ARG_WITH([bashcompletiondir],
1338         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
1339         [],
1340         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1341                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1342         ] , [
1343                 with_bashcompletiondir=${datadir}/bash-completion/completions
1344         ])])
1345 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
1346 AX_NORMALIZE_PATH([with_bashcompletiondir])
1347
1348 AC_ARG_WITH([zshcompletiondir],
1349         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
1350         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1351 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
1352 AX_NORMALIZE_PATH([with_zshcompletiondir])
1353
1354 AC_ARG_WITH([rootprefix],
1355         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1356         [], [with_rootprefix=${ac_default_prefix}])
1357 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1358 # defaults those to ".", solve that here for now until we can find a suitable
1359 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1360 # See: https://github.com/systemd/systemd/issues/54
1361 if test "x${with_rootprefix}" = "x"; then
1362         with_rootprefix="/"
1363 fi
1364 AX_NORMALIZE_PATH([with_rootprefix])
1365
1366 AC_ARG_WITH([rootlibdir],
1367         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
1368         [],
1369         [with_rootlibdir=${libdir}])
1370 AX_NORMALIZE_PATH([with_rootlibdir])
1371
1372 AC_ARG_WITH([pamlibdir],
1373         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
1374         [],
1375         [with_pamlibdir=${with_rootlibdir}/security])
1376 AX_NORMALIZE_PATH([with_pamlibdir])
1377
1378 AC_ARG_WITH([pamconfdir],
1379         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
1380         [],
1381         [with_pamconfdir=${sysconfdir}/pam.d])
1382 AX_NORMALIZE_PATH([with_pamconfdir])
1383
1384 AC_ARG_ENABLE([split-usr],
1385         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
1386         [],
1387         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1388                 enable_split_usr=yes
1389         ], [
1390                 enable_split_usr=no
1391         ])])
1392
1393 AC_ARG_WITH([dkr-index-url],
1394         [AS_HELP_STRING([--dkr-index-url=URL], [Specify the default index URL to use for image downloads])],
1395         [DEFAULT_DKR_INDEX_URL="\"$withval\""],
1396         [DEFAULT_DKR_INDEX_URL="NULL"])
1397
1398 AC_DEFINE_UNQUOTED(DEFAULT_DKR_INDEX_URL, [$DEFAULT_DKR_INDEX_URL], [Default index URL to use for image downloads])
1399 AC_SUBST(DEFAULT_DKR_INDEX_URL)
1400
1401 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1402         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1403 ])
1404 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1405
1406 # work around intltool-update issues during 'make distcheck'
1407 AS_IF([test "x$0" != "x./configure"], [
1408         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1409 ])
1410
1411 # QEMU and OVMF UEFI firmware
1412 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1413         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1414         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1415                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1416         AC_SUBST([QEMU_BIOS])
1417 ])
1418
1419 AC_ARG_ENABLE(tests,
1420         [AC_HELP_STRING([--disable-tests], [disable tests])],
1421         enable_tests=$enableval, enable_tests=yes)
1422 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
1423
1424 AC_ARG_ENABLE(debug,
1425         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1426         [if test "x$enableval" = "xyes"; then
1427                 enableval="hashmap,mmap-cache"
1428         fi
1429         saved_ifs="$IFS"
1430         IFS="$IFS$PATH_SEPARATOR,"
1431         for name in $enableval; do
1432                 case $name in
1433                 hashmap)
1434                         enable_debug_hashmap=yes
1435                         ;;
1436                 mmap-cache)
1437                         enable_debug_mmap_cache=yes
1438                         ;;
1439                 esac
1440         done
1441         IFS="$saved_ifs"],[])
1442
1443 enable_debug=""
1444 AS_IF([test x$enable_debug_hashmap = xyes], [
1445         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1446         enable_debug="hashmap $enable_debug"
1447 ])
1448 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1449         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1450         enable_debug="mmap-cache $enable_debug"
1451 ])
1452 test -z "$enable_debug" && enable_debug="none"
1453
1454 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1455 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1456 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1457 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1458 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1459 AC_SUBST([pamlibdir], [$with_pamlibdir])
1460 AC_SUBST([pamconfdir], [$with_pamconfdir])
1461 AC_SUBST([rootprefix], [$with_rootprefix])
1462 AC_SUBST([rootlibdir], [$with_rootlibdir])
1463
1464 AC_CONFIG_FILES([
1465         Makefile
1466         po/Makefile.in
1467 ])
1468
1469 AC_OUTPUT
1470 AC_MSG_RESULT([
1471         $PACKAGE_NAME $VERSION
1472
1473         libcryptsetup:           ${have_libcryptsetup}
1474         PAM:                     ${have_pam}
1475         AUDIT:                   ${have_audit}
1476         IMA:                     ${have_ima}
1477         AppArmor:                ${have_apparmor}
1478         SELinux:                 ${have_selinux}
1479         SECCOMP:                 ${have_seccomp}
1480         SMACK:                   ${have_smack}
1481         ZLIB:                    ${have_zlib}
1482         XZ:                      ${have_xz}
1483         LZ4:                     ${have_lz4}
1484         BZIP2:                   ${have_bzip2}
1485         ACL:                     ${have_acl}
1486         GCRYPT:                  ${have_gcrypt}
1487         QRENCODE:                ${have_qrencode}
1488         MICROHTTPD:              ${have_microhttpd}
1489         GNUTLS:                  ${have_gnutls}
1490         libcurl:                 ${have_libcurl}
1491         libidn:                  ${have_libidn}
1492         libiptc:                 ${have_libiptc}
1493         ELFUTILS:                ${have_elfutils}
1494         binfmt:                  ${have_binfmt}
1495         vconsole:                ${have_vconsole}
1496         bootchart:               ${have_bootchart}
1497         quotacheck:              ${have_quotacheck}
1498         tmpfiles:                ${have_tmpfiles}
1499         sysusers:                ${have_sysusers}
1500         firstboot:               ${have_firstboot}
1501         randomseed:              ${have_randomseed}
1502         backlight:               ${have_backlight}
1503         rfkill:                  ${have_rfkill}
1504         logind:                  ${have_logind}
1505         machined:                ${have_machined}
1506         importd:                 ${have_importd}
1507         hostnamed:               ${have_hostnamed}
1508         timedated:               ${have_timedated}
1509         timesyncd:               ${have_timesyncd}
1510         default NTP servers:     ${NTP_SERVERS}
1511         time epoch:              ${TIME_EPOCH}
1512         localed:                 ${have_localed}
1513         networkd:                ${have_networkd}
1514         resolved:                ${have_resolved}
1515         default DNS servers:     ${DNS_SERVERS}
1516         coredump:                ${have_coredump}
1517         polkit:                  ${have_polkit}
1518         efi:                     ${have_efi}
1519         gnuefi:                  ${have_gnuefi}
1520         efi arch:                ${EFI_ARCH}
1521         EFI machine type:        ${EFI_MACHINE_TYPE_NAME}
1522         EFI CC                   ${EFI_CC}
1523         EFI libdir:              ${EFI_LIB_DIR}
1524         EFI ldsdir:              ${EFI_LDS_DIR}
1525         EFI includedir:          ${EFI_INC_DIR}
1526         kmod:                    ${have_kmod}
1527         xkbcommon:               ${have_xkbcommon}
1528         blkid:                   ${have_blkid}
1529         libmount:                ${have_libmount}
1530         dbus:                    ${have_dbus}
1531         nss-myhostname:          ${have_myhostname}
1532         hwdb:                    ${enable_hwdb}
1533         kdbus:                   ${have_kdbus}
1534         Python:                  ${have_python}
1535         man pages:               ${have_manpages}
1536         test coverage:           ${have_coverage}
1537         Split /usr:              ${enable_split_usr}
1538         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1539         compatibility libraries: ${have_compat_libs}
1540         utmp/wtmp support:       ${have_utmp}
1541         ldconfig support:        ${enable_ldconfig}
1542         hibernate support:       ${enable_hibernate}
1543         extra debugging:         ${enable_debug}
1544
1545         prefix:                  ${prefix}
1546         rootprefix:              ${with_rootprefix}
1547         sysconf dir:             ${sysconfdir}
1548         datarootdir:             ${datarootdir}
1549         includedir:              ${includedir}
1550         lib dir:                 ${libdir}
1551         rootlib dir:             ${with_rootlibdir}
1552         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1553         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1554         Build Python:            ${PYTHON}
1555         sphinx binary:           ${SPHINX_BUILD}
1556         PAM modules dir:         ${with_pamlibdir}
1557         PAM configuration dir:   ${with_pamconfdir}
1558         D-Bus policy dir:        ${with_dbuspolicydir}
1559         D-Bus session dir:       ${with_dbussessionservicedir}
1560         D-Bus system dir:        ${with_dbussystemservicedir}
1561         Bash completions dir:    ${with_bashcompletiondir}
1562         Zsh completions dir:     ${with_zshcompletiondir}
1563         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1564         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1565         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1566         TTY GID:                 ${TTY_GID}
1567         Maximum System UID:      ${SYSTEM_UID_MAX}
1568         Maximum System GID:      ${SYSTEM_GID_MAX}
1569         Certificate root:        ${CERTIFICATEROOT}
1570         Default dkr Index        ${DEFAULT_DKR_INDEX_URL}
1571
1572         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1573         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1574         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1575 ])