From: Aki Tuomi <aki.tuomi@open-xchange.com>
Date: Mon, 25 Apr 2022 19:42:04 +0000 (+0300)
Subject: m4: want_db.m4 - Modernize m4 syntax
X-Git-Tag: 2.4.0~3879
X-Git-Url: http://git.ipfire.org/gitweb.cgi?a=commitdiff_plain;h=4d080798d935497a86d305cdd3b0797b4e9d1d6f;p=thirdparty%2Fdovecot%2Fcore.git

m4: want_db.m4 - Modernize m4 syntax
---

diff --git a/m4/want_db.m4 b/m4/want_db.m4
index 469dedb190..d2ff25f572 100644
--- a/m4/want_db.m4
+++ b/m4/want_db.m4
@@ -1,33 +1,33 @@
 AC_DEFUN([DOVECOT_WANT_DB], [
-  if test $want_db != no; then
+  AS_IF([test $want_db != no], [
     AC_CACHE_CHECK([db_env_create in -ldb],i_cv_have_db_env_create,[
       old_LIBS=$LIBS
       LIBS="$LIBS -ldb"
-      AC_TRY_LINK([
+      AC_LINK_IFELSE([AC_LANG_PROGRAM([[
         #include <db.h>
-      ], [
+      ]], [[
         db_env_create(0, 0);
-      ], [
+      ]])],[
         i_cv_have_db_env_create=yes
       ], [
         i_cv_have_db_env_create=no
       ])
       LIBS=$old_LIBS
     ])
-    if test $i_cv_have_db_env_create = yes; then
+    AS_IF([test $i_cv_have_db_env_create = yes], [
       AC_CHECK_HEADER(db.h, [
         DICT_LIBS="$DICT_LIBS -ldb"
         dict_drivers="$dict_drivers db"
         AC_DEFINE(BUILD_DB,, [Build with Berkeley DB support])
       ], [
-        if test $want_db = yes; then
-          AC_ERROR([Can't build with db support: db.h not found])
-        fi
+        AS_IF([test $want_db = yes], [
+          AC_MSG_ERROR(Can't build with db support: db.h not found)
+        ])
       ])
-    else
-      if test $want_db = yes; then
+    ], [
+      AS_IF([test $want_db = yes], [
         AC_ERROR([Can't build with db support: libdb not found])
-      fi
-    fi
-  fi
+      ])
+    ])
+  ])
 ])