config/cfgroot/ids-functions.pl

   1 #!/usr/bin/perl -w
   2 ############################################################################
   3 #                                                                          #
   4 # This file is part of the IPFire Firewall.                                #
   5 #                                                                          #
   6 # IPFire is free software; you can redistribute it and/or modify           #
   7 # it under the terms of the GNU General Public License as published by     #
   8 # the Free Software Foundation; either version 2 of the License, or        #
   9 # (at your option) any later version.                                      #
  10 #                                                                          #
  11 # IPFire is distributed in the hope that it will be useful,                #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of           #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the            #
  14 # GNU General Public License for more details.                             #
  15 #                                                                          #
  16 # You should have received a copy of the GNU General Public License        #
  17 # along with IPFire; if not, write to the Free Software                    #
  18 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA #
  19 #                                                                          #
  20 # Copyright (C) 2018-2019 IPFire Team <info@ipfire.org>                    #
  21 #                                                                          #
  22 ############################################################################
  23
  24 use strict;
  25
  26 package IDS;
  27
  28 require '/var/ipfire/general-functions.pl';
  29 require "${General::swroot}/network-functions.pl";
  30 require "${General::swroot}/suricata/ruleset-sources";
  31
  32 # Location where all config and settings files are stored.
  33 our $settingsdir = "${General::swroot}/suricata";
  34
  35 # File where the main file for providers ruleset inclusion exists.
  36 our $suricata_used_providers_file = "$settingsdir/suricata-used-providers.yaml";
  37
  38 # File for static ruleset inclusions.
  39 our $suricata_static_rulefiles_file = "$settingsdir/suricata-static-included-rulefiles.yaml";
  40
  41 # DEPRECATED - File where the used rulefiles are stored.
  42 our $used_rulefiles_file = "$settingsdir/suricata-used-rulefiles.yaml";
  43
  44 # File where the addresses of the homenet are stored.
  45 our $homenet_file = "$settingsdir/suricata-homenet.yaml";
  46
  47 # File where the addresses of the used DNS servers are stored.
  48 our $dns_servers_file = "$settingsdir/suricata-dns-servers.yaml";
  49
  50 # File where the HTTP ports definition is stored.
  51 our $http_ports_file = "$settingsdir/suricata-http-ports.yaml";
  52
  53 # DEPRECATED - File which contains the enabled sids.
  54 our $enabled_sids_file = "$settingsdir/oinkmaster-enabled-sids.conf";
  55
  56 # DEPRECATED - File which contains the disabled sids.
  57 our $disabled_sids_file = "$settingsdir/oinkmaster-disabled-sids.conf";
  58
  59 # File which contains includes for provider specific rule modifications.
  60 our $oinkmaster_provider_includes_file = "$settingsdir/oinkmaster-provider-includes.conf";
  61
  62 # File which contains wheater the rules should be changed.
  63 our $modify_sids_file = "$settingsdir/oinkmaster-modify-sids.conf";
  64
  65 # File which stores the configured IPS settings.
  66 our $ids_settings_file = "$settingsdir/settings";
  67
  68 # DEPRECATED - File which stores the configured rules-settings.
  69 our $rules_settings_file = "$settingsdir/rules-settings";
  70
  71 # File which stores the used and configured ruleset providers.
  72 our $providers_settings_file = "$settingsdir/providers-settings";
  73
  74 # File which stores the configured settings for whitelisted addresses.
  75 our $ignored_file = "$settingsdir/ignored";
  76
  77 # DEPRECATED - Location and name of the tarball which contains the ruleset.
  78 our $rulestarball = "/var/tmp/idsrules.tar.gz";
  79
  80 # Location where the downloaded rulesets are stored.
  81 our $dl_rules_path = "/var/tmp";
  82
  83 # File to store any errors, which also will be read and displayed by the wui.
  84 our $storederrorfile = "/tmp/ids_storederror";
  85
  86 # File to lock the WUI, while the autoupdate script runs.
  87 our $ids_page_lock_file = "/tmp/ids_page_locked";
  88
  89 # Location where the rulefiles are stored.
  90 our $rulespath = "/var/lib/suricata";
  91
  92 # Location of the classification file.
  93 our $classification_file = "$rulespath/classification.config";
  94
  95 # Location of the sid to msg mappings file.
  96 our $sid_msg_file = "$rulespath/sid-msg.map";
  97
  98 # Location to store local rules. This file will not be touched.
  99 our $local_rules_file = "$rulespath/local.rules";
 100
 101 # File which contains the rules to whitelist addresses on suricata.
 102 our $whitelist_file = "$rulespath/whitelist.rules";
 103
 104 # File which contains a list of all supported ruleset sources.
 105 # (Sourcefire, Emergingthreads, etc..)
 106 our $rulesetsourcesfile = "$settingsdir/ruleset-sources";
 107
 108 # The pidfile of the IDS.
 109 our $idspidfile = "/var/run/suricata.pid";
 110
 111 # Location of suricatactrl.
 112 my $suricatactrl = "/usr/local/bin/suricatactrl";
 113
 114 # Prefix for each downloaded ruleset.
 115 my $dl_rulesfile_prefix = "idsrules";
 116
 117 # Temporary directory where the rulesets will be extracted.
 118 my $tmp_directory = "/tmp/ids_tmp";
 119
 120 # Temporary directory where the extracted rules files will be stored.
 121 my $tmp_rules_directory = "$tmp_directory/rules";
 122
 123 # Temporary directory where the extracted additional config files will be stored.
 124 my $tmp_conf_directory = "$tmp_directory/conf";
 125
 126 # Array with allowed commands of suricatactrl.
 127 my @suricatactrl_cmds = ( 'start', 'stop', 'restart', 'reload', 'fix-rules-dir', 'cron' );
 128
 129 # Array with supported cron intervals.
 130 my @cron_intervals = ('off', 'daily', 'weekly' );
 131
 132 # Array which contains the HTTP ports, which statically will be declared as HTTP_PORTS in the
 133 # http_ports_file.
 134 my @http_ports = ('80', '81');
 135
 136 # Array which contains a list of rulefiles which always will be included if they exist.
 137 my @static_included_rulefiles = ('local.rules', 'whitelist.rules' );
 138
 139 # Hash which allows to convert the download type (dl_type) to a file suffix.
 140 my %dl_type_to_suffix = (
 141         "archive" => ".tar.gz",
 142         "plain" => ".rules",
 143 );
 144
 145 #
 146 ## Function to check and create all IDS related files, if the does not exist.
 147 #
 148 sub check_and_create_filelayout() {
 149         # Check if the files exist and if not, create them.
 150         unless (-f "$oinkmaster_provider_includes_file") { &create_empty_file($oinkmaster_provider_includes_file); }
 151         unless (-f "$modify_sids_file") { &create_empty_file($modify_sids_file); }
 152         unless (-f "$suricata_used_providers_file") { &create_empty_file($suricata_used_providers_file); }
 153         unless (-f "$ids_settings_file") { &create_empty_file($ids_settings_file); }
 154         unless (-f "$providers_settings_file") { &create_empty_file($providers_settings_file); }
 155         unless (-f "$ignored_file") { &create_empty_file($ignored_file); }
 156         unless (-f "$whitelist_file" ) { &create_empty_file($whitelist_file); }
 157 }
 158
 159 #
 160 ## Function to get a list of all available ruleset providers.
 161 ##
 162 ## They will be returned as a sorted array.
 163 #
 164 sub get_ruleset_providers() {
 165         my @providers;
 166
 167         # Loop through the hash of providers.
 168         foreach my $provider ( keys %IDS::Ruleset::Providers ) {
 169                 # Add the provider to the array.
 170                 push(@providers, $provider);
 171         }
 172
 173         # Sort and return the array.
 174         return sort(@providers);
 175 }
 176
 177 #
 178 ## Function to get a list of all enabled ruleset providers.
 179 ##
 180 ## They will be returned as an array.
 181 #
 182 sub get_enabled_providers () {
 183         my %used_providers = ();
 184
 185         # Array to store the enabled providers.
 186         my @enabled_providers = ();
 187
 188         # Read-in the providers config file.
 189         &General::readhasharray("$providers_settings_file", \%used_providers);
 190
 191         # Loop through the hash of used_providers.
 192         foreach my $id (keys %used_providers) {
 193                 # Skip disabled providers.
 194                 next unless ($used_providers{$id}[3] eq "enabled");
 195
 196                 # Grab the provider handle.
 197                 my $provider = "$used_providers{$id}[0]";
 198
 199                 # Add the provider to the array of enabled providers.
 200                 push(@enabled_providers, $provider);
 201         }
 202
 203         # Return the array.
 204         return @enabled_providers;
 205 }
 206
 207 #
 208 ## Function for checking if at least 300MB of free disk space are available
 209 ## on the "/var" partition.
 210 #
 211 sub checkdiskspace () {
 212         # Call diskfree to gather the free disk space of /var.
 213         my @df = &General::system_output("/bin/df", "-B", "M", "/var");
 214
 215         # Loop through the output.
 216         foreach my $line (@df) {
 217                 # Ignore header line.
 218                 next if $line =~ m/^Filesystem/;
 219
 220                 # Search for a line with the device information.
 221                 if ($line =~ m/dev/ ) {
 222                         # Split the line into single pieces.
 223                         my @values = split(' ', $line);
 224                         my ($filesystem, $blocks, $used, $available, $used_perenctage, $mounted_on) = @values;
 225
 226                         # Check if the available disk space is more than 300MB.
 227                         if ($available < 300) {
 228                                 # Log error to syslog.
 229                                 &_log_to_syslog("Not enough free disk space on /var. Only $available MB from 300 MB available.");
 230
 231                                 # Exit function and return "1" - False.
 232                                 return 1;
 233                         }
 234                 }
 235         }
 236
 237         # Everything okay, return nothing.
 238         return;
 239 }
 240
 241 #
 242 ## This function is responsible for downloading the configured IDS rulesets or if no one is specified
 243 ## all configured rulesets will be downloaded.
 244 ##
 245 ## * At first it gathers all configured ruleset providers, initialize the downloader and sets an
 246 ##   upstream proxy if configured.
 247 ## * After that, the given ruleset or in case all rulesets should be downloaded, it will determine wether it
 248 ##   is enabled or not.
 249 ## * The next step will be to generate the final download url, by obtaining the URL for the desired
 250 ##   ruleset, add the settings for the upstream proxy.
 251 ## * Finally the function will grab all the rules files or tarballs from the servers.
 252 #
 253 sub downloadruleset ($) {
 254         my ($provider) = @_;
 255
 256         # If no provider is given default to "all".
 257         $provider //= 'all';
 258
 259         # Hash to store the providers and access id's, for which rules should be downloaded.
 260         my %sheduled_providers = ();
 261
 262         # Get used provider settings.
 263         my %used_providers = ();
 264         &General::readhasharray("$providers_settings_file", \%used_providers);
 265
 266         # Check if a ruleset has been configured.
 267         unless(%used_providers) {
 268                 # Log that no ruleset has been configured and abort.
 269                 &_log_to_syslog("No ruleset provider has been configured.");
 270
 271                 # Return "1".
 272                 return 1;
 273         }
 274
 275         # Read proxysettings.
 276         my %proxysettings=();
 277         &General::readhash("${General::swroot}/proxy/settings", \%proxysettings);
 278
 279         # Load required perl module to handle the download.
 280         use LWP::UserAgent;
 281
 282         # Init the download module.
 283         my $downloader = LWP::UserAgent->new;
 284
 285         # Set timeout to 10 seconds.
 286         $downloader->timeout(10);
 287
 288         # Check if an upstream proxy is configured.
 289         if ($proxysettings{'UPSTREAM_PROXY'}) {
 290                 my $proxy_url;
 291
 292                 $proxy_url = "http://";
 293
 294                 # Check if the proxy requires authentication.
 295                 if (($proxysettings{'UPSTREAM_USER'}) && ($proxysettings{'UPSTREAM_PASSWORD'})) {
 296                         $proxy_url .= "$proxysettings{'UPSTREAM_USER'}\:$proxysettings{'UPSTREAM_PASSWORD'}\@";
 297                 }
 298
 299                 # Add proxy server address and port.
 300                 $proxy_url .= $proxysettings{'UPSTREAM_PROXY'};
 301
 302                 # Setup proxy settings.
 303                 $downloader->proxy(['http', 'https'], $proxy_url);
 304         }
 305
 306         # Loop through the hash of configured providers.
 307         foreach my $id ( keys %used_providers ) {
 308                 # Skip providers which are not enabled.
 309                 next if ($used_providers{$id}[3] ne "enabled");
 310
 311                 # Obtain the provider handle.
 312                 my $provider_handle = $used_providers{$id}[0];
 313
 314                 # Handle update off all providers.
 315                 if (($provider eq "all") || ($provider_handle eq "$provider")) {
 316                         # Add provider handle and it's id to the hash of sheduled providers.
 317                         $sheduled_providers{$provider_handle} = $id;
 318                 }
 319         }
 320
 321         # Loop through the hash of sheduled providers.
 322         foreach my $provider ( keys %sheduled_providers) {
 323                 # Grab the download url for the provider.
 324                 my $url = $IDS::Ruleset::Providers{$provider}{'dl_url'};
 325
 326                 # Check if the provider requires a subscription.
 327                 if ($IDS::Ruleset::Providers{$provider}{'requires_subscription'} eq "True") {
 328                         # Grab the previously stored access id for the provider from hash.
 329                         my $id = $sheduled_providers{$provider};
 330
 331                         # Grab the subscription code.
 332                         my $subscription_code = $used_providers{$id}[1];
 333
 334                         # Add the subscription code to the download url.
 335                         $url =~ s/\<subscription_code\>/$subscription_code/g;
 336
 337                 }
 338
 339                 # Abort if no url could be determined for the provider.
 340                 unless ($url) {
 341                         # Log error and abort.
 342                         &_log_to_syslog("Unable to gather a download URL for the selected ruleset provider.");
 343                         return 1;
 344                 }
 345
 346                 # Variable to store the filesize of the remote object.
 347                 my $remote_filesize;
 348
 349                 # The sourcfire (snort rules) does not allow to send "HEAD" requests, so skip this check
 350                 # for this webserver.
 351                 #
 352                 # Check if the ruleset source contains "snort.org".
 353                 unless ($url =~ /\.snort\.org/) {
 354                         # Pass the requrested url to the downloader.
 355                         my $request = HTTP::Request->new(HEAD => $url);
 356
 357                         # Accept the html header.
 358                         $request->header('Accept' => 'text/html');
 359
 360                         # Perform the request and fetch the html header.
 361                         my $response = $downloader->request($request);
 362
 363                         # Check if there was any error.
 364                         unless ($response->is_success) {
 365                                 # Obtain error.
 366                                 my $error = $response->status_line();
 367
 368                                 # Log error message.
 369                                 &_log_to_syslog("Unable to download the ruleset. \($error\)");
 370
 371                                 # Return "1" - false.
 372                                 return 1;
 373                         }
 374
 375                         # Assign the fetched header object.
 376                         my $header = $response->headers();
 377
 378                         # Grab the remote file size from the object and store it in the
 379                         # variable.
 380                         $remote_filesize = $header->content_length;
 381                 }
 382
 383                 # Load perl module to deal with temporary files.
 384                 use File::Temp;
 385
 386                 # Generate temporary file name, located in "/var/tmp" and with a suffix of ".tmp".
 387                 my $tmp = File::Temp->new( SUFFIX => ".tmp", DIR => "/var/tmp/", UNLINK => 0 );
 388                 my $tmpfile = $tmp->filename();
 389
 390                 # Pass the requested url to the downloader.
 391                 my $request = HTTP::Request->new(GET => $url);
 392
 393                 # Perform the request and save the output into the tmpfile.
 394                 my $response = $downloader->request($request, $tmpfile);
 395
 396                 # Check if there was any error.
 397                 unless ($response->is_success) {
 398                         # Obtain error.
 399                         my $error = $response->content;
 400
 401                         # Log error message.
 402                         &_log_to_syslog("Unable to download the ruleset. \($error\)");
 403
 404                         # Return "1" - false.
 405                         return 1;
 406                 }
 407
 408                 # Load perl stat module.
 409                 use File::stat;
 410
 411                 # Perform stat on the tmpfile.
 412                 my $stat = stat($tmpfile);
 413
 414                 # Grab the local filesize of the downloaded tarball.
 415                 my $local_filesize = $stat->size;
 416
 417                 # Check if both file sizes match.
 418                 if (($remote_filesize) && ($remote_filesize ne $local_filesize)) {
 419                         # Log error message.
 420                         &_log_to_syslog("Unable to completely download the ruleset. ");
 421                         &_log_to_syslog("Only got $local_filesize Bytes instead of $remote_filesize Bytes. ");
 422
 423                         # Delete temporary file.
 424                         unlink("$tmpfile");
 425
 426                         # Return "1" - false.
 427                         return 1;
 428                 }
 429
 430                 # Genarate and assign file name and path to store the downloaded rules file.
 431                 my $dl_rulesfile = &_get_dl_rulesfile($provider);
 432
 433                 # Check if a file name could be obtained.
 434                 unless ($dl_rulesfile) {
 435                         # Log error message.
 436                         &_log_to_syslog("Unable to store the downloaded rules file. ");
 437
 438                         # Delete downloaded temporary file.
 439                         unlink("$tmpfile");
 440
 441                         # Return "1" - false.
 442                 }
 443
 444                 # Load file copy module, which contains the move() function.
 445                 use File::Copy;
 446
 447                 # Overwrite the may existing rulefile or tarball with the downloaded one.
 448                 move("$tmpfile", "$dl_rulesfile");
 449
 450                 # Delete temporary file.
 451                 unlink("$tmpfile");
 452
 453                 # Set correct ownership for the tarball.
 454                 set_ownership("$dl_rulesfile");
 455         }
 456
 457         # If we got here, everything worked fine. Return nothing.
 458         return;
 459 }
 460
 461 #
 462 ## Function to extract a given ruleset.
 463 ##
 464 ## In case the ruleset provider offers a plain file, it simply will
 465 ## be copied.
 466 #
 467 sub extractruleset ($) {
 468         my ($provider) = @_;
 469
 470         # Load perl module to deal with archives.
 471         use Archive::Tar;
 472
 473         # Load perl module to deal with files and path.
 474         use File::Basename;
 475
 476         # Load perl module for file copying.
 477         use File::Copy;
 478
 479         # Get full path and downloaded rulesfile for the given provider.
 480         my $tarball = &_get_dl_rulesfile($provider);
 481
 482         # Check if the file exists.
 483         unless (-f $tarball) {
 484                 &_log_to_syslog("Could not find ruleset file: $tarball");
 485
 486                 # Return nothing.
 487                 return;
 488         }
 489
 490         # Check if the temporary directories exist, otherwise create them.
 491         mkdir("$tmp_directory") unless (-d "$tmp_directory");
 492         mkdir("$tmp_rules_directory") unless (-d "$tmp_rules_directory");
 493         mkdir("$tmp_conf_directory") unless (-d "$tmp_conf_directory");
 494
 495         # Omit the type (dl_type) of the stored ruleset.
 496         my $type = $IDS::Ruleset::Providers{$provider}{'dl_type'};
 497
 498         # Handle the different ruleset types.
 499         if ($type eq "plain") {
 500                 # Generate destination filename an full path.
 501                 my $destination = "$tmp_rules_directory/$provider\-ruleset.rules";
 502
 503                 # Copy the file into the temporary rules directory.
 504                 copy($tarball, $destination);
 505
 506         } elsif ( $type eq "archive") {
 507                 # Initialize the tar module.
 508                 my $tar = Archive::Tar->new($tarball);
 509
 510                 # Get the filelist inside the tarball.
 511                 my @packed_files = $tar->list_files;
 512
 513                 # Loop through the filelist.
 514                 foreach my $packed_file (@packed_files) {
 515                         my $destination;
 516
 517                         # Splitt the packed file into chunks.
 518                         my $file = fileparse($packed_file);
 519
 520                         # Handle msg-id.map file.
 521                         if ("$file" eq "sid-msg.map") {
 522                                 # Set extract destination to temporary config_dir.
 523                                 $destination = "$tmp_conf_directory/$provider\-sid-msg.map";
 524
 525                         # Handle classification.conf
 526                         } elsif ("$file" eq "classification.config") {
 527                                 # Set extract destination to temporary config_dir.
 528                                 $destination = "$tmp_conf_directory/$provider\-classification.config";
 529
 530                         # Handle rules files.
 531                         } elsif ($file =~ m/\.rules$/) {
 532                                 my $rulesfilename;
 533
 534                                 # Splitt the filename into chunks.
 535                                 my @filename = split("-", $file);
 536
 537                                 # Reverse the array.
 538                                 @filename = reverse(@filename);
 539
 540                                 # Get the amount of elements in the array.
 541                                 my $elements = @filename;
 542
 543                                 # Remove last element of the hash.
 544                                 # It contains the vendor name, which will be replaced.
 545                                 if ($elements >= 3) {
 546                                 # Remove last element from hash.
 547                                         pop(@filename);
 548                                 }
 549
 550                                 # Check if the last element of the filename does not
 551                                 # contain the providers name.
 552                                 if ($filename[-1] ne "$provider") {
 553                                         # Add provider name as last element.
 554                                         push(@filename, $provider);
 555                                 }
 556
 557                                 # Reverse the array back.
 558                                 @filename = reverse(@filename);
 559
 560                                 # Generate the name for the rulesfile.
 561                                 $rulesfilename = join("-", @filename);
 562
 563                                 # Set extract destination to temporaray rules_dir.
 564                                 $destination = "$tmp_rules_directory/$rulesfilename";
 565                         } else {
 566                                 # Skip all other files.
 567                                 next;
 568                         }
 569
 570                         # Extract the file to the temporary directory.
 571                         $tar->extract_file("$packed_file", "$destination");
 572                 }
 573         }
 574 }
 575
 576 #
 577 ## A wrapper function to call the oinkmaster script, setup the rules structues and
 578 ## call the functions to merge the additional config files. (classification, sid-msg, etc.).
 579 #
 580 sub oinkmaster () {
 581         # Check if the files in rulesdir have the correct permissions.
 582         &_check_rulesdir_permissions();
 583
 584         # Cleanup the rules directory before filling it with the new rulests.
 585         &_cleanup_rulesdir();
 586
 587         # Get all enabled providers.
 588         my @enabled_providers = &get_enabled_providers();
 589
 590         # Loop through the array of enabled providers.
 591         foreach my $provider (@enabled_providers) {
 592                 # Call the extractruleset function.
 593                 &extractruleset($provider);
 594         }
 595
 596         # Load perl module to talk to the kernel syslog.
 597         use Sys::Syslog qw(:DEFAULT setlogsock);
 598
 599         # Establish the connection to the syslog service.
 600         openlog('oinkmaster', 'cons,pid', 'user');
 601
 602         # Call oinkmaster to generate ruleset.
 603         open(OINKMASTER, "/usr/local/bin/oinkmaster.pl -s -u dir://$tmp_rules_directory -C $settingsdir/oinkmaster.conf -o $rulespath 2>&1 |") or die "Could not execute oinkmaster $!\n";
 604
 605         # Log output of oinkmaster to syslog.
 606         while(<OINKMASTER>) {
 607                 # The syslog function works best with an array based input,
 608                 # so generate one before passing the message details to syslog.
 609                 my @syslog = ("INFO", "$_");
 610
 611                 # Send the log message.
 612                 syslog(@syslog);
 613         }
 614
 615         # Close the pipe to oinkmaster process.
 616         close(OINKMASTER);
 617
 618         # Close the log handle.
 619         closelog();
 620
 621         # Call function to merge the classification files.
 622         &merge_classifications(@enabled_providers);
 623
 624         # Call function to merge the sid to message mapping files.
 625         &merge_sid_msg(@enabled_providers);
 626
 627         # Cleanup temporary directory.
 628         &cleanup_tmp_directory();
 629 }
 630
 631 #
 632 ## Function to merge the classifications for a given amount of providers and write them
 633 ## to the classifications file.
 634 #
 635 sub merge_classifications(@) {
 636         my @providers = @_;
 637
 638         # Hash to store all collected classifications.
 639         my %classifications = ();
 640
 641         # Loop through the given array of providers.
 642         foreach my $provider (@providers) {
 643                 # Generate full path to classification file.
 644                 my $classification_file = "$tmp_conf_directory/$provider\-classification.config";
 645
 646                 # Skip provider if no classification file exists.
 647                 next unless (-f "$classification_file");
 648
 649                 # Open the classification file.
 650                 open(CLASSIFICATION, $classification_file) or die "Could not open file $classification_file. $!\n";
 651
 652                 # Loop through the file content.
 653                 while(<CLASSIFICATION>) {
 654                         # Parse the file and grab the classification details.
 655                         if ($_ =~/.*config classification\: (.*)/) {
 656                                 # Split the grabbed details.
 657                                 my ($short_name, $short_desc, $priority) = split("\,", $1);
 658
 659                                 # Check if the grabbed classification is allready known and the priority value is greater
 660                                 # than the stored one (which causes less priority in the IDS).
 661                                 if (($classifications{$short_name}) && ($classifications{$short_name}[1] >= $priority)) {
 662                                         #Change the priority value to the stricter one.
 663                                         $classifications{$short_name} = [ "$classifications{$short_name}[0]", "$priority" ];
 664                                 } else {
 665                                         # Add the classification to the hash.
 666                                         $classifications{$short_name} = [ "$short_desc", "$priority" ];
 667                                 }
 668                         }
 669                 }
 670
 671                 # Close the file.
 672                 close(CLASSIFICATION);
 673         }
 674
 675         # Open classification file for writing.
 676         open(FILE, ">", "$classification_file") or die "Could not write to $classification_file. $!\n";
 677
 678         # Print notice about autogenerated file.
 679         print FILE "#Autogenerated file. Any custom changes will be overwritten!\n\n";
 680
 681         # Sort and loop through the hash of classifications.
 682         foreach my $key (sort keys %classifications) {
 683                 # Assign some nice variable names for the items.
 684                 my $short_name = $key;
 685                 my $short_desc = $classifications{$key}[0];
 686                 my $priority = $classifications{$key}[1];
 687
 688                 # Write the classification to the file.
 689                 print FILE "config classification: $short_name,$short_desc,$priority\n";
 690         }
 691
 692         # Close file handle.
 693         close(FILE);
 694 }
 695
 696 #
 697 ## Function to merge the "sid to message mapping" files of various given providers.
 698 #
 699 sub merge_sid_msg (@) {
 700         my @providers = @_;
 701
 702         # Hash which contains all the sid to message mappings.
 703         my %mappings = ();
 704
 705         # Loop through the array of given providers.
 706         foreach my $provider (@providers) {
 707                 # Generate full path and filename.
 708                 my $sid_msg_file = "$tmp_conf_directory/$provider\-sid-msg.map";
 709
 710                 # Skip provider if no sid to msg mapping file for this provider exists.
 711                 next unless (-f $sid_msg_file);
 712
 713                 # Open the file.
 714                 open(MAPPING, $sid_msg_file) or die "Could not open $sid_msg_file. $!\n";
 715
 716                 # Loop through the file content.
 717                 while (<MAPPING>) {
 718                         # Remove newlines.
 719                         chomp($_);
 720
 721                         # Skip lines which do not start with a number,
 722                         next unless ($_ =~ /^\d+/);
 723
 724                         # Split line content and assign it to an array.
 725                         my @line = split(/ \|\| /, $_);
 726
 727                         # Grab the first element (and remove it) from the line array.
 728                         # It contains the sid.
 729                         my $sid = shift(@line);
 730
 731                         # Store the grabbed sid and the remain array as hash value.
 732                         # It still contains the messages, references etc.
 733                         $mappings{$sid} = [@line];
 734                 }
 735
 736                 # Close file handle.
 737                 close(MAPPING);
 738         }
 739
 740         # Open mappings file for writing.
 741         open(FILE, ">", $sid_msg_file) or die "Could not write $sid_msg_file. $!\n";
 742
 743         # Write notice about autogenerated file.
 744         print FILE "#Autogenerated file. Any custom changes will be overwritten!\n\n";
 745
 746         # Loop through the hash of mappings.
 747         foreach my $sid ( sort keys %mappings) {
 748                 # Grab data for the sid.
 749                 my @data = @{$mappings{$sid}};
 750
 751                 # Add the sid to the data array.
 752                 unshift(@data, $sid);
 753
 754                 # Generate line.
 755                 my $line = join(" \|\| ", @data);
 756
 757                 print FILE "$line\n";
 758
 759         }
 760
 761         # Close file handle.
 762         close(FILE);
 763 }
 764
 765 #
 766 ## A very tiny function to move an extracted ruleset from the temporary directory into
 767 ## the rules directory.
 768 #
 769 sub move_tmp_ruleset() {
 770         # Load perl module.
 771         use File::Copy;
 772
 773         # Do a directory listing of the temporary directory.
 774         opendir  DH, $tmp_rules_directory;
 775
 776         # Loop over all files.
 777         while(my $file = readdir DH) {
 778                 # Move them to the rules directory.
 779                 move "$tmp_rules_directory/$file" , "$rulespath/$file";
 780         }
 781
 782         # Close directory handle.
 783         closedir DH;
 784 }
 785
 786 #
 787 ## Function to cleanup the temporary IDS directroy.
 788 #
 789 sub cleanup_tmp_directory () {
 790         # Load rmtree() function from file path perl module.
 791         use File::Path 'rmtree';
 792
 793         # Delete temporary directory and all containing files.
 794         rmtree([ "$tmp_directory" ]);
 795 }
 796
 797 #
 798 ## Function to do all the logging stuff if the downloading or updating of the ruleset fails.
 799 #
 800 sub log_error ($) {
 801         my ($error) = @_;
 802
 803         # Remove any newline.
 804         chomp($error);
 805
 806         # Call private function to log the error message to syslog.
 807         &_log_to_syslog($error);
 808
 809         # Call private function to write/store the error message in the storederrorfile.
 810         &_store_error_message($error);
 811 }
 812
 813 #
 814 ## Function to log a given error message to the kernel syslog.
 815 #
 816 sub _log_to_syslog ($) {
 817         my ($message) = @_;
 818
 819         # Load perl module to talk to the kernel syslog.
 820         use Sys::Syslog qw(:DEFAULT setlogsock);
 821
 822         # The syslog function works best with an array based input,
 823         # so generate one before passing the message details to syslog.
 824         my @syslog = ("ERR", "<ERROR> $message");
 825
 826         # Establish the connection to the syslog service.
 827         openlog('oinkmaster', 'cons,pid', 'user');
 828
 829         # Send the log message.
 830         syslog(@syslog);
 831
 832         # Close the log handle.
 833         closelog();
 834 }
 835
 836 #
 837 ## Private function to write a given error message to the storederror file.
 838 #
 839 sub _store_error_message ($) {
 840         my ($message) = @_;
 841
 842         # Remove any newline.
 843         chomp($message);
 844
 845         # Open file for writing.
 846         open (ERRORFILE, ">$storederrorfile") or die "Could not write to $storederrorfile. $!\n";
 847
 848         # Write error to file.
 849         print ERRORFILE "$message\n";
 850
 851         # Close file.
 852         close (ERRORFILE);
 853
 854         # Set correct ownership for the file.
 855         &set_ownership("$storederrorfile");
 856 }
 857
 858 #
 859 ## Private function to get the path and filename for a downloaded ruleset by a given provider.
 860 #
 861 sub _get_dl_rulesfile($) {
 862         my ($provider) = @_;
 863
 864         # Gather the download type for the given provider.
 865         my $dl_type = $IDS::Ruleset::Providers{$provider}{'dl_type'};
 866
 867         # Obtain the file suffix for the download file type.
 868         my $suffix = $dl_type_to_suffix{$dl_type};
 869
 870         # Check if a suffix has been found.
 871         unless ($suffix) {
 872                 # Abort return - nothing.
 873                 return;
 874         }
 875
 876         # Generate the full filename and path for the stored rules file.
 877         my $rulesfile = "$dl_rules_path/$dl_rulesfile_prefix-$provider$suffix";
 878
 879         # Return the generated filename.
 880         return $rulesfile;
 881 }
 882
 883 #
 884 ## Tiny function to delete the stored ruleset file or tarball for a given provider.
 885 #
 886 sub drop_dl_rulesfile ($) {
 887         my ($provider) = @_;
 888
 889         # Gather the full path and name of the stored rulesfile.
 890         my $rulesfile = &_get_dl_rulesfile($provider);
 891
 892         # Check if the given rulesfile exists.
 893         if (-f $rulesfile) {
 894                 # Delete the stored rulesfile.
 895                 unlink($rulesfile) or die "Could not delete $rulesfile. $!\n";
 896         }
 897 }
 898
 899 #
 900 ## Tiny function to get/generate the full path and filename for the providers oinkmaster
 901 ## modified sids file.
 902 #
 903 sub get_oinkmaster_provider_modified_sids_file ($) {
 904         my ($provider) = @_;
 905
 906         # Generate the filename.
 907         my $filename = "$settingsdir/oinkmaster-$provider-modified-sids.conf";
 908
 909         # Return the filename.
 910         return $filename;
 911 }
 912
 913 #
 914 ## Function to directly altering the oinkmaster provider includes file.
 915 ##
 916 ## Requires tha acition "remove" or "add" and a provider handle.
 917 #
 918 sub alter_oinkmaster_provider_includes_file ($$) {
 919         my ($action, $provider) = @_;
 920
 921         # Call function to get the path and name for the given providers
 922         # oinkmaster modified sids file.
 923         my $provider_modified_sids_file = &get_oinkmaster_provider_modified_sids_file($provider);
 924
 925         # Open the file for reading..
 926         open (FILE, $oinkmaster_provider_includes_file) or die "Could not read $oinkmaster_provider_includes_file. $!\n";
 927
 928         # Read-in file content.
 929         my @lines = <FILE>;
 930
 931         # Close file after reading.
 932         close(FILE);
 933
 934         # Re-open the file for writing.
 935         open(FILE, ">", $oinkmaster_provider_includes_file) or die "Could not write to $oinkmaster_provider_includes_file. $!\n";
 936
 937         # Loop through the file content.
 938         foreach my $line (@lines) {
 939                 # Remove newlines.
 940                 chomp($line);
 941
 942                 # Skip line if we found our given provider and the action should be remove.
 943                 next if (($line =~ /$provider/) && ($action eq "remove"));
 944
 945                 # Write the read-in line back to the file.
 946                 print FILE "$line\n";
 947         }
 948
 949         # Check if the file exists and add the provider if requested.
 950         if ((-f $provider_modified_sids_file) && ($action eq "add")) {
 951                 print FILE "include $provider_modified_sids_file\n";
 952         }
 953
 954         # Close file handle.
 955         close(FILE);
 956 }
 957
 958 #
 959 ## Function to check if the IDS is running.
 960 #
 961 sub ids_is_running () {
 962         if(-f $idspidfile) {
 963                 # Open PID file for reading.
 964                 open(PIDFILE, "$idspidfile") or die "Could not open $idspidfile. $!\n";
 965
 966                 # Grab the process-id.
 967                 my $pid = <PIDFILE>;
 968
 969                 # Close filehandle.
 970                 close(PIDFILE);
 971
 972                 # Remove any newline.
 973                 chomp($pid);
 974
 975                 # Check if a directory for the process-id exists in proc.
 976                 if(-d "/proc/$pid") {
 977                         # The IDS daemon is running return the process id.
 978                         return $pid;
 979                 }
 980         }
 981
 982         # Return nothing - IDS is not running.
 983         return;
 984 }
 985
 986 #
 987 ## Function to call suricatactrl binary with a given command.
 988 #
 989 sub call_suricatactrl ($) {
 990         # Get called option.
 991         my ($option, $interval) = @_;
 992
 993         # Loop through the array of supported commands and check if
 994         # the given one is part of it.
 995         foreach my $cmd (@suricatactrl_cmds) {
 996                 # Skip current command unless the given one has been found.
 997                 next unless($cmd eq $option);
 998
 999                 # Check if the given command is "cron".
1000                 if ($option eq "cron") {
1001                         # Check if an interval has been given.
1002                         if ($interval) {
1003                                 # Check if the given interval is valid.
1004                                 foreach my $element (@cron_intervals) {
1005                                         # Skip current element until the given one has been found.
1006                                         next unless($element eq $interval);
1007
1008                                         # Call the suricatactrl binary and pass the "cron" command
1009                                         # with the requrested interval.
1010                                         &General::system("$suricatactrl", "$option", "$interval");
1011
1012                                         # Return "1" - True.
1013                                         return 1;
1014                                 }
1015                         }
1016
1017                         # If we got here, the given interval is not supported or none has been given. - Return nothing.
1018                         return;
1019                 } else {
1020                         # Call the suricatactrl binary and pass the requrested
1021                         # option to it.
1022                         &General::system("$suricatactrl", "$option");
1023
1024                         # Return "1" - True.
1025                         return 1;
1026                 }
1027         }
1028
1029         # Command not found - return nothing.
1030         return;
1031 }
1032
1033 #
1034 ## Function to create a new empty file.
1035 #
1036 sub create_empty_file($) {
1037         my ($file) = @_;
1038
1039         # Check if the given file exists.
1040         if(-e $file) {
1041                 # Do nothing to prevent from overwriting existing files.
1042                 return;
1043         }
1044
1045         # Open the file for writing.
1046         open(FILE, ">$file") or die "Could not write to $file. $!\n";
1047
1048         # Close file handle.
1049         close(FILE);
1050
1051         # Return true.
1052         return 1;
1053 }
1054
1055 #
1056 ## Private function to check if the file permission of the rulespath are correct.
1057 ## If not, call suricatactrl to fix them.
1058 #
1059 sub _check_rulesdir_permissions() {
1060         # Check if the rulepath main directory is writable.
1061         unless (-W $rulespath) {
1062                 # If not call suricatctrl to fix it.
1063                 &call_suricatactrl("fix-rules-dir");
1064         }
1065
1066         # Open snort rules directory and do a directory listing.
1067         opendir(DIR, $rulespath) or die $!;
1068         # Loop through the direcory.
1069         while (my $file = readdir(DIR)) {
1070                 # We only want files.
1071                 next unless (-f "$rulespath/$file");
1072
1073                 # Check if the file is writable by the user.
1074                 if (-W "$rulespath/$file") {
1075                         # Everything is okay - go on to the next file.
1076                         next;
1077                 } else {
1078                         # There are wrong permissions, call suricatactrl to fix it.
1079                         &call_suricatactrl("fix-rules-dir");
1080                 }
1081         }
1082 }
1083
1084 #
1085 ## Private function to cleanup the directory which contains
1086 ## the IDS rules, before extracting and modifing the new ruleset.
1087 #
1088 sub _cleanup_rulesdir() {
1089         # Open rules directory and do a directory listing.
1090         opendir(DIR, $rulespath) or die $!;
1091
1092         # Loop through the direcory.
1093         while (my $file = readdir(DIR)) {
1094                 # We only want files.
1095                 next unless (-f "$rulespath/$file");
1096
1097                 # Skip rules file for whitelisted hosts.
1098                 next if ("$rulespath/$file" eq $whitelist_file);
1099
1100                 # Skip rules file with local rules.
1101                 next if ("$rulespath/$file" eq $local_rules_file);
1102
1103                 # Delete the current processed file, if not, exit this function
1104                 # and return an error message.
1105                 unlink("$rulespath/$file") or return "Could not delete $rulespath/$file. $!\n";
1106         }
1107
1108         # Return nothing;
1109         return;
1110 }
1111
1112 #
1113 ## Function to generate the file which contains the home net information.
1114 #
1115 sub generate_home_net_file() {
1116         my %netsettings;
1117
1118         # Read-in network settings.
1119         &General::readhash("${General::swroot}/ethernet/settings", \%netsettings);
1120
1121         # Get available network zones.
1122         my @network_zones = &Network::get_available_network_zones();
1123
1124         # Temporary array to store network address and prefix of the configured
1125         # networks.
1126         my @networks;
1127
1128         # Loop through the array of available network zones.
1129         foreach my $zone (@network_zones) {
1130                 # Check if the current processed zone is red.
1131                 if($zone eq "red") {
1132                         # Grab the IP-address of the red interface.
1133                         my $red_address = &get_red_address();
1134
1135                         # Check if an address has been obtained.
1136                         if ($red_address) {
1137                                 # Generate full network string.
1138                                 my $red_network = join("/", $red_address, "32");
1139
1140                                 # Add the red network to the array of networks.
1141                                 push(@networks, $red_network);
1142                         }
1143
1144                         # Check if the configured RED_TYPE is static.
1145                         if ($netsettings{'RED_TYPE'} eq "STATIC") {
1146                                 # Get configured and enabled aliases.
1147                                 my @aliases = &get_aliases();
1148
1149                                 # Loop through the array.
1150                                 foreach my $alias (@aliases) {
1151                                         # Add "/32" prefix.
1152                                         my $network = join("/", $alias, "32");
1153
1154                                         # Add the generated network to the array of networks.
1155                                         push(@networks, $network);
1156                                 }
1157                         }
1158                 # Process remaining network zones.
1159                 } else {
1160                         # Convert current zone name into upper case.
1161                         $zone = uc($zone);
1162
1163                         # Generate key to access the required data from the netsettings hash.
1164                         my $zone_netaddress = $zone . "_NETADDRESS";
1165                         my $zone_netmask = $zone . "_NETMASK";
1166
1167                         # Obtain the settings from the netsettings hash.
1168                         my $netaddress = $netsettings{$zone_netaddress};
1169                         my $netmask = $netsettings{$zone_netmask};
1170
1171                         # Convert the subnetmask into prefix notation.
1172                         my $prefix = &Network::convert_netmask2prefix($netmask);
1173
1174                         # Generate full network string.
1175                         my $network = join("/", $netaddress,$prefix);
1176
1177                         # Check if the network is valid.
1178                         if(&Network::check_subnet($network)) {
1179                                 # Add the generated network to the array of networks.
1180                                 push(@networks, $network);
1181                         }
1182                 }
1183         }
1184
1185         # Format home net declaration.
1186         my $line = "\"[" . join(',', @networks) . "]\"";
1187
1188         # Open file to store the addresses of the home net.
1189         open(FILE, ">$homenet_file") or die "Could not open $homenet_file. $!\n";
1190
1191         # Print yaml header.
1192         print FILE "%YAML 1.1\n";
1193         print FILE "---\n\n";
1194
1195         # Print notice about autogenerated file.
1196         print FILE "#Autogenerated file. Any custom changes will be overwritten!\n";
1197
1198         # Print the generated and required HOME_NET declaration to the file.
1199         print FILE "HOME_NET:\t$line\n";
1200
1201         # Close file handle.
1202         close(FILE);
1203 }
1204
1205 #
1206 # Function to generate and write the file which contains the configured and used DNS servers.
1207 #
1208 sub generate_dns_servers_file() {
1209         # Get the used DNS servers.
1210         my @nameservers = &General::get_nameservers();
1211
1212         # Get network settings.
1213         my %netsettings;
1214         &General::readhash("${General::swroot}/ethernet/settings", \%netsettings);
1215
1216         # Format dns servers declaration.
1217         my $line = "";
1218
1219         # Check if the system has configured nameservers.
1220         if (@nameservers) {
1221                 # Add the GREEN address as DNS servers.
1222                 push(@nameservers, $netsettings{'GREEN_ADDRESS'});
1223
1224                 # Check if a BLUE zone exists.
1225                 if ($netsettings{'BLUE_ADDRESS'}) {
1226                         # Add the BLUE address to the array of nameservers.
1227                         push(@nameservers, $netsettings{'BLUE_ADDRESS'});
1228                 }
1229
1230                 # Generate the line which will be written to the DNS servers file.
1231                 $line = join(",", @nameservers);
1232         } else {
1233                 # External net simply contains (any).
1234                 $line = "\$EXTERNAL_NET";
1235         }
1236
1237         # Open file to store the used DNS server addresses.
1238         open(FILE, ">$dns_servers_file") or die "Could not open $dns_servers_file. $!\n";
1239
1240         # Print yaml header.
1241         print FILE "%YAML 1.1\n";
1242         print FILE "---\n\n";
1243
1244         # Print notice about autogenerated file.
1245         print FILE "#Autogenerated file. Any custom changes will be overwritten!\n";
1246
1247         # Print the generated DNS declaration to the file.
1248         print FILE "DNS_SERVERS:\t\"[$line]\"\n";
1249
1250         # Close file handle.
1251         close(FILE);
1252 }
1253
1254 #
1255 # Function to generate and write the file which contains the HTTP_PORTS definition.
1256 #
1257 sub generate_http_ports_file() {
1258         my %proxysettings;
1259
1260         # Read-in proxy settings
1261         &General::readhash("${General::swroot}/proxy/advanced/settings", \%proxysettings);
1262
1263         # Check if the proxy is enabled.
1264         if (( -e "${General::swroot}/proxy/enable") || (-e "${General::swroot}/proxy/enable_blue")) {
1265                 # Add the proxy port to the array of HTTP ports.
1266                 push(@http_ports, $proxysettings{'PROXY_PORT'});
1267         }
1268
1269         # Check if the transparent mode of the proxy is enabled.
1270         if ((-e "${General::swroot}/proxy/transparent") || (-e "${General::swroot}/proxy/transparent_blue")) {
1271                 # Add the transparent proxy port to the array of HTTP ports.
1272                 push(@http_ports, $proxysettings{'TRANSPARENT_PORT'});
1273         }
1274
1275         # Format HTTP_PORTS declaration.
1276         my $line = "";
1277
1278         # Generate line which will be written to the http ports file.
1279         $line = join(",", @http_ports);
1280
1281         # Open file to store the HTTP_PORTS.
1282         open(FILE, ">$http_ports_file") or die "Could not open $http_ports_file. $!\n";
1283
1284         # Print yaml header.
1285         print FILE "%YAML 1.1\n";
1286         print FILE "---\n\n";
1287
1288         # Print notice about autogenerated file.
1289         print FILE "#Autogenerated file. Any custom changes will be overwritten!\n";
1290
1291         # Print the generated HTTP_PORTS declaration to the file.
1292         print FILE "HTTP_PORTS:\t\"[$line]\"\n";
1293
1294         # Close file handle.
1295         close(FILE);
1296 }
1297
1298 #
1299 ## Function to generate and write the file for used rulefiles file for a given provider.
1300 ##
1301 ## The function requires as first argument a provider handle, and as second an array with files.
1302 #
1303 sub write_used_provider_rulefiles_file($@) {
1304         my ($provider, @files) = @_;
1305
1306         # Get the path and file for the provider specific used rulefiles file.
1307         my $used_provider_rulesfile_file = &get_used_provider_rulesfile_file($provider);
1308
1309         # Open file for used rulefiles.
1310         open (FILE, ">$used_provider_rulesfile_file") or die "Could not write to $used_provider_rulesfile_file. $!\n";
1311
1312         # Write yaml header to the file.
1313         print FILE "%YAML 1.1\n";
1314         print FILE "---\n\n";
1315
1316         # Write header to file.
1317         print FILE "#Autogenerated file. Any custom changes will be overwritten!\n";
1318
1319         # Loop through the array of given files.
1320         foreach my $file (@files) {
1321                 # Check if the given filename exists and write it to the file of used rulefiles.
1322                 if(-f "$rulespath/$file") {
1323                         print FILE " - $file\n";
1324                 }
1325         }
1326
1327         # Close file after writing.
1328         close(FILE);
1329 }
1330
1331 #
1332 ## Function to write the main file for provider rulesfiles inclusions.
1333 ##
1334 ## This function requires an array of provider handles.
1335 #
1336 sub write_main_used_rulefiles_file (@) {
1337         my (@providers) = @_;
1338
1339         # Call function to write the static rulefiles file.
1340         &_write_static_rulefiles_file();
1341
1342         # Open file for used rulefils inclusion.
1343         open (FILE, ">", "$suricata_used_providers_file") or die "Could not write to $suricata_used_providers_file. $!\n";
1344
1345         # Write yaml header to the file.
1346         print FILE "%YAML 1.1\n";
1347         print FILE "---\n\n";
1348
1349         # Write header to file.
1350         print FILE "#Autogenerated file. Any custom changes will be overwritten!\n";
1351
1352         # Loop through the list of given providers.
1353         foreach my $provider (@providers) {
1354                 # Call function to get the providers used rulefiles file.
1355                 my $filename = &get_used_provider_rulesfile_file($provider);
1356
1357                 # Print the provider to the file.
1358                 print FILE "include\: $filename\n";
1359         }
1360
1361         # Always include the file which hold the static includes.
1362         print FILE "include\: $suricata_static_rulefiles_file\n";
1363
1364         # Close the filehandle after writing.
1365         close(FILE);
1366 }
1367
1368 sub _write_static_rulefiles_file () {
1369         # Open file.
1370         open (FILE, ">", $suricata_static_rulefiles_file) or die "Could not write to $suricata_static_rulefiles_file. $!\n";
1371
1372         # Write yaml header to the file.
1373         print FILE "%YAML 1.1\n";
1374         print FILE "---\n\n";
1375
1376         # Write notice about autogenerated file.
1377         print FILE "#Autogenerated file. Any custom changes will be overwritten!\n";
1378
1379         # Loop through the array of static included rulesfiles.
1380         foreach my $file (@static_included_rulefiles) {
1381                 # Check if the file exists.
1382                 if (-f "$rulespath/$file") {
1383                         # Write the rulesfile name to the file.
1384                         print FILE " - $file\n";
1385                 }
1386         }
1387
1388         # Close the file handle
1389         close(FILE);
1390 }
1391
1392 #
1393 ## Tiny function to generate the full path and name for the used_provider_rulesfile file of a given provider.
1394 #
1395 sub get_used_provider_rulesfile_file ($) {
1396         my ($provider) = @_;
1397
1398         my $filename = "$settingsdir/suricata\-$provider\-used\-rulefiles.yaml";
1399
1400         # Return the gernerated file.
1401         return $filename;
1402 }
1403
1404 #
1405 ## Function to generate and write the file for modify the ruleset.
1406 #
1407 sub write_modify_sids_file() {
1408         # Get configured settings.
1409         my %idssettings=();
1410         &General::readhash("$ids_settings_file", \%idssettings);
1411
1412         # Open modify sid's file for writing.
1413         open(FILE, ">$modify_sids_file") or die "Could not write to $modify_sids_file. $!\n";
1414
1415         # Write file header.
1416         print FILE "#Autogenerated file. Any custom changes will be overwritten!\n";
1417
1418         # Check if the traffic only should be monitored.
1419         unless($idssettings{'MONITOR_TRAFFIC_ONLY'} eq 'on') {
1420                 # Suricata is in IPS mode, which means that the rule actions have to be changed
1421                 # from 'alert' to 'drop', however not all rules should be changed.  Some rules
1422                 # exist purely to set a flowbit which is used to convey other information, such
1423                 # as a specific type of file being downloaded, to other rulewhich then check for
1424                 # malware in that file.  Rules which fall into the first category should stay as
1425                 # alert since not all flows of that type contain malware.
1426
1427                 # These types of rulesfiles contain meta-data which gives the action that should
1428                 # be used when in IPS mode.  Do the following:
1429                 #
1430                 # 1. Disable all rules and set the action to 'drop'
1431                 # 2. Set the action back to 'alert' if the rule contains 'flowbits:noalert;'
1432                 #    This should give rules not in the policy a reasonable default if the user
1433                 #    manually enables them.
1434                 # 3. Enable rules and set actions according to the meta-data strings.
1435
1436                 my $policy = 'balanced';  # Placeholder to allow policy to be changed.
1437
1438                         print FILE <<END;
1439 modifysid * "^#(?:alert|drop)(.+policy $policy-ips alert)" | "alert\${1}"
1440 modifysid * "^#(?:alert|drop)(.+policy $policy-ips drop)" | "drop\${1}"
1441 modifysid * "^(#?)(?:alert|drop)" | "\${1}drop"
1442 modifysid * "^(#?)drop(.+flowbits:noalert;)" | "\${1}alert\${2}"
1443 END
1444                 }
1445
1446         # Close file handle.
1447         close(FILE);
1448 }
1449
1450 #
1451 ## Function to get the ruleset date for a given provider.
1452 ##
1453 ## The function simply return the creation date in a human read-able format
1454 ## of the stored providers rulesfile.
1455 #
1456 sub get_ruleset_date($) {
1457         my ($provider) = @_;
1458
1459         # Load neccessary perl modules for file stat and to format the timestamp.
1460         use File::stat;
1461         use POSIX qw( strftime );
1462
1463         # Get the stored rulesfile for this provider.
1464         my $stored_rulesfile = &_get_dl_rulesfile($provider);
1465
1466         # Call stat on the rulestarball.
1467         my $stat = stat("$stored_rulesfile");
1468
1469         # Get timestamp the file creation.
1470         my $mtime = $stat->mtime;
1471
1472         # Convert into human read-able format.
1473         my $date = strftime('%Y-%m-%d %H:%M:%S', localtime($mtime));
1474
1475         # Return the date.
1476         return $date;
1477 }
1478
1479 #
1480 ## Function to gather the version of suricata.
1481 #
1482 sub get_suricata_version($) {
1483         my ($format) = @_;
1484
1485         # Execute piped suricata command and return the version information.
1486         open(SURICATA, "suricata -V |") or die "Couldn't execute program: $!";
1487
1488         # Grab and store the output of the piped program.
1489         my $version_string = <SURICATA>;
1490
1491         # Close pipe.
1492         close(SURICATA);
1493
1494         # Remove newlines.
1495         chomp($version_string);
1496
1497         # Grab the version from the version string.
1498         $version_string =~ /([0-9]+([.][0-9]+)+)/;
1499
1500         # Splitt the version into single chunks.
1501         my ($major_ver, $minor_ver, $patchlevel) = split(/\./, $1);
1502
1503         # Check and return the requested version sheme.
1504         if ($format eq "major") {
1505                 # Return the full version.
1506                 return "$major_ver";
1507         } elsif ($format eq "minor") {
1508                 # Return the major and minor part.
1509                 return "$major_ver.$minor_ver";
1510         } else {
1511                 # Return the full version string.
1512                 return "$major_ver.$minor_ver.$patchlevel";
1513         }
1514 }
1515
1516 #
1517 ## Function to generate the rules file with whitelisted addresses.
1518 #
1519 sub generate_ignore_file() {
1520         my %ignored = ();
1521
1522         # SID range 1000000-1999999 Reserved for Local Use
1523         # Put your custom rules in this range to avoid conflicts
1524         my $sid = 1500000;
1525
1526         # Read-in ignoredfile.
1527         &General::readhasharray($IDS::ignored_file, \%ignored);
1528
1529         # Open ignorefile for writing.
1530         open(FILE, ">$IDS::whitelist_file") or die "Could not write to $IDS::whitelist_file. $!\n";
1531
1532         # Config file header.
1533         print FILE "# Autogenerated file.\n";
1534         print FILE "# All user modifications will be overwritten.\n\n";
1535
1536         # Add all user defined addresses to the whitelist.
1537         #
1538         # Check if the hash contains any elements.
1539         if (keys (%ignored)) {
1540                 # Loop through the entire hash and write the host/network
1541                 # and remark to the ignore file.
1542                 while ( (my $key) = each %ignored) {
1543                         my $address = $ignored{$key}[0];
1544                         my $remark = $ignored{$key}[1];
1545                         my $status = $ignored{$key}[2];
1546
1547                         # Check if the status of the entry is "enabled".
1548                         if ($status eq "enabled") {
1549                                 # Check if the address/network is valid.
1550                                 if ((&General::validip($address)) || (&General::validipandmask($address))) {
1551                                         # Write rule line to the file to pass any traffic from this IP
1552                                         print FILE "pass ip $address any -> any any (msg:\"pass all traffic from/to $address\"\; sid:$sid\;)\n";
1553
1554                                         # Increment sid.
1555                                         $sid++;
1556                                 }
1557                         }
1558                 }
1559         }
1560
1561         close(FILE);
1562 }
1563
1564 #
1565 ## Function to set correct ownership for single files and directories.
1566 #
1567
1568 sub set_ownership($) {
1569         my ($target) = @_;
1570
1571         # User and group of the WUI.
1572         my $uname = "nobody";
1573         my $grname = "nobody";
1574
1575         # The chown function implemented in perl requies the user and group as nummeric id's.
1576         my $uid = getpwnam($uname);
1577         my $gid = getgrnam($grname);
1578
1579         # Check if the given target exists.
1580         unless ($target) {
1581                 # Stop the script and print error message.
1582                 die "The $target does not exist. Cannot change the ownership!\n";
1583         }
1584
1585         # Check weather the target is a file or directory.
1586         if (-f $target) {
1587                 # Change ownership ot the single file.
1588                 chown($uid, $gid, "$target");
1589         } elsif (-d $target) {
1590                 # Do a directory listing.
1591                 opendir(DIR, $target) or die $!;
1592                         # Loop through the direcory.
1593                         while (my $file = readdir(DIR)) {
1594
1595                                 # We only want files.
1596                                 next unless (-f "$target/$file");
1597
1598                                 # Set correct ownership for the files.
1599                                 chown($uid, $gid, "$target/$file");
1600                         }
1601
1602                 closedir(DIR);
1603
1604                 # Change ownership of the directory.
1605                 chown($uid, $gid, "$target");
1606         }
1607 }
1608
1609 #
1610 ## Function to read-in the aliases file and returns all configured and enabled aliases.
1611 #
1612 sub get_aliases() {
1613         # Location of the aliases file.
1614         my $aliases_file = "${General::swroot}/ethernet/aliases";
1615
1616         # Array to store the aliases.
1617         my @aliases;
1618
1619         # Check if the file is empty.
1620         if (-z $aliases_file) {
1621                 # Abort nothing to do.
1622                 return;
1623         }
1624
1625         # Open the aliases file.
1626         open(ALIASES, $aliases_file) or die "Could not open $aliases_file. $!\n";
1627
1628         # Loop through the file content.
1629         while (my $line = <ALIASES>) {
1630                 # Remove newlines.
1631                 chomp($line);
1632
1633                 # Splitt line content into single chunks.
1634                 my ($address, $state, $remark) = split(/\,/, $line);
1635
1636                 # Check if the state of the current processed alias is "on".
1637                 if ($state eq "on") {
1638                         # Check if the address is valid.
1639                         if(&Network::check_ip_address($address)) {
1640                                 # Add the alias to the array of aliases.
1641                                 push(@aliases, $address);
1642                         }
1643                 }
1644         }
1645
1646         # Close file handle.
1647         close(ALIASES);
1648
1649         # Return the array.
1650         return @aliases;
1651 }
1652
1653 #
1654 ## Function to grab the current assigned IP-address on red.
1655 #
1656 sub get_red_address() {
1657         # File, which contains the current IP-address of the red interface.
1658         my $file = "${General::swroot}/red/local-ipaddress";
1659
1660         # Check if the file exists.
1661         if (-e $file) {
1662                 # Open the given file.
1663                 open(FILE, "$file") or die "Could not open $file.";
1664
1665                 # Obtain the address from the first line of the file.
1666                 my $address = <FILE>;
1667
1668                 # Close filehandle
1669                 close(FILE);
1670
1671                 # Remove newlines.
1672                 chomp $address;
1673
1674                 # Check if the grabbed address is valid.
1675                 if (&General::validip($address)) {
1676                         # Return the address.
1677                         return $address;
1678                 }
1679         }
1680
1681         # Return nothing.
1682         return;
1683 }
1684
1685 #
1686 ## Function to get the used rules files of a given provider.
1687 #
1688 sub read_used_provider_rulesfiles($) {
1689         my ($provider) = @_;
1690
1691         # Array to store the used rulefiles.
1692         my @used_rulesfiles = ();
1693
1694         # Get the used rulesefile file for the provider.
1695         my $rulesfile_file = &get_used_provider_rulesfile_file($provider);
1696
1697         # Check if the a used rulesfile exists for this provider.
1698         if (-f $rulesfile_file) {
1699                 # Open the file or used rulefiles and read-in content.
1700                 open(FILE, $rulesfile_file) or die "Could not open $rulesfile_file. $!\n";
1701
1702                 while (<FILE>) {
1703                         # Assign the current line to a nice variable.
1704                         my $line = $_;
1705
1706                         # Remove newlines.
1707                         chomp($line);
1708
1709                         # Skip comments.
1710                         next if ($line =~ /\#/);
1711
1712                         # Skip blank  lines.
1713                         next if ($line =~ /^\s*$/);
1714
1715                         # Gather the rulefile.
1716                         if ($line =~ /.*- (.*)/) {
1717                                 my $rulefile = $1;
1718
1719                                 # Add the rulefile to the array of used rulesfiles.
1720                                 push(@used_rulesfiles, $rulefile);
1721                         }
1722                 }
1723
1724                 # Close the file.
1725                 close(FILE);
1726         }
1727
1728         # Return the array of used rulesfiles.
1729         return @used_rulesfiles;
1730 }
1731
1732 #
1733 ## Function to write the lock file for locking the WUI, while
1734 ## the autoupdate script runs.
1735 #
1736 sub lock_ids_page() {
1737         # Call subfunction to create the file.
1738         &create_empty_file($ids_page_lock_file);
1739 }
1740
1741 #
1742 ## Function to release the lock of the WUI, again.
1743 #
1744 sub unlock_ids_page() {
1745         # Delete lock file.
1746         unlink($ids_page_lock_file);
1747 }
1748
1749 1;