From: Aki Tuomi <aki.tuomi@open-xchange.com>
Date: Mon, 25 Apr 2022 18:35:35 +0000 (+0300)
Subject: m4: ioloop.m4 - Modernize m4 syntax
X-Git-Tag: 2.4.0~3899
X-Git-Url: http://git.ipfire.org/gitweb.cgi?a=commitdiff_plain;h=57564089a92fc6288033a3d316eec858ddae0701;p=thirdparty%2Fdovecot%2Fcore.git

m4: ioloop.m4 - Modernize m4 syntax
---

diff --git a/m4/ioloop.m4 b/m4/ioloop.m4
index 0f7dde05e6..d8932127b7 100644
--- a/m4/ioloop.m4
+++ b/m4/ioloop.m4
@@ -2,52 +2,53 @@ dnl * I/O loop function
 AC_DEFUN([DOVECOT_IOLOOP], [
   have_ioloop=no
   
-  if test "$ioloop" = "best" || test "$ioloop" = "epoll"; then
+  AS_IF([test "$ioloop" = "best" || test "$ioloop" = "epoll"], [
     AC_CACHE_CHECK([whether we can use epoll],i_cv_epoll_works,[
-      AC_TRY_RUN([
+      AC_RUN_IFELSE([AC_LANG_PROGRAM([[
         #include <sys/epoll.h>
-    
-        int main()
-        {
+      ]], [[
   	return epoll_create(5) < 1;
-        }
-      ], [
+      ]])],[
         i_cv_epoll_works=yes
       ], [
         i_cv_epoll_works=no
-      ])
+      ],[])
     ])
-    if test $i_cv_epoll_works = yes; then
+    AS_IF([test $i_cv_epoll_works = yes], [
       AC_DEFINE(IOLOOP_EPOLL,, [Implement I/O loop with Linux 2.6 epoll()])
       have_ioloop=yes
       ioloop=epoll
-    else
-      if test "$ioloop" = "epoll" ; then
+    ], [
+      AS_IF([test "$ioloop" = "epoll"], [
         AC_MSG_ERROR([epoll ioloop requested but epoll_create() is not available])
-      fi
-    fi
-  fi
+      ])
+    ])
+  ])
   
-  if test "$ioloop" = "best" || test "$ioloop" = "kqueue"; then
-      if test "$ac_cv_func_kqueue" = yes && test "$ac_cv_func_kevent" = yes; then
+  AS_IF([test "$ioloop" = "best" || test "$ioloop" = "kqueue"], [
+      AS_IF([test "$ac_cv_func_kqueue" = yes && test "$ac_cv_func_kevent" = yes], [
         AC_DEFINE(IOLOOP_KQUEUE,, [Implement I/O loop with BSD kqueue()])
         ioloop=kqueue
         have_ioloop=yes
-      elif test "$ioloop" = "kqueue"; then
+      ], [test "$ioloop" = "kqueue"], [
         AC_MSG_ERROR([kqueue ioloop requested but kqueue() is not available])
-      fi
-  fi
+      ])
+  ])
   
-  if test "$ioloop" = "best" || test "$ioloop" = "poll"; then
+  AS_IF([test "$ioloop" = "best" || test "$ioloop" = "poll"], [
     AC_CHECK_FUNC(poll, [
       AC_DEFINE(IOLOOP_POLL,, [Implement I/O loop with poll()])
       ioloop=poll
       have_ioloop=yes
-    ])
-  fi
+    ], [
+      AS_IF([test "$ioloop" = "poll"], [
+        AC_MSG_ERROR([pool ioloop requested but poll() is not available])
+      ])
+     ])
+  ])
   
-  if test "$have_ioloop" = "no"; then
+  AS_IF([test "$have_ioloop" = "no"], [
     AC_DEFINE(IOLOOP_SELECT,, [Implement I/O loop with select()])
     ioloop="select"
-  fi
-]) 
+  ])
+])