From: Jim Meyering <jim@meyering.net>
Date: Fri, 6 Jun 2003 19:54:14 +0000 (+0000)
Subject: from gnulib
X-Git-Tag: v5.0.1~362
X-Git-Url: http://git.ipfire.org/gitweb/index.cgi?a=commitdiff_plain;h=46e87665861c13dcdfd26283950a81a561896feb;p=thirdparty%2Fcoreutils.git

from gnulib
---

diff --git a/m4/alloca.m4 b/m4/alloca.m4
new file mode 100644
index 0000000000..4df039d203
--- /dev/null
+++ b/m4/alloca.m4
@@ -0,0 +1,36 @@
+# alloca.m4 serial 2 (gettext-0.12)
+dnl Copyright (C) 2002-2003 Free Software Foundation, Inc.
+dnl This file is free software, distributed under the terms of the GNU
+dnl General Public License.  As a special exception to the GNU General
+dnl Public License, this file may be distributed as part of a program
+dnl that contains a configuration script generated by Autoconf, under
+dnl the same distribution terms as the rest of that program.
+
+AC_DEFUN([gl_FUNC_ALLOCA],
+[
+  dnl Work around a bug of AC_EGREP_CPP in autoconf-2.57.
+  AC_REQUIRE([AC_PROG_CPP])
+  AC_REQUIRE([AC_PROG_EGREP])
+
+  AC_REQUIRE([AC_FUNC_ALLOCA])
+  if test $ac_cv_func_alloca_works = no; then
+    gl_PREREQ_ALLOCA
+  fi
+
+  # Define an additional variable used in the Makefile substitution.
+
+  AC_EGREP_CPP([Need own alloca], [
+#if defined __GNUC__ || defined _MSC_VER || !HAVE_ALLOCA_H
+  Need own alloca
+#endif
+    ],
+    ALLOCA_H=alloca.h,
+    ALLOCA_H=)
+  AC_SUBST([ALLOCA_H])
+])
+
+# Prerequisites of lib/alloca.c.
+# STACK_DIRECTION is already handled by AC_FUNC_ALLOCA.
+AC_DEFUN([gl_PREREQ_ALLOCA], [
+  AC_CHECK_HEADERS_ONCE(stdlib.h string.h)
+])