gdb/testsuite/configure.in

   1 dnl Process this file file with autoconf to produce a configure script.
   2 dnl This file is a shell script fragment that supplies the information
   3 dnl necessary to tailor a template configure script into the configure
   4 dnl script appropriate for this directory.  For more information, check
   5 dnl any existing configure script.
   6
   7 AC_PREREQ(2.12.1)
   8 AC_INIT(gdb.base)
   9
  10 CC=${CC-cc}
  11 AC_SUBST(CC)
  12 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/../..)
  13 AC_CANONICAL_SYSTEM
  14
  15 # Directories to use in all configurations.
  16 configdirs="gdb.asm gdb.base gdb.c++ gdb.disasm gdb.chill gdb.threads gdb.trace"
  17
  18 # Directories to use for a configuration which uses stabs.
  19 stabsdirs="gdb.stabs"
  20
  21         # this section is for targets that use stabs
  22 # add stabs tests for appropriate targets
  23 case "${target}" in
  24         powerpc-*-aix*) configdirs="${configdirs} ${stabsdirs}" ;;
  25         rs6000-*-aix*)  configdirs="${configdirs} ${stabsdirs}" ;;
  26         *-*-bsd*)       configdirs="${configdirs} ${stabsdirs}" ;;
  27         *-*-go32*)      configdirs="${configdirs} ${stabsdirs}" ;;
  28         *-*-linux*)     configdirs="${configdirs} ${stabsdirs}" ;;
  29         *-*-lynxos*)    configdirs="${configdirs} ${stabsdirs}" ;;
  30         *-sun-*)        configdirs="${configdirs} ${stabsdirs}" ;;
  31         hppa*-*-*)      configdirs="${configdirs} ${stabsdirs}" ;;
  32         *-*-elf*)       configdirs="${configdirs} ${stabsdirs}" ;;
  33         *)              if test "x${with_stabs}" = x"yes" ; then
  34                           configdirs="${configdirs} ${stabsdirs}"
  35                         fi ;;
  36 esac
  37
  38 # Directory with HP specific tests. They will run only with HP's compilers.
  39 # These tests will not work on other platforms and compilers.
  40
  41 hpdir="gdb.hp"
  42
  43 case "${target}" in
  44  hppa*-*-hpux*) configdirs="${configdirs} ${hpdir}" ;;
  45 esac
  46
  47
  48 # Begin stuff to support --enable-shared
  49 AC_ARG_ENABLE(shared,
  50 [  --enable-shared         use shared libraries],
  51 [case "${enableval}" in
  52   yes) shared=true ;;
  53   no)  shared=false ;;
  54   *) shared=true ;;
  55 esac])dnl
  56 RPATH_ENVVAR=LD_LIBRARY_PATH
  57 # If we have shared libraries, try to set RPATH_ENVVAR reasonably.
  58 if test "${shared}" = "true"; then
  59   case "${host}" in
  60   *-*-hpux*)
  61     RPATH_ENVVAR=SHLIB_PATH
  62     ;;
  63   esac
  64 fi
  65 AC_SUBST(RPATH_ENVVAR)
  66 # End stuff to support --enable-shared
  67
  68 # configure the subdirectories too
  69 AC_CONFIG_SUBDIRS($configdirs)
  70
  71 dnl AC_SUBST(gdb_target_cpu)
  72 AC_OUTPUT(Makefile)