arch/arm/lib/relocate.S

   1 /*
   2  *  relocate - common relocation function for ARM U-Boot
   3  *
   4  *  Copyright (c) 2013  Albert ARIBAUD <albert.u.boot@aribaud.net>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25 #include <linux/linkage.h>
  26
  27 /*
  28  * void relocate_code(addr_moni)
  29  *
  30  * This function relocates the monitor code.
  31  *
  32  * NOTE:
  33  * To prevent the code below from containing references with an R_ARM_ABS32
  34  * relocation record type, we never refer to linker-defined symbols directly.
  35  * Instead, we declare literals which contain their relative location with
  36  * respect to relocate_code, and at run time, add relocate_code back to them.
  37  */
  38
  39 ENTRY(relocate_code)
  40         ldr     r1, =__image_copy_start /* r1 <- SRC &__image_copy_start */
  41         subs    r9, r0, r1              /* r9 <- relocation offset */
  42         beq     relocate_done           /* skip relocation */
  43         ldr     r2, =__image_copy_end   /* r2 <- SRC &__image_copy_end */
  44
  45 copy_loop:
  46         ldmia   r1!, {r10-r11}          /* copy from source address [r1]    */
  47         stmia   r0!, {r10-r11}          /* copy to   target address [r0]    */
  48         cmp     r1, r2                  /* until source end address [r2]    */
  49         blo     copy_loop
  50
  51         /*
  52          * fix .rel.dyn relocations
  53          */
  54         ldr     r2, =__rel_dyn_start    /* r2 <- SRC &__rel_dyn_start */
  55         ldr     r3, =__rel_dyn_end      /* r3 <- SRC &__rel_dyn_end */
  56 fixloop:
  57         ldmia   r2!, {r0-r1}            /* (r0,r1) <- (SRC location,fixup) */
  58         and     r1, r1, #0xff
  59         cmp     r1, #23                 /* relative fixup? */
  60         bne     fixnext
  61
  62         /* relative fix: increase location by offset */
  63         add     r0, r0, r9
  64         ldr     r1, [r0]
  65         add     r1, r1, r9
  66         str     r1, [r0]
  67 fixnext:
  68         cmp     r2, r3
  69         blo     fixloop
  70
  71 relocate_done:
  72
  73 #ifdef __XSCALE__
  74         /*
  75          * On xscale, icache must be invalidated and write buffers drained,
  76          * even with cache disabled - 4.2.7 of xscale core developer's manual
  77          */
  78         mcr     p15, 0, r0, c7, c7, 0   /* invalidate icache */
  79         mcr     p15, 0, r0, c7, c10, 4  /* drain write buffer */
  80 #endif
  81
  82         /* ARMv4- don't know bx lr but the assembler fails to see that */
  83
  84 #ifdef __ARM_ARCH_4__
  85         mov        pc, lr
  86 #else
  87         bx        lr
  88 #endif
  89
  90 ENDPROC(relocate_code)