bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.12.1)
   5 AC_INIT(libbfd.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 AM_INIT_AUTOMAKE(bfd, 2.9.4)
  11
  12 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  13 dnl to call AC_CHECK_PROG.
  14 AC_CHECK_TOOL(AR, ar)
  15 AC_CHECK_TOOL(RANLIB, ranlib, :)
  16
  17 dnl Default to a non shared library.  This may be overridden by the
  18 dnl configure option --enable-shared.
  19 AM_DISABLE_SHARED
  20
  21 AM_PROG_LIBTOOL
  22
  23 AC_ARG_ENABLE(64-bit-bfd,
  24 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  25 [case "${enableval}" in
  26   yes)  want64=true  ;;
  27   no)   want64=false ;;
  28   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  29 esac],[want64=false])dnl
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  44 esac])dnl
  45 AC_ARG_WITH(mmap,
  46 [  --with-mmap             try using mmap for BFD input files if available],
  47 [case "${withval}" in
  48   yes)  want_mmap=true ;;
  49   no)   want_mmap=false ;;
  50   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  51 esac],[want_mmap=false])dnl
  52
  53 AM_CONFIG_HEADER(config.h:config.in)
  54
  55 if test -z "$target" ; then
  56     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  57 fi
  58 AC_ARG_PROGRAM
  59
  60 AM_MAINTAINER_MODE
  61 AM_CYGWIN32
  62 AM_EXEEXT
  63
  64 host64=false
  65 target64=false
  66
  67 # host stuff:
  68
  69 AC_PROG_CC
  70
  71 ALL_LINGUAS=
  72 CY_GNU_GETTEXT
  73
  74 # Permit host specific settings.
  75 . ${srcdir}/configure.host
  76
  77 AC_SUBST(HDEFINES)
  78 AM_PROG_INSTALL
  79
  80 BFD_HOST_64BIT_LONG=0
  81 BFD_HOST_64_BIT_DEFINED=0
  82 BFD_HOST_64_BIT=
  83 BFD_HOST_U_64_BIT=
  84 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
  85   BFD_HOST_64BIT_LONG=1
  86 elif test "x${HOST_64BIT_TYPE}" != "x"; then
  87   BFD_HOST_64_BIT_DEFINED=1
  88   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
  89   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
  90 fi
  91 AC_SUBST(BFD_HOST_64BIT_LONG)
  92 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
  93 AC_SUBST(BFD_HOST_64_BIT)
  94 AC_SUBST(BFD_HOST_U_64_BIT)
  95
  96 BFD_CC_FOR_BUILD
  97
  98 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
  99 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 100 AC_HEADER_TIME
 101 AC_HEADER_DIRENT
 102 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen)
 103
 104 BFD_BINARY_FOPEN
 105
 106 BFD_NEED_DECLARATION(strstr)
 107 BFD_NEED_DECLARATION(malloc)
 108 BFD_NEED_DECLARATION(realloc)
 109 BFD_NEED_DECLARATION(free)
 110 BFD_NEED_DECLARATION(getenv)
 111
 112 # If we are configured native, pick a core file support file.
 113 COREFILE=
 114 COREFLAG=
 115 if test "${target}" = "${host}"; then
 116   case "${host}" in
 117   alpha*-*-linux-gnu*)
 118         COREFILE=trad-core.lo
 119         AC_DEFINE(TRAD_HEADER,"hosts/alphalinux.h")
 120         ;;
 121   alpha*-*-netbsd*)     COREFILE=netbsd-core.lo ;;
 122   alpha*-*-*)           COREFILE=osf-core.lo ;;
 123   arm-*-riscix)         COREFILE=trad-core.lo ;;
 124   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 125   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 126   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 127   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 128                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 129 changequote(,)dnl
 130   i[3456]86-sequent-bsd*)
 131 changequote([,])dnl
 132         COREFILE=trad-core.lo;
 133         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 134         ;;
 135 changequote(,)dnl
 136   i[3456]86-sequent-sysv4*) ;;
 137   i[3456]86-sequent-sysv*)
 138 changequote([,])dnl
 139         COREFILE=trad-core.lo
 140         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 141         ;;
 142 changequote(,)dnl
 143   i[3456]86-*-bsd* | i[3456]86-*-freebsd*)
 144 changequote([,])dnl
 145         COREFILE=trad-core.lo
 146         AC_DEFINE(TRAD_HEADER,"hosts/i386bsd.h")
 147         ;;
 148 changequote(,)dnl
 149   i[3456]86-*-netbsd* | i[3456]86-*-openbsd*)
 150 changequote([,])dnl
 151         COREFILE=netbsd-core.lo
 152         ;;
 153 changequote(,)dnl
 154   i[3456]86-esix-sysv3*)
 155 changequote([,])dnl
 156         COREFILE=trad-core.lo
 157         AC_DEFINE(TRAD_HEADER,"hosts/esix.h")
 158         ;;
 159 changequote(,)dnl
 160   i[3456]86-*-sco3.2v5*)
 161 changequote([,])dnl
 162         COREFILE=sco5-core.lo
 163         ;;
 164 changequote(,)dnl
 165   i[3456]86-*-sco* | i[3456]86-*-isc*)
 166 changequote([,])dnl
 167         COREFILE=trad-core.lo
 168         AC_DEFINE(TRAD_HEADER,"hosts/i386sco.h")
 169         ;;
 170 changequote(,)dnl
 171   i[3456]86-*-mach3*)
 172 changequote([,])dnl
 173         COREFILE=trad-core.lo
 174         AC_DEFINE(TRAD_HEADER,"hosts/i386mach3.h")
 175         ;;
 176 changequote(,)dnl
 177   i[3456]86-*-linux-gnu*)
 178 changequote([,])dnl
 179         COREFILE=trad-core.lo
 180         AC_DEFINE(TRAD_HEADER,"hosts/i386linux.h")
 181         ;;
 182 changequote(,)dnl
 183   i[3456]86-*-isc*)     COREFILE=trad-core.lo ;;
 184   i[3456]86-*-aix*)     COREFILE=aix386-core.lo ;;
 185 changequote([,])dnl
 186   i860-*-mach3* | i860-*-osf1*)
 187         COREFILE=trad-core.lo
 188         AC_DEFINE(TRAD_HEADER,"hosts/i860mach3.h")
 189         ;;
 190   mips-dec-bsd*)
 191         COREFILE=trad-core.lo
 192         AC_DEFINE(TRAD_HEADER,"hosts/mipsbsd.h")
 193         ;;
 194   mips-dec-mach3*)
 195         COREFILE=trad-core.lo
 196         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 197         ;;
 198   mips-*-netbsd* | mips*-*-openbsd*)
 199         COREFILE=netbsd-core.lo
 200         ;;
 201   mips-dec-*)
 202         COREFILE=trad-core.lo
 203         AC_DEFINE(TRAD_HEADER,"hosts/decstation.h")
 204         ;;
 205   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 206   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 207   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 208   mips-*-mach3*)
 209         COREFILE=trad-core.lo
 210         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 211         ;;
 212   mips-*-sysv4*)        ;;
 213   mips-*-sysv* | mips-*-riscos*)
 214         COREFILE=trad-core.lo
 215         AC_DEFINE(TRAD_HEADER,"hosts/riscos.h")
 216         ;;
 217   mips-sony-bsd*)
 218         COREFILE=trad-core.lo
 219         AC_DEFINE(TRAD_HEADER,"hosts/news-mips.h")
 220         ;;
 221   m68*-bull*-sysv*)
 222         COREFILE=trad-core.lo
 223         AC_DEFINE(TRAD_HEADER,"hosts/dpx2.h")
 224         ;;
 225   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 226   m68*-hp-bsd*)
 227         COREFILE=trad-core.lo
 228         AC_DEFINE(TRAD_HEADER,"hosts/hp300bsd.h")
 229         ;;
 230   m68*-*-linux-gnu*)
 231         COREFILE=trad-core.lo
 232         AC_DEFINE(TRAD_HEADER,"hosts/m68klinux.h")
 233         ;;
 234   m68*-motorola-sysv*)
 235         COREFILE=trad-core.lo
 236         AC_DEFINE(TRAD_HEADER, "hosts/delta68.h")
 237         ;;
 238   m68*-sony-*)
 239         COREFILE=trad-core.lo
 240         AC_DEFINE(TRAD_HEADER,"hosts/news.h")
 241         ;;
 242   m68*-*-netbsd* | m68*-*-openbsd*)
 243         COREFILE=netbsd-core.lo
 244         ;;
 245   m68*-apple-aux*)
 246         COREFILE=trad-core.lo
 247         AC_DEFINE(TRAD_HEADER,"hosts/m68kaux.h")
 248         ;;
 249   m88*-*-sysv4*)        ;;
 250   m88*-motorola-sysv*)  COREFILE=ptrace-core.lo ;;
 251   m88*-*-mach3*)
 252         COREFILE=trad-core.lo
 253         AC_DEFINE(TRAD_HEADER,"hosts/m88kmach3.h")
 254         ;;
 255   ns32k-pc532-mach)
 256         COREFILE=trad-core.lo
 257         AC_DEFINE(TRAD_HEADER,"hosts/pc532mach.h")
 258         ;;
 259   ns32k-*-netbsd* | ns32k-*-openbsd*)
 260         COREFILE=netbsd-core.lo
 261         ;;
 262   rs6000-*-lynx*)       COREFILE=lynx-core.lo ;;
 263   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 264   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 265   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 266   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 267   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 268   powerpc-*-beos*)      ;;
 269   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 270   sparc-*-netbsd* | sparc-*-openbsd*)
 271         COREFILE=netbsd-core.lo
 272         ;;
 273   tahoe-*-*)
 274         COREFILE=trad-core.lo
 275         AC_DEFINE(TRAD_HEADER,"hosts/tahoe.h")
 276         ;;
 277   vax-*-ultrix2*)
 278         COREFILE=trad-core.lo
 279         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 280         ;;
 281   vax-*-ultrix*)
 282         COREFILE=trad-core.lo
 283         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 284         ;;
 285   vax-*-*)
 286         COREFILE=trad-core.lo
 287         AC_DEFINE(TRAD_HEADER,"hosts/vaxbsd.h")
 288         ;;
 289   esac
 290
 291   case "$COREFILE" in
 292   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 293   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 294   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 295   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 296   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 297   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 298   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 299   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 300   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 301   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 302   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 303   esac
 304
 305   # ELF corefile support has several flavors, but all of
 306   # them use something called <sys/procfs.h>
 307   AC_CHECK_HEADERS(sys/procfs.h)
 308   if test "$ac_cv_header_sys_procfs_h" = yes; then
 309     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 310     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 311     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 312     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 313     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 314     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 315     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 316     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 317   fi
 318 fi
 319 AC_SUBST(COREFILE)
 320 AC_SUBST(COREFLAG)
 321
 322 # Horrible hacks to build DLLs on Windows.
 323 WIN32LDFLAGS=
 324 WIN32LIBADD=
 325 case "${host}" in
 326 *-*-cygwin*)
 327   if test "$enable_shared" = "yes"; then
 328     WIN32LDFLAGS="-no-undefined"
 329     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 330   fi
 331   ;;
 332 esac
 333 AC_SUBST(WIN32LDFLAGS)
 334 AC_SUBST(WIN32LIBADD)
 335
 336 # target stuff:
 337
 338 # Canonicalize the secondary target names.
 339 if test -n "$enable_targets" ; then
 340     for targ in `echo $enable_targets | sed 's/,/ /g'`
 341     do
 342         result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 343         if test -n "$result" ; then
 344             canon_targets="$canon_targets $result"
 345         else
 346             # Allow targets that config.sub doesn't recognize, like "all".
 347             canon_targets="$canon_targets $targ"
 348         fi
 349     done
 350 fi
 351
 352 all_targets=false
 353 defvec=
 354 selvecs=
 355 selarchs=
 356 TDEFINES=
 357 for targ in $target $canon_targets
 358 do
 359     if test "x$targ" = "xall"; then
 360         all_targets=true
 361     else
 362         . $srcdir/config.bfd
 363         if test "x$targ" = "x$target"; then
 364             defvec=$targ_defvec
 365         fi
 366         selvecs="$selvecs $targ_defvec $targ_selvecs"
 367         selarchs="$selarchs $targ_archs"
 368         TDEFINES="$TDEFINES $targ_cflags"
 369     fi
 370 done
 371 AC_SUBST(TDEFINES)
 372
 373 # This processing still needs to be done if we're to decide properly whether
 374 # 64-bit support needs to be compiled in.  Currently, it will be included if
 375 # the default or any other explicitly requested target requires it; it
 376 # will not be included on a 32-bit host if no 64-bit target is requested, and
 377 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 378 # used.
 379
 380 # uniq the default and selected vectors in all the configured targets.
 381 f=""
 382 for i in $selvecs ; do
 383     case " $f " in
 384     *" $i "*) ;;
 385     *) f="$f $i" ;;
 386     esac
 387 done
 388 selvecs="$f"
 389
 390 # start-sanitize-sky
 391 # dvp is really mips, but we need to distinguish it from mips for opcodes
 392 selarchs=`echo $selarchs | sed -e s/dvp/mips/g`
 393 # end-sanitize-sky
 394
 395 # uniq the architectures in all the configured targets.
 396 f=""
 397 for i in $selarchs ; do
 398     case " $f " in
 399     *" $i "*) ;;
 400     *) f="$f $i" ;;
 401     esac
 402 done
 403 selarchs="$f"
 404
 405 # Target backend .o files.
 406 tb=
 407
 408 elf="elf.lo elflink.lo dwarf2.lo dwarf1.lo"
 409
 410 for vec in $selvecs
 411 do
 412     case "$vec" in
 413     # This list is alphabetized to make it easy to compare
 414     # with the two vector lists in targets.c.
 415     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 416     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 417     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 418     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 419     armpe_little_vec)           tb="$tb pe-arm.lo coff-arm.lo cofflink.lo " ;;
 420     armpe_big_vec)              tb="$tb pe-arm.lo coff-arm.lo cofflink.lo " ;;
 421     armpei_little_vec)          tb="$tb pei-arm.lo cofflink.lo " ;;
 422     armpei_big_vec)             tb="$tb pei-arm.lo cofflink.lo " ;;
 423     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 424     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 425     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 426     aout_mips_big_vec)          tb="$tb mipsbsd.lo aout32.lo" ;;
 427     aout_mips_little_vec)       tb="$tb mipsbsd.lo aout32.lo" ;;
 428     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 429     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 430     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 431     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"
 432                                 target64=true ;;
 433     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 434     bfd_elf32_littlearm_vec)    tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 435     bfd_elf32_littlearm_oabi_vec) tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 436     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 437     bfd_elf32_bigarm_vec)       tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 438     bfd_elf32_bigarm_oabi_vec)  tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 439     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 440     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 441     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 442                                 target64=true ;;
 443     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 444     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 445     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 446     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 447     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 448     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 449     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 450     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 451     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 452                                 target64=true ;;
 453     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 454     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 455     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 456     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 457     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 458     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 459     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 460     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 461     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 462     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 463     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 464     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"
 465                                 target64=true ;;
 466     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"
 467                                 target64=true ;;
 468     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"
 469                                 target64=true ;;
 470     cisco_core_vec)             tb="$tb cisco-core.lo" ;;
 471     demo_64_vec)                tb="$tb demo64.lo aout64.lo"
 472                                 target64=true ;;
 473     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 474     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 475     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 476     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"
 477                                 target64=true ;;
 478     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 479     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 480     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 481     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 482     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 483     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 484     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 485     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 486     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 487     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 488     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 489     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 490     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 491     i386pe_vec)                 tb="$tb pe-i386.lo cofflink.lo " ;;
 492     i386pei_vec)                tb="$tb pei-i386.lo cofflink.lo" ;;
 493     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 494     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 495     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 496     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 497     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 498     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 499     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 500     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 501     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 502     ieee_vec)                   tb="$tb ieee.lo" ;;
 503     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 504     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 505     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 506     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 507     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 508     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 509     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 510     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 511     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 512     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 513     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 514     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 515     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 516     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"
 517                                 target64=true ;;
 518     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 519     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 520     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 521     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 522     pmac_xcoff_vec)             tb="$tb coff-pmac.lo xcofflink.lo" ;;
 523     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 524     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo cofflink.lo" ;;
 525     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo cofflink.lo" ;;
 526     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo cofflink.lo" ;;
 527     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo cofflink.lo" ;;
 528     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 529     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 530     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 531     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 532     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 533     som_vec)                    tb="$tb som.lo" ;;
 534     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 535     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 536     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 537     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 538     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 539     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 540     srec_vec)                   tb="$tb srec.lo" ;;
 541     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 542     symbolsrec_vec)             tb="$tb srec.lo" ;;
 543     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 544     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 545     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 546 # start-sanitize-tic80
 547     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 548 # end-sanitize-tic80
 549     versados_vec)               tb="$tb versados.lo" ;;
 550     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"
 551                                 target64=true ;;
 552     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 553     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 554     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 555     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 556
 557     "")                 ;;
 558     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 559     esac
 560 done
 561
 562 # Target architecture .o files.
 563 # A couple of CPUs use shorter file names to avoid problems on DOS
 564 # filesystems.
 565 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 566
 567 # Weed out duplicate .o files.
 568 f=""
 569 for i in $tb ; do
 570     case " $f " in
 571     *" $i "*) ;;
 572     *) f="$f $i" ;;
 573     esac
 574 done
 575 tb="$f"
 576
 577 f=""
 578 for i in $ta ; do
 579     case " $f " in
 580     *" $i "*) ;;
 581     *) f="$f $i" ;;
 582     esac
 583 done
 584 ta="$f"
 585
 586 bfd_backends="$tb"
 587 bfd_machines="$ta"
 588
 589 if test x${all_targets} = xtrue ; then
 590   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 591   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 592   selvecs=
 593   havevecs=
 594   selarchs=
 595 else    # all_targets is true
 596   # Only set these if they will be nonempty, for the clever echo.
 597   havevecs=
 598   test -n "$selvecs" &&
 599     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 600   test -n "$selvecs" &&
 601     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 602   test -n "$selarchs" &&
 603     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 604 fi      # all_targets is true
 605
 606 case ${host64}-${target64}-${want64} in
 607   *true*)
 608     wordsize=64
 609     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 610     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 611       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 612       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 613     fi
 614     ;;
 615   false-false-false)
 616     wordsize=32
 617     all_backends='$(BFD32_BACKENDS)'
 618     ;;
 619 esac
 620
 621 AC_SUBST(wordsize)
 622 AC_SUBST(all_backends)
 623 AC_SUBST(bfd_backends)
 624 AC_SUBST(bfd_machines)
 625
 626 tdefaults=""
 627 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 628 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 629 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 630 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 631 AC_SUBST(tdefaults)
 632
 633 dnl AC_CHECK_HEADERS(sys/mman.h)
 634 AC_FUNC_MMAP
 635 AC_CHECK_FUNCS(madvise mprotect)
 636 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 637   true+yes )  AC_DEFINE(USE_MMAP) ;;
 638 esac
 639
 640 rm -f doc/config.status
 641 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in,
 642 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])