configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="06-Nov-2018"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77
  78 # default for old versions without $runstatedir
  79 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  80
  81 # our default if $localstatedir unchanged
  82 AS_CASE([$localstatedir:$runstatedir],
  83  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  84    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  85 )
  86
  87 AC_SUBST([runstatedir])
  88
  89
  90 # The original default values of {bin,sbin,lib}dir
  91 usrbin_execdir='${exec_prefix}/bin'
  92 AC_SUBST([usrbin_execdir])
  93
  94 usrsbin_execdir='${exec_prefix}/sbin'
  95 AC_SUBST([usrsbin_execdir])
  96
  97 AS_CASE([$libdir],
  98  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  99    [usrlib_execdir=$libdir],
 100  [usrlib_execdir='${exec_prefix}'$libdir]
 101 )
 102 AC_SUBST([usrlib_execdir])
 103
 104
 105 AM_PROG_CC_C_O
 106 AC_PROG_MKDIR_P
 107 AC_PROG_CC_STDC
 108 AC_PROG_YACC
 109 AC_CANONICAL_HOST
 110 AC_C_CONST
 111 AC_C_VOLATILE
 112 AC_C_BIGENDIAN
 113
 114 dnl Compiler warnings
 115 UL_WARN_ADD([-fno-common])
 116 UL_WARN_ADD([-Wall])
 117 UL_WARN_ADD([-Werror=sequence-point])
 118 UL_WARN_ADD([-Wextra])
 119 UL_WARN_ADD([-Wextra-semi])
 120 UL_WARN_ADD([-Wembedded-directive])
 121 UL_WARN_ADD([-Wmissing-declarations])
 122 UL_WARN_ADD([-Wmissing-parameter-type])
 123 UL_WARN_ADD([-Wmissing-prototypes])
 124 UL_WARN_ADD([-Wno-missing-field-initializers])
 125 UL_WARN_ADD([-Wredundant-decls])
 126 UL_WARN_ADD([-Wsign-compare])
 127 UL_WARN_ADD([-Wtype-limits])
 128 UL_WARN_ADD([-Wuninitialized])
 129 UL_WARN_ADD([-Wunused-but-set-parameter])
 130 UL_WARN_ADD([-Wunused-but-set-variable])
 131 UL_WARN_ADD([-Wunused-parameter])
 132 UL_WARN_ADD([-Wunused-result])
 133 UL_WARN_ADD([-Wunused-variable])
 134 UL_WARN_ADD([-Wnested-externs])
 135 UL_WARN_ADD([-Wpointer-arith])
 136 UL_WARN_ADD([-Wstrict-prototypes])
 137 UL_WARN_ADD([-Wformat-security])
 138 UL_WARN_ADD([-Wimplicit-function-declaration])
 139 UL_WARN_ADD([-Wdiscarded-qualifiers])
 140 AC_SUBST([WARN_CFLAGS])
 141
 142 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 143 AC_SUBST([BSD_WARN_CFLAGS])
 144
 145 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 146 AC_SUBST([PYTHON_WARN_CFLAGS])
 147
 148 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 149 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 150
 151
 152 AC_ARG_ENABLE([asan],
 153   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 154   [], [enable_asan=no]
 155 )
 156 AS_IF([test "x$enable_asan" = xyes], [
 157   UL_WARN_ADD([-fsanitize=address])
 158   ASAN_LDFLAGS="-fsanitize=address"
 159 ],[
 160   AC_DEFINE([USE_CLOSE_ATEXIT], [1], [close stdout at exit])
 161 ])
 162
 163 AC_SUBST([ASAN_LDFLAGS])
 164
 165 dnl libtool-2
 166 LT_INIT
 167
 168 dnl check supported linker flags
 169 AX_CHECK_VSCRIPT
 170
 171 m4_ifndef([PKG_PROG_PKG_CONFIG],
 172   [m4_fatal([Could not locate the pkg-config autoconf
 173     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 174     If your macros are in a different location, try setting the
 175     environment variable AL_OPTS="-I/other/macro/dir" before running
 176     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 177 PKG_PROG_PKG_CONFIG
 178
 179 GTK_DOC_CHECK([1.10])
 180 AC_PATH_PROG([XSLTPROC], [xsltproc])
 181
 182 linux_os=no
 183 bsd_os=no
 184 AS_CASE([${host_os}],
 185   [*linux*],
 186      [linux_os=yes],
 187   [*darwin*],
 188      [darwin_os=yes],
 189   [*bsd*],
 190      [bsd_os=yes])
 191 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 192 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 193 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 194
 195 AS_IF([test  "x$darwin_os" = xyes], [
 196   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 197 ])
 198
 199 dnl define ARCH_<NAME> conditionals
 200 UL_SET_ARCH([I86], [i?86-*])
 201 UL_SET_ARCH([86_64], [x86_64*])
 202 UL_SET_ARCH([IA64], [ia64*])
 203 UL_SET_ARCH([S390], [s390*])
 204 UL_SET_ARCH([SPARC], [sparc*])
 205 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 206 UL_SET_ARCH([M68K], [m68*])
 207 UL_SET_ARCH([MIPS], [mips*])
 208 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 209
 210 AC_SYS_LARGEFILE
 211 AC_HEADER_ASSERT
 212 AC_STRUCT_TIMEZONE
 213
 214 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 215 AM_GNU_GETTEXT_VERSION([0.18.3])
 216 AM_GNU_GETTEXT([external])
 217
 218 AS_IF([test -d "$srcdir/po"], [
 219   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 220 ], [
 221   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 222 ])
 223
 224 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 225 #ifdef HAVE_LINUX_COMPILER_H
 226 #include <linux/compiler.h>
 227 #endif
 228 ])
 229 AC_CHECK_HEADERS([ \
 230         asm/io.h \
 231         err.h \
 232         errno.h \
 233         fcntl.h \
 234         getopt.h \
 235         inttypes.h \
 236         lastlog.h \
 237         libutil.h \
 238         linux/btrfs.h \
 239         linux/cdrom.h \
 240         linux/falloc.h \
 241         linux/watchdog.h \
 242         linux/fd.h \
 243         linux/raw.h \
 244         linux/tiocl.h \
 245         linux/version.h \
 246         linux/securebits.h \
 247         linux/net_namespace.h \
 248         locale.h \
 249         mntent.h \
 250         net/if.h \
 251         net/if_dl.h \
 252         netinet/in.h \
 253         paths.h \
 254         pty.h \
 255         security/pam_appl.h \
 256         stdint.h \
 257         stdio_ext.h \
 258         stdlib.h \
 259         endian.h \
 260         byteswap.h \
 261         sys/endian.h \
 262         sys/disk.h \
 263         sys/disklabel.h \
 264         sys/file.h \
 265         sys/io.h \
 266         sys/ioccom.h \
 267         sys/ioctl.h \
 268         sys/mkdev.h \
 269         sys/mount.h \
 270         sys/param.h \
 271         sys/prctl.h \
 272         sys/resource.h \
 273         sys/signalfd.h \
 274         sys/socket.h \
 275         sys/sockio.h \
 276         sys/stat.h \
 277         sys/sysmacros.h \
 278         sys/swap.h \
 279         sys/syscall.h \
 280         sys/time.h \
 281         sys/timex.h \
 282         sys/ttydefaults.h \
 283         sys/types.h \
 284         sys/ucred.h \
 285         sys/un.h \
 286         unistd.h \
 287         shadow.h \
 288         utmp.h \
 289         utmpx.h \
 290 ])
 291
 292 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 293 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 294 #
 295 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 296  [#ifdef HAVE_SYS_MOUNT_H
 297    # include <linux/fs.h>
 298    # include <sys/mount.h>
 299   #endif
 300 ])
 301
 302 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 303  [#ifdef LINUX_GSMMUX_H
 304    # include <linux/gsmmux.h>
 305    #endif
 306 ])
 307
 308 AC_CHECK_HEADERS([security/pam_misc.h],
 309                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 310                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 311 #ifdef HAVE_SECURITY_PAM_APPL_H
 312 #include <security/pam_appl.h>
 313 #endif
 314 ])
 315
 316 AC_CHECK_HEADERS([linux/blkzoned.h])
 317
 318 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 319 #ifdef HAVE_SECURITY_PAM_APPL_H
 320 #include <security/pam_appl.h>
 321 #endif
 322 ])
 323
 324 AC_CHECK_HEADERS([langinfo.h],
 325                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 326                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 327
 328 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 329 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 330         #include <langinfo.h>
 331 ]], [[
 332         char *str;
 333         str = nl_langinfo (ALTMON_1);
 334         str = nl_langinfo (ALTMON_2);
 335         str = nl_langinfo (ALTMON_3);
 336         str = nl_langinfo (ALTMON_4);
 337         str = nl_langinfo (ALTMON_5);
 338         str = nl_langinfo (ALTMON_6);
 339         str = nl_langinfo (ALTMON_7);
 340         str = nl_langinfo (ALTMON_8);
 341         str = nl_langinfo (ALTMON_9);
 342         str = nl_langinfo (ALTMON_10);
 343         str = nl_langinfo (ALTMON_11);
 344         str = nl_langinfo (ALTMON_12);
 345 ]])], [
 346         AC_MSG_RESULT([yes])
 347         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 348                 [Define if langinfo.h defines ALTMON_x constants])
 349 ], [
 350         AC_MSG_RESULT([no])
 351 ])
 352
 353
 354 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 355 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 356         #include <langinfo.h>
 357 ]], [[
 358         char *str;
 359         str = nl_langinfo (_NL_ABALTMON_1);
 360         str = nl_langinfo (_NL_ABALTMON_2);
 361         str = nl_langinfo (_NL_ABALTMON_3);
 362         str = nl_langinfo (_NL_ABALTMON_4);
 363         str = nl_langinfo (_NL_ABALTMON_5);
 364         str = nl_langinfo (_NL_ABALTMON_6);
 365         str = nl_langinfo (_NL_ABALTMON_7);
 366         str = nl_langinfo (_NL_ABALTMON_8);
 367         str = nl_langinfo (_NL_ABALTMON_9);
 368         str = nl_langinfo (_NL_ABALTMON_10);
 369         str = nl_langinfo (_NL_ABALTMON_11);
 370         str = nl_langinfo (_NL_ABALTMON_12);
 371 ]])], [
 372         AC_MSG_RESULT([yes])
 373         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 374                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 375 ], [
 376         AC_MSG_RESULT([no])
 377 ])
 378
 379
 380 dnl Convert some ac_cv_header_* variables to have_*
 381 dnl
 382 have_linux_version_h=$ac_cv_header_linux_version_h
 383 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 384 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 385 have_linux_raw_h=$ac_cv_header_linux_raw_h
 386 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 387 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 388 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 389 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 390 have_security_openpam_h=$ac_cv_header_security_openpam_h
 391 have_shadow_h=$ac_cv_header_shadow_h
 392 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 393 have_utmpx_h=$ac_cv_header_utmpx_h
 394
 395 AS_CASE([$linux_os:$have_linux_version_h],
 396   [yes:no],
 397     [AC_MSG_ERROR([kernel headers required on Linux])]
 398 )
 399
 400 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 401 #include <time.h>
 402 #include <unistd.h>
 403 ]], [[
 404     int a = 0;
 405     struct tm *tm = localtime(0);
 406     if (a == -1)  /* false */
 407         sleep(tm->tm_gmtoff);
 408 ]])],
 409 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 410 ])
 411
 412 AC_CHECK_MEMBERS([struct termios.c_line],,,
 413     [[#include <termios.h>]])
 414
 415 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 416         [#include <sys/stat.h>])
 417
 418 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 419
 420 AC_CHECK_DECL([llseek],
 421         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 422                         [Define to 1 if have llseek prototype])],
 423         [],
 424         [#include <unistd.h>])
 425
 426 AC_CHECK_DECL([lseek64],
 427         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 428                         [Define to 1 if have lseek64 prototype])],
 429         [],
 430         [#define _LARGEFILE_SOURCE
 431          #define _LARGEFILE64_SOURCE
 432          #include <unistd.h>])
 433
 434 AC_CHECK_DECL([environ],
 435         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 436                 [Define to 1 if have **environ prototype])],
 437 )
 438
 439 AC_CHECK_DECL([strsignal],
 440         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 441                 [Define to 1 if have strsignal function prototype])],
 442 )
 443
 444 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 445               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 446               [#include <sys/ioctl.h>])
 447 AC_CHECK_DECL([SOCK_CLOEXEC],
 448               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 449               [#include <sys/types.h>
 450                #include <sys/socket.h>])
 451 AC_CHECK_DECL([SOCK_NONBLOCK],
 452               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 453               [#include <sys/types.h>
 454                #include <sys/socket.h>])
 455 AC_CHECK_DECL([SO_PASSCRED],
 456               [have_so_passcred=yes], [have_so_passcred=no],
 457               [#include <sys/types.h>
 458                #include <sys/socket.h>])
 459
 460 AC_CHECK_FUNCS([ \
 461         clearenv \
 462         __fpurge \
 463         fpurge \
 464         __fpending \
 465         secure_getenv \
 466         __secure_getenv \
 467         eaccess \
 468         err \
 469         errx \
 470         explicit_bzero \
 471         fsync \
 472         utimensat \
 473         getdomainname \
 474         getdtablesize \
 475         getexecname \
 476         getmntinfo \
 477         getrandom \
 478         getrlimit \
 479         getsgnam \
 480         inotify_init \
 481         jrand48 \
 482         lchown \
 483         llseek \
 484         lseek64 \
 485         mempcpy \
 486         mkostemp \
 487         nanosleep \
 488         ntp_gettime \
 489         personality \
 490         posix_fadvise \
 491         prctl \
 492         qsort_r \
 493         rpmatch \
 494         scandirat \
 495         setprogname \
 496         setresgid \
 497         setresuid \
 498         sched_setattr \
 499         sched_setscheduler \
 500         sigqueue \
 501         srandom \
 502         strnchr \
 503         strndup \
 504         strnlen \
 505         sysconf \
 506         sysinfo \
 507         timegm \
 508         usleep \
 509         vwarnx \
 510         warn \
 511         warnx \
 512 ])
 513 AC_FUNC_FSEEKO
 514
 515 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 516 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 517 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 518 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 519 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 520 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 521 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 522 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 523
 524 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 525
 526 have_setns_syscall="yes"
 527 UL_CHECK_SYSCALL([setns])
 528 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 529    have_setns_syscall="no"
 530 ])
 531
 532 AC_CHECK_FUNCS([isnan], [],
 533         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 534         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 535 )
 536 AC_SUBST([MATH_LIBS])
 537
 538
 539 dnl lib/mononotic.c may require -lrt
 540 AC_CHECK_FUNCS([clock_gettime], [],
 541         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 542 )
 543
 544 have_timer="no"
 545 AC_CHECK_FUNCS([timer_create],
 546         [have_timer="yes"],
 547         [AC_CHECK_LIB([rt], [timer_create], [
 548                 have_timer="yes"
 549                 REALTIME_LIBS="-lrt"
 550                 AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 551         ],[
 552                 AC_SEARCH_LIBS([timer_create], [rt], [
 553                         AC_MSG_RESULT(yes)
 554                         have_timer="yes"
 555                         REALTIME_LIBS="-lrt -lpthread"
 556                         AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 557                 ],[], [-lpthread]
 558                 )
 559         ])]
 560 )
 561
 562 AC_SUBST([REALTIME_LIBS])
 563
 564 AS_IF([test x"$have_timer" = xno], [
 565        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 566 ])
 567
 568
 569 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 570         RTAS_LIBS="-lrtas"
 571         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 572 ])
 573 AC_SUBST([RTAS_LIBS])
 574
 575
 576 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 577                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 578         [#include <sys/types.h>
 579          #include <sys/socket.h>])
 580
 581 SOCKET_LIBS=
 582 AC_SEARCH_LIBS([socket], [socket],
 583         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 584                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 585 ])
 586 AC_SUBST([SOCKET_LIBS])
 587
 588
 589 have_dirfd=no
 590 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 591 AS_IF([test x"$have_dirfd" = xno], [
 592         AC_CHECK_DECLS([dirfd],
 593                 [have_dirfd=yes], [have_dirfd=no],
 594                 [#include <sys/types.h>
 595                  #include <dirent.h>])
 596 ])
 597
 598 have_ddfd=no
 599 AS_IF([test x"$have_dirfd" = xno], [
 600         AC_CHECK_MEMBERS([DIR.dd_fd],
 601                 [have_ddfd=yes], [have_ddfd=no],
 602                 [#include <sys/types.h>
 603                  #include <dirent.h>])
 604 ])
 605
 606 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes -o "x$have_ddfd" = xyes])
 607
 608
 609 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 610 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 611         #include <errno.h>
 612 ]], [[
 613         program_invocation_short_name = "test";
 614 ]])], [
 615         AC_MSG_RESULT([yes])
 616         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 617                 [Define if program_invocation_short_name is defined])
 618 ], [
 619         AC_MSG_RESULT([no])
 620 ])
 621
 622
 623 AC_MSG_CHECKING([whether __progname is defined])
 624 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 625            [if (*__progname == 0) return 1;])],
 626            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 627            AC_MSG_RESULT([yes]),
 628            AC_MSG_RESULT([no]))
 629
 630 dnl Static compilation
 631 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 632
 633 AC_ARG_ENABLE([static-programs],
 634   [AS_HELP_STRING([--enable-static-programs=LIST],
 635       [link static the programs in LIST (comma-separated,
 636       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 637
 638 AS_CASE([$enable_static_programs],
 639   [yes],
 640     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 641   [no],
 642     [enable_static_programs=]
 643 )
 644
 645 dnl Set all the individual AM_CONDITIONALs
 646 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 647   AS_CASE([,$enable_static_programs,],
 648    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 649   )
 650   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 651   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 652     [test "x$static_[]UL_PRG" = xyes])
 653 ])
 654
 655
 656 AC_ARG_ENABLE([all-programs],
 657   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 658   [], [enable_all_programs=undefined]
 659 )
 660
 661 AS_CASE([$enable_all_programs],
 662   [yes], [AC_MSG_WARN([force to build all programs by default])
 663           ul_default_estate=check],
 664   [no],  [AC_MSG_WARN([disable all programs by default])
 665           ul_default_estate=no]
 666 )
 667
 668
 669 AX_CHECK_TLS
 670
 671 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 672 # include <stdio.h>
 673 # include <stdlib.h>
 674 int main()
 675 {
 676         int i;
 677         int rc = 1;
 678         char *s;
 679         i = sscanf("x", $1, &s);
 680         if (i == 1  && *s == 'x')
 681                 rc = 0;
 682         free(s);
 683         return rc;
 684 }])
 685
 686 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 687   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 688     [scanf_cv_alloc_modifier=ms],
 689     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 690       [scanf_cv_alloc_modifier=as],
 691       [scanf_cv_alloc_modifier=no]
 692     )
 693     ,
 694
 695     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 696      #include <stdio.h>
 697      #include <unistd.h>
 698
 699      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 700
 701      #if !(__GLIBC_PREREQ(2, 7))
 702      #error %m is not available
 703      #endif
 704
 705      #elif defined(_POSIX_VERSION)
 706
 707      #if _POSIX_VERSION < 200809L
 708      #error %m is not available
 709      #endif
 710
 711      #else
 712      #error Your C-library is not supported.
 713      #endif
 714      ])],
 715     [scanf_cv_alloc_modifier=ms],
 716     [scanf_cv_alloc_modifier=no])]
 717   )
 718 )
 719
 720 AC_MSG_CHECKING([scanf string alloc modifiers])
 721 AS_CASE([$scanf_cv_alloc_modifier],
 722   [ms],
 723     [AC_MSG_RESULT([(%ms) yes])
 724      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 725      have_scanf_alloc_modifier=yes],
 726   [as],
 727     [AC_MSG_RESULT([(%as) yes])
 728      have_scanf_alloc_modifier=yes
 729      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 730   [AC_MSG_RESULT([no])
 731    have_scanf_alloc_modifier=no]
 732 )
 733
 734
 735 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 736   [], [with_util=auto]
 737 )
 738 AS_IF([test "x$with_util" = xno], [
 739   AM_CONDITIONAL([HAVE_UTIL], [false])
 740   have_util=no
 741 ], [
 742   UL_CHECK_LIB([util], [openpty])
 743 ])
 744
 745
 746 AC_CHECK_TYPES([union semun], [], [], [[
 747 #include <sys/sem.h>
 748 ]])
 749 AC_CHECK_TYPES([loff_t])
 750
 751
 752 AC_ARG_ENABLE([widechar],
 753   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 754   [], [enable_widechar=check]
 755 )
 756 UL_BUILD_INIT([widechar])
 757 UL_REQUIRES_COMPILE([widechar], [[
 758   #include <wchar.h>
 759   #include <wctype.h>
 760   #include <stdio.h>
 761   ]], [[
 762     wchar_t wc;
 763     wint_t w;
 764     w = fgetwc(stdin);
 765     if (w == WEOF) exit(1);
 766     wc = w;
 767     fputwc(wc,stdout);
 768   ]],
 769   [wchar_t support])
 770
 771 AS_IF([test "x$build_widechar" = xyes ], [
 772   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 773 ])
 774
 775
 776 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 777 #include <sched.h>
 778 ]])
 779
 780 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 781
 782 AC_CHECK_TYPES([sighandler_t], [], [], [[
 783 #include <signal.h>
 784 ]])
 785
 786 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 787 #include <sched.h>
 788 ]])
 789
 790 # on Solaris, you can't mix and match standards, since we use c99
 791 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 792 # check for crypt.h and use that without XOPEN_SOURCE.
 793 have_crypt=no
 794 AC_CHECK_HEADERS([crypt.h])
 795 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 796 #ifdef HAVE_CRYPT_H
 797 #include <crypt.h>
 798 #else
 799 #define _XOPEN_SOURCE
 800 #include <unistd.h>
 801 #endif
 802 ]], [[
 803 char *c = crypt("abc","pw");
 804 ]])],[
 805   have_libcrypt=no
 806   have_crypt=yes
 807 ],[
 808   LIBS="$LIBS -lcrypt"
 809   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 810   #ifdef HAVE_CRYPT_H
 811   #include <crypt.h>
 812   #else
 813   #define _XOPEN_SOURCE
 814   #include <unistd.h>
 815   #endif
 816   ]], [[
 817   char *c = crypt("abc","pw");
 818   ]])],[
 819   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 820   have_libcrypt=yes
 821   have_crypt=yes
 822   ],[
 823   AC_MSG_WARN([crypt() is not available])
 824   ])
 825 ])
 826 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 827
 828
 829 AC_ARG_WITH([selinux],
 830   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 831   [], [with_selinux=no]
 832 )
 833
 834 AS_IF([test "x$with_selinux" = xno], [
 835   AM_CONDITIONAL([HAVE_SELINUX], [false])
 836 ], [
 837   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 838         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 839          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 840          AM_CONDITIONAL([HAVE_SELINUX], [true])
 841          have_selinux=yes],
 842         [have_selinux=no])
 843
 844   AS_CASE([$with_selinux:$have_selinux],
 845     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 846   )
 847
 848   AS_IF([test "x$have_selinux" = xyes], [
 849     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 850     # This function is missing in old libselinux 1.xx versions
 851     AC_CHECK_FUNCS([security_get_initial_context])
 852     UL_RESTORE_FLAGS
 853   ])
 854 ])
 855 AC_SUBST([SELINUX_LIBS])
 856 AC_SUBST([SELINUX_LIBS_STATIC])
 857
 858
 859 AC_ARG_WITH([audit],
 860   AS_HELP_STRING([--with-audit], [compile with audit support]),
 861   [], [with_audit=no]
 862 )
 863
 864 AS_IF([test "x$with_audit" = xno], [
 865   AM_CONDITIONAL([HAVE_AUDIT], [false])
 866 ], [
 867   UL_CHECK_LIB([audit], [audit_log_user_message])
 868   AS_CASE([$with_audit:$have_audit],
 869     [yes:no],
 870       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 871   )
 872 ])
 873
 874 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 875   [], [with_udev=auto]
 876 )
 877
 878 AS_IF([test "x$with_udev" = xno], [
 879   AM_CONDITIONAL([HAVE_UDEV], [false])
 880 ], [
 881   UL_CHECK_LIB([udev], [udev_new])
 882   AS_CASE([$with_udev:$have_udev],
 883     [yes:no],
 884       [AC_MSG_ERROR([udev selected but libudev not found])]
 885   )
 886 ])
 887
 888
 889 dnl wide-char ncurses
 890 AC_ARG_WITH([ncursesw],
 891   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 892   [], [with_ncursesw=auto]
 893 )
 894 have_ncursesw=no
 895 have_ncursesw_header=no
 896 AS_IF([test "x$with_ncursesw" != xno], [
 897   UL_NCURSES_CHECK([ncursesw])
 898   AS_IF([test "x$have_ncursesw" = xyes], [
 899     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 900     AC_CHECK_HEADERS([ncursesw/term.h])
 901
 902     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 903     # unsuccessful to avoid too many *_H permitations in config.h
 904     AS_IF([test "x$have_ncursesw_header" = xno], [
 905            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 906            AC_CHECK_HEADERS([term.h])
 907     ])
 908     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 909   ])
 910   AS_IF([test "x$have_ncursesw" = xyes], [
 911     CURSES_LIB_NAME="ncursesw"
 912     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 913   ])
 914 ])
 915 AS_CASE([$with_ncursesw:$have_ncursesw],
 916   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 917
 918
 919 dnl non-wide ncurses
 920 AC_ARG_WITH([ncurses],
 921   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 922   [], [with_ncurses=auto]
 923 )
 924 have_ncurses=no
 925 have_ncurses_header=no
 926 AS_CASE([$with_ncurses:$build_widechar],
 927   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 928
 929 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 930   UL_NCURSES_CHECK([ncurses])
 931   AS_IF([test "x$have_ncurses" = xyes], [
 932     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 933     AC_CHECK_HEADERS([ncurses/term.h])
 934
 935     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 936     # unsuccessful to avoid too many *_H permitations in config.h
 937     AS_IF([test "x$have_ncurses_header" = xno], [
 938            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 939            AC_CHECK_HEADERS([term.h])
 940     ])
 941     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 942   ])
 943   AS_IF([test "x$have_ncurses" = xyes], [
 944     CURSES_LIB_NAME="ncurses"
 945     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 946   ])
 947 ])
 948 AS_CASE([$with_ncurses:$have_ncurses],
 949   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 950
 951 AC_SUBST([NCURSES_CFLAGS])
 952 AC_SUBST([NCURSES_LIBS])
 953 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 954
 955
 956 AC_ARG_WITH([slang],
 957   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 958   [], [with_slang=no]
 959 )
 960 have_slang=no
 961 AS_IF([test "x$with_slang" = xyes], [
 962   AC_CHECK_HEADERS([slang.h slang/slang.h])
 963   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 964                    [have_slang=yes], [], [
 965 #ifdef HAVE_SLANG_H
 966 #include <slang.h>
 967 #elif defined(HAVE_SLANG_SLANG_H)
 968 #include <slang/slang.h>
 969 #endif
 970 ])
 971   AS_IF([test "x$have_slang" = xno], [
 972     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 973     [CURSES_LIB_NAME=slang
 974   ])
 975 ])
 976 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 977
 978
 979 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 980         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 981                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 982                                [Define if curses library has the use_default_colors().])
 983         ])
 984         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 985                      AC_DEFINE(HAVE_RESIZETERM, 1,
 986                                [Define if curses library has the resizeterm().])
 987         ])
 988 ])
 989
 990
 991 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 992   [], [with_tinfo=auto]
 993 )
 994 have_tinfo=no
 995 have_tinfow=no
 996 AS_IF([test "x$with_tinfo" != xno], [
 997   AS_IF([test "x$have_ncursesw" = xyes], [
 998     UL_TINFO_CHECK([tinfow])
 999   ])
1000   AS_IF([test "x$have_tinfow" = xno], [
1001     UL_TINFO_CHECK([tinfo])
1002   ])
1003 ])
1004 AC_SUBST([TINFO_LIBS])
1005 AC_SUBST([TINFO_LIBS_STATIC])
1006 AC_SUBST([TINFO_CFLAGS])
1007 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
1008 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
1009   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1010 ])
1011
1012
1013 AC_ARG_WITH([readline],
1014   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1015   [], [with_readline=auto]
1016 )
1017
1018 AS_IF([test "x$with_readline" = xno], [
1019   AM_CONDITIONAL([HAVE_READLINE], [false])
1020 ], [
1021   UL_CHECK_LIB([readline], [readline])
1022   AS_CASE([$with_readline:$have_readline],
1023     [yes:no],
1024       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1025     [*:yes],
1026       [READLINE_LIBS="-lreadline"
1027        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1028   )
1029 ])
1030 AC_SUBST([READLINE_LIBS])
1031 AC_SUBST([READLINE_LIBS_STATIC])
1032
1033
1034 AC_ARG_WITH([utempter],
1035   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1036   [], [with_utempter=no]
1037 )
1038
1039 AS_IF([test "x$with_utempter" = xyes], [
1040   UL_CHECK_LIB([utempter], [utempter_add_record])
1041   AS_IF([test "x$have_utempter" = xno], [
1042     AC_MSG_ERROR([utempter selected but libutempter not found])
1043   ])
1044 ], [
1045   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1046 ])
1047
1048
1049 dnl
1050 dnl libuuid
1051 dnl
1052 AC_ARG_ENABLE([libuuid],
1053   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1054   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1055 )
1056 UL_BUILD_INIT([libuuid])
1057 AC_SUBST([LIBUUID_VERSION])
1058 AC_SUBST([LIBUUID_VERSION_INFO])
1059 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1060
1061 AC_ARG_ENABLE([libuuid-force-uuidd],
1062   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1063   [], [enable_libuuid_force_uuidd=no]
1064 )
1065
1066 AS_IF([test "x$build_libuuid" = xyes], [
1067   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1068 ])
1069
1070 dnl
1071 dnl libblkid
1072 dnl
1073 AC_ARG_ENABLE([libblkid],
1074   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1075   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1076 )
1077 UL_BUILD_INIT([libblkid])
1078 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1079 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1080 AC_SUBST([LIBBLKID_DATE])
1081 AC_SUBST([LIBBLKID_VERSION])
1082 AC_SUBST([LIBBLKID_VERSION_INFO])
1083 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1084 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1085 AS_IF([test "x$build_libblkid" = xyes], [
1086   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1087 ])
1088 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1089 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1090
1091 dnl
1092 dnl libmount
1093 dnl
1094 AC_ARG_ENABLE([libmount],
1095   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1096   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1097 )
1098 UL_BUILD_INIT([libmount])
1099 UL_REQUIRES_BUILD([libmount], [libblkid])
1100 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1101 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1102 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1103 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1104 AS_IF([test "x$build_libmount" = xyes], [
1105   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1106   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1107     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1108   ],[
1109     AC_MSG_WARN([libmount will be compiled without namespaces support])
1110   ])
1111 ])
1112
1113 AC_SUBST([LIBMOUNT_VERSION])
1114 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1115 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1116 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1117 AC_SUBST([LIBMOUNT_VERSION_INFO])
1118 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1119
1120 AC_ARG_ENABLE([libmount-support-mtab],
1121   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1122   [], [enable_libmount_support_mtab=no]
1123 )
1124
1125 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1126   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1127 ])
1128
1129 dnl
1130 dnl libsmartcols
1131 dnl
1132 AC_ARG_ENABLE([libsmartcols],
1133   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1134   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1135 )
1136 UL_BUILD_INIT([libsmartcols])
1137 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1138
1139 AC_SUBST([LIBSMARTCOLS_VERSION])
1140 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1141 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1142
1143
1144 dnl
1145 dnl libfdisk
1146 dnl
1147 AC_ARG_ENABLE([libfdisk],
1148   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1149   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1150 )
1151 UL_BUILD_INIT([libfdisk])
1152 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1153 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1154 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1155
1156 AS_IF([test "x$build_libblkid" = xyes],
1157   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1158 AC_SUBST([LIBFDISK_PC_REQUIRES])
1159
1160 AC_SUBST([LIBFDISK_VERSION])
1161 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1162 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1163 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1164 AC_SUBST([LIBFDISK_VERSION_INFO])
1165 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1166
1167
1168 AC_ARG_ENABLE([fdisks],
1169   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1170   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1171 )
1172 enable_fdisk=$enable_fdisks
1173 enable_sfdisk=$enable_fdisks
1174 enable_cfdisk=$enable_fdisks
1175
1176 UL_BUILD_INIT([fdisk])
1177 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1178 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1179 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1180 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1181 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1182
1183
1184 UL_BUILD_INIT([sfdisk])
1185 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1186 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1187 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1188 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1189 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1190
1191
1192 UL_BUILD_INIT([cfdisk])
1193 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1194 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1195 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1196 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1197 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1198
1199
1200 AC_ARG_ENABLE([mount],
1201   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1202   [], [UL_DEFAULT_ENABLE([mount], [check])]
1203 )
1204 UL_BUILD_INIT([mount])
1205 UL_REQUIRES_LINUX([mount])
1206 UL_REQUIRES_BUILD([mount], [libmount])
1207 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1208
1209
1210 AC_ARG_ENABLE([losetup],
1211   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1212   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1213 )
1214 UL_BUILD_INIT([losetup])
1215 UL_REQUIRES_LINUX([losetup])
1216 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1217 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1218
1219 AC_ARG_ENABLE([zramctl],
1220   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1221   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1222 )
1223 UL_BUILD_INIT([zramctl])
1224 UL_REQUIRES_LINUX([zramctl])
1225 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1226 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1227
1228 AC_ARG_ENABLE([fsck],
1229   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1230   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1231 )
1232 UL_BUILD_INIT([fsck])
1233 UL_REQUIRES_BUILD([fsck], [libmount])
1234 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1235
1236
1237 AC_ARG_ENABLE([partx],
1238   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1239   [], [UL_DEFAULT_ENABLE([partx], [check])]
1240 )
1241 UL_BUILD_INIT([partx])
1242 UL_REQUIRES_LINUX([partx])
1243 UL_REQUIRES_BUILD([partx], [libblkid])
1244 UL_REQUIRES_BUILD([partx], [libsmartcols])
1245 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1246
1247
1248 AC_ARG_ENABLE([uuidd],
1249   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1250   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1251 )
1252 UL_BUILD_INIT([uuidd])
1253 UL_REQUIRES_BUILD([uuidd], [libuuid])
1254 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1255 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1256 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1257   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1258 ])
1259 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1260
1261
1262 UL_BUILD_INIT([uuidgen], [check])
1263 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1264 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1265
1266 UL_BUILD_INIT([uuidparse], [check])
1267 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1268 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1269 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1270
1271 UL_BUILD_INIT([blkid], [check])
1272 UL_REQUIRES_BUILD([blkid], [libblkid])
1273 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1274
1275 UL_BUILD_INIT([findfs], [check])
1276 UL_REQUIRES_BUILD([findfs], [libblkid])
1277 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1278
1279 UL_BUILD_INIT([wipefs], [check])
1280 UL_REQUIRES_BUILD([wipefs], [libblkid])
1281 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1282 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1283
1284 UL_BUILD_INIT([findmnt], [check])
1285 UL_REQUIRES_BUILD([findmnt], [libmount])
1286 UL_REQUIRES_BUILD([findmnt], [libblkid])
1287 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1288 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1289
1290
1291 AC_ARG_ENABLE([mountpoint],
1292   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1293   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1294 )
1295 UL_BUILD_INIT([mountpoint])
1296 UL_REQUIRES_BUILD([mountpoint], [libmount])
1297 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1298
1299
1300 AC_ARG_ENABLE([fallocate],
1301   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1302   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1303 )
1304 UL_BUILD_INIT([fallocate])
1305 UL_REQUIRES_LINUX([fallocate])
1306 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1307 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1308
1309 AS_IF([test "x$build_fallocate" = xyes], [
1310   dnl check for valid fallocate() function
1311   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1312   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1313   dnl and program can't be linked.
1314   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1315   dnl function prototype.
1316   AC_MSG_CHECKING([for valid fallocate() function])
1317   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1318 #ifdef HAVE_UNISTD_H
1319 # include <unistd.h>
1320 #endif
1321 #ifdef HAVE_SYS_TYPES_H
1322 # include <sys/types.h>
1323 #endif
1324 #ifdef HAVE_LINUX_FALLOC_H
1325 # include <linux/falloc.h>
1326 #endif
1327 #ifdef HAVE_FCNTL_H
1328 # include <fcntl.h>
1329 #endif
1330 ]],[[
1331    long ret;
1332    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1333    if (ret != 0) {
1334       return 1;
1335    }
1336    ]])],[
1337   AC_MSG_RESULT([yes])
1338   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1339   AC_MSG_RESULT([no])])
1340 ])
1341
1342 AS_IF([test "x$build_fallocate" = xyes], [
1343   dnl check for valid posix_fallocate() function
1344   AC_MSG_CHECKING([for valid posix_fallocate() function])
1345   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1346 #ifdef HAVE_UNISTD_H
1347 # include <unistd.h>
1348 #endif
1349 #ifdef HAVE_SYS_TYPES_H
1350 # include <sys/types.h>
1351 #endif
1352 #ifdef HAVE_LINUX_FALLOC_H
1353 # include <linux/falloc.h>
1354 #endif
1355 #ifdef HAVE_FCNTL_H
1356 # include <fcntl.h>
1357 #endif
1358 ]],[[
1359    long ret;
1360    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1361    if (ret != 0) {
1362       return 1;
1363    }
1364    ]])],[
1365   AC_MSG_RESULT([yes])
1366   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1367   AC_MSG_RESULT([no])])
1368 ])
1369
1370
1371 AC_ARG_ENABLE([unshare],
1372   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1373   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1374 )
1375 UL_BUILD_INIT([unshare])
1376 UL_REQUIRES_LINUX([unshare])
1377 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1378 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1379 AC_CHECK_FUNCS([unshare])
1380
1381 AC_ARG_ENABLE([nsenter],
1382   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1383   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1384 )
1385 UL_BUILD_INIT([nsenter])
1386 UL_REQUIRES_LINUX([nsenter])
1387 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1388 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1389 AC_CHECK_FUNCS([setns])
1390
1391
1392 AC_ARG_WITH([cap_ng],
1393   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1394   [], [with_cap_ng=auto]
1395 )
1396 AS_IF([test "x$with_cap_ng" = xno], [
1397   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1398   have_cap_ng=no
1399 ],[
1400   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1401 ])
1402
1403
1404 AC_ARG_ENABLE([setpriv],
1405   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1406   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1407 )
1408 UL_BUILD_INIT([setpriv])
1409 UL_REQUIRES_LINUX([setpriv])
1410 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1411 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1412 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1413
1414 PKG_CHECK_MODULES([PCRE], [libpcre2-8], [have_pcre=yes], [have_pcre=no])
1415 AS_IF([test "x$have_pcre" = xyes ], [
1416     AC_DEFINE([HAVE_PCRE], [1], [Define if libpcre2 is available])
1417 ])
1418 AM_CONDITIONAL([HAVE_PCRE], [test "x$have_pcre" = xyes])
1419
1420 AC_ARG_ENABLE([hardlink],
1421   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1422   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1423 )
1424 UL_BUILD_INIT([hardlink])
1425 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1426
1427 AC_ARG_ENABLE([eject],
1428   AS_HELP_STRING([--disable-eject], [do not build eject]),
1429   [], [UL_DEFAULT_ENABLE([eject], [check])]
1430 )
1431 UL_BUILD_INIT([eject])
1432 UL_REQUIRES_LINUX([eject])
1433 UL_REQUIRES_BUILD([eject], [libmount])
1434 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1435
1436
1437 AC_ARG_ENABLE([agetty],
1438   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1439   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1440 )
1441 UL_BUILD_INIT([agetty])
1442 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1443 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1444 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1445 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1446   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1447 ],[
1448   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1449 ])
1450
1451
1452 AC_ARG_ENABLE([plymouth_support],
1453   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sylogin(8) and agetty(8)]),
1454   [], [enable_plymouth_support=check]
1455 )
1456 UL_BUILD_INIT([plymouth_support])
1457 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1458 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1459 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1460 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1461 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1462 AS_IF([test "x$build_plymouth_support" = xyes ], [
1463     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1464 ])
1465
1466
1467 AC_ARG_WITH([libz],
1468   AS_HELP_STRING([--without-libz], [compile without libz]),
1469   [], [with_libz=auto]
1470 )
1471 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1472   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1473 ])
1474
1475
1476 AC_ARG_ENABLE([cramfs],
1477   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1478   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1479 )
1480 UL_BUILD_INIT([cramfs])
1481 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1482 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1483
1484
1485 AC_ARG_ENABLE([bfs],
1486   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1487   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1488 )
1489 UL_BUILD_INIT([bfs])
1490 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1491
1492
1493 AC_ARG_ENABLE([minix],
1494   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1495   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1496 )
1497 UL_BUILD_INIT([minix])
1498 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1499
1500
1501 AC_ARG_ENABLE([fdformat],
1502   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1503   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1504 )
1505 UL_BUILD_INIT([fdformat])
1506 UL_REQUIRES_LINUX([fdformat])
1507 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1508
1509
1510 AC_ARG_ENABLE([hwclock],
1511   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1512   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1513 )
1514 have_linuxdummy=$linux_os
1515
1516 UL_BUILD_INIT([hwclock])
1517 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1518 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1519
1520
1521 UL_BUILD_INIT([mkfs], [yes])
1522 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1523
1524 UL_BUILD_INIT([isosize], [yes])
1525 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1526
1527
1528 UL_BUILD_INIT([fstrim], [check])
1529 UL_REQUIRES_LINUX([fstrim])
1530 UL_REQUIRES_BUILD([fstrim], [libmount])
1531 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1532
1533
1534 UL_BUILD_INIT([swapon], [check])
1535 UL_REQUIRES_LINUX([swapon])
1536 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1537 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1538 UL_REQUIRES_BUILD([swapon], [libblkid])
1539 UL_REQUIRES_BUILD([swapon], [libmount])
1540 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1541 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1542 AC_CHECK_FUNCS([swapon])
1543 AC_CHECK_FUNCS([swapoff])
1544
1545
1546 UL_BUILD_INIT([lsblk], [check])
1547 UL_REQUIRES_LINUX([lsblk])
1548 UL_REQUIRES_BUILD([lsblk], [libblkid])
1549 UL_REQUIRES_BUILD([lsblk], [libmount])
1550 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1551 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1552
1553
1554 UL_BUILD_INIT([lscpu], [check])
1555 UL_REQUIRES_LINUX([lscpu])
1556 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1557 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1558 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1559
1560
1561 AC_ARG_ENABLE([lslogins],
1562   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1563   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1564 )
1565 UL_BUILD_INIT([lslogins])
1566 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1567 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1568 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1569 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1570 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1571
1572
1573 UL_BUILD_INIT([chcpu], [check])
1574 UL_REQUIRES_LINUX([chcpu])
1575 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1576 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1577
1578
1579 AC_ARG_ENABLE([wdctl],
1580   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1581   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1582 )
1583 UL_BUILD_INIT([wdctl])
1584 UL_REQUIRES_LINUX([wdctl])
1585 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1586 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1587 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1588
1589
1590 UL_BUILD_INIT([swaplabel], [check])
1591 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1592 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1593
1594
1595 UL_BUILD_INIT([mkswap], [yes])
1596 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1597 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1598   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1599 ])
1600
1601
1602 AC_ARG_ENABLE([cal],
1603   AS_HELP_STRING([--disable-cal], [do not build cal]),
1604   [], [UL_DEFAULT_ENABLE([cal], [check])]
1605 )
1606 UL_BUILD_INIT([cal])
1607 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1608
1609 AC_ARG_ENABLE([logger],
1610   AS_HELP_STRING([--disable-logger], [do not build logger]),
1611   [], [UL_DEFAULT_ENABLE([logger], [check])]
1612 )
1613 UL_BUILD_INIT([logger])
1614 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1615
1616 UL_BUILD_INIT([look], [yes])
1617 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1618
1619 UL_BUILD_INIT([mcookie], [yes])
1620 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1621
1622 UL_BUILD_INIT([namei], [yes])
1623 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1624
1625 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1626 if test "x$matriplet" != "x"; then
1627   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1628   ["Multi-arch triplet for whereis library search path"])
1629 fi
1630 UL_BUILD_INIT([whereis], [yes])
1631 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1632
1633 UL_BUILD_INIT([getopt], [yes])
1634 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1635
1636
1637 UL_BUILD_INIT([blockdev], [check])
1638 UL_REQUIRES_LINUX([blockdev])
1639 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1640
1641
1642 UL_BUILD_INIT([prlimit], [check])
1643 UL_REQUIRES_LINUX([prlimit])
1644 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1645 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1646 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1647 AS_IF([test "x$build_prlimit" = xyes], [
1648   AC_CHECK_FUNCS([prlimit])
1649 ])
1650
1651
1652 UL_BUILD_INIT([lslocks], [check])
1653 UL_REQUIRES_LINUX([lslocks])
1654 UL_REQUIRES_BUILD([lslocks], [libmount])
1655 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1656 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1657
1658
1659 AC_ARG_ENABLE([switch_root],
1660   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1661   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1662 )
1663 UL_BUILD_INIT([switch_root])
1664 UL_REQUIRES_LINUX([switch_root])
1665 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1666 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
1667 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1668
1669
1670 AC_ARG_ENABLE([pivot_root],
1671   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1672   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1673 )
1674 UL_BUILD_INIT([pivot_root])
1675 UL_REQUIRES_LINUX([pivot_root])
1676 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1677 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1678
1679
1680 UL_BUILD_INIT([flock], [check])
1681 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
1682 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1683
1684
1685 AC_ARG_ENABLE([lsmem],
1686   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1687   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1688 )
1689 UL_BUILD_INIT([lsmem])
1690 UL_REQUIRES_LINUX([lsmem])
1691 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1692 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1693
1694
1695 AC_ARG_ENABLE([chmem],
1696   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1697   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1698 )
1699 UL_BUILD_INIT([chmem])
1700 UL_REQUIRES_LINUX([chmem])
1701 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1702
1703 UL_BUILD_INIT([ipcmk], [yes])
1704 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1705
1706
1707 AC_ARG_ENABLE([ipcrm],
1708   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1709   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1710 )
1711 UL_BUILD_INIT([ipcrm])
1712 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1713
1714 AC_ARG_ENABLE([ipcs],
1715   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1716   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1717 )
1718 UL_BUILD_INIT([ipcs])
1719 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1720
1721 UL_BUILD_INIT([choom], [check])
1722 UL_REQUIRES_LINUX([choom])
1723 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1724
1725 UL_BUILD_INIT([lsipc], [check])
1726 UL_REQUIRES_LINUX([lsipc])
1727 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1728 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1729
1730 UL_BUILD_INIT([lsns], [check])
1731 UL_REQUIRES_LINUX([lsns])
1732 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1733 UL_REQUIRES_BUILD([lsns], [libmount])
1734 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1735
1736 UL_BUILD_INIT([renice], [yes])
1737 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1738
1739
1740 AC_ARG_ENABLE([rfkill],
1741   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1742   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1743 )
1744 UL_BUILD_INIT([rfkill])
1745 UL_REQUIRES_LINUX([rfkill])
1746 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1747 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1748
1749
1750 UL_BUILD_INIT([setsid], [yes])
1751 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1752
1753 UL_BUILD_INIT([readprofile], [check])
1754 UL_REQUIRES_LINUX([readprofile])
1755 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1756
1757 UL_BUILD_INIT([dmesg], [check])
1758 UL_REQUIRES_LINUX([dmesg])
1759 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1760
1761 UL_BUILD_INIT([ctrlaltdel], [check])
1762 UL_REQUIRES_LINUX([ctrlaltdel])
1763 dnl we assume reboot() to be the 1-argument variant, because even considering
1764 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1765 dnl reboot() with multiple arguments is yet only found in glibc versions
1766 dnl earlier than 2.x.
1767 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1768 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1769
1770 UL_BUILD_INIT([fincore], [check])
1771 UL_REQUIRES_LINUX([fincore])
1772 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1773 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1774
1775 UL_BUILD_INIT([fsfreeze], [check])
1776 UL_REQUIRES_LINUX([fsfreeze])
1777 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1778
1779 UL_BUILD_INIT([blkdiscard], [check])
1780 UL_REQUIRES_LINUX([blkdiscard])
1781 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1782
1783 UL_BUILD_INIT([blkzone], [check])
1784 UL_REQUIRES_LINUX([blkzone])
1785 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1786 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1787
1788 UL_BUILD_INIT([ldattach], [check])
1789 UL_REQUIRES_LINUX([ldattach])
1790 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1791
1792 UL_BUILD_INIT([rtcwake], [check])
1793 UL_REQUIRES_LINUX([rtcwake])
1794 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1795
1796 UL_BUILD_INIT([setarch], [check])
1797 UL_REQUIRES_LINUX([setarch])
1798 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1799
1800 UL_BUILD_INIT([script], [check])
1801 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1802 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1803
1804 UL_BUILD_INIT([scriptreplay], [yes])
1805 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1806
1807 UL_BUILD_INIT([col], [yes])
1808 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1809
1810 UL_BUILD_INIT([colcrt], [yes])
1811 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1812
1813 UL_BUILD_INIT([colrm], [yes])
1814 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1815
1816 UL_BUILD_INIT([column], [check])
1817 UL_REQUIRES_BUILD([column], [libsmartcols])
1818 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1819
1820 UL_BUILD_INIT([hexdump], [yes])
1821 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1822
1823 UL_BUILD_INIT([rev], [yes])
1824 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1825
1826
1827 AC_ARG_ENABLE([tunelp],
1828   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1829   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1830 )
1831 UL_BUILD_INIT([tunelp])
1832 UL_REQUIRES_LINUX([tunelp])
1833 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1834
1835
1836 AC_ARG_ENABLE([kill],
1837   AS_HELP_STRING([--disable-kill], [do not build kill]),
1838   [], [UL_DEFAULT_ENABLE([kill], [check])]
1839 )
1840 UL_BUILD_INIT([kill])
1841 UL_REQUIRES_LINUX([kill])
1842 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1843
1844
1845 AC_ARG_ENABLE([last],
1846   AS_HELP_STRING([--disable-last], [do not build last]),
1847   [], [UL_DEFAULT_ENABLE([last], [check])]
1848 )
1849 UL_BUILD_INIT([last])
1850 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1851 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1852 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1853
1854
1855 AC_ARG_ENABLE([utmpdump],
1856   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1857   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1858 )
1859 UL_BUILD_INIT([utmpdump])
1860 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1861 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1862 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1863
1864
1865 AC_ARG_ENABLE([line],
1866   AS_HELP_STRING([--enable-line], [build line]),
1867   [], [UL_DEFAULT_ENABLE([line], [no])]
1868 )
1869 UL_BUILD_INIT([line])
1870 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1871
1872
1873 AC_ARG_ENABLE([mesg],
1874   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1875   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1876 )
1877 UL_BUILD_INIT([mesg])
1878 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1879
1880
1881 AC_ARG_ENABLE([raw],
1882   AS_HELP_STRING([--disable-raw], [do not build raw]),
1883   [], [UL_DEFAULT_ENABLE([raw], [check])]
1884 )
1885 UL_BUILD_INIT([raw])
1886 UL_REQUIRES_LINUX([raw])
1887 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1888 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1889
1890
1891 AC_ARG_ENABLE([rename],
1892   AS_HELP_STRING([--disable-rename], [do not build rename]),
1893   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1894 )
1895 UL_BUILD_INIT([rename])
1896 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1897
1898
1899 AC_ARG_ENABLE([vipw],
1900   AS_HELP_STRING([--enable-vipw], [build vipw]),
1901   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1902 )
1903 UL_BUILD_INIT([vipw])
1904 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1905 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1906
1907
1908 AC_ARG_ENABLE([newgrp],
1909   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1910   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1911 )
1912 UL_BUILD_INIT([newgrp])
1913 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
1914 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1915
1916
1917 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1918   [], [with_user=check]
1919 )
1920 have_user=no
1921 AS_IF([test "x$with_user" != xno], [
1922   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1923   AS_CASE([$with_user:$have_user],
1924     [yes:no],
1925       [AC_MSG_ERROR([user selected but libuser not found])],
1926     [*:yes],
1927       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1928   )
1929   # temporary solution, libuser has stupid .pc where are exported all
1930   # private dependencies to Requires: instead of Requires.private:
1931   AS_IF([test "x$have_user" = xyes], [
1932     LIBUSER_LIBS=-luser
1933   ])
1934 ])
1935 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1936
1937 AC_ARG_ENABLE([chfn-chsh-password],
1938   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1939   [], [enable_chfn_chsh_password=yes]
1940 )
1941
1942 AC_ARG_ENABLE([chfn-chsh],
1943   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1944   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1945 )
1946 UL_BUILD_INIT([chfn_chsh])
1947 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1948 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1949
1950 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1951   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1952   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1953 ])
1954 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1955 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1956
1957 AC_ARG_ENABLE([chsh-only-listed],
1958   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1959   [], enable_chsh_only_listed=yes
1960 )
1961
1962 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1963   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1964 ])
1965
1966
1967 AC_ARG_ENABLE([login],
1968   AS_HELP_STRING([--disable-login], [do not build login]),
1969   [], [UL_DEFAULT_ENABLE([login], [check])]
1970 )
1971 UL_BUILD_INIT([login])
1972 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1973 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1974 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1975 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1976 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1977
1978 AC_ARG_ENABLE([login-chown-vcs],
1979   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1980   [], [enable_login_chown_vcs=no]
1981 )
1982
1983 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1984   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1985 ])
1986
1987 AC_ARG_ENABLE([login-stat-mail],
1988   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
1989   [], [enable_login_stat_mail=no]
1990 )
1991
1992 AS_IF([test "x$enable_login_stat_mail" = xyes], [
1993   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
1994 ])
1995
1996
1997 AC_ARG_ENABLE([nologin],
1998   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
1999   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
2000 )
2001 UL_BUILD_INIT([nologin])
2002 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
2003
2004
2005 AC_ARG_ENABLE([sulogin],
2006   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
2007   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
2008 )
2009 UL_BUILD_INIT([sulogin])
2010 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
2011 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
2012 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
2013
2014
2015 AC_ARG_ENABLE([su],
2016   AS_HELP_STRING([--disable-su], [do not build su]),
2017   [], [UL_DEFAULT_ENABLE([su], [check])]
2018 )
2019 UL_BUILD_INIT([su])
2020 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2021 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2022 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2023 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2024
2025
2026 AC_ARG_ENABLE([runuser],
2027   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2028   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2029 )
2030 UL_BUILD_INIT([runuser])
2031 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2032 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2033 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2034 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2035
2036
2037 AC_ARG_ENABLE([ul],
2038   AS_HELP_STRING([--disable-ul], [do not build ul]),
2039   [], [UL_DEFAULT_ENABLE([ul], [check])]
2040 )
2041 UL_BUILD_INIT([ul])
2042 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2043 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2044
2045
2046 AC_ARG_ENABLE([more],
2047   AS_HELP_STRING([--disable-more], [do not build more]),
2048   [], [UL_DEFAULT_ENABLE([more], [check])]
2049 )
2050 UL_BUILD_INIT([more])
2051 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2052 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2053
2054
2055 AC_ARG_ENABLE([pg],
2056   AS_HELP_STRING([--enable-pg], [build pg]),
2057   [], [UL_DEFAULT_ENABLE([pg], [no])]
2058 )
2059 UL_BUILD_INIT([pg])
2060 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2061 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2062
2063
2064 AC_ARG_ENABLE([setterm],
2065   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2066   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2067 )
2068 UL_BUILD_INIT([setterm])
2069 UL_REQUIRES_LINUX([setterm])
2070 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2071 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2072
2073 # build_schedutils= is just configure-only variable to control
2074 # ionice, taskset and chrt
2075 AC_ARG_ENABLE([schedutils],
2076   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2077   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2078 )
2079
2080
2081 UL_ENABLE_ALIAS([ionice], [schedutils])
2082 UL_BUILD_INIT([ionice])
2083 UL_REQUIRES_SYSCALL_CHECK([ionice],
2084         [UL_CHECK_SYSCALL([ioprio_set],
2085           [alpha],      [442],
2086           [i*86],       [289],
2087           [ia64*],      [1274],
2088           [powerpc*],   [273],
2089           [s390*],      [282],
2090           [sparc*],     [196],
2091           [sh*],        [288],
2092           [x86_64*],    [251])],
2093         [ioprio_set])
2094
2095 UL_REQUIRES_SYSCALL_CHECK([ionice],
2096         [UL_CHECK_SYSCALL([ioprio_get],
2097           [alpha],      [443],
2098           [i*86],       [290],
2099           [ia64*],      [1275],
2100           [powerpc*],   [274],
2101           [s390*],      [283],
2102           [sparc*],     [218],
2103           [sh*],        [289],
2104           [x86_64*],    [252])],
2105         [ioprio_get])
2106
2107 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2108
2109
2110 UL_ENABLE_ALIAS([taskset], [schedutils])
2111 UL_BUILD_INIT([taskset])
2112 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2113 UL_REQUIRES_SYSCALL_CHECK([taskset],
2114         [UL_CHECK_SYSCALL([sched_getaffinity])],
2115         [sched_getaffinity])
2116 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2117
2118
2119 have_schedsetter=no
2120 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2121       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2122
2123 UL_ENABLE_ALIAS([chrt], [schedutils])
2124 UL_BUILD_INIT([chrt])
2125 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2126 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2127
2128 AS_IF([test "x$build_chrt" = xyes], [
2129         UL_CHECK_SYSCALL([sched_setattr])
2130 ])
2131
2132
2133 AC_ARG_ENABLE([wall],
2134   AS_HELP_STRING([--disable-wall], [do not build wall]),
2135   [], [UL_DEFAULT_ENABLE([wall], [check])]
2136 )
2137 UL_BUILD_INIT([wall])
2138 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2139 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2140
2141
2142 AC_ARG_ENABLE([write],
2143   AS_HELP_STRING([--enable-write], [build write]),
2144   [], [UL_DEFAULT_ENABLE([write], [no])]
2145 )
2146 UL_BUILD_INIT([write])
2147 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2148 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2149 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2150
2151
2152 AC_ARG_WITH([btrfs],
2153   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2154   [], [with_btrfs=check]
2155 )
2156 have_btrfs=no
2157 AS_IF([test "x$with_btrfs" != xno], [
2158   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2159     [yes:no],
2160     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2161     [check:no],
2162        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2163     [*:yes],
2164        [have_btrfs=yes
2165         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2166   )
2167 ])
2168 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2169
2170
2171 AC_ARG_WITH([systemd],
2172   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2173   [], [with_systemd=check]
2174 )
2175
2176 have_systemd=no
2177 AS_IF([test "x$with_systemd" != xno], [
2178   # new version -- all libsystemd-* libs merged into libsystemd
2179   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2180   # old versions
2181   AS_IF([test "x$have_systemd" != "xyes"], [
2182     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2183                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2184     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2185                       [have_systemd_journal=yes], [have_systemd_journal=no])
2186     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2187            have_systemd=yes])
2188   ])
2189   AS_CASE([$with_systemd:$have_systemd],
2190     [yes:no],
2191       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2192     [*:yes],
2193        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2194   )
2195 ])
2196 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2197
2198
2199 AC_ARG_WITH([systemdsystemunitdir],
2200   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2201   [], [with_systemdsystemunitdir=check]
2202 )
2203 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2204   AS_IF([test "x$have_systemd" = xyes], [
2205     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2206   ],[
2207     with_systemdsystemunitdir=no
2208   ])
2209 ])
2210 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2211   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2212 ])
2213
2214
2215 AC_ARG_WITH([smack],
2216   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2217   [], [with_smack=no]
2218 )
2219 AS_IF([test "x$with_smack" = xyes], [
2220   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2221 ])
2222
2223
2224 AC_ARG_WITH([bashcompletiondir],
2225   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2226   [],
2227   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2228     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2229   ], [
2230     with_bashcompletiondir=${datadir}/bash-completion/completions
2231   ])
2232 ])
2233 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2234
2235 AC_ARG_ENABLE([bash-completion],
2236   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2237   [], [enable_bash_completion=yes]
2238 )
2239
2240 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2241
2242
2243 AC_ARG_WITH([python],
2244   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2245   [], [with_python=check withval=check]
2246 )
2247
2248 have_python=no
2249 have_libpython=no
2250 AS_IF([test "x$with_python" != xno], [
2251   # We follow distributions default and look for PKG module name "python"
2252   # (minimal version is 2) but if major version is explicitly specified by
2253   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2254   # "python3".
2255   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2256         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2257
2258   # check for python interpreter
2259   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2260   AS_CASE([$with_python:$have_python],
2261     [yes:no],
2262       [AC_MSG_ERROR([python selected but python interpreter not found])],
2263     [check:no],
2264        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2265     [*:yes],
2266        # check for python development stuff
2267        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2268                           [have_libpython=yes], [have_libpython=no])]
2269   )
2270 ])
2271
2272
2273 AC_ARG_ENABLE([pylibmount],
2274   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2275   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2276 )
2277 UL_BUILD_INIT([pylibmount])
2278 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2279 UL_REQUIRES_BUILD([pylibmount], [libmount])
2280 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2281
2282 # We need to introduce a verbatim dependency into the Makefile, without automake
2283 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2284 verbatim_pylibmount_dependency='
2285
2286 # pylibmountexec module must be installed after usrlib_exec libraries,
2287 # otherwise the libtool relink step will fail to find libmount.la and
2288 # will try -lmount which is possibly not available.
2289 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2290
2291 '
2292 AC_SUBST([verbatim_pylibmount_dependency])
2293 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2294
2295 AC_ARG_ENABLE([pg-bell],
2296   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2297   [], [enable_pg_bell=yes]
2298 )
2299
2300 AS_IF([test "x$enable_pg_bell" = xyes], [
2301   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2302 ])
2303
2304
2305 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2306 AC_ARG_ENABLE([fs-paths-default],
2307   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2308   [AS_CASE([$enableval],
2309     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2310     [no],  [fs_paths_defaults=""],
2311     [fs_paths_defaults="$enableval"]
2312   )],
2313   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2314 )
2315 AC_ARG_ENABLE([fs-paths-extra],
2316   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2317   [AS_CASE([$enableval],
2318      [yes|no], [fs_paths_extra=""],
2319      [fs_paths_extra="$enableval"]
2320   )],
2321   [fs_paths_extra=""]
2322 )
2323 fs_paths="$fs_paths_defaults"
2324 AS_IF([test "x$fs_paths_extra" != "x"], [
2325   AS_IF([test "x$fs_paths" != "x"], [
2326     fs_paths="${fs_paths}:"
2327   ])
2328   fs_paths="${fs_paths}${fs_paths_extra}"
2329 ])
2330 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2331
2332
2333 AC_ARG_ENABLE([use-tty-group],
2334   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2335   [], [enable_use_tty_group=yes]
2336 )
2337 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2338
2339 AS_IF([test "x$enable_use_tty_group" = xyes], [
2340   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2341 ])
2342
2343
2344 AC_ARG_ENABLE([sulogin-emergency-mount],
2345   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2346                  [use emergency mount of /dev and /proc for sulogin]),
2347   [], [enable_sulogin_emergency_mount=no]
2348 )
2349
2350 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2351   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2352             [Should sulogin use a emergency mount of /dev and /proc?])
2353 ])
2354
2355
2356 AC_ARG_ENABLE([usrdir-path],
2357   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2358   [], [enable_usrdir_path=no]
2359 )
2360
2361 AS_IF([test "x$enable_usrdir_path" = xyes], [
2362   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2363 ])
2364
2365
2366 AC_ARG_ENABLE([makeinstall-chown],
2367   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2368   [], [enable_makeinstall_chown=yes]
2369 )
2370 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2371
2372
2373 AC_ARG_ENABLE([makeinstall-setuid],
2374   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2375   [], [enable_makeinstall_setuid=yes]
2376 )
2377 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2378
2379
2380 AC_ARG_ENABLE([colors-default],
2381   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2382   [], [enable_colors_default=yes]
2383 )
2384 AS_IF([test "x$enable_colors_default" = xyes], [
2385   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2386 ])
2387
2388
2389 AC_ARG_VAR([SUID_CFLAGS],
2390            [CFLAGS used for binaries which are usually with the suid bit])
2391 AC_ARG_VAR([SUID_LDFLAGS],
2392            [LDFLAGS used for binaries which are usually with the suid bit])
2393
2394 AC_ARG_VAR([DAEMON_CFLAGS],
2395            [CFLAGS used for binaries which are usually executed as daemons])
2396 AC_ARG_VAR([DAEMON_LDFLAGS],
2397            [LDFLAGS used for binaries which are usually executed as daemons])
2398
2399 AC_ARG_VAR([SOLIB_CFLAGS],
2400            [CFLAGS used for shared libraries])
2401 AC_ARG_VAR([SOLIB_LDFLAGS],
2402            [LDFLAGS used for shared libraries])
2403
2404 AC_ARG_VAR([ADJTIME_PATH],
2405            [Path to hwclock adjtime file, default /etc/adjtime])
2406 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2407 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2408
2409
2410 LIBS=""
2411
2412
2413 AC_CONFIG_HEADERS([config.h])
2414
2415 #
2416 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2417 # more details.
2418 #
2419 AC_CONFIG_FILES([
2420 Makefile
2421 libblkid/docs/Makefile
2422 libblkid/docs/version.xml
2423 libblkid/src/blkid.h
2424 libfdisk/docs/Makefile
2425 libfdisk/docs/version.xml
2426 libfdisk/src/libfdisk.h
2427 libmount/docs/Makefile
2428 libmount/docs/version.xml
2429 libmount/src/libmount.h
2430 libsmartcols/docs/Makefile
2431 libsmartcols/docs/version.xml
2432 libsmartcols/src/libsmartcols.h
2433 po/Makefile.in
2434 ])
2435
2436 AC_OUTPUT
2437
2438 AC_MSG_RESULT([
2439         ${PACKAGE}  ${VERSION}
2440
2441         prefix:            ${prefix}
2442         exec prefix:       ${exec_prefix}
2443
2444         runstatedir:       ${runstatedir}
2445         bindir:            ${bindir}
2446         sbindir:           ${sbindir}
2447         libdir:            ${libdir}
2448         includedir:        ${includedir}
2449         usrbin_execdir:    ${usrbin_execdir}
2450         usrsbin_execdir:   ${usrsbin_execdir}
2451         usrlib_execdir:    ${usrlib_execdir}
2452
2453         compiler:          ${CC}
2454         cflags:            ${CFLAGS}
2455         suid cflags:       ${SUID_CFLAGS}
2456         ldflags:           ${LDFLAGS}
2457         suid ldflags:      ${SUID_LDFLAGS}
2458
2459         Python:            ${PYTHON}
2460         Python version:    ${PYTHON_VERSION}
2461         Python libs:       ${pyexecdir}
2462
2463         Bash completions:  ${with_bashcompletiondir}
2464         Systemd support:   ${have_systemd}
2465         Systemd unitdir:   ${with_systemdsystemunitdir}
2466         Btrfs support:     ${have_btrfs}
2467         Wide-char support: ${build_widechar}
2468
2469         warnings:
2470
2471 ${WARN_CFLAGS}
2472
2473         Type 'make' or 'make <utilname>' to compile.
2474 ])