From: Aki Tuomi <aki.tuomi@open-xchange.com>
Date: Mon, 25 Apr 2022 19:28:29 +0000 (+0300)
Subject: m4: st_tim.m4 - Modernize m4 syntax
X-Git-Tag: 2.4.0~3884
X-Git-Url: http://git.ipfire.org/cgi-bin/gitweb.cgi?a=commitdiff_plain;h=8bf56c69832c862bba26383365e629f2ebbca02f;p=thirdparty%2Fdovecot%2Fcore.git

m4: st_tim.m4 - Modernize m4 syntax
---

diff --git a/m4/st_tim.m4 b/m4/st_tim.m4
index aa790b63e7..f66c95692a 100644
--- a/m4/st_tim.m4
+++ b/m4/st_tim.m4
@@ -1,41 +1,41 @@
 AC_DEFUN([DOVECOT_ST_TIM_TIMESPEC], [
   AC_CACHE_CHECK([if struct stat has st_?tim timespec fields],i_cv_have_st_tim_timespec,[
-    AC_TRY_COMPILE([
+    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
       #include <sys/types.h>
       #include <sys/stat.h>
       #include <unistd.h>
-    ], [
+    ]], [[
       struct stat st;
       unsigned long x = st.st_mtim.tv_nsec;
   
       return 0;
-    ], [
+    ]])],[
       i_cv_have_st_tim_timespec=yes
     ], [
       i_cv_have_st_tim_timespec=no
     ])
   ])
-  if test $i_cv_have_st_tim_timespec = yes; then
+  AS_IF([test $i_cv_have_st_tim_timespec = yes], [
     AC_DEFINE(HAVE_STAT_XTIM,, [Define if you have st_?tim timespec fields in struct stat])
-  fi
+  ])
 
   AC_CACHE_CHECK([if struct stat has st_?timespec fields],i_cv_have_st_timespec,[
-    AC_TRY_COMPILE([
+    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
       #include <sys/types.h>
       #include <sys/stat.h>
       #include <unistd.h>
-    ], [
+    ]], [[
       struct stat st;
       unsigned long x = st.st_mtimespec.tv_nsec;
   
       return 0;
-    ], [
+    ]])],[
       i_cv_have_st_timespec=yes
     ], [
       i_cv_have_st_timespec=no
     ])
   ])
-  if test $i_cv_have_st_timespec = yes; then
+  AS_IF([test $i_cv_have_st_timespec = yes], [
     AC_DEFINE(HAVE_STAT_XTIMESPEC,, [Define if you have st_?timespec fields in struct stat])
-  fi
+  ])
 ])