From: BVK Chaitanya <bvk.groups@gmail.com>
Date: Wed, 2 Jun 2010 09:48:33 +0000 (+0530)
Subject: pull-in emu-lite fixes
X-Git-Tag: 1.99~647^2~60
X-Git-Url: http://git.ipfire.org/gitweb.cgi?a=commitdiff_plain;h=bd7390ee844a575da9a515aaf6a843d17b69b841;p=thirdparty%2Fgrub.git

pull-in emu-lite fixes
---

bd7390ee844a575da9a515aaf6a843d17b69b841
diff --cc configure.common
index 51a0caec4,000000000..8c100e2da
mode 100644,000000..100644
--- a/configure.common
+++ b/configure.common
@@@ -1,807 -1,0 +1,824 @@@
 +# -*- autoconf -*-
 +
 +# Process this file with autoconf to produce a configure script.
 +
 +# Copyright (C) 2002,2003,2004,2005,2006,2007,2008,2009,2010  Free Software Foundation, Inc.
 +#
 +# This configure.ac is free software; the author
 +# gives unlimited permission to copy and/or distribute it,
 +# with or without modifications, as long as this notice is preserved.
 +#
 +# This program is distributed in the hope that it will be useful,
 +# but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 +# even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 +# PARTICULAR PURPOSE.
 +
 +# This file is shared between grub-core and util configure scripts.
 +
 +# Program name transformations
 +AC_ARG_PROGRAM
 +
 +# Optimization flag.  Allow user to override.
 +if test "x$CFLAGS" = x; then
 +  CFLAGS="$CFLAGS -Os"
 +fi
 +
 +# Default HOST_CPPFLAGS
 +CPPFLAGS=''
 +HOST_CPPFLAGS="$HOST_CPPFLAGS -Wall -W"
 +HOST_CPPFLAGS="$HOST_CPPFLAGS -I\$(top_srcdir)/grub-core/include"
 +HOST_CPPFLAGS="$HOST_CPPFLAGS -I\$(top_builddir)/include"
 +HOST_CPPFLAGS="$HOST_CPPFLAGS -I\$(top_srcdir)/grub-core/gnulib"
 +HOST_CPPFLAGS="$HOST_CPPFLAGS -DGRUB_UTIL=1"
 +HOST_CPPFLAGS="$HOST_CPPFLAGS -DGRUB_LIBDIR=\\\"\$(pkglibdir)\\\""
 +HOST_CPPFLAGS="$HOST_CPPFLAGS -DLOCALEDIR=\\\"\$(localedir)\\\""
 +
 +TARGET_CPPFLAGS="$TARGET_CPPFLAGS -Wall -W"
 +TARGET_CPPFLAGS="$TARGET_CPPFLAGS -I\$(top_srcdir)/include"
 +TARGET_CPPFLAGS="$TARGET_CPPFLAGS -I\$(top_builddir)/include"
 +
 +case "$target_cpu" in
 +  i[[3456]]86)	target_cpu=i386 ;;
 +  amd64)	target_cpu=x86_64 ;;
 +  sparc)	target_cpu=sparc64 ;;
 +  mipsel|mips64el)
 +                target_cpu=mips;
 +		cpu_CPPFLAGS="-DGRUB_CPU_MIPSEL=1";
 +		;;
 +  mips|mips64)
 +                target_cpu=mips;
 +		cpu_CPPFLAGS="-DGRUB_CPU_MIPS=1";
 +		;;
 +esac
 +
 +# Specify the platform (such as firmware).
 +AC_ARG_WITH([platform],
 +            AS_HELP_STRING([--with-platform=PLATFORM],
 +                           [select the host platform [[guessed]]]))
 +
 +# Guess the platform if not specified.
 +if test "x$with_platform" = x; then
 +  case "$target_cpu"-"$target_vendor" in
 +    i386-apple) platform=efi ;;
 +    i386-*) platform=pc ;;
 +    x86_64-apple) platform=efi ;;
 +    x86_64-*) platform=pc ;;
 +    powerpc-*) platform=ieee1275 ;;
 +    powerpc64-*) platform=ieee1275 ;;
 +    sparc64-*) platform=ieee1275 ;;
 +    mips-*) platform=yeeloong ;;
 +    *) AC_MSG_ERROR([unsupported CPU: "$target_cpu"]) ;;
 +  esac
 +else
 +  platform="$with_platform"
 +fi
 +
 +# Adjust CPU unless target was explicitly specified.
 +if test -z "$target_alias"; then
 +  case "$target_cpu"-"$platform" in
 +    x86_64-efi) ;;
 +    x86_64-emu) ;;
 +    x86_64-*) target_cpu=i386 ;;
 +    powerpc64-ieee1275) target_cpu=powerpc ;;
 +  esac
 +fi
 +
 +# Check if the platform is supported, make final adjustments.
 +case "$target_cpu"-"$platform" in
 +  i386-efi) ;;
 +  x86_64-efi) ;;
 +  i386-pc) ;;
 +  i386-multiboot) ;;
 +  i386-coreboot) ;;
 +  i386-linuxbios) platform=coreboot ;;
 +  i386-ieee1275) ;;
 +  i386-qemu) ;;
 +  powerpc-ieee1275) ;;
 +  sparc64-ieee1275) ;;
 +  mips-qemu-mips) ;;
 +  mips-yeeloong) ;;
 +  *-emu) ;;
 +  *) AC_MSG_ERROR([platform "$platform" is not supported for target CPU "$target_cpu"]) ;;
 +esac
 +
 +case "$target_cpu" in
 +  i386 | powerpc) target_m32=1 ;;
 +  x86_64 | sparc64) target_m64=1 ;;
 +esac
 +
 +case "$host_os" in
 +  mingw32*) host_os=cygwin ;;
 +esac
 +
 +# This normalizes the names, and creates a new variable ("host_kernel")
 +# while at it, since the mapping is not always 1:1 (e.g. different OSes
 +# using the same kernel type).
 +case "$host_os" in
 +  gnu*)				host_kernel=hurd ;;
 +  linux*)			host_kernel=linux ;;
 +  freebsd* | kfreebsd*-gnu)	host_kernel=kfreebsd ;;
 +  netbsd*)			host_kernel=netbsd ;;
 +  cygwin)			host_kernel=windows ;;
 +esac
 +
 +case "$platform" in
 +  coreboot)	machine_CPPFLAGS="-DGRUB_MACHINE_COREBOOT=1" ;;
 +  multiboot)	machine_CPPFLAGS="-DGRUB_MACHINE_MULTIBOOT=1" ;;
 +  efi)		machine_CPPFLAGS="-DGRUB_MACHINE_EFI=1" ;;
 +  ieee1275)	machine_CPPFLAGS="-DGRUB_MACHINE_IEEE1275=1" ;;
 +  qemu)		machine_CPPFLAGS="-DGRUB_MACHINE_QEMU=1" ;;
 +  pc)		machine_CPPFLAGS="-DGRUB_MACHINE_PCBIOS=1" ;;
 +  emu)		machine_CPPFLAGS="-DGRUB_MACHINE_EMU=1" ;;
 +  yeeloong)	machine_CPPFLAGS="-DGRUB_MACHINE_MIPS_YEELOONG=1 -DGRUB_MACHINE_MIPS_BONITO=1" ;;
 +  qemu-mips)	machine_CPPFLAGS="-DGRUB_MACHINE_MIPS_QEMU_MIPS=1 -DGRUB_MACHINE_MIPS_BONITO=1" ;;
 +esac
 +case "$target_cpu" in
 +  i386)         cpu_CPPFLAGS="$cpu_CPPFLAGS -DGRUB_CPU_I386";;
 +  x86_64)       cpu_CPPFLAGS="$cpu_CPPFLAGS -DGRUB_CPU_X86_64";;
 +  powerpc)      cpu_CPPFLAGS="$cpu_CPPFLAGS -DGRUB_CPU_POWERPC";;
 +  mips)      	machine_CPPFLAGS="$machine_CPPFLAGS -DGRUB_MACHINE_MIPS=1" ;; # cpu_CPPFLAGS handled above
 +  sparc64)      cpu_CPPFLAGS="$cpu_CPPFLAGS -DGRUB_CPU_SPARC64";
 +                machine_CPPFLAGS="$machine_CPPFLAGS -DGRUB_MACHINE_SPARC64=1" ;;
 +esac
 +machine_CPPFLAGS="$machine_CPPFLAGS -DMACHINE=`echo ${target_cpu}_$platform | sed y,abcdefghijklmnopqrstuvwxyz,ABCDEFGHIJKLMNOPQRSTUVWXYZ,`"
 +
 +HOST_CPPFLAGS="$HOST_CPPFLAGS $cpu_CPPFLAGS $machine_CPPFLAGS"
 +TARGET_CPPFLAGS="$TARGET_CPPFLAGS $cpu_CPPFLAGS $machine_CPPFLAGS"
 +
 +AC_SUBST(host_cpu)
 +AC_SUBST(host_os)
 +AC_SUBST(host_kernel)
 +
 +AC_SUBST(target_cpu)
 +AC_SUBST(platform)
 +
 +#
 +# Checks for build programs.
 +#
 +
 +# Although cmp is listed in the GNU Coding Standards as a command which
 +# can used directly, OpenBSD lacks cmp in the default installation.
 +AC_CHECK_PROGS([CMP], [cmp])
 +if test "x$CMP" = x; then
 +  AC_MSG_ERROR([cmp is not found])
 +fi
 +
 +for file in /usr/src/unifont.bdf /usr/share/fonts/X11/misc/unifont.pcf.gz /usr/share/fonts/unifont/unifont.pcf.gz; do
 +  if test -e $file ; then
 +    FONT_SOURCE=$file
 +    HOST_CPPFLAGS="$HOST_CPPFLAGS -DUSE_ASCII_FAILBACK=1"
 +    TARGET_CPPFLAGS="$TARGET_CPPFLAGS -DUSE_ASCII_FAILBACK=1"
 +    break
 +  fi
 +done
 +
 +AC_PROG_RANLIB
 +AC_PROG_INSTALL
 +AC_PROG_AWK
 +AC_PROG_LEX
 +AC_PROG_YACC
 +AC_PROG_MAKE_SET
 +AC_PROG_MKDIR_P
 +
 +if test "x$LEX" = "x:"; then
 +  AC_MSG_ERROR([flex is not found])
 +else
 +  version=`$LEX --version | $AWK '{ split($NF,x,"."); print x[[1]]*10000+x[[2]]*100+x[[3]]; }'`
 +  if test -n "$version" -a "$version" -ge 20535; then
 +    :
 +  else
 +    AC_MSG_ERROR([flex is too old. GRUB requires 2.5.35 or above])
 +  fi
 +fi
 +
 +# These are not a "must".
 +AC_PATH_PROG(MAKEINFO, makeinfo)
 +
 +#
 +# Checks for host programs.
 +#
 +
 +AC_PROG_CC
 +AM_PROG_CC_C_O
 +AM_PROG_AS
 +
 +# Must be GCC.
 +test "x$GCC" = xyes || AC_MSG_ERROR([GCC is required])
 +
 +AC_GNU_SOURCE
 +AM_GNU_GETTEXT([external])
 +AC_SYS_LARGEFILE
 +
 +# Identify characteristics of the host architecture.
 +AC_C_BIGENDIAN
 +AC_CHECK_SIZEOF(void *)
 +AC_CHECK_SIZEOF(long)
 +
 +grub_apple_cc
 +if test x$grub_cv_apple_cc = xyes ; then
 +  HOST_CPPFLAGS="$HOST_CPPFLAGS -DAPPLE_CC=1"
 +  HOST_CFLAGS="$HOST_CFLAGS -fnested-functions"
 +fi
 +
 +if test "x$cross_compiling" = xyes; then
 +  AC_MSG_WARN([cannot generate manual pages while cross compiling])
 +else
 +  AC_PATH_PROG(HELP2MAN, help2man)
 +fi
 +
 +# Check for functions.
 +AC_CHECK_FUNCS(posix_memalign memalign asprintf vasprintf)
 +
 +# For grub-mkisofs
 +AC_HEADER_MAJOR
 +AC_HEADER_DIRENT
 +AC_CHECK_FUNCS(memmove sbrk strdup lstat getuid getgid)
 +AC_CHECK_HEADERS(sys/mkdev.h sys/sysmacros.h malloc.h termios.h sys/types.h)
 +AC_CHECK_HEADERS(unistd.h string.h strings.h sys/stat.h sys/fcntl.h limits.h)
 +
 +# For opendisk() and getrawpartition() on NetBSD.
 +# Used in util/deviceiter.c and in util/hostdisk.c.
 +AC_CHECK_HEADER([util.h], [
 +  AC_CHECK_LIB([util], [opendisk], [
 +    LIBUTIL="-lutil"
 +    AC_DEFINE(HAVE_OPENDISK, 1, [Define if opendisk() in -lutil can be used])
 +  ])
 +  AC_CHECK_LIB([util], [getrawpartition], [
 +    LIBUTIL="-lutil"
 +    AC_DEFINE(HAVE_GETRAWPARTITION, 1, [Define if getrawpartition() in -lutil can be used])
 +  ])
 +])
 +AC_SUBST([LIBUTIL])
 +
 +#
 +# Check for host and build compilers.
 +#
 +HOST_CC=$CC
 +AC_CHECK_PROGS(BUILD_CC, [gcc egcs cc],
 +                 [AC_MSG_ERROR([none of gcc, egcs and cc is found. set BUILD_CC manually.])])
 +
 +#
 +# Check for target programs.
 +#
 +
 +# Find tools for the target.
 +if test "x$target_alias" != x && test "x$host_alias" != "x$target_alias"; then
 +  tmp_ac_tool_prefix="$ac_tool_prefix"
 +  ac_tool_prefix=$target_alias-
 +
 +  AC_CHECK_TOOLS(TARGET_CC, [gcc egcs cc],
 +                 [AC_MSG_ERROR([none of gcc, egcs and cc is found. set TARGET_CC manually.])])
 +  AC_CHECK_TOOL(OBJCOPY, objcopy)
 +  AC_CHECK_TOOL(STRIP, strip)
 +  AC_CHECK_TOOL(NM, nm)
 +
 +  ac_tool_prefix="$tmp_ac_tool_prefix"
 +else
 +  if test "x$TARGET_CC" = x; then
 +    TARGET_CC=$CC
 +  fi
 +  AC_CHECK_TOOL(OBJCOPY, objcopy)
 +  AC_CHECK_TOOL(STRIP, strip)
 +  AC_CHECK_TOOL(NM, nm)
 +fi
 +AC_SUBST(HOST_CC)
 +AC_SUBST(BUILD_CC)
 +AC_SUBST(TARGET_CC)
 +
 +# Test the C compiler for the target environment.
 +tmp_CC="$CC"
 +tmp_CFLAGS="$CFLAGS"
 +tmp_LDFLAGS="$LDFLAGS"
 +tmp_CPPFLAGS="$CPPFLAGS"
 +tmp_LIBS="$LIBS"
 +CC="$TARGET_CC"
 +CFLAGS="$TARGET_CFLAGS"
 +CPPFLAGS="$TARGET_CPPFLAGS"
 +LDFLAGS="$TARGET_LDFLAGS"
 +LIBS=""
 +
 +# debug flags.
 +TARGET_CFLAGS="$TARGET_CFLAGS -Wall -W -Wshadow -Wpointer-arith -Wmissing-prototypes -Wundef -Wstrict-prototypes -g"
 +TARGET_CCASFLAGS="$TARGET_CCASFLAGS -g"
 +
 +# Force no alignment to save space on i386.
 +if test "x$target_cpu" = xi386; then
 +  AC_CACHE_CHECK([whether -falign-loops works], [grub_cv_cc_falign_loop], [
 +    CFLAGS="$CFLAGS -falign-loops=1"
 +    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 +        [grub_cv_cc_falign_loop=yes],
 +	[grub_cv_cc_falign_loop=no])
 +  ])
 +
 +  if test "x$grub_cv_cc_falign_loop" = xyes; then
 +    TARGET_CFLAGS="$TARGET_CFLAGS -falign-jumps=1 -falign-loops=1 -falign-functions=1"
 +  else
 +    TARGET_CFLAGS="$TARGET_CFLAGS -malign-jumps=1 -malign-loops=1 -malign-functions=1"
 +  fi
 +
 +  # Some toolchains enable these features by default, but they need
 +  # registers that aren't set up properly in GRUB.
 +  TARGET_CFLAGS="$TARGET_CFLAGS -mno-mmx -mno-sse -mno-sse2 -mno-3dnow"
 +fi
 +
 +# By default, GCC 4.4 generates .eh_frame sections containing unwind
 +# information in some cases where it previously did not. GRUB doesn't need
 +# these and they just use up vital space. Restore the old compiler
 +# behaviour.
 +AC_CACHE_CHECK([whether -fno-dwarf2-cfi-asm works], [grub_cv_cc_fno_dwarf2_cfi_asm], [
 +  SAVE_CFLAGS="$CFLAGS"
 +  CFLAGS="$CFLAGS -fno-dwarf2-cfi-asm"
 +  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 +      [grub_cv_cc_fno_dwarf2_cfi_asm=yes],
 +      [grub_cv_cc_fno_dwarf2_cfi_asm=no])
 +  CFLAGS="$SAVE_CFLAGS"
 +])
 +
 +if test "x$grub_cv_cc_fno_dwarf2_cfi_asm" = xyes; then
 +  TARGET_CFLAGS="$TARGET_CFLAGS -fno-dwarf2-cfi-asm"
 +fi
 +
 +grub_apple_target_cc
 +if test x$grub_cv_apple_target_cc = xyes ; then
 +  TARGET_CPPFLAGS="$TARGET_CPPFLAGS -DAPPLE_CC=1"
 +  TARGET_CFLAGS="$TARGET_CFLAGS -fnested-functions"
 +
 +  CFLAGS="$CFLAGS -DAPPLE_CC=1 -fnested-functions"
 +  TARGET_APPLE_CC=1
 +  AC_CHECK_PROG([OBJCONV], [objconv], [objconv], [])
 +  if test "x$OBJCONV" = x ; then
 +     AC_CHECK_PROG([OBJCONV], [objconv], [./objconv], [], [.])
 +  fi
 +  if test "x$OBJCONV" = x ; then
 +    AC_MSG_ERROR([objconv not found which is required when building with apple compiler])
 +  fi
 +  TARGET_IMG_LDSCRIPT=
 +  TARGET_IMG_CFLAGS="-static"
 +  TARGET_IMG_LDFLAGS='-nostdlib -static -Wl,-preload -Wl,-segalign,20 -Wl,-image_base,'
 +  TARGET_IMG_LDFLAGS_AC='-nostdlib -static -Wl,-preload -Wl,-segalign,20 -Wl,-image_base,'
 +else
 +  TARGET_APPLE_CC=0
 +# Use linker script if present, otherwise use builtin -N script.
 +if test -f "${srcdir}/conf/${target_cpu}-${platform}-${host_os}-img-ld.sc"; then
 +  TARGET_IMG_LDSCRIPT='$(top_srcdir)'"/conf/${target_cpu}-${platform}-${host_os}-img-ld.sc"
 +  TARGET_IMG_LDFLAGS="-Wl,-T${TARGET_IMG_LDSCRIPT}  -Wl,-Ttext,"
 +  TARGET_IMG_LDFLAGS_AC="-Wl,-T${srcdir}/conf/${target_cpu}-${platform}-${host_os}-img-ld.sc  -Wl,-Ttext,"
 +else
 +  TARGET_IMG_LDSCRIPT=
 +  TARGET_IMG_LDFLAGS='-Wl,-N  -Wl,-Ttext,'
 +  TARGET_IMG_LDFLAGS_AC='-Wl,-N  -Wl,-Ttext,'
 +fi
 +TARGET_IMG_CFLAGS=
 +fi
 +
 +# For platforms where ELF is not the default link format.
 +AC_MSG_CHECKING([for command to convert module to ELF format])
 +case "${host_os}" in
 +  cygwin) TARGET_OBJ2ELF='grub-pe2elf';
 +# FIXME: put proper test here
 +  AC_DEFINE([NEED_REGISTER_FRAME_INFO], 1,
 +	    [Define to 1 if GCC generates calls to __register_frame_info()])
 +  ;;
 +  *) ;;
 +esac
 +AC_MSG_RESULT([$TARGET_OBJ2ELF])
 +
 +if test "x$target_m32" = x1; then
 +  # Force 32-bit mode.
 +  TARGET_CFLAGS="$TARGET_CFLAGS -m32"
 +  TARGET_CCASFLAGS="$TARGET_CCASFLAGS -m32"
 +  TARGET_LDFLAGS="$TARGET_LDFLAGS -m32"
 +  TARGET_MODULE_FORMAT="elf32"
 +fi
 +
 +if test "x$target_m64" = x1; then
 +  # Force 64-bit mode.
 +  TARGET_CFLAGS="$TARGET_CFLAGS -m64"
 +  TARGET_CCASFLAGS="$TARGET_CCASFLAGS -m64"
 +  TARGET_LDFLAGS="$TARGET_LDFLAGS -m64"
 +  TARGET_MODULE_FORMAT="elf64"
 +fi
 +
 +if test "$target_cpu"-"$platform" = x86_64-efi; then
 +  # Use large model to support 4G memory
 +  AC_CACHE_CHECK([whether option -mcmodel=large works], grub_cv_cc_mcmodel, [
 +    SAVED_CFLAGS=$CFLAGS
 +    CFLAGS="$CFLAGS -m64 -mcmodel=large"
 +    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 +		      [grub_cv_cc_mcmodel=yes],
 +		      [grub_cv_cc_mcmodel=no])
 +  ])
 +  if test "x$grub_cv_cc_mcmodel" = xno; then
 +    AC_MSG_ERROR([-mcmodel=large not supported. Upgrade your gcc.])
 +  else
 +    TARGET_CFLAGS="$TARGET_CFLAGS -mcmodel=large"
 +  fi
 +
 +  # EFI writes to stack below %rsp, we must not use the red zone
 +  AC_CACHE_CHECK([whether option -mno-red-zone works], grub_cv_cc_no_red_zone, [
 +    CFLAGS="$CFLAGS -m64 -mno-red-zone"
 +    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 +		      [grub_cv_cc_no_red_zone=yes],
 +		      [grub_cv_cc_no_red_zone=no])
 +  ])
 +  if test "x$grub_cv_cc_no_red_zone" = xno; then
 +    AC_MSG_ERROR([-mno-red-zone not supported, upgrade your gcc])
 +  fi
 +
 +  TARGET_CFLAGS="$TARGET_CFLAGS -mno-red-zone"
 +fi
 +
 +#
 +# Compiler features.
 +#
 +
 +# Need __enable_execute_stack() for nested function trampolines?
 +grub_CHECK_ENABLE_EXECUTE_STACK
 +
 +# Position independent executable.
 +grub_CHECK_PIE
 +[# Need that, because some distributions ship compilers that include
 +# `-fPIE' in the default specs.
 +if [ x"$pie_possible" = xyes ]; then
 +  TARGET_CFLAGS="$TARGET_CFLAGS -fno-PIE"
 +fi]
 +
 +# Smashing stack protector.
 +grub_CHECK_STACK_PROTECTOR
 +# Need that, because some distributions ship compilers that include
 +# `-fstack-protector' in the default specs.
 +if test "x$ssp_possible" = xyes; then
 +  TARGET_CFLAGS="$TARGET_CFLAGS -fno-stack-protector"
 +fi
 +grub_CHECK_STACK_ARG_PROBE
 +# Cygwin's GCC uses alloca() to probe the stackframe on static
 +# stack allocations above some threshold.
 +if test x"$sap_possible" = xyes; then
 +  TARGET_CFLAGS="$TARGET_CFLAGS -mno-stack-arg-probe"
 +fi
 +
 +AC_ARG_ENABLE([werror],
 +	      [AS_HELP_STRING([--disable-werror],
 +                             [do not use -Werror when building GRUB])])
 +if test x"$enable_werror" != xno ; then
 +  TARGET_CFLAGS="$TARGET_CFLAGS -Werror"
 +fi
 +
 +AC_SUBST(TARGET_MODULE_FORMAT)
 +AC_SUBST(OBJCONV)
 +AC_SUBST(TARGET_APPLE_CC)
 +
 +AC_SUBST(TARGET_CFLAGS)
 +AC_SUBST(TARGET_LDFLAGS)
 +AC_SUBST(TARGET_CPPFLAGS)
 +AC_SUBST(TARGET_CCASFLAGS)
 +
 +AC_SUBST(HOST_CFLAGS)
 +AC_SUBST(HOST_LDFLAGS)
 +AC_SUBST(HOST_CPPFLAGS)
 +AC_SUBST(HOST_CCASFLAGS)
 +
 +# Set them to their new values for the tests below.
 +CC="$TARGET_CC"
 +if test "x$TARGET_APPLE_CC" = x1 ; then
 +CFLAGS="$TARGET_CFLAGS -nostdlib -Wno-error"
 +else
 +CFLAGS="$TARGET_CFLAGS -nostdlib -Wl,--defsym,___main=0x8100 -Wno-error"
 +fi
 +CPPFLAGS="$TARGET_CPPFLAGS"
 +LDFLAGS="$TARGET_LDFLAGS"
 +LIBS=-lgcc
 +
 +grub_ASM_USCORE
 +if test x$grub_cv_asm_uscore = xyes; then
 +CFLAGS="$CFLAGS -Wl,--defsym,_abort=_main"
 +else
 +CFLAGS="$CFLAGS -Wl,--defsym,abort=main"
 +fi
 +
 +# Check for libgcc symbols
 +AC_CHECK_FUNCS(__bswapsi2 __bswapdi2 __ashldi3 __ashrdi3 __lshrdi3 __trampoline_setup __ucmpdi2 _restgpr_14_x)
 +
 +if test "x$TARGET_APPLE_CC" = x1 ; then
 +CFLAGS="$TARGET_CFLAGS -nostdlib"
 +else
 +CFLAGS="$TARGET_CFLAGS -nostdlib -Wl,--defsym,___main=0x8100"
 +fi
 +LIBS=""
 +
 +# Defined in aclocal.m4.
 +grub_PROG_TARGET_CC
 +if test "x$TARGET_APPLE_CC" != x1 ; then
 +grub_PROG_OBJCOPY_ABSOLUTE
 +fi
 +grub_PROG_LD_BUILD_ID_NONE
 +if test "x$target_cpu" = xi386; then
 +  if test "$platform" != emu && test "x$TARGET_APPLE_CC" != x1 ; then
 +    if test ! -z "$TARGET_IMG_LDSCRIPT"; then
 +      # Check symbols provided by linker script.
 +      CFLAGS="$TARGET_CFLAGS -nostdlib ${TARGET_IMG_LDFLAGS_AC}8000 -Wl,--defsym,___main=0x8100"
 +    fi
 +    grub_CHECK_BSS_START_SYMBOL
 +    grub_CHECK_END_SYMBOL
 +  fi
 +  CFLAGS="$TARGET_CFLAGS"
 +  grub_I386_ASM_PREFIX_REQUIREMENT
 +  grub_I386_ASM_ADDR32
 +  grub_I386_ASM_ABSOLUTE_WITHOUT_ASTERISK
 +else
 +  AC_DEFINE([NESTED_FUNC_ATTR], [], [Catch gcc bug])
 +fi
 +
 +AH_BOTTOM([#if defined(__i386__) && !defined(GRUB_UTIL)
 +#define NESTED_FUNC_ATTR __attribute__ ((__regparm__ (1)))
 +#else
 +#define NESTED_FUNC_ATTR
 +#endif])
 +
 +AC_ARG_ENABLE([efiemu],
 +	      [AS_HELP_STRING([--enable-efiemu],
 +                             [build and install the efiemu runtimes (default=guessed)])])
 +if test x"$enable_efiemu" = xno ; then
 +  efiemu_excuse="explicitly disabled"
 +fi
 +if test x"$efiemu_excuse" = x ; then
 +  AC_CACHE_CHECK([whether options required for efiemu work], grub_cv_cc_efiemu, [
 +    CFLAGS="$CFLAGS -m64 -mcmodel=large -mno-red-zone -nostdlib"
 +    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 +		      [grub_cv_cc_efiemu=yes],
 +		      [grub_cv_cc_efiemu=no])
 +  ])
 +  if test x$grub_cv_cc_efiemu = xno; then
 +     efiemu_excuse="cannot compile with -m64 -mcmodel=large -mno-red-zone -nostdlib"
 +  fi
 +fi
 +if test x"$enable_efiemu" = xyes && test x"$efiemu_excuse" != x ; then
 +  AC_MSG_ERROR([efiemu runtime was explicitly requested but can't be compiled])
 +fi
 +if test x"$efiemu_excuse" = x ; then
 +enable_efiemu=yes
 +else
 +enable_efiemu=no
 +fi
 +AC_SUBST([enable_efiemu])
 +
 +if test "$platform" != emu; then
 +AC_CACHE_CHECK([whether -nostdinc -isystem works], [grub_cv_cc_isystem], [
 +  SAVED_CPPFLAGS="$CPPFLAGS"
 +  CPPFLAGS="$TARGET_CPPFLAGS -nostdinc -isystem `$TARGET_CC -print-file-name=include`"
 +  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>
 +int va_arg_func (int fixed, va_list args);]], [[]])],
 +      [grub_cv_cc_isystem=yes],
 +      [grub_cv_cc_isystem=no])
 +  CPPFLAGS="$SAVED_CPPFLAGS"
 +])
 +
 +if test x"$grub_cv_cc_isystem" = xyes ; then
 +  TARGET_CPPFLAGS="$TARGET_CPPFLAGS -nostdinc -isystem `$TARGET_CC -print-file-name=include`"
 +fi
 +fi
 +
 +# Restore the flags.
 +CC="$tmp_CC"
 +CFLAGS="$tmp_CFLAGS"
 +CPPFLAGS="$tmp_CPPFLAGS"
 +LDFLAGS="$tmp_LDFLAGS"
 +LIBS="$tmp_LIBS"
 +
 +#
 +# Check for options.
 +#
 +
 +# Memory manager debugging.
 +AC_ARG_ENABLE([mm-debug],
 +	      AS_HELP_STRING([--enable-mm-debug],
 +                             [include memory manager debugging]),
 +              [AC_DEFINE([MM_DEBUG], [1],
 +                         [Define to 1 if you enable memory manager debugging.])])
 +
 +AC_ARG_ENABLE([grub-emu-usb],
 +	      [AS_HELP_STRING([--enable-grub-emu-usb],
 +                             [build and install the `grub-emu' debugging utility with USB support (default=guessed)])])
 +
 +AC_ARG_ENABLE([grub-emu-sdl],
 +	      [AS_HELP_STRING([--enable-grub-emu-sdl],
 +                             [build and install the `grub-emu' debugging utility with SDL support (default=guessed)])])
 +
 +AC_ARG_ENABLE([grub-emu-pci],
 +	      [AS_HELP_STRING([--enable-grub-emu-pci],
 +                             [build and install the `grub-emu' debugging utility with PCI support (potentially dangerous) (default=no)])])
 +
 +if test "$platform" = emu; then
 +  missing_ncurses=
 +[# Check for curses libraries.]
 +  AC_CHECK_LIB([ncurses], [wgetch], [LIBCURSES="-lncurses"],
 +    [AC_CHECK_LIB([curses], [wgetch], [LIBCURSES="-lcurses"],
 +      [missing_ncurses=[true]])])
 +  AC_SUBST([LIBCURSES])
 +[if [ x"$missing_ncurses" = x ]; then ]
 +  [# Check for headers.]
 +  AC_CHECK_HEADERS([ncurses/curses.h], [],
 +    [AC_CHECK_HEADERS([ncurses.h], [],
 +      [AC_CHECK_HEADERS([curses.h], [],
 +	[missing_ncurses=[true]])])])
 +[fi]
 +if test x"$missing_ncurses" = xtrue ; then
 +  AC_MSG_ERROR([grub-emu can't be compiled without ncurses])
 +fi
 +
 +if test x"$enable_grub_emu_usb" = xno ; then
 +  grub_emu_usb_excuse="explicitly disabled"
 +fi
 +
 +if test x"$enable_grub_emu_pci" = xyes ; then
 +   grub_emu_usb_excuse="conflicts with PCI support"
 +fi
 +
 +[if [ x"$grub_emu_usb_excuse" = x ]; then
 +    # Check for libusb libraries.]
 +AC_CHECK_LIB([usb], [usb_claim_interface], [LIBUSB="-lusb"],
 +    [grub_emu_usb_excuse=["need libusb library"]])
 +    AC_SUBST([LIBUSB])
 +[fi]
 +[if [ x"$grub_emu_usb_excuse" = x ]; then
 +    # Check for headers.]
 +    AC_CHECK_HEADERS([usb.h], [],
 +      [grub_emu_usb_excuse=["need libusb headers"]])
 +[fi]
 +if test x"$enable_grub_emu_usb" = xyes && test x"$grub_emu_usb_excuse" != x ; then
 +  AC_MSG_ERROR([USB support for grub-emu was explicitly requested but can't be compiled])
 +fi
 +if test x"$grub_emu_usb_excuse" = x ; then
 +enable_grub_emu_usb=yes
 +else
 +enable_grub_emu_usb=no
 +fi
 +
 +if test x"$enable_grub_emu_sdl" = xno ; then
 +  grub_emu_sdl_excuse="explicitely disabled"
 +fi
 +[if [ x"$grub_emu_sdl_excuse" = x ]; then
 +    # Check for libSDL libraries.]
 +AC_CHECK_LIB([SDL], [SDL_Init], [LIBSDL="-lSDL"],
 +    [grub_emu_sdl_excuse=["libSDL libraries are required to build \`grub-emu' with SDL support"]])
 +    AC_SUBST([LIBSDL])
 +[fi]
 +
 +[if [ x"$grub_emu_sdl_excuse" = x ]; then
 +    # Check for headers.]
 +    AC_CHECK_HEADERS([SDL/SDL.h], [],
 +      [grub_emu_sdl_excuse=["libSDL header file is required to build \`grub-emu' with SDL support"]])
 +[fi]
 +
 +if test x"enable_grub_emu_sdl" = xyes && test x"$grub_emu_sdl_excuse" != x ; then
 +  AC_MSG_ERROR([SDL support for grub-emu was explicitely requested but can't be compiled])
 +fi
 +if test x"$grub_emu_sdl_excuse" = x ; then
 +enable_grub_emu_sdl=yes
 +else
 +enable_grub_emu_sdl=no
 +fi
 +
 +if test x"$enable_grub_emu_pci" != xyes ; then
 +   grub_emu_pci_excuse="not enabled"
 +fi
 +
 +if test x"$enable_grub_emu_usb" = xyes ; then
 +   grub_emu_pci_excuse="conflicts with USB support"
 +fi
 +
 +[if [ x"$grub_emu_pci_excuse" = x ]; then
 +      # Check for libpci libraries.]
 +   AC_CHECK_LIB([pciaccess], [pci_system_init], [LIBPCIACCESS="-lpciaccess"],
 +      [grub_emu_pci_excuse=["need libpciaccess library"]])
 +    AC_SUBST([LIBPCIACCESS])
 +[fi]
 +[if [ x"$grub_emu_pci_excuse" = x ]; then
 +    # Check for headers.]
 +    AC_CHECK_HEADERS([pci/pci.h], [],
 +      [grub_emu_pci_excuse=["need libpciaccess headers"]])
 +[fi]
 +
 +if test x"$grub_emu_pci_excuse" = x ; then
 +enable_grub_emu_pci=yes
 +else
 +
 +enable_grub_emu_pci=no
 +fi
 +
 +AC_SUBST([enable_grub_emu_sdl])
 +AC_SUBST([enable_grub_emu_usb])
 +AC_SUBST([enable_grub_emu_pci])
 +fi
 +
 +AC_ARG_ENABLE([grub-fstest],
 +	      [AS_HELP_STRING([--enable-grub-fstest],
 +                             [build and install the `grub-fstest' debugging utility (default=guessed)])])
 +if test x"$enable_grub_fstest" = xno ; then
 +  grub_fstest_excuse="explicitly disabled"
 +fi
 +if test x"$grub_fstest_excuse" = x ; then
 +enable_grub_fstest=yes
 +else
 +enable_grub_fstest=no
 +fi
 +AC_SUBST([enable_grub_fstest])
 +
 +AC_ARG_ENABLE([grub-mkfont],
 +	      [AS_HELP_STRING([--enable-grub-mkfont],
 +                             [build and install the `grub-mkfont' utility (default=guessed)])])
 +if test x"$enable_grub_mkfont" = xno ; then
 +  grub_mkfont_excuse="explicitly disabled"
 +fi
 +
 +if test x"$grub_mkfont_excuse" = x ; then
 +  # Check for freetype libraries.
 +  AC_CHECK_PROGS([FREETYPE], [freetype-config])
 +  if test "x$FREETYPE" = x ; then
 +    grub_mkfont_excuse=["need freetype2 library"]
 +  fi
 +  freetype_cflags=`freetype-config --cflags`
 +  freetype_libs=`freetype-config --libs`
 +fi
 +
 +if test x"$grub_mkfont_excuse" = x ; then
 +  # Check for freetype libraries.
 +  SAVED_CPPFLAGS="$CPPFLAGS"
 +  CPPFLAGS="$CPPFLAGS $freetype_cflags"
 +  AC_CHECK_HEADERS([ft2build.h], [],
 +  	[grub_mkfont_excuse=["need freetype2 headers"]])
 +  CPPFLAGS="$SAVED_CPPFLAGS"
 +fi
 +
 +if test x"$enable_grub_mkfont" = xyes && test x"$grub_mkfont_excuse" != x ; then
 +  AC_MSG_ERROR([grub-mkfont was explicitly requested but can't be compiled])
 +fi
 +if test x"$grub_mkfont_excuse" = x ; then
 +enable_grub_mkfont=yes
 +else
 +enable_grub_mkfont=no
 +fi
 +AC_SUBST([enable_grub_mkfont])
 +AC_SUBST([freetype_cflags])
 +AC_SUBST([freetype_libs])
 +
++AC_ARG_ENABLE([device-mapper],
++              [AS_HELP_STRING([--enable-device-mapper],
++                              [enable Linux device-mapper support (default=guessed)])])
++if test x"$enable_device_mapper" = xno ; then
++  device_mapper_excuse="explicitly disabled"
++fi
++
++if test x"$device_mapper_excuse" = x ; then
++  # Check for device-mapper library.
++  AC_CHECK_LIB([devmapper], [dm_task_create],
++               [LDFLAGS="$LDFLAGS -ldevmapper"
++                AC_DEFINE([HAVE_DEVICE_MAPPER], [1],
++                          [Define to 1 if you have the devmapper library.])],
++               [device_mapper_excuse="need devmapper library"])
++fi
++AC_SUBST(ASFLAGS)
++
 +AC_SUBST([FONT_SOURCE])
 +AS_IF([test x$target_cpu = xi386 -a x$platform = xpc],
 +	    [AC_SUBST([GRUB_KERNEL_MACHINE_LINK_ADDR], 0x8200)])
 +AS_IF([test x$target_cpu = xi386 -a x$platform = xcoreboot],
 +	    [AC_SUBST([GRUB_KERNEL_MACHINE_LINK_ADDR], 0x8200)])
 +AS_IF([test x$target_cpu = xi386 -a x$platform = xmultiboot],
 +	    [AC_SUBST([GRUB_KERNEL_MACHINE_LINK_ADDR], 0x8200)])
 +AS_IF([test x$target_cpu = xmips -a x$platform = xyeeloong],
 +	    [AC_SUBST([GRUB_KERNEL_MACHINE_LINK_ADDR], 0x80200000)])
 +AS_IF([test x$target_cpu = xpowerpc -a x$platform = xieee1275],
 +	    [AC_SUBST([GRUB_KERNEL_MACHINE_LINK_ADDR], 0x200000)])
 +AS_IF([test x$target_cpu = xi386 -a x$platform = xqemu],
 +	    [AC_SUBST([GRUB_BOOT_MACHINE_LINK_ADDR], 0xffe00)])
 +AS_IF([test x$target_cpu = xi386 -a x$platform = xieee1275],
 +	    [AC_SUBST([GRUB_KERNEL_MACHINE_LINK_ADDR], 0x10000)])
 +AS_IF([test x$TARGET_APPLE_CC = x1],
 +	    [AC_SUBST([USE_APPLE_CC_FIXES], yes)])
 +
 +#
 +# Automake conditionals
 +#
 +
 +AM_CONDITIONAL([COND_emu], [test x$platform = xemu])
 +AM_CONDITIONAL([COND_i386_pc], [test x$target_cpu = xi386 -a x$platform = xpc])
 +AM_CONDITIONAL([COND_i386_efi], [test x$target_cpu = xi386 -a x$platform = xefi])
 +AM_CONDITIONAL([COND_i386_qemu], [test x$target_cpu = xi386 -a x$platform = xqemu])
 +AM_CONDITIONAL([COND_i386_ieee1275], [test x$target_cpu = xi386 -a x$platform = xieee1275])
 +AM_CONDITIONAL([COND_i386_coreboot], [test x$target_cpu = xi386 -a x$platform = xcoreboot])
 +AM_CONDITIONAL([COND_i386_multiboot], [test x$target_cpu = xi386 -a x$platform = xmultiboot])
 +AM_CONDITIONAL([COND_x86_64_efi], [test x$target_cpu = xx86_64 -a x$platform = xefi])
 +AM_CONDITIONAL([COND_mips_yeeloong], [test x$target_cpu = xmips -a x$platform = xyeeloong])
 +AM_CONDITIONAL([COND_mips_qemu_mips], [test x$target_cpu = xmips -a x$platform = xqemu_mips])
 +AM_CONDITIONAL([COND_sparc64_ieee1275], [test x$target_cpu = xsparc64 -a x$platform = xieee1275])
 +AM_CONDITIONAL([COND_powerpc_ieee1275], [test x$target_cpu = xpowerpc -a x$platform = xieee1275])
 +
 +AM_CONDITIONAL([COND_MAN_PAGES], [test x$cross_compiling = xno -a x$HELP2MAN != x])
 +AM_CONDITIONAL([COND_GRUB_EMU_USB], [test x$enable_grub_emu_usb = xyes])
 +AM_CONDITIONAL([COND_GRUB_EMU_SDL], [test x$enable_grub_emu_sdl = xyes])
 +AM_CONDITIONAL([COND_GRUB_EMU_PCI], [test x$enable_grub_emu_pci = xyes])
 +AM_CONDITIONAL([COND_GRUB_MKFONT], [test x$enable_grub_mkfont = xyes])
 +AM_CONDITIONAL([COND_HAVE_FONT_SOURCE], [test x$FONT_SOURCE != x])
 +AM_CONDITIONAL([COND_GRUB_FSTEST], [test x$enable_grub_fstest = xyes])
 +AM_CONDITIONAL([COND_ENABLE_EFIEMU], [test x$enable_efiemu = xyes])