gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2019 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(main.c)
  22 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  23 AM_MAINTAINER_MODE
  24
  25 # Set the 'development' global.
  26 . $srcdir/../bfd/development.sh
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_CC_STDC
  34 AM_PROG_INSTALL_STRIP
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 dnl List of object files and targets accumulated by configure.
  49
  50 CONFIG_OBS=
  51 CONFIG_DEPS=
  52 CONFIG_SRCS=
  53 ENABLE_CFLAGS=
  54
  55 CONFIG_ALL=
  56 CONFIG_CLEAN=
  57 CONFIG_INSTALL=
  58 CONFIG_UNINSTALL=
  59
  60 dnl Set up for gettext.
  61 ZW_GNU_GETTEXT_SISTER_DIR
  62
  63 localedir='${datadir}/locale'
  64 AC_SUBST(localedir)
  65
  66 if test x"$USE_NLS" = xyes; then
  67    CONFIG_ALL="$CONFIG_ALL all-po"
  68    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  69    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  70    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  71 fi
  72
  73 PACKAGE=gdb
  74 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  75 AC_SUBST(PACKAGE)
  76
  77 # We never need to detect it in this sub-configure.
  78 # But preserve it for config.status --recheck.
  79 AC_ARG_VAR(MAKEINFO,
  80   [Parent configure detects if it is of sufficient version.])
  81 AC_ARG_VAR(MAKEINFOFLAGS,
  82   [Parameters for MAKEINFO.])
  83
  84 MAKEINFO_EXTRA_FLAGS=""
  85 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  86   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  87   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  88     gdb_cv_have_makeinfo_click=yes
  89   else
  90     gdb_cv_have_makeinfo_click=no
  91   fi])
  92 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
  93   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
  94 fi
  95 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
  96
  97 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  98     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  99     [${libdir}/debug])
 100
 101 # We can't pass paths as command line arguments.
 102 # Mingw32 tries to be clever and will convert the paths for us.
 103 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 104 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 105 # This breaks GDB's relocatable path conversions since paths passed in
 106 # config.h would not get so translated, the path prefixes no longer match.
 107 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 108
 109 # GDB's datadir relocation
 110
 111 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 112     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 113     [${datadir}/gdb])
 114
 115 AC_ARG_WITH(relocated-sources,
 116 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 117 [reloc_srcdir="${withval}"
 118  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 119               [Relocated directory for source files. ])
 120 ])
 121
 122 AC_MSG_CHECKING([for default auto-load directory])
 123 AC_ARG_WITH(auto-load-dir,
 124 AS_HELP_STRING([--with-auto-load-dir=PATH],
 125   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 126   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 127 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 128 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 129               [Directories from which to load auto-loaded scripts.])
 130 AC_MSG_RESULT([$with_auto_load_dir])
 131
 132 AC_MSG_CHECKING([for default auto-load safe-path])
 133 AC_ARG_WITH(auto-load-safe-path,
 134 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 135   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 136 AS_HELP_STRING([--without-auto-load-safe-path],
 137                [do not restrict auto-loaded files locations]),
 138     [if test "$with_auto_load_safe_path" = "no"; then
 139      with_auto_load_safe_path="/"
 140      fi],
 141 [with_auto_load_safe_path="$with_auto_load_dir"])
 142 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 143 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 144               [Directories safe to hold auto-loaded files.])
 145 AC_MSG_RESULT([$with_auto_load_safe_path])
 146
 147 AC_CONFIG_SUBDIRS(testsuite)
 148
 149 # Check whether to support alternative target configurations
 150 AC_ARG_ENABLE(targets,
 151 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 152 [case "${enableval}" in
 153   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 154             ;;
 155   no)       enable_targets= ;;
 156   *)        enable_targets=$enableval ;;
 157 esac])
 158
 159 # Check whether to enable 64-bit support on 32-bit hosts
 160 AC_ARG_ENABLE(64-bit-bfd,
 161 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 162 [case "${enableval}" in
 163   yes)  want64=true  ;;
 164   no)   want64=false ;;
 165   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 166 esac],[want64=false])dnl
 167
 168 # Provide defaults for some variables set by the per-host and per-target
 169 # configuration.
 170 gdb_host_obs=posix-hdep.o
 171
 172 if test "${target}" = "${host}"; then
 173   gdb_native=yes
 174 else
 175   gdb_native=no
 176 fi
 177
 178 . $srcdir/configure.host
 179
 180 # Add in the common host objects.
 181 . $srcdir/gdbsupport/common.host
 182 gdb_host_obs="$gdb_host_obs $common_host_obs"
 183
 184 # Accumulate some settings from configure.tgt over all enabled targets
 185
 186 TARGET_OBS=
 187 all_targets=
 188 HAVE_NATIVE_GCORE_TARGET=
 189
 190 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 191 do
 192   if test "$targ_alias" = "all"; then
 193     all_targets=true
 194   else
 195     # Canonicalize the secondary target names.
 196     result=`$ac_config_sub $targ_alias 2>/dev/null`
 197     if test -n "$result"; then
 198         targ=$result
 199     else
 200         targ=$targ_alias
 201     fi
 202
 203     . ${srcdir}/configure.tgt
 204
 205     AS_IF([test -z "${gdb_target_obs}"],
 206       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 207
 208     # Target-specific object files
 209     for i in ${gdb_target_obs}; do
 210         case " $TARGET_OBS " in
 211         *" ${i} "*) ;;
 212         *)
 213           TARGET_OBS="$TARGET_OBS ${i}"
 214           ;;
 215         esac
 216     done
 217
 218     # Check whether this target needs 64-bit CORE_ADDR
 219     if test x${want64} = xfalse; then
 220       . ${srcdir}/../bfd/config.bfd
 221     fi
 222
 223     # Check whether this target is native and supports gcore.
 224     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 225        && $gdb_have_gcore; then
 226       HAVE_NATIVE_GCORE_TARGET=1
 227     fi
 228   fi
 229 done
 230
 231 if test x${all_targets} = xtrue; then
 232
 233   # We want all 64-bit targets if we either:
 234   #  - run on a 64-bit host  or
 235   #  - already require 64-bit support for some other target  or
 236   #  - the --enable-64-bit-bfd option was supplied
 237   # Otherwise we only support all 32-bit targets.
 238   #
 239   # NOTE: This test must be in sync with the corresponding
 240   #       tests in BFD!
 241
 242   if test x${want64} = xfalse; then
 243     AC_CHECK_SIZEOF(long)
 244     if test "x${ac_cv_sizeof_long}" = "x8"; then
 245       want64=true
 246     fi
 247   fi
 248   if test x${want64} = xtrue; then
 249     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 250   else
 251     TARGET_OBS='$(ALL_TARGET_OBS)'
 252   fi
 253 fi
 254
 255 AC_SUBST(TARGET_OBS)
 256 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 257
 258 # For other settings, only the main target counts.
 259 gdb_sim=
 260 gdb_osabi=
 261 build_gdbserver=
 262 targ=$target; . ${srcdir}/configure.tgt
 263
 264 # Fetch the default architecture and default target vector from BFD.
 265 targ=$target; . $srcdir/../bfd/config.bfd
 266
 267 # We only want the first architecture, so strip off the others if
 268 # there is more than one.
 269 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 270
 271 if test "x$targ_archs" != x; then
 272   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 273     [Define to BFD's default architecture. ])
 274 fi
 275 if test "x$targ_defvec" != x; then
 276   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 277     [Define to BFD's default target vector. ])
 278 fi
 279
 280 # Enable MI.
 281 AC_ARG_ENABLE(gdbmi,
 282 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 283   [case $enableval in
 284     yes | no)
 285       ;;
 286     *)
 287       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 288   esac],
 289   [enable_gdbmi=yes])
 290 if test x"$enable_gdbmi" = xyes; then
 291   if test -d $srcdir/mi; then
 292     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 293     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 294     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 295     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 296   fi
 297 fi
 298
 299 # Enable TUI.
 300 AC_ARG_ENABLE(tui,
 301 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 302   [case $enableval in
 303     yes | no | auto)
 304       ;;
 305     *)
 306       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 307   esac],enable_tui=auto)
 308
 309 # Enable gdbtk.
 310 AC_ARG_ENABLE(gdbtk,
 311 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 312   [case $enableval in
 313     yes | no)
 314       ;;
 315     *)
 316       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 317   esac],
 318   [if test -d $srcdir/gdbtk; then
 319     enable_gdbtk=yes
 320   else
 321     enable_gdbtk=no
 322   fi])
 323 # We unconditionally disable gdbtk tests on selected platforms.
 324 case $host_os in
 325   go32* | windows*)
 326     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 327     enable_gdbtk=no ;;
 328 esac
 329
 330 # Libunwind support for ia64.
 331
 332 AC_ARG_WITH(libunwind-ia64,
 333 AS_HELP_STRING([--with-libunwind-ia64],
 334                [use libunwind frame unwinding for ia64 targets]),,
 335             [with_libunwind_ia64=auto])
 336
 337 # Backward compatibility option.
 338 if test "${with_libunwind+set}" = set; then
 339   if test x"$with_libunwind_ia64" != xauto; then
 340     AC_MSG_ERROR(
 341       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 342   fi
 343   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 344   with_libunwind_ia64="$with_libunwind"
 345 fi
 346
 347 case "$with_libunwind_ia64" in
 348   yes | no)
 349     ;;
 350   auto)
 351     AC_CHECK_HEADERS(libunwind-ia64.h)
 352     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 353     ;;
 354   *)
 355     AC_MSG_ERROR(
 356       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 357     ;;
 358 esac
 359
 360 if test x"$with_libunwind_ia64" = xyes; then
 361   AC_CHECK_HEADERS(libunwind-ia64.h)
 362   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 363     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 364   fi
 365   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 366   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 367   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 368 fi
 369
 370 opt_curses=no
 371 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 372
 373 prefer_curses=no
 374 if test "$opt_curses" = "yes"; then
 375   prefer_curses=yes
 376 fi
 377
 378 # Profiling support.
 379 AC_ARG_ENABLE(profiling,
 380 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 381   [case $enableval in
 382     yes | no)
 383       ;;
 384     *)
 385       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 386   esac],
 387  [enable_profiling=no])
 388
 389 AC_CHECK_FUNCS(monstartup _mcleanup)
 390 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 391 [AC_TRY_LINK(
 392 [#include <stdlib.h>
 393 extern char _etext;
 394 ],
 395 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 396 if test $ac_cv_var__etext = yes; then
 397   AC_DEFINE(HAVE__ETEXT, 1,
 398             [Define to 1 if your system has the _etext variable. ])
 399 fi
 400 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 401 [AC_TRY_LINK(
 402 [#include <stdlib.h>
 403 extern char etext;
 404 ],
 405 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 406 if test $ac_cv_var_etext = yes; then
 407   AC_DEFINE(HAVE_ETEXT, 1,
 408             [Define to 1 if your system has the etext variable. ])
 409 fi
 410 if test "$enable_profiling" = yes ; then
 411   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 412     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 413   fi
 414   PROFILE_CFLAGS=-pg
 415   OLD_CFLAGS="$CFLAGS"
 416   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 417
 418   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 419     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 420      ac_cv_cc_supports_pg=no)])
 421
 422   if test $ac_cv_cc_supports_pg = no; then
 423     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 424   fi
 425
 426   CFLAGS="$OLD_CFLAGS"
 427 fi
 428
 429 CODESIGN_CERT=
 430 AC_ARG_ENABLE([codesign],
 431   AS_HELP_STRING([--enable-codesign=CERT],
 432                  [sign gdb with 'codesign -s CERT']),
 433   [CODESIGN_CERT=$enableval])
 434 AC_SUBST([CODESIGN_CERT])
 435
 436 ACX_PKGVERSION([GDB])
 437 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 438 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 439 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 440
 441 # --------------------- #
 442 # Checks for programs.  #
 443 # --------------------- #
 444
 445 AC_PROG_AWK
 446 AC_PROG_INSTALL
 447 AC_PROG_LN_S
 448 AC_PROG_RANLIB
 449 AC_PROG_YACC
 450
 451 AC_CHECK_TOOL(AR, ar)
 452 AC_CHECK_TOOL(DLLTOOL, dlltool)
 453 AC_CHECK_TOOL(WINDRES, windres)
 454
 455 case $host_os in
 456   gnu*)
 457     # Needed for GNU Hurd hosts.
 458     AC_CHECK_TOOL(MIG, mig)
 459     if test x"$MIG" = x; then
 460       AC_MSG_ERROR([MIG not found but required for $host hosts])
 461     fi
 462     ;;
 463 esac
 464
 465 # ---------------------- #
 466 # Checks for libraries.  #
 467 # ---------------------- #
 468
 469 # We might need to link with -lm; most simulators need it.
 470 AC_CHECK_LIB(m, main)
 471
 472 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 473 AC_SEARCH_LIBS(gethostbyname, nsl)
 474
 475 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 476 AC_SEARCH_LIBS(socketpair, socket)
 477
 478 # Link in zlib if we can.  This allows us to read compressed debug sections.
 479 AM_ZLIB
 480
 481 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 482 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 483 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 484   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 485             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 486
 487 # fbsd-nat.c can also use kinfo_getfile.
 488 AC_SEARCH_LIBS(kinfo_getfile, util util-freebsd,
 489   [AC_DEFINE(HAVE_KINFO_GETFILE, 1,
 490             [Define to 1 if your system has the kinfo_getfile function. ])])
 491
 492 AM_ICONV
 493
 494 # GDB may fork/exec the iconv program to get the list of supported character
 495 # sets.  Allow the user to specify where to find it.
 496 # There are several factors affecting the choice of option name:
 497 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 498 #   the build-time location of libiconv files.
 499 # - The program we need to find is iconv, which comes with glibc.  The user
 500 #   doesn't necessarily have libiconv installed.  Therefore naming this
 501 #   --with-libiconv-foo feels wrong.
 502 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 503 #   defined to work on directories not files (though it really doesn't know
 504 #   the difference).
 505 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 506 #   with --with-libiconv-prefix.
 507 # Putting these together is why the option name is --with-iconv-bin.
 508
 509 AC_ARG_WITH(iconv-bin,
 510 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 511 [iconv_bin="${withval}"
 512  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 513                     [Path of directory of iconv program.])
 514  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 515 ])
 516
 517 # For the TUI, we need enhanced curses functionality.
 518 if test x"$enable_tui" != xno; then
 519   prefer_curses=yes
 520 fi
 521
 522 curses_found=no
 523 if test x"$prefer_curses" = xyes; then
 524   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 525   # curses library because the latter might not provide all the
 526   # functionality we need.  However, this leads to problems on systems
 527   # where the linker searches /usr/local/lib, but the compiler doesn't
 528   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 529   # default installation of ncurses on alpha*-dec-osf* will lead to such
 530   # a situation.
 531   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 532
 533   if test "$ac_cv_search_waddstr" != no; then
 534     curses_found=yes
 535   fi
 536 fi
 537
 538 # Check whether we should enable the TUI, but only do so if we really
 539 # can.
 540 if test x"$enable_tui" != xno; then
 541   if test -d $srcdir/tui; then
 542     if test "$curses_found" != no; then
 543       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 544       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 545       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 546       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 547     else
 548       if test x"$enable_tui" = xyes; then
 549         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 550       else
 551         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 552       fi
 553     fi
 554   fi
 555 fi
 556
 557 # Since GDB uses Readline, we need termcap functionality.  In many
 558 # cases this will be provided by the curses library, but some systems
 559 # have a separate termcap library, or no curses library at all.
 560
 561 case $host_os in
 562   cygwin*)
 563     if test -d $srcdir/libtermcap; then
 564       LIBS="../libtermcap/libtermcap.a $LIBS"
 565       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 566     fi ;;
 567   go32* | *djgpp*)
 568     ac_cv_search_tgetent="none required"
 569     ;;
 570 esac
 571
 572 # These are the libraries checked by Readline.
 573 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 574
 575 if test "$ac_cv_search_tgetent" = no; then
 576   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 577 fi
 578
 579 AC_ARG_WITH([system-readline],
 580   [AS_HELP_STRING([--with-system-readline],
 581                   [use installed readline library])])
 582
 583 if test "$with_system_readline" = yes; then
 584    AC_CACHE_CHECK([whether system readline is new enough],
 585      [gdb_cv_readline_ok],
 586      [AC_TRY_COMPILE(
 587        [#include <stdio.h>
 588 #include <readline/readline.h>],
 589        [#if RL_VERSION_MAJOR < 7
 590 # error "readline version 7 required"
 591 #endif],
 592     gdb_cv_readline_ok=yes,
 593     gdb_cv_readline_ok=no)])
 594   if test "$gdb_cv_readline_ok" != yes; then
 595     AC_MSG_ERROR([system readline is not new enough])
 596   fi
 597
 598   READLINE=-lreadline
 599   READLINE_DEPS=
 600   READLINE_CFLAGS=
 601   READLINE_TEXI_INCFLAG=
 602 else
 603   READLINE='$(READLINE_DIR)/libreadline.a'
 604   READLINE_DEPS='$(READLINE)'
 605   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 606   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 607 fi
 608 AC_SUBST(READLINE)
 609 AC_SUBST(READLINE_DEPS)
 610 AC_SUBST(READLINE_CFLAGS)
 611 AC_SUBST(READLINE_TEXI_INCFLAG)
 612
 613 # Generate jit-reader.h
 614
 615 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 616 TARGET_PTR=
 617
 618 AC_CHECK_SIZEOF(unsigned long long)
 619 AC_CHECK_SIZEOF(unsigned long)
 620 AC_CHECK_SIZEOF(unsigned __int128)
 621
 622 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 623   TARGET_PTR="unsigned long"
 624 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 625   TARGET_PTR="unsigned long long"
 626 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 627   TARGET_PTR="unsigned __int128"
 628 else
 629   TARGET_PTR="unsigned long"
 630 fi
 631
 632 AC_SUBST(TARGET_PTR)
 633 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 634
 635 AC_SEARCH_LIBS(dlopen, dl)
 636
 637 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 638                 [directory to load the JIT readers from],
 639                 [${libdir}/gdb])
 640
 641 AC_ARG_WITH(expat,
 642   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 643   [], [with_expat=auto])
 644 AC_MSG_CHECKING([whether to use expat])
 645 AC_MSG_RESULT([$with_expat])
 646
 647 if test "${with_expat}" = no; then
 648   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 649   HAVE_LIBEXPAT=no
 650 else
 651   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 652                         [XML_Parser p = XML_ParserCreate (0);])
 653   if test "$HAVE_LIBEXPAT" != yes; then
 654     if test "$with_expat" = yes; then
 655       AC_MSG_ERROR([expat is missing or unusable])
 656     else
 657       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 658     fi
 659   else
 660     save_LIBS=$LIBS
 661     LIBS="$LIBS $LIBEXPAT"
 662     AC_CHECK_FUNCS(XML_StopParser)
 663     LIBS=$save_LIBS
 664   fi
 665 fi
 666
 667 AC_ARG_WITH(mpfr,
 668   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 669   [], [with_mpfr=auto])
 670 AC_MSG_CHECKING([whether to use MPFR])
 671 AC_MSG_RESULT([$with_mpfr])
 672
 673 if test "${with_mpfr}" = no; then
 674   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 675   HAVE_LIBMPFR=no
 676 else
 677   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 678                         [mpfr_exp_t exp; mpfr_t x;
 679                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 680   if test "$HAVE_LIBMPFR" != yes; then
 681     if test "$with_mpfr" = yes; then
 682       AC_MSG_ERROR([MPFR is missing or unusable])
 683     else
 684       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 685     fi
 686   fi
 687 fi
 688
 689 # --------------------- #
 690 # Check for libpython.  #
 691 # --------------------- #
 692
 693 dnl Utility to simplify finding libpython.
 694 dnl $1 = pythonX.Y
 695 dnl $2 = the shell variable to assign the result to
 696 dnl      If libpython is found we store $version here.
 697 dnl $3 = additional flags to add to CPPFLAGS
 698 dnl $4 = additional flags to add to LIBS
 699
 700 AC_DEFUN([AC_TRY_LIBPYTHON],
 701 [
 702   version=$1
 703   define([have_libpython_var],$2)
 704   new_CPPFLAGS=$3
 705   new_LIBS=$4
 706   AC_MSG_CHECKING([for ${version}])
 707   save_CPPFLAGS=$CPPFLAGS
 708   save_LIBS=$LIBS
 709   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 710   LIBS="$new_LIBS $LIBS"
 711   found_usable_python=no
 712   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 713                                  [[Py_Initialize ();]])],
 714                  [have_libpython_var=${version}
 715                   found_usable_python=yes
 716                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 717                   PYTHON_LIBS=$new_LIBS])
 718   CPPFLAGS=$save_CPPFLAGS
 719   LIBS=$save_LIBS
 720   AC_MSG_RESULT([${found_usable_python}])
 721 ])
 722
 723 dnl There are several different values for --with-python:
 724 dnl
 725 dnl no -   Don't include python support.
 726 dnl yes -  Include python support, error if it's missing.
 727 dnl        If we find python in $PATH, use it to fetch configure options,
 728 dnl        otherwise assume the compiler can find it with no help from us.
 729 dnl        Python 2.7 and 2.6 are tried in turn.
 730 dnl auto - Same as "yes", but if python is missing from the system,
 731 dnl        fall back to "no".
 732 dnl /path/to/python/exec-prefix -
 733 dnl        Use the python located in this directory.
 734 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 735 dnl        the compilation parameters.  Otherwise use
 736 dnl        -I/path/to/python/exec-prefix/include,
 737 dnl        -L/path/to/python/exec-prefix/lib.
 738 dnl        Python 2.7 and 2.6 are tried in turn.
 739 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 740 dnl        but is deprecated.
 741 dnl /path/to/python/executable -
 742 dnl        Run python-config.py with this version of python to fetch the
 743 dnl        compilation parameters.
 744 dnl        NOTE: This needn't be the real python executable.
 745 dnl        In a cross-compilation scenario (build != host), this could be
 746 dnl        a shell script that provides what python-config.py provides for
 747 dnl        --ldflags, --includes, --exec-prefix.
 748 dnl python-executable -
 749 dnl        Find python-executable in $PATH, and then handle the same as
 750 dnl        /path/to/python/executable.
 751 dnl
 752 dnl If a python program is specified, it is used to run python-config.py and
 753 dnl is passed --ldflags, --includes, --exec-prefix.
 754
 755 AC_ARG_WITH(python,
 756   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 757   [], [with_python=auto])
 758 AC_MSG_CHECKING([whether to use python])
 759 AC_MSG_RESULT([$with_python])
 760
 761 if test "${with_python}" = no; then
 762   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 763   have_libpython=no
 764 else
 765   case "${with_python}" in
 766   [[\\/]]* | ?:[[\\/]]*)
 767     if test -d ${with_python}; then
 768       # Assume the python binary is ${with_python}/bin/python.
 769       python_prog="${with_python}/bin/python"
 770       python_prefix=
 771       # If python does not exit ${with_python}/bin, then try in
 772       # ${with_python}.  On Windows/MinGW, this is where the Python
 773       # executable is.
 774       if test ! -x "${python_prog}"; then
 775         python_prog="${with_python}/python"
 776         python_prefix=
 777       fi
 778       if test ! -x "${python_prog}"; then
 779         # Fall back to gdb 7.0/7.1 behaviour.
 780         python_prog=missing
 781         python_prefix=${with_python}
 782       fi
 783     elif test -x "${with_python}"; then
 784       # While we can't run python compiled for $host (unless host == build),
 785       # the user could write a script that provides the needed information,
 786       # so we support that.
 787       python_prog=${with_python}
 788       python_prefix=
 789     else
 790       AC_ERROR(invalid value for --with-python)
 791     fi
 792     ;;
 793   */*)
 794     # Disallow --with-python=foo/bar.
 795     AC_ERROR(invalid value for --with-python)
 796     ;;
 797   *)
 798     # The user has either specified auto, yes, or the name of the python
 799     # program assumed to be in $PATH.
 800     python_prefix=
 801     case "${with_python}" in
 802     yes | auto)
 803       if test ${build} = ${host}; then
 804         AC_PATH_PROG(python_prog_path, python, missing)
 805         if test "${python_prog_path}" = missing; then
 806           python_prog=missing
 807         else
 808           python_prog=${python_prog_path}
 809         fi
 810       else
 811         # Not much we can do except assume the cross-compiler will find the
 812         # right files.
 813         python_prog=missing
 814       fi
 815       ;;
 816     *)
 817       # While we can't run python compiled for $host (unless host == build),
 818       # the user could write a script that provides the needed information,
 819       # so we support that.
 820       python_prog="${with_python}"
 821       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 822       if test "${python_prog_path}" = missing; then
 823         AC_ERROR(unable to find python program ${python_prog})
 824       fi
 825       ;;
 826     esac
 827   esac
 828
 829   if test "${python_prog}" != missing; then
 830     # We have a python program to use, but it may be too old.
 831     # Don't flag an error for --with-python=auto (the default).
 832     have_python_config=yes
 833     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 834     if test $? != 0; then
 835       have_python_config=failed
 836       if test "${with_python}" != auto; then
 837         AC_ERROR(failure running python-config --includes)
 838       fi
 839     fi
 840     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 841     if test $? != 0; then
 842       have_python_config=failed
 843       if test "${with_python}" != auto; then
 844         AC_ERROR(failure running python-config --ldflags)
 845       fi
 846     fi
 847     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 848     if test $? != 0; then
 849       have_python_config=failed
 850       if test "${with_python}" != auto; then
 851         AC_ERROR(failure running python-config --exec-prefix)
 852       fi
 853     fi
 854   else
 855     # We do not have a python executable we can use to determine where
 856     # to find the Python headers and libs.  We cannot guess the include
 857     # path from the python_prefix either, because that include path
 858     # depends on the Python version.  So, there is nothing much we can
 859     # do except assume that the compiler will be able to find those files.
 860     python_includes=
 861     python_libs=
 862     have_python_config=no
 863   fi
 864
 865   # If we have python-config, only try the configuration it provides.
 866   # Otherwise fallback on the old way of trying different versions of
 867   # python in turn.
 868
 869   have_libpython=no
 870   if test "${have_python_config}" = yes; then
 871     # Determine the Python version by extracting "-lpython<version>"
 872     # part of the python_libs. <version> is usually X.Y with X and Y
 873     # being decimal numbers, but can also be XY (seen on Windows).
 874     #
 875     # The extraction is performed using sed with a regular expression.
 876     # Initially, the regexp used was using the '?' quantifier to make
 877     # the dot in the version number optional.  Unfortunately, this
 878     # does not work with non-GNU versions of sed because, because of
 879     # what looks like a limitation (the '?' quantifier does not work
 880     # with back-references).  We work around this limitation by using
 881     # the '*' quantifier instead.  It means that, in theory, we might
 882     # match unexpected version strings such as "-lpython2..7", but
 883     # this seems unlikely in practice.  And even if that happens,
 884     # an error will be triggered later on, when checking that version
 885     # number.
 886     python_version=`echo " ${python_libs} " \
 887                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 888     case "${python_version}" in
 889     python*)
 890       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 891                        ${python_includes}, ${python_libs})
 892       ;;
 893     *)
 894       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 895       ;;
 896     esac
 897   elif test "${have_python_config}" != failed; then
 898     if test "${have_libpython}" = no; then
 899       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 900                        ${python_includes}, "-lpython2.7 ${python_libs}")
 901     fi
 902     if test "${have_libpython}" = no; then
 903       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 904                        ${python_includes}, "-lpython2.6 ${python_libs}")
 905     fi
 906   fi
 907   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 908     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 909   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 910     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 911   fi
 912
 913   if test "${have_libpython}" = no; then
 914     case "${with_python}" in
 915     yes)
 916       AC_MSG_ERROR([python is missing or unusable])
 917       ;;
 918     auto)
 919       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 920       ;;
 921     *)
 922       AC_MSG_ERROR([no usable python found at ${with_python}])
 923       ;;
 924     esac
 925   else
 926     if test -n "${python_prefix}"; then
 927       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 928                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 929       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 930     fi
 931   fi
 932 fi
 933
 934 if test "${have_libpython}" != no; then
 935   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 936   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 937   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 938   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 939   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 940   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 941
 942   # Flags needed to compile Python code (taken from python-config --cflags).
 943   # We cannot call python-config directly because it will output whatever was
 944   # used when compiling the Python interpreter itself, including flags which
 945   # would make the python-related objects be compiled differently from the
 946   # rest of GDB (e.g., -O2 and -fPIC).
 947   if test "${GCC}" = yes; then
 948     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 949     # Python headers recommend -DNDEBUG, but it's unclear if that just
 950     # refers to building Python itself.  In release mode, though, it
 951     # doesn't hurt for the Python code in gdb to follow.
 952     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 953   fi
 954
 955   if test "x${tentative_python_cflags}" != x; then
 956     AC_MSG_CHECKING(compiler flags for python code)
 957     for flag in ${tentative_python_cflags}; do
 958       # Check that the compiler accepts it
 959       saved_CFLAGS="$CFLAGS"
 960       CFLAGS="$CFLAGS $flag"
 961       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 962       CFLAGS="$saved_CFLAGS"
 963     done
 964     AC_MSG_RESULT(${PYTHON_CFLAGS})
 965   fi
 966
 967   # On x64 Windows, Python's include headers, and pyconfig.h in
 968   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 969   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 970   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 971   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 972   # The issue was reported to the Python community, but still isn't
 973   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 974
 975   case "$gdb_host" in
 976     mingw64)
 977            if test "${GCC}" = yes; then
 978              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 979            fi
 980            ;;
 981   esac
 982
 983   # Note that "python -m threading" cannot be used to check for
 984   # threading support due to a bug in Python 2.7.3
 985   # (http://bugs.python.org/issue15567).
 986   AC_MSG_CHECKING(whether python supports threads)
 987   saved_CPPFLAGS="${CPPFLAGS}"
 988   CPPFLAGS="${PYTHON_CPPFLAGS}"
 989   # Note that the test is reversed so that python_has_threads=yes on
 990   # unexpected failures.
 991   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 992 #include <Python.h>
 993 #ifdef WITH_THREAD
 994 # error
 995 #endif
 996   ]])], [python_has_threads=no], [python_has_threads=yes])
 997   AC_MSG_RESULT(${python_has_threads})
 998   CPPFLAGS="${saved_CPPFLAGS}"
 999 else
1000   # Even if Python support is not compiled in, we need to have this file
1001   # included so that the "python" command, et.al., still exists.
1002   CONFIG_OBS="$CONFIG_OBS python/python.o"
1003   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1004 fi
1005
1006 # Work around Python http://bugs.python.org/issue10112.  See also
1007 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1008 # no effect.  Note that the only test after this that uses Python is
1009 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1010 # run without -export-dynamic too.
1011 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1012
1013 AC_SUBST(PYTHON_CFLAGS)
1014 AC_SUBST(PYTHON_CPPFLAGS)
1015 AC_SUBST(PYTHON_LIBS)
1016 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1017
1018 # -------------------- #
1019 # Check for libguile.  #
1020 # -------------------- #
1021
1022 dnl Utility to simplify finding libguile.
1023 dnl $1 = pkg-config-program
1024 dnl $2 = space-separate list of guile versions to try
1025 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1026 dnl $4 = the shell variable to assign the result to
1027 dnl      If libguile is found we store "yes" here.
1028
1029 AC_DEFUN([AC_TRY_LIBGUILE],
1030 [
1031   pkg_config=$1
1032   guile_version_list=$2
1033   flag_errors=$3
1034   define([have_libguile_var],$4)
1035   found_usable_guile=checking
1036   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1037   for guile_version in ${guile_version_list}; do
1038     ${pkg_config} --exists ${guile_version} 2>/dev/null
1039     if test $? != 0; then
1040       continue
1041     fi
1042     dnl pkg-config says the package exists, so if we get an error now,
1043     dnl that's bad.
1044     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1045     if test $? != 0; then
1046       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1047     fi
1048     new_LIBS=`${pkg_config} --libs ${guile_version}`
1049     if test $? != 0; then
1050       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1051     fi
1052     dnl If we get this far, great.
1053     found_usable_guile=${guile_version}
1054     break
1055   done
1056   if test "${found_usable_guile}" = "checking"; then
1057     if test "${flag_errors}" = "yes"; then
1058       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1059     else
1060       found_usable_guile=no
1061     fi
1062   fi
1063   dnl One final sanity check.
1064   dnl The user could have said --with-guile=python-2.7.
1065   if test "${found_usable_guile}" != no; then
1066     save_CPPFLAGS=$CPPFLAGS
1067     save_LIBS=$LIBS
1068     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1069     LIBS="$LIBS $new_LIBS"
1070     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1071                                    [[scm_init_guile ();]])],
1072                    [have_libguile_var=yes
1073                     GUILE_CPPFLAGS=$new_CPPFLAGS
1074                     GUILE_LIBS=$new_LIBS],
1075                    [found_usable_guile=no])
1076     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1077     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1078       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1079                 [Define if Guile supports manual finalization.])
1080     )
1081     CPPFLAGS=$save_CPPFLAGS
1082     LIBS=$save_LIBS
1083     if test "${found_usable_guile}" = no; then
1084       if test "${flag_errors}" = yes; then
1085         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1086       fi
1087     fi
1088   fi
1089   AC_MSG_RESULT([${found_usable_guile}])
1090 ])
1091
1092 dnl There are several different values for --with-guile:
1093 dnl
1094 dnl no -   Don't include guile support.
1095 dnl yes -  Include guile support, error if it's missing.
1096 dnl        The pkg-config program must be in $PATH.
1097 dnl auto - Same as "yes", but if guile is missing from the system,
1098 dnl        fall back to "no".
1099 dnl guile-version [guile-version-choice-2 ...] -
1100 dnl        A space-separated list of guile package versions to try.
1101 dnl        These are passed to pkg-config as-is.
1102 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1103 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1104 dnl /path/to/pkg-config -
1105 dnl        Use this pkg-config program.
1106 dnl        NOTE: This needn't be the "real" pkg-config program.
1107 dnl        It could be a shell script.  It is invoked as:
1108 dnl        pkg-config --exists $version
1109 dnl        pkg-config --cflags $version
1110 dnl        pkg-config --libs $version
1111 dnl        pkg-config --variable guild $version
1112 dnl        The script will be called with $version having each value in
1113 dnl        $try_guile_versions until --exists indicates success.
1114
1115 AC_ARG_WITH(guile,
1116   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1117   [], [with_guile=auto])
1118 AC_MSG_CHECKING([whether to use guile])
1119 AC_MSG_RESULT([$with_guile])
1120
1121 dnl We check guile with pkg-config.
1122 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1123
1124 try_guile_versions="guile-2.0"
1125 have_libguile=no
1126 case "${with_guile}" in
1127 no)
1128   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1129   ;;
1130 auto)
1131   if test "${pkg_config_prog_path}" = "missing"; then
1132     AC_MSG_WARN([pkg-config not found, guile support disabled])
1133   else
1134     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1135   fi
1136   ;;
1137 yes)
1138   if test "${pkg_config_prog_path}" = "missing"; then
1139     AC_MSG_ERROR([pkg-config not found])
1140   fi
1141   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1142   ;;
1143 [[\\/]]* | ?:[[\\/]]*)
1144   if test -x "${with_guile}"; then
1145     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1146   else
1147     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1148   fi
1149   ;;
1150 "" | */*)
1151   # Disallow --with=guile="" and --with-guile=foo/bar.
1152   AC_MSG_ERROR([invalid value for --with-guile])
1153   ;;
1154 *)
1155   # A space separate list of guile versions to try, in order.
1156   if test "${pkg_config_prog_path}" = "missing"; then
1157     AC_MSG_ERROR([pkg-config not found])
1158   fi
1159   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1160   ;;
1161 esac
1162
1163 if test "${have_libguile}" != no; then
1164   dnl Get the name of the 'guild' program.
1165   case "${with_guile}" in
1166   [[\\/]]* | ?:[[\\/]]*)
1167     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1168     ;;
1169   *)
1170     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1171     ;;
1172   esac
1173
1174   dnl Make sure guild can handle this host.
1175   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1176   dnl If not, disable guile support.
1177   if test "$ac_cv_guild_ok" = no; then
1178     have_libguile=no
1179     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1180   fi
1181 fi
1182
1183 if test "${have_libguile}" != no; then
1184   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1185   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1186   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1187   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1188   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1189   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1190
1191   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1192   save_LIBS="$LIBS"
1193   save_CPPFLAGS="$CPPFLAGS"
1194   LIBS="$GUILE_LIBS"
1195   CPPFLAGS="$GUILE_CPPFLAGS"
1196   AC_CHECK_FUNCS([scm_new_smob])
1197   LIBS="$save_LIBS"
1198   CPPFLAGS="$save_CPPFLAGS"
1199 else
1200   # Even if Guile support is not compiled in, we need to have these files
1201   # included.
1202   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1203   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1204 fi
1205 AC_SUBST(GUILE_CPPFLAGS)
1206 AC_SUBST(GUILE_LIBS)
1207 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1208
1209 # ---------------------------- #
1210 # Check for source highlight.  #
1211 # ---------------------------- #
1212
1213 SRCHIGH_LIBS=
1214 SRCHIGH_CFLAGS=
1215
1216 AC_ARG_ENABLE(source-highlight,
1217   AS_HELP_STRING([--enable-source-highlight],
1218     [enable source-highlight for source listings]),
1219   [case "${enableval}" in
1220   yes)  enable_source_highlight=yes ;;
1221   no)   enable_source_highlight=no  ;;
1222   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1223 esac],
1224 [enable_source_highlight=auto])
1225
1226 if test "${enable_source_highlight}" != "no"; then
1227   AC_MSG_CHECKING([for the source-highlight library])
1228   if test "${pkg_config_prog_path}" = "missing"; then
1229     AC_MSG_RESULT([no - pkg-config not found])
1230     if test "${enable_source_highlight}" = "yes"; then
1231       AC_MSG_ERROR([pkg-config was not found in your system])
1232     fi
1233   else
1234     case "$LDFLAGS" in
1235       *static-libstdc*)
1236         AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1237 either use --disable-source-highlight or dnl
1238 --without-static-standard-libraries])
1239         ;;
1240     esac
1241
1242     if ${pkg_config_prog_path} --exists source-highlight; then
1243       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1244       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1245       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1246                 [Define to 1 if the source-highlight library is available])
1247       AC_MSG_RESULT([yes])
1248     else
1249       AC_MSG_RESULT([no])
1250       if test "${enable_source_highlight}" = "yes"; then
1251         AC_MSG_ERROR([source-highlight was not found in your system])
1252       fi
1253     fi
1254   fi
1255 fi
1256 AC_SUBST(SRCHIGH_LIBS)
1257 AC_SUBST(SRCHIGH_CFLAGS)
1258
1259 AC_ARG_WITH(intel_pt,
1260   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1261   [], [with_intel_pt=auto])
1262 AC_MSG_CHECKING([whether to use intel pt])
1263 AC_MSG_RESULT([$with_intel_pt])
1264
1265 if test "${with_intel_pt}" = no; then
1266   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1267   HAVE_LIBIPT=no
1268 else
1269   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
1270 #include <linux/perf_event.h>
1271 #ifndef PERF_ATTR_SIZE_VER5
1272 # error
1273 #endif
1274   ]])], [perf_event=yes], [perf_event=no])
1275   if test "$perf_event" != yes; then
1276     if test "$with_intel_pt" = yes; then
1277       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1278     else
1279       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1280     fi
1281   fi
1282
1283   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1284   if test "$HAVE_LIBIPT" != yes; then
1285     if test "$with_intel_pt" = yes; then
1286       AC_MSG_ERROR([libipt is missing or unusable])
1287     else
1288       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1289     fi
1290   else
1291     save_LIBS=$LIBS
1292     LIBS="$LIBS $LIBIPT"
1293     AC_CHECK_FUNCS(pt_insn_event)
1294     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1295                      [#include <intel-pt.h>])
1296     LIBS=$save_LIBS
1297   fi
1298 fi
1299
1300 # ------------------------- #
1301 # Checks for header files.  #
1302 # ------------------------- #
1303
1304 AC_HEADER_STDC
1305 # elf_hp.h is for HP/UX 64-bit shared library support.
1306 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1307                   thread_db.h linux/elf.h \
1308                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1309                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1310                   sys/reg.h sys/debugreg.h sys/select.h \
1311                   termios.h elf_hp.h])
1312 AC_CHECK_HEADERS(sys/user.h, [], [],
1313 [#if HAVE_SYS_PARAM_H
1314 # include <sys/param.h>
1315 #endif
1316 ])
1317
1318 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1319 AC_CHECK_HEADERS(term.h, [], [],
1320 [#if HAVE_CURSES_H
1321 # include <curses.h>
1322 #endif
1323 ])
1324
1325 # ------------------------- #
1326 # Checks for declarations.  #
1327 # ------------------------- #
1328
1329 libiberty_INIT
1330
1331 AC_CHECK_DECLS([snprintf])
1332 AM_LC_MESSAGES
1333
1334 # ----------------------- #
1335 # Checks for structures.  #
1336 # ----------------------- #
1337
1338 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1339
1340 # ------------------ #
1341 # Checks for types.  #
1342 # ------------------ #
1343
1344 AC_CHECK_TYPES(socklen_t, [], [],
1345 [#include <sys/types.h>
1346 #include <sys/socket.h>
1347 ])
1348
1349 # ------------------------------------- #
1350 # Checks for compiler characteristics.  #
1351 # ------------------------------------- #
1352
1353 AC_C_CONST
1354 AC_C_INLINE
1355 AC_C_BIGENDIAN
1356
1357 # ------------------------------ #
1358 # Checks for library functions.  #
1359 # ------------------------------ #
1360
1361 AC_FUNC_MMAP
1362 AC_FUNC_VFORK
1363 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1364                 pipe poll pread pread64 pwrite resize_term \
1365                 sbrk getpgid setpgid setpgrp setsid \
1366                 sigaction sigprocmask sigsetmask socketpair \
1367                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1368                 setrlimit getrlimit posix_madvise waitpid \
1369                 ptrace64 sigaltstack setns use_default_colors])
1370 AM_LANGINFO_CODESET
1371 GDB_AC_COMMON
1372
1373 # Check the return and argument types of ptrace.
1374 GDB_AC_PTRACE
1375
1376 dnl AC_FUNC_SETPGRP does not work when cross compiling
1377 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1378 if test "$cross_compiling" = no; then
1379   AC_FUNC_SETPGRP
1380 else
1381   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1382     [AC_TRY_COMPILE([
1383 #include <unistd.h>
1384 ], [
1385   if (setpgrp(1,1) == -1)
1386     exit (0);
1387   else
1388     exit (1);
1389 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1390 if test $ac_cv_func_setpgrp_void = yes; then
1391   AC_DEFINE(SETPGRP_VOID, 1)
1392 fi
1393 fi
1394
1395 # Assume we'll default to using the included libiberty regex.
1396 gdb_use_included_regex=yes
1397
1398 # However, if the system regex is GNU regex, then default to *not*
1399 # using the included regex.
1400 AC_CACHE_CHECK(
1401   [for GNU regex],
1402   [gdb_cv_have_gnu_regex],
1403   [AC_TRY_COMPILE(
1404     [#include <gnu-versions.h>],
1405     [#define REGEX_INTERFACE_VERSION 1
1406 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1407 # error "Version mismatch"
1408 #endif],
1409     gdb_cv_have_gnu_regex=yes,
1410     gdb_cv_have_gnu_regex=no)])
1411 if test $gdb_cv_have_gnu_regex = yes; then
1412   gdb_use_included_regex=no
1413 fi
1414
1415 AC_ARG_WITH(included-regex,
1416   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1417   gdb_with_regex=$withval,
1418   gdb_with_regex=$gdb_use_included_regex)
1419 if test "$gdb_with_regex" = yes; then
1420   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1421     [Define to 1 if the regex included in libiberty should be used.])
1422 fi
1423
1424 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1425 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1426 [#include <sys/param.h>
1427 #include <sys/proc.h>
1428 ])
1429
1430 # See if <sys/lwp.h> defines `struct lwp`.
1431 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1432 [AC_TRY_COMPILE([#include <sys/param.h>
1433 #define _KMEMUSER
1434 #include <sys/lwp.h>], [struct lwp l;],
1435 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1436 if test $gdb_cv_struct_lwp = yes; then
1437   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1438             [Define to 1 if your system has struct lwp.])
1439 fi
1440
1441 # See if <machine/reg.h> degines `struct reg'.
1442 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1443 [AC_TRY_COMPILE([#include <sys/types.h>
1444 #include <machine/reg.h>], [struct reg r;],
1445 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1446 if test $gdb_cv_struct_reg = yes; then
1447   AC_DEFINE(HAVE_STRUCT_REG, 1,
1448             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1449 fi
1450
1451 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1452 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1453 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1454                  [#include <sys/types.h>
1455 #include <machine/reg.h>])
1456
1457 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1458 # Older amd64 Linux's don't have the fs_base and gs_base members of
1459 # `struct user_regs_struct'.
1460 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1461      [], [], [#include <sys/types.h>
1462 #include <sys/user.h>])
1463
1464 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1465 AC_MSG_CHECKING(for PTRACE_GETREGS)
1466 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1467 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1468                 [PTRACE_GETREGS;],
1469                 [gdb_cv_have_ptrace_getregs=yes],
1470                 [gdb_cv_have_ptrace_getregs=no])])
1471 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1472 if test $gdb_cv_have_ptrace_getregs = yes; then
1473   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1474   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1475 fi
1476
1477 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1478 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1479 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1480 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1481                 [PTRACE_GETFPXREGS;],
1482                 [gdb_cv_have_ptrace_getfpxregs=yes],
1483                 [gdb_cv_have_ptrace_getfpxregs=no])])
1484 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1485 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1486   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1487   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1488 fi
1489
1490 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1491 AC_MSG_CHECKING(for PT_GETDBREGS)
1492 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1493 [AC_TRY_COMPILE([#include <sys/types.h>
1494 #include <sys/ptrace.h>],
1495                 [PT_GETDBREGS;],
1496                 [gdb_cv_have_pt_getdbregs=yes],
1497                 [gdb_cv_have_pt_getdbregs=no])])
1498 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1499 if test $gdb_cv_have_pt_getdbregs = yes; then
1500   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1501   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1502 fi
1503
1504 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1505 AC_MSG_CHECKING(for PT_GETXMMREGS)
1506 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1507 [AC_TRY_COMPILE([#include <sys/types.h>
1508 #include <sys/ptrace.h>],
1509                 [PT_GETXMMREGS;],
1510                 [gdb_cv_have_pt_getxmmregs=yes],
1511                 [gdb_cv_have_pt_getxmmregs=no])])
1512 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1513 if test $gdb_cv_have_pt_getxmmregs = yes; then
1514   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1515   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1516 fi
1517
1518 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1519 # Older FreeBSD versions don't have the pl_tdname member of
1520 # `struct ptrace_lwpinfo'.
1521 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1522                  [#include <sys/ptrace.h>])
1523
1524 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1525 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1526 # FreeBSD 10.3.
1527 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1528                  [#include <sys/ptrace.h>])
1529
1530 if test "$ac_cv_header_sys_procfs_h" = yes; then
1531   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1532   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1533   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1534   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1535   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1536   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1537   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1538   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
1539 fi
1540
1541 # Check if the compiler supports the `long long' type.
1542
1543 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1544                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1545 [[extern long long foo;]],
1546 [[switch (foo & 2) { case 0: return 1; }]])],
1547                                   gdb_cv_c_long_long=yes,
1548                                   gdb_cv_c_long_long=no)])
1549 if test $gdb_cv_c_long_long != yes; then
1550   # libdecnumber requires long long.
1551   AC_MSG_ERROR([Compiler must support long long for GDB.])
1552 fi
1553
1554 # Check if the compiler and runtime support printing long longs.
1555
1556 AC_CACHE_CHECK([for long long support in printf],
1557                gdb_cv_printf_has_long_long,
1558                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1559 [[char buf[32];
1560   long long l = 0;
1561   l = (l << 16) + 0x0123;
1562   l = (l << 16) + 0x4567;
1563   l = (l << 16) + 0x89ab;
1564   l = (l << 16) + 0xcdef;
1565   sprintf (buf, "0x%016llx", l);
1566   return (strcmp ("0x0123456789abcdef", buf));]])],
1567                               gdb_cv_printf_has_long_long=yes,
1568                               gdb_cv_printf_has_long_long=no,
1569                               gdb_cv_printf_has_long_long=no)])
1570 if test $gdb_cv_printf_has_long_long = yes; then
1571   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1572             [Define to 1 if the "%ll" format works to print long longs.])
1573 fi
1574
1575 # Check if the compiler and runtime support printing decfloats.
1576
1577 AC_CACHE_CHECK([for decfloat support in printf],
1578                gdb_cv_printf_has_decfloat,
1579                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1580 [[char buf[64];
1581   _Decimal32 d32 = 1.2345df;
1582   _Decimal64 d64 = 1.2345dd;
1583   _Decimal128 d128 = 1.2345dl;
1584   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1585   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1586                               gdb_cv_printf_has_decfloat=yes,
1587                               gdb_cv_printf_has_decfloat=no,
1588                               gdb_cv_printf_has_decfloat=no)])
1589 if test $gdb_cv_printf_has_decfloat = yes; then
1590   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1591             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1592 fi
1593
1594 # Check if the compiler supports the `long double' type.  We can't use
1595 # AC_C_LONG_DOUBLE because that one does additional checks on the
1596 # constants defined in <float.h> that fail on some systems,
1597 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1598
1599 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1600                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1601                                   gdb_cv_c_long_double=yes,
1602                                   gdb_cv_c_long_double=no)])
1603 if test $gdb_cv_c_long_double = yes; then
1604   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1605            [Define to 1 if the compiler supports long double.])
1606 fi
1607
1608 # Check if the compiler and runtime support printing long doubles.
1609
1610 AC_CACHE_CHECK([for long double support in printf],
1611                gdb_cv_printf_has_long_double,
1612                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1613 [[char buf[16];
1614   long double f = 3.141592653;
1615   sprintf (buf, "%Lg", f);
1616   return (strncmp ("3.14159", buf, 7));]])],
1617                               gdb_cv_printf_has_long_double=yes,
1618                               gdb_cv_printf_has_long_double=no,
1619                               gdb_cv_printf_has_long_double=no)])
1620 if test $gdb_cv_printf_has_long_double = yes; then
1621   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1622             [Define to 1 if the "%Lg" format works to print long doubles.])
1623 fi
1624
1625 # Check if the compiler and runtime support scanning long doubles.
1626
1627 AC_CACHE_CHECK([for long double support in scanf],
1628                gdb_cv_scanf_has_long_double,
1629                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1630 [[#include <stdio.h>]],
1631 [[char *buf = "3.141592653";
1632   long double f = 0;
1633   sscanf (buf, "%Lg", &f);
1634   return !(f > 3.14159 && f < 3.14160);]])],
1635                               gdb_cv_scanf_has_long_double=yes,
1636                               gdb_cv_scanf_has_long_double=no,
1637                               gdb_cv_scanf_has_long_double=no)])
1638 if test $gdb_cv_scanf_has_long_double = yes; then
1639   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1640             [Define to 1 if the "%Lg" format works to scan long doubles.])
1641 fi
1642
1643 case ${host_os} in
1644 aix*)
1645   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1646     SAVE_LDFLAGS=$LDFLAGS
1647
1648     case $GCC in
1649     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1650     *) gdb_cv_bigtoc=-bbigtoc ;;
1651     esac
1652
1653     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1654     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1655     LDFLAGS="${SAVE_LDFLAGS}"
1656   ])
1657   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1658   ;;
1659 esac
1660
1661 AC_MSG_CHECKING(for the dynamic export flag)
1662 dynamic_list=false
1663 if test "${gdb_native}" = yes; then
1664    # The dynamically loaded libthread_db needs access to symbols in the gdb
1665    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1666    # may not be supported there.
1667    old_LDFLAGS="$LDFLAGS"
1668    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1669    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1670    LDFLAGS="$LDFLAGS $RDYNAMIC"
1671    if test "${have_libpython}" = no; then
1672      AC_TRY_LINK([], [], [dynamic_list=true])
1673    else
1674      # Workaround http://bugs.python.org/issue4434 where static
1675      # libpythonX.Y.a would get its symbols required for
1676      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1677      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1678
1679      # Note the workaround for Python
1680      # http://bugs.python.org/issue10112 earlier has removed
1681      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1682      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1683      # always pass.
1684      old_CFLAGS="$CFLAGS"
1685      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1686      old_LIBS="$LIBS"
1687      LIBS="$LIBS $PYTHON_LIBS"
1688      old_CPPFLAGS="$CPPFLAGS"
1689      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1690      AC_RUN_IFELSE(
1691        [AC_LANG_PROGRAM(
1692          [#include "Python.h"],
1693          [int err;
1694           Py_Initialize ();
1695           err = PyRun_SimpleString ("import itertools\n");
1696           Py_Finalize ();
1697           return err == 0 ? 0 : 1;])],
1698        [dynamic_list=true], [], [true])
1699      LIBS="$old_LIBS"
1700      CFLAGS="$old_CFLAGS"
1701      CPPFLAGS="$old_CPPFLAGS"
1702    fi
1703    LDFLAGS="$old_LDFLAGS"
1704 fi
1705 if $dynamic_list; then
1706   found="-Wl,--dynamic-list"
1707   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1708 else
1709   found="-rdynamic"
1710   RDYNAMIC="-rdynamic"
1711 fi
1712 AC_SUBST(RDYNAMIC)
1713 AC_MSG_RESULT($found)
1714
1715 dnl For certain native configurations, we need to check whether thread
1716 dnl support can be built in or not.
1717 dnl
1718 dnl Note that we only want this if we are both native (host == target),
1719 dnl and not doing a canadian cross build (build == host).
1720
1721 if test ${build} = ${host} -a ${host} = ${target} ; then
1722    case ${host_os} in
1723    aix*)
1724       AC_MSG_CHECKING(for AiX thread debugging library)
1725       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1726                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1727                                    [#ifndef PTHDB_VERSION_3
1728                                     #error
1729                                     #endif],
1730                                    gdb_cv_have_aix_thread_debug=yes,
1731                                    gdb_cv_have_aix_thread_debug=no)])
1732       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1733       if test $gdb_cv_have_aix_thread_debug = yes; then
1734          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1735          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1736          LIBS="$LIBS -lpthdebug"
1737
1738          # Older versions of AIX do not provide the declaration for
1739          # the getthrds function (it appears that it was introduced
1740          # with AIX 6.x).
1741          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1742       fi
1743       ;;
1744    esac
1745    AC_SUBST(CONFIG_LDFLAGS)
1746 fi
1747
1748 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1749 dnl other error codes.
1750 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1751    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1752                   gdb_cv_thread_db_h_has_td_notalloc,
1753      AC_TRY_COMPILE(
1754        [#include <thread_db.h>],
1755        [int i = TD_NOTALLOC;],
1756        gdb_cv_thread_db_h_has_td_notalloc=yes,
1757        gdb_cv_thread_db_h_has_td_notalloc=no
1758      )
1759    )
1760    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1761                   gdb_cv_thread_db_h_has_td_version,
1762      AC_TRY_COMPILE(
1763        [#include <thread_db.h>],
1764        [int i = TD_VERSION;],
1765        gdb_cv_thread_db_h_has_td_version=yes,
1766        gdb_cv_thread_db_h_has_td_version=no
1767      )
1768    )
1769    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1770                   gdb_cv_thread_db_h_has_td_notls,
1771      AC_TRY_COMPILE(
1772        [#include <thread_db.h>],
1773        [int i = TD_NOTLS;],
1774        gdb_cv_thread_db_h_has_td_notls=yes,
1775        gdb_cv_thread_db_h_has_td_notls=no
1776      )
1777    )
1778 fi
1779 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1780   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1781             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1782 fi
1783 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1784   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1785             [Define if <thread_db.h> has the TD_VERSION error code.])
1786 fi
1787 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1788   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1789             [Define if <thread_db.h> has the TD_NOTLS error code.])
1790 fi
1791
1792 dnl Check if we can disable the virtual address space randomization.
1793 dnl The functionality of setarch -R.
1794 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1795 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1796 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1797 #       define ADDR_NO_RANDOMIZE 0x0040000
1798 #      endif
1799        /* Test the flag could be set and stays set.  */
1800        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1801        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1802            return 1])])
1803 AC_RUN_IFELSE([PERSONALITY_TEST],
1804               [have_personality=true],
1805               [have_personality=false],
1806               [AC_LINK_IFELSE([PERSONALITY_TEST],
1807                               [have_personality=true],
1808                               [have_personality=false])])
1809 if $have_personality
1810 then
1811     AC_DEFINE([HAVE_PERSONALITY], 1,
1812               [Define if you support the personality syscall.])
1813 fi
1814
1815 dnl Set the host's .gdbinit filename.
1816 case $host_os in
1817   go32* | *djgpp*)
1818     gdbinit=gdb.ini
1819     ;;
1820   *)
1821     gdbinit=.gdbinit
1822     ;;
1823 esac
1824 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1825
1826 dnl Handle optional features that can be enabled.
1827
1828 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1829 # except that the argument to --with-sysroot is optional.
1830 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1831 if test "x$with_sysroot" = xyes; then
1832   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1833 fi
1834 AC_ARG_WITH(sysroot,
1835   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1836                  [search for usr/lib et al within DIR]),
1837   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1838 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1839               [search for usr/lib et al within DIR])
1840 AC_SUBST(TARGET_SYSTEM_ROOT)
1841 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1842
1843 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1844     [automatically load a system-wide gdbinit file],
1845     [])
1846
1847 AM_GDB_WARNINGS
1848 AM_GDB_UBSAN
1849
1850 # In the Cygwin environment, we need some additional flags.
1851 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1852 [AC_EGREP_CPP(^lose$, [
1853 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1854 lose
1855 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1856
1857
1858 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1859 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1860 case ${host} in
1861   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1862   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1863   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1864   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1865 esac
1866 AC_SUBST(SER_HARDWIRE)
1867
1868 # libreadline needs libuser32.a in a cygwin environment
1869 WIN32LIBS=
1870 if test x$gdb_cv_os_cygwin = xyes; then
1871     WIN32LIBS="-luser32"
1872     case "${target}" in
1873         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1874         ;;
1875     esac
1876 fi
1877
1878 # The ser-tcp.c module requires sockets.
1879 case ${host} in
1880   *mingw32*)
1881     AC_DEFINE(USE_WIN32API, 1,
1882               [Define if we should use the Windows API, instead of the
1883                POSIX API.  On Windows, we use the Windows API when
1884                building for MinGW, but the POSIX API when building
1885                for Cygwin.])
1886     WIN32LIBS="$WIN32LIBS -lws2_32"
1887     ;;
1888 esac
1889 AC_SUBST(WIN32LIBS)
1890
1891 # Add ELF support to GDB, but only if BFD includes ELF support.
1892 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1893                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1894 if test $gdb_cv_var_elf = yes; then
1895   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1896   AC_DEFINE(HAVE_ELF, 1,
1897             [Define if ELF support should be included.])
1898   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1899   if test "$plugins" = "yes"; then
1900     AC_SEARCH_LIBS(dlopen, dl)
1901   fi
1902 fi
1903
1904 # Add macho support to GDB, but only if BFD includes it.
1905 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1906                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1907 if test $gdb_cv_var_macho = yes; then
1908   CONFIG_OBS="$CONFIG_OBS machoread.o"
1909 fi
1910
1911 # Add any host-specific objects to GDB.
1912 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1913
1914 # If building on ELF, look for lzma support for embedded compressed debug info.
1915 if test $gdb_cv_var_elf = yes; then
1916   AC_ARG_WITH(lzma,
1917     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1918     [], [with_lzma=auto])
1919   AC_MSG_CHECKING([whether to use lzma])
1920   AC_MSG_RESULT([$with_lzma])
1921
1922   if test "${with_lzma}" != no; then
1923     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1924                           [lzma_index_iter iter;
1925                            lzma_index_iter_init (&iter, 0);
1926                            lzma_mf_is_supported (LZMA_MF_HC3);])
1927     if test "$HAVE_LIBLZMA" != yes; then
1928       if test "$with_lzma" = yes; then
1929         AC_MSG_ERROR([missing liblzma for --with-lzma])
1930       fi
1931     fi
1932   fi
1933 fi
1934
1935 LIBGUI="../libgui/src/libgui.a"
1936 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1937 AC_SUBST(LIBGUI)
1938 AC_SUBST(GUI_CFLAGS_X)
1939
1940 WIN32LDAPP=
1941 AC_SUBST(WIN32LIBS)
1942 AC_SUBST(WIN32LDAPP)
1943
1944 case "${host}" in
1945 *-*-cygwin* | *-*-mingw* )
1946     configdir="win"
1947     ;;
1948 *)
1949     configdir="unix"
1950     ;;
1951 esac
1952
1953 GDBTKLIBS=
1954 if test "${enable_gdbtk}" = "yes"; then
1955
1956     # Gdbtk must have an absolute path to srcdir in order to run
1957     # properly when not installed.
1958     here=`pwd`
1959     cd ${srcdir}
1960     GDBTK_SRC_DIR=`pwd`
1961     cd $here
1962
1963     SC_PATH_TCLCONFIG
1964
1965     # If $no_tk is nonempty, then we can't do Tk, and there is no
1966     # point to doing Tcl.
1967     SC_PATH_TKCONFIG
1968
1969     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1970         SC_LOAD_TCLCONFIG
1971
1972         # Check for in-tree tcl
1973         here=`pwd`
1974         cd ${srcdir}/..
1975         topdir=`pwd`
1976         cd ${here}
1977
1978         intree="no"
1979         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1980           intree="yes"
1981         fi
1982
1983         # Find Tcl private headers
1984         if test x"${intree}" = xno; then
1985           CY_AC_TCL_PRIVATE_HEADERS
1986           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1987           TCL_LIBRARY="${TCL_LIB_SPEC}"
1988           TCL_DEPS=""
1989         else
1990           # If building tcl in the same src tree, private headers
1991           # are not needed, but we need to be sure to use the right
1992           # headers library
1993           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1994           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1995           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1996         fi
1997         AC_SUBST(TCL_INCLUDE)
1998         AC_SUBST(TCL_LIBRARY)
1999         AC_SUBST(TCL_DEPS)
2000
2001         SC_LOAD_TKCONFIG
2002
2003         # Check for in-tree Tk
2004         intree="no"
2005         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2006           intree="yes"
2007         fi
2008
2009         # Find Tk private headers
2010         if test x"${intree}" = xno; then
2011           CY_AC_TK_PRIVATE_HEADERS
2012           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2013           TK_LIBRARY=${TK_LIB_SPEC}
2014           TK_DEPS=""
2015         else
2016           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2017           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2018           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2019         fi
2020         AC_SUBST(TK_INCLUDE)
2021         AC_SUBST(TK_LIBRARY)
2022         AC_SUBST(TK_DEPS)
2023         AC_SUBST(TK_XINCLUDES)
2024
2025         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2026
2027         # Include some libraries that Tcl and Tk want.
2028         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2029         # Yes, the ordering seems wrong here.  But it isn't.
2030         # TK_LIBS is the list of libraries that need to be linked
2031         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2032         # were in LIBS then any link tests after this point would
2033         # try to include things like `$(LIBGUI)', which wouldn't work.
2034         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2035
2036         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2037         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2038         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2039         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2040         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2041         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2042         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2043
2044         if test x$gdb_cv_os_cygwin = xyes; then
2045           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2046           WIN32LDAPP="-Wl,--subsystem,console"
2047           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2048         fi
2049
2050         AC_CONFIG_SUBDIRS(gdbtk)
2051     fi
2052 fi
2053
2054 AC_SUBST(X_CFLAGS)
2055 AC_SUBST(X_LDFLAGS)
2056 AC_SUBST(X_LIBS)
2057 AC_SUBST(GDBTKLIBS)
2058 AC_SUBST(GDBTK_CFLAGS)
2059 AC_SUBST(GDBTK_SRC_DIR)
2060
2061 AC_PATH_X
2062
2063 # Unlike the sim directory, whether a simulator is linked is controlled by
2064 # presence of a gdb_sim definition in the target configure.tgt entry.
2065 # This code just checks for a few cases where we'd like to ignore those
2066 # definitions, even when they're present in the '.mt' file.  These cases
2067 # are when --disable-sim is specified, or if the simulator directory is
2068 # not part of the source tree.
2069 #
2070 AC_ARG_ENABLE(sim,
2071 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2072 [echo "enable_sim = $enable_sim";
2073  echo "enableval = ${enableval}";
2074  case "${enableval}" in
2075   yes) ignore_sim=false ;;
2076   no)  ignore_sim=true ;;
2077   *)   ignore_sim=false ;;
2078  esac],
2079 [ignore_sim=false])
2080
2081 if test ! -d "${srcdir}/../sim"; then
2082   ignore_sim=true
2083 fi
2084
2085 SIM=
2086 SIM_OBS=
2087 if test "${ignore_sim}" = "false"; then
2088   if test x"${gdb_sim}" != x ; then
2089     SIM="${gdb_sim}"
2090     SIM_OBS="remote-sim.o"
2091     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2092
2093     # Some tdep code should only be compiled in when the ppc sim is
2094     # built.  PR sim/13418.
2095     case $target in
2096       powerpc*-*-*)
2097         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2098         ;;
2099     esac
2100   fi
2101 fi
2102 AC_SUBST(SIM)
2103 AC_SUBST(SIM_OBS)
2104
2105 AC_SUBST(ENABLE_CFLAGS)
2106 AC_SUBST(PROFILE_CFLAGS)
2107
2108 AC_SUBST(CONFIG_OBS)
2109 AC_SUBST(CONFIG_DEPS)
2110 AC_SUBST(CONFIG_SRCS)
2111 AC_SUBST(CONFIG_ALL)
2112 AC_SUBST(CONFIG_CLEAN)
2113 AC_SUBST(CONFIG_INSTALL)
2114 AC_SUBST(CONFIG_UNINSTALL)
2115
2116 # List of host floatformats.
2117 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2118 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2119 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2120
2121 # target_subdir is used by the testsuite to find the target libraries.
2122 target_subdir=
2123 if test "${host}" != "${target}"; then
2124     target_subdir="${target_alias}/"
2125 fi
2126 AC_SUBST(target_subdir)
2127
2128 # Import nat definitions.
2129 nat_makefile_frag=/dev/null
2130 if test "${gdb_native}" = "yes"; then
2131   . ${srcdir}/configure.nat
2132   nativefile=$NAT_FILE
2133 fi
2134
2135 AC_SUBST(NAT_FILE)
2136 AC_SUBST(NATDEPFILES)
2137 AC_SUBST(NAT_CDEPS)
2138 AC_SUBST(LOADLIBES)
2139 AC_SUBST(MH_CFLAGS)
2140 AC_SUBST(XM_CLIBS)
2141 AC_SUBST(NAT_GENERATED_FILES)
2142 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2143 AC_SUBST_FILE(nat_makefile_frag)
2144
2145 if test x"${gdb_osabi}" != x ; then
2146     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2147                        [Define to the default OS ABI for this configuration.])
2148 fi
2149
2150 AC_ARG_ENABLE(gdbserver,
2151 AS_HELP_STRING([--enable-gdbserver],
2152                [automatically build gdbserver (yes/no/auto, default is auto)]),
2153 [case "${enableval}" in
2154   yes| no|auto) ;;
2155   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2156 esac],[enable_gdbserver=auto])
2157
2158 # We only build gdbserver automatically in a native configuration, and
2159 # only if the user did not explicitly disable its build.
2160 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2161   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2162   if test "x$build_gdbserver" = xyes; then
2163     AC_MSG_RESULT(yes)
2164     AC_CONFIG_SUBDIRS(gdbserver)
2165     gdbserver_build_enabled=yes
2166   else
2167     AC_MSG_RESULT(no)
2168   fi
2169 fi
2170
2171 # If the user explicitly request the gdbserver to be built, verify that
2172 # we were in fact able to enable it.
2173 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2174   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2175 fi
2176
2177 # Check for babeltrace and babeltrace-ctf
2178 AC_ARG_WITH(babeltrace,
2179   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2180   [], [with_babeltrace=auto])
2181 AC_MSG_CHECKING([whether to use babeltrace])
2182 AC_MSG_RESULT([$with_babeltrace])
2183
2184 if test "x$with_babeltrace" = "xno"; then
2185   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2186 else
2187   # Append -Werror to CFLAGS so that configure can catch the warning
2188   # "assignment from incompatible pointer type", which is related to
2189   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2190   # in GDB, while babeltrace 1.0.3 is broken.
2191   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2192   # safe to save and restore CFLAGS here.
2193   saved_CFLAGS=$CFLAGS
2194   CFLAGS="$CFLAGS -Werror"
2195   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2196                         [#include <babeltrace/babeltrace.h>
2197                          #include <babeltrace/ctf/events.h>
2198                          #include <babeltrace/ctf/iterator.h>],
2199                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2200                         struct bt_ctf_event *event = NULL;
2201                         const struct bt_definition *scope;
2202
2203                         pos->type = BT_SEEK_BEGIN;
2204                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2205                         scope = bt_ctf_get_top_level_scope (event,
2206                                                            BT_STREAM_EVENT_HEADER);
2207                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2208                         ])
2209   CFLAGS=$saved_CFLAGS
2210
2211   if test "$HAVE_LIBBABELTRACE" != yes; then
2212      if test "$with_babeltrace" = yes; then
2213        AC_MSG_ERROR([babeltrace is missing or unusable])
2214      else
2215        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2216      fi
2217   fi
2218 fi
2219
2220 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2221 # empty version.
2222
2223 files=
2224 links=
2225
2226 rm -f nm.h
2227 if test "${nativefile}" != ""; then
2228     case "${nativefile}" in
2229       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2230       * ) GDB_NM_FILE="${nativefile}"
2231     esac
2232     files="${files} ${GDB_NM_FILE}"
2233     links="${links} nm.h"
2234     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2235 fi
2236 AC_SUBST(GDB_NM_FILE)
2237
2238 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2239 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2240 if test "x$USE_MAINTAINER_MODE" = xyes; then
2241   if test "${XSLTPROC}" = missing; then
2242     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2243   fi
2244 fi
2245 AC_SUBST(XSLTPROC)
2246
2247 AC_LINK_FILES($files, $links)
2248
2249 dnl Check for exe extension set on certain hosts (e.g. Win32)
2250 AC_EXEEXT
2251
2252 dnl  Detect the character set used by this host.
2253 dnl  At the moment, we just assume it's UTF-8.
2254 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2255           [Define to be a string naming the default host character set.])
2256
2257 GDB_AC_SELFTEST([
2258   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) gdbsupport/selftest.o selftest-arch.o"
2259   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) gdbsupport/selftest.c selftest-arch.c"
2260 ])
2261
2262 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2263 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2264 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2265 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2266
2267 AC_OUTPUT