xfsprogs: convert to SPDX license tags

xfsprogs: convert to SPDX license tags

Remove the verbose license text from XFS files and replace them
with SPDX tags. This does not change the license of any of the code,
merely refers to the common, up-to-date license files in LICENSES/

This change was mostly scripted. Makefiles and various scripts
and build files were modified by hand. Files missing license
statements were tagged as GPLv2.0, the rest were detected
and modified by the following command:

for f in `git grep -l "GNU General" |grep [ch]$` ; do
        echo $f
        cat $f | awk -f hdr.awk > $f.new
        mv -f $f.new $f
done

And the hdr.awk script that did the modification (including
detecting the difference between GPL-2.0 and GPL-2.0+ licenses)
is as follows:

$ cat hdr.awk
BEGIN {
        hdr = 1.0
        tag = "GPL-2.0"
        str = ""
}

/^ \* This program is free software/ {
        hdr = 2.0;
        next
}

/any later version./ {
        tag = "GPL-2.0+"
        next
}

/^ \*\// {
        if (hdr > 0.0) {
                print "// SPDX-License-Identifier: " tag
                print str
                print $0
                str=""
                hdr = 0.0
                next
        }
        print $0
        next
}

/^ \* / {
        if (hdr > 1.0)
                next
        if (hdr > 0.0) {
                if (str != "")
                        str = str "\n"
                str = str $0
                next
        }
        print $0
        next
}

/^ \*/ {
        if (hdr > 0.0)
                next
        print $0
        next
}

// {
        if (hdr > 0.0) {
                if (str != "")
                        str = str "\n"
                str = str $0
                next
        }
        print $0
}

END { }
$

[sandeen: drop libxfs bits inherited from kernel]

Signed-off-by: Dave Chinner <dchinner@redhat.com>
Reviewed-by: Eric Sandeen <sandeen@redhat.com>
Signed-off-by: Eric Sandeen <sandeen@sandeen.net>