From: Jeff Trawick <trawick@apache.org>
Date: Tue, 3 Nov 2009 14:36:48 +0000 (+0000)
Subject: Change the configure-based MPM build mechanism to support building
X-Git-Tag: 2.3.3~61
X-Git-Url: http://git.ipfire.org/gitweb.cgi?a=commitdiff_plain;h=d4e7b85b2f4f6e169841ce74cab119e0c9bb2a77;p=thirdparty%2Fapache%2Fhttpd.git

Change the configure-based MPM build mechanism to support building
an MPM as a shared shared or dynamic module, primarily using the
APACHE_MPM_MODULE() function.

--enable-mpms-shared now builds/installs the MPMs as dynamic modules.
(But no LoadModule directives are added.)


git-svn-id: https://svn.apache.org/repos/asf/httpd/httpd/trunk@832434 13f79535-47bb-0310-9956-ffa450edef68
---

diff --git a/CHANGES b/CHANGES
index 4fe5853d7e6..a886f3e0289 100644
--- a/CHANGES
+++ b/CHANGES
@@ -252,9 +252,10 @@ Changes with Apache 2.3.3
   *) mod_proxy_ajp: Forward remote port information by default.
      [Rainer Jung]
 
-  *) Allow MPMs to be loaded dynamically, as with most other modules.  This
-     required changes to the MPM interfaces.  Removed: mpm.h, mpm_default.h
-     (as an installed header), APACHE_MPM_DIR, MPM_NAME, ap_threads_per_child, 
+  *) Allow MPMs to be loaded dynamically, as with most other modules.  Use
+     --enable-mpms-shared={list|"all"} to enable.  This required changes to
+     the MPM interfaces.  Removed: mpm.h, mpm_default.h (as an installed 
+     header), APACHE_MPM_DIR, MPM_NAME, ap_threads_per_child,
      ap_max_daemons_limit, ap_my_generation, etc.  ap_mpm_query() can't be
      called until after the register-hooks phase.  [Jeff Trawick]
 
diff --git a/acinclude.m4 b/acinclude.m4
index e9dcec84253..5caeecc0694 100644
--- a/acinclude.m4
+++ b/acinclude.m4
@@ -200,6 +200,59 @@ EOF
   fi
 ])dnl
 
+dnl
+dnl APACHE_MPM_MODULE(name[, shared[, objects[, config[, path]]]])
+dnl
+dnl Provide information for building the MPM.  (Enablement is handled using
+dnl --with-mpm/--enable-mpms-shared.)
+dnl
+dnl name     -- name of MPM, same as MPM directory name
+dnl shared   -- variable to check for value "shared" to indicate shared module build
+dnl objects  -- one or more .lo files to link into the MPM module (default: mpmname.lo)
+dnl config   -- configuration logic to run if the MPM is enabled
+dnl path     -- relative path to MPM (default: server/mpm/mpmname)
+dnl
+AC_DEFUN(APACHE_MPM_MODULE,[
+    if ap_mpm_is_enabled $1; then
+        if test -z "$3"; then
+            objects="$1.lo"
+        else
+            objects="$3"
+        fi
+
+        if test -z "$5"; then
+            mpmpath="server/mpm/$1"
+        else
+            mpmpath=$5
+        fi
+
+        APACHE_FAST_OUTPUT($mpmpath/Makefile)
+
+        if test -z "$2"; then
+            libname="lib$1.la"
+            cat >$mpmpath/modules.mk<<EOF
+$libname: $objects
+	\$(MOD_LINK) $objects
+DISTCLEAN_TARGETS = modules.mk
+static = $libname
+shared =
+EOF
+        else
+            apache_need_shared=yes
+            libname="mod_mpm_$1.la"
+            shobjects=`echo $objects | sed 's/\.lo/.slo/g'`
+            cat >$mpmpath/modules.mk<<EOF
+$libname: $shobjects
+	\$(SH_LINK) -rpath \$(libexecdir) -module -avoid-version $objects
+DISTCLEAN_TARGETS = modules.mk
+static =
+shared = $libname
+EOF
+        fi
+        $4
+    fi
+])dnl
+
 dnl
 dnl APACHE_MODULE(name, helptext[, objects[, structname[, default[, config]]]])
 dnl
