From: Bruno Haible <bruno@clisp.org>
Date: Sat, 22 Jul 2006 15:43:56 +0000 (+0000)
Subject: Module 'minmax' from gnulib.
X-Git-Tag: 0.16.x-branchpoint~341
X-Git-Url: http://git.ipfire.org/cgi-bin/gitweb.cgi?a=commitdiff_plain;h=b31bdd9392154c9367d7a1f122da0fc1ce0929a4;p=thirdparty%2Fgettext.git

Module 'minmax' from gnulib.
---

diff --git a/gettext-tools/m4/ChangeLog b/gettext-tools/m4/ChangeLog
index 0ab037e00..1e0dff69b 100644
--- a/gettext-tools/m4/ChangeLog
+++ b/gettext-tools/m4/ChangeLog
@@ -1,5 +1,8 @@
 2006-07-22  Bruno Haible  <bruno@clisp.org>
 
+	* minmax.m4: New file, from gnulib.
+	* Makefile.am (EXTRA_DIST): Add it.
+
 	* mbswidth.m4: Update from gnulib.
 
 	* wcwidth.m4: New file, from gnulib.
diff --git a/gettext-tools/m4/Makefile.am b/gettext-tools/m4/Makefile.am
index 2127047f5..0234e6e91 100644
--- a/gettext-tools/m4/Makefile.am
+++ b/gettext-tools/m4/Makefile.am
@@ -74,6 +74,7 @@ mbrtowc.m4 \
 mbstate_t.m4 \
 mbswidth.m4 \
 memchr.m4 \
+minmax.m4 \
 mkdtemp.m4 \
 onceonly.m4 \
 pathmax.m4 \
diff --git a/gettext-tools/m4/minmax.m4 b/gettext-tools/m4/minmax.m4
new file mode 100644
index 000000000..bbd1ba0b8
--- /dev/null
+++ b/gettext-tools/m4/minmax.m4
@@ -0,0 +1,41 @@
+# minmax.m4 serial 2
+dnl Copyright (C) 2005 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_PREREQ(2.52)
+
+AC_DEFUN([gl_MINMAX],
+[
+  AC_REQUIRE([gl_PREREQ_MINMAX])
+])
+
+# Prerequisites of lib/minmax.h.
+AC_DEFUN([gl_PREREQ_MINMAX],
+[
+  gl_MINMAX_IN_HEADER([limits.h])
+  gl_MINMAX_IN_HEADER([sys/param.h])
+])
+
+dnl gl_MINMAX_IN_HEADER(HEADER)
+dnl The parameter has to be a literal header name; it cannot be macro,
+dnl nor a shell variable. (Because autoheader collects only AC_DEFINE
+dnl invocations with a literal macro name.)
+AC_DEFUN([gl_MINMAX_IN_HEADER],
+[
+  m4_pushdef([header], AS_TR_SH([$1]))
+  m4_pushdef([HEADER], AS_TR_CPP([$1]))
+  AC_CACHE_CHECK([whether <$1> defines MIN and MAX],
+    [gl_cv_minmax_in_]header,
+    [AC_TRY_COMPILE([#include <$1>
+int x = MIN (42, 17);], [],
+       [gl_cv_minmax_in_]header[=yes],
+       [gl_cv_minmax_in_]header[=no])])
+  if test $gl_cv_minmax_in_[]header = yes; then
+    AC_DEFINE([HAVE_MINMAX_IN_]HEADER, 1,
+      [Define to 1 if <$1> defines the MIN and MAX macros.])
+  fi
+  m4_popdef([HEADER])
+  m4_popdef([header])
+])