From: Bruno Haible <bruno@clisp.org>
Date: Mon, 5 Dec 2005 12:01:50 +0000 (+0000)
Subject: Reliable construction of DLLs on Woe32.
X-Git-Tag: v0.15~340
X-Git-Url: http://git.ipfire.org/gitweb.cgi?a=commitdiff_plain;h=6942eb8201d887d73aef5cd7ee0a9ff0b1ee5bba;p=thirdparty%2Fgettext.git

Reliable construction of DLLs on Woe32.
---

diff --git a/gettext-runtime/m4/woe32-dll.m4 b/gettext-runtime/m4/woe32-dll.m4
new file mode 100644
index 000000000..73530b426
--- /dev/null
+++ b/gettext-runtime/m4/woe32-dll.m4
@@ -0,0 +1,41 @@
+# woe32-dll.m4 serial 1
+dnl Copyright (C) 2005 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Bruno Haible.
+
+# Add --disable-auto-import to the LDFLAGS if the linker supports it.
+# GNU ld has an --enable-auto-import option, and it is the default on Cygwin
+# since July 2005. But it two fatal drawbacks:
+#   - It produces executables and shared libraries with relocations in the
+#     .text segment, defeating the principles of virtual memory.
+#   - For some constructs such as
+#         extern int var;
+#         int * const b = &var;
+#     it creates an executable that will give an error at runtime, rather than
+#     either a compile-time or link-time error or a working executable.
+#     (This is with both gcc and g++.) Whereas this code, not relying on auto-
+#     import:
+#         extern __declspec (dllimport) int var;
+#         int * const b = &var;
+#     gives a compile-time error with gcc and works with g++.
+AC_DEFUN([gl_WOE32_DLL],
+[
+  AC_REQUIRE([AC_CANONICAL_HOST])
+  case "$host_os" in
+    mingw* | cygwin*)
+      AC_MSG_CHECKING([for auto-import of symbols])
+      AC_CACHE_VAL([gl_cv_ld_autoimport], [
+        gl_save_LDFLAGS="$LDFLAGS"
+        LDFLAGS="$LDFLAGS -Wl,--disable-auto-import"
+        AC_TRY_LINK([], [], [gl_cv_ld_autoimport=yes], [gl_cv_ld_autoimport=no])
+        LDFLAGS="$gl_save_LDFLAGS"])
+      AC_MSG_RESULT([$gl_cv_ld_autoimport])
+      if test $gl_cv_ld_autoimport = yes; then
+        LDFLAGS="$LDFLAGS -Wl,--disable-auto-import"
+      fi
+      ;;
+  esac
+])