diff --git a/server/mpm/config.m4 b/server/mpm/config.m4
index b855368492c..08541b0932b 100644
--- a/server/mpm/config.m4
+++ b/server/mpm/config.m4
@@ -49,7 +49,11 @@ AC_DEFUN(APACHE_MPM_SUPPORTED,[
 
 dnl APACHE_MPM_ENABLED(name)
 AC_DEFUN(APACHE_MPM_ENABLED,[
-    ENABLED_MPMS="$ENABLED_MPMS $1 "
+    if ap_mpm_is_enabled $1; then
+        :
+    else
+        ENABLED_MPMS="$ENABLED_MPMS $1 "
+    fi
 ])dnl
 
 ap_mpm_is_supported ()
diff --git a/server/mpm/event/Makefile.in b/server/mpm/event/Makefile.in
index 7c2a1a7a6df..f34af9cbd66 100644
--- a/server/mpm/event/Makefile.in
+++ b/server/mpm/event/Makefile.in
@@ -1,5 +1 @@
-
-LTLIBRARY_NAME    = libevent.la
-LTLIBRARY_SOURCES = event.c fdqueue.c pod.c
-
-include $(top_srcdir)/build/ltlib.mk
+include $(top_srcdir)/build/special.mk
diff --git a/server/mpm/event/config3.m4 b/server/mpm/event/config3.m4
index d4378cf3ab8..649d8638746 100644
--- a/server/mpm/event/config3.m4
+++ b/server/mpm/event/config3.m4
@@ -1,6 +1,5 @@
 dnl ## XXX - Need a more thorough check of the proper flags to use
 
-if ap_mpm_is_enabled "event"; then
+APACHE_MPM_MODULE(event, $enable_mpm_event, event.lo fdqueue.lo pod.lo,[
     AC_CHECK_FUNCS(pthread_kill)
-    APACHE_FAST_OUTPUT(server/mpm/event/Makefile)
-fi
+])
diff --git a/server/mpm/mpmt_os2/Makefile.in b/server/mpm/mpmt_os2/Makefile.in
index 38e598edf3a..f34af9cbd66 100644
--- a/server/mpm/mpmt_os2/Makefile.in
+++ b/server/mpm/mpmt_os2/Makefile.in
@@ -1,5 +1 @@
-
-LTLIBRARY_NAME    = libmpmt_os2.la
-LTLIBRARY_SOURCES = mpmt_os2.c mpmt_os2_child.c
-
-include $(top_srcdir)/build/ltlib.mk
+include $(top_srcdir)/build/special.mk
diff --git a/server/mpm/mpmt_os2/config5.m4 b/server/mpm/mpmt_os2/config5.m4
index 51bc4cb61c8..c74f1452bbc 100644
--- a/server/mpm/mpmt_os2/config5.m4
+++ b/server/mpm/mpmt_os2/config5.m4
@@ -1,5 +1,3 @@
-if ap_mpm_is_enabled "mpmt_os2"; then
-    AC_CACHE_SAVE
-    APACHE_FAST_OUTPUT(server/mpm/mpmt_os2/Makefile)
+APACHE_MPM_MODULE(mpmt_os2, $enable_mpm_mpmt_os2, mpmt_os2.lo mpmt_os2_child.lo,[
     APR_ADDTO(CFLAGS,-Zmt)
-fi
+])
diff --git a/server/mpm/prefork/Makefile.in b/server/mpm/prefork/Makefile.in
index 034bf5ce84c..f34af9cbd66 100644
--- a/server/mpm/prefork/Makefile.in
+++ b/server/mpm/prefork/Makefile.in
@@ -1,5 +1 @@
-
-LTLIBRARY_NAME    = libprefork.la
-LTLIBRARY_SOURCES = prefork.c
-
-include $(top_srcdir)/build/ltlib.mk
+include $(top_srcdir)/build/special.mk
diff --git a/server/mpm/prefork/config3.m4 b/server/mpm/prefork/config3.m4
index 9cafecbd3fc..25fd8df3397 100644
--- a/server/mpm/prefork/config3.m4
+++ b/server/mpm/prefork/config3.m4
@@ -1,3 +1 @@
-if ap_mpm_is_enabled "prefork"; then
-    APACHE_FAST_OUTPUT(server/mpm/prefork/Makefile)
-fi
+APACHE_MPM_MODULE(prefork, $enable_mpm_prefork)
diff --git a/server/mpm/simple/Makefile.in b/server/mpm/simple/Makefile.in
index 4c9dee07fdc..f34af9cbd66 100644
--- a/server/mpm/simple/Makefile.in
+++ b/server/mpm/simple/Makefile.in
@@ -1,4 +1 @@
-LTLIBRARY_NAME    = libsimple.la
-LTLIBRARY_SOURCES = simple_api.c simple_children.c simple_core.c simple_event.c simple_run.c simple_io.c
-
-include $(top_srcdir)/build/ltlib.mk
+include $(top_srcdir)/build/special.mk
diff --git a/server/mpm/simple/config3.m4 b/server/mpm/simple/config3.m4
index fcdc9b03273..e518119518c 100644
--- a/server/mpm/simple/config3.m4
+++ b/server/mpm/simple/config3.m4
@@ -1,3 +1,3 @@
-if ap_mpm_is_enabled "simple"; then
-    APACHE_FAST_OUTPUT(server/mpm/simple/Makefile)
-fi
+simple_objects="simple_api.lo simple_children.lo simple_core.lo \
+simple_event.lo simple_run.lo simple_io.lo"
+APACHE_MPM_MODULE(simple, $enable_mpm_simple, $simple_objects)
diff --git a/server/mpm/winnt/Makefile.in b/server/mpm/winnt/Makefile.in
index d28a5ea5873..f34af9cbd66 100644
--- a/server/mpm/winnt/Makefile.in
+++ b/server/mpm/winnt/Makefile.in
@@ -1,5 +1 @@
-
-LTLIBRARY_NAME    = libwinnt.la
-LTLIBRARY_SOURCES = child.c mpm_winnt.c nt_eventlog.c service.c
-
-include $(top_srcdir)/build/ltlib.mk
+include $(top_srcdir)/build/special.mk
diff --git a/server/mpm/winnt/config3.m4 b/server/mpm/winnt/config3.m4
index 8486288092f..f937e404950 100644
--- a/server/mpm/winnt/config3.m4
+++ b/server/mpm/winnt/config3.m4
@@ -1,3 +1,2 @@
-if ap_mpm_is_enabled "winnt"; then
-    APACHE_FAST_OUTPUT(server/mpm/winnt/Makefile)
-fi
+winnt_objects="child.lo mpm_winnt.lo nt_eventlog.lo service.lo"
+APACHE_MPM_MODULE(winnt, $enable_mpm_winnt, $winnt_objects)
diff --git a/server/mpm/worker/Makefile.in b/server/mpm/worker/Makefile.in
index b45b848341f..e32210f1851 100644
--- a/server/mpm/worker/Makefile.in
+++ b/server/mpm/worker/Makefile.in
@@ -1,5 +1,2 @@
 
-LTLIBRARY_NAME    = libworker.la
-LTLIBRARY_SOURCES = worker.c fdqueue.c pod.c
-
-include $(top_srcdir)/build/ltlib.mk
+include $(top_srcdir)/build/special.mk
diff --git a/server/mpm/worker/config3.m4 b/server/mpm/worker/config3.m4
index be556259093..dc2bccb5542 100644
--- a/server/mpm/worker/config3.m4
+++ b/server/mpm/worker/config3.m4
@@ -1,6 +1,5 @@
 dnl ## XXX - Need a more thorough check of the proper flags to use
 
-if ap_mpm_is_enabled "worker"; then
+APACHE_MPM_MODULE(worker, $enable_mpm_worker, worker.lo fdqueue.lo pod.lo,[
     AC_CHECK_FUNCS(pthread_kill)
-    APACHE_FAST_OUTPUT(server/mpm/worker/Makefile)
-fi
+])