gdb/testsuite/gdb.asm/asm-source.exp

   1 # Copyright 1998-2024 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15 #
  16 # This file was written by Kendra.
  17
  18 #
  19 # Test debugging assembly level programs.
  20 # This file uses asmsrc[12].s for input.
  21 #
  22
  23
  24 set asm-arch ""
  25 set asm-note "empty"
  26 set asm-flags ""
  27 set link-flags "-e _start"
  28 set debug-flags ""
  29
  30 set obj_include -I[host_standard_output_file {}]
  31
  32 switch -glob -- [istarget] {
  33     "alpha*-*-*" {
  34         set asm-arch alpha
  35         # ??? Won't work with ecoff systems like Tru64, but then we also
  36         # don't have any other -g flag that creates mdebug output.
  37         set asm-flags "-no-mdebug -I${srcdir}/${subdir} $obj_include"
  38         set debug-flags "-gdwarf-2"
  39     }
  40     "arm*-*-*" {
  41         set asm-arch arm
  42     }
  43     "aarch64*-*-*" {
  44         set asm-arch aarch64
  45     }
  46     "bfin-*-*" {
  47         set asm-arch bfin
  48     }
  49     "frv-*-*" {
  50         set asm-arch frv
  51     }
  52     "s390-*-*" {
  53         set asm-arch s390
  54     }
  55     "s390x-*-*" {
  56         set asm-arch s390x
  57     }
  58     "x86_64-*-*" {
  59         set asm-arch x86_64
  60         set debug-flags "-gdwarf-2"
  61     }
  62     "i\[3456\]86-*-*" {
  63         set asm-arch i386
  64     }
  65     "lm32-*" {
  66         set asm-arch lm32
  67     }
  68     "m32r*-linux*" {
  69         set asm-arch m32r-linux
  70     }
  71     "m32c-*-*" {
  72         set asm-arch m32c
  73     }
  74     "m32r*-*" {
  75         set asm-arch m32r
  76         append link-flags "--whole-archive -lgloss --no-whole-archive"
  77     }
  78     "m6811-*-*" {
  79         set asm-arch m68hc11
  80         set asm-flags "-mshort-double -m68hc11 --no-warn -I${srcdir}/${subdir} $obj_include"
  81         set debug-flags "-gdwarf-2"
  82         # This asm test is specific and uses the linker directly.
  83         # We must not use the target board linker script defined for other
  84         # tests.  Remove it and restore it later on.
  85         set board [target_info name]
  86         set old_ldscript [board_info $board ldscript]
  87         unset_board_info "ldscript"
  88     }
  89     "m6812-*-*" {
  90         set asm-arch m68hc11
  91         set asm-flags "-mshort-double -m68hc12 --no-warn -I${srcdir}/${subdir} $obj_include"
  92         set debug-flags "-gdwarf-2"
  93         # This asm test is specific and uses the linker directly.
  94         # We must not use the target board linker script defined for other
  95         # tests.  Remove it and restore it later on.
  96         set board [target_info name]
  97         set old_ldscript [board_info $board ldscript]
  98         set_board_info ldscript ""
  99     }
 100     "mips*-*" {
 101         set asm-arch mips
 102     }
 103     "powerpc64le-*" {
 104         set asm-arch powerpc64le
 105         set asm-flags "-a64 -I${srcdir}/${subdir} $obj_include"
 106         append link-flags " -m elf64lppc"
 107     }
 108     "powerpc*-*" {
 109         if { [is_lp64_target] } {
 110             set asm-arch powerpc64
 111             set asm-flags "-a64 -I${srcdir}/${subdir} $obj_include"
 112             append link-flags " -m elf64ppc"
 113         } else {
 114             set asm-arch powerpc
 115             set asm-flags "-a32 -I${srcdir}/${subdir} $obj_include"
 116             append link-flags " -m elf32ppc"
 117         }
 118     }
 119     "sh*-*-*" {
 120         set asm-arch sh
 121         set debug-flags "-gdwarf-2"
 122     }
 123     "sparc-*-*" {
 124         set asm-arch sparc
 125     }
 126     "sparc64-*-*" {
 127         set asm-arch sparc64
 128         set asm-flags "-xarch=v9 -I${srcdir}/${subdir} $obj_include"
 129         set debug-flags "-gdwarf-2"
 130     }
 131     "xstormy16-*-*" {
 132         set asm-arch xstormy16
 133         set debug-flags "-gdwarf-2"
 134     }
 135     "v850-*-*" {
 136         set asm-arch v850
 137         set gdb_wrapper_initialized 1
 138     }
 139     "m68k-*-*" {
 140         set asm-arch m68k
 141     }
 142     "ia64-*-*" {
 143         set asm-arch ia64
 144         set debug-flags "-gdwarf-2"
 145     }
 146     "iq2000-*-*" {
 147         set asm-arch iq2000
 148     }
 149     "hppa*-linux-*" {
 150         set asm-arch pa
 151         set debug-flags "-gdwarf-2"
 152     }
 153     "hppa-*-openbsd*" {
 154         set asm-arch pa
 155         set debug-flags "-gdwarf-2"
 156     }
 157     "h83*-*" {
 158         set asm-arch h8300
 159         set debug-flags "-gdwarf-2"
 160     }
 161 }
 162
 163 if { "${asm-arch}" == "" } {
 164     untested "skipping tests due to no asm architecture"
 165     return -1
 166 }
 167
 168 # On NetBSD/ELF we need a special NetBSD-identifying note section.
 169 if {[istarget "*-*-netbsd*"] && ![istarget "*-*-netbsdaout*"]} {
 170     set asm-note "netbsd"
 171 }
 172
 173 # On OpenBSD/ELF we need a similar note section.  We make no attempt
 174 # of handing a.out here since most OpenBSD/a.out systems use a rather
 175 # outdated assembler that doesn't assemble this test's code anyway.
 176 if {[istarget "*-*-openbsd*"]} {
 177     set asm-note "openbsd"
 178 }
 179
 180 # Watch out, we are invoking the assembler, but the testsuite sets multilib
 181 # switches according to compiler syntax.  If we pass these options straight
 182 # to the assembler, they won't always make sense.  If we don't pass them to
 183 # the assembler, the final link will complain that the object files were
 184 # built with different defaults.  So no matter what we do, we lose.  We may as
 185 # well get out of this test sooner rather than later.
 186 set dest [target_info name]
 187 if [board_info $dest exists multilib_flags] {
 188         set multilib_flags [board_info $dest multilib_flags]
 189         if { "${multilib_flags}" != "" } {
 190            untested "failed to compile"
 191            return -1
 192            return
 193          }
 194 }
 195
 196 standard_testfile asmsrc1.s asmsrc2.s
 197
 198 set arch_inc [standard_output_file arch.inc]
 199 set note_inc [standard_output_file note.inc]
 200
 201 remote_exec build "rm -f $arch_inc"
 202 remote_download build ${srcdir}/${subdir}/${asm-arch}.inc $arch_inc
 203 remote_exec build "rm -f $note_inc"
 204 remote_download build ${srcdir}/${subdir}/${asm-note}.inc $note_inc
 205
 206 gdb_remote_download host $arch_inc
 207 gdb_remote_download host $note_inc
 208 gdb_remote_download host ${srcdir}/${subdir}/common.inc
 209
 210 if { [string equal ${asm-flags} ""] } {
 211     set asm-flags "$obj_include"
 212 }
 213
 214 if { [string equal ${debug-flags} ""] } {
 215     set debug-flags "-g"
 216 }
 217
 218 # Allow the target board to override the debug flags.
 219 if {[board_info $dest exists debug_flags]} {
 220     set debug-flags "[board_info $dest debug_flags]"
 221 }
 222
 223 # The debug flags are in the format that gcc expects:
 224 # "-gdwarf-2", "-gstabs+", or "-gstabs".  To be compatible with the
 225 # other languages in the test suite, we accept this input format.
 226 # So the user can run the test suite with:
 227 #
 228 #   runtest --target_board unix/gdb:debug_flags=-gdwarf-2
 229 #   make check RUNTESTFLAGS="--target_board unix/gdb:debug_flags=-gdwarf-2"
 230 #
 231 # However, the GNU assembler has different spellings than gcc.
 232 # So I adjust the debug flags here.
 233
 234 # The GNU assembler spells "dwarf-2" as "dwarf2".
 235 regsub "--" "-gdwarf-2" "${debug-flags}" "-gdwarf2" debug-flags
 236
 237 # The GNU assembler before 2.15 did not support "stabs+".
 238 regsub "--" "-gstabs\[+\]" "${debug-flags}" "-gstabs" debug-flags
 239
 240 # The GNU assembler does not support level options like "-g2" or "-g3".
 241 regsub "--" "-g\[0-9\]" "${debug-flags}" "" debug-flags
 242
 243 set asm1obj [standard_output_file asmrc1.o]
 244 set asm2obj [standard_output_file asmrc2.o]
 245
 246 if {[target_assemble ${srcdir}/${subdir}/${srcfile} $asm1obj "${asm-flags} ${debug-flags}"] != ""} {
 247      untested "failed to assemble"
 248      return -1
 249 }
 250 if {[target_assemble ${srcdir}/${subdir}/${srcfile2} $asm2obj "${asm-flags} ${debug-flags}"] != ""} {
 251      untested "failed to assemble"
 252      return -1
 253 }
 254
 255 # We deliberately don't use gdb_compile here to link together the
 256 # assembled object files.  Using gdb_compile, and therefore the C
 257 # compiler, is conceptually wrong, since we're testing raw assembler
 258 # code here that provides its own startup code.  Using target_link
 259 # also avoids a lot of problems on many systems, most notably on
 260 # *-*-*bsd* and *-*-solaris2*.
 261 if {[target_link [list $asm1obj $asm2obj] "${binfile}" ${link-flags}] != ""} {
 262      untested "failed to link"
 263      return -1
 264 }
 265
 266 # Restore the target board linker script for HC11/HC12.
 267 if { [istarget "m6811-*-*"] || [istarget "m6812-*-*"] } {
 268     set_board_info ldscript $old_ldscript
 269 }
 270
 271 # Collect some line numbers.
 272 set line_enter      [expr [gdb_get_line_number "main enter" "asmsrc1.s"] + 1]
 273 set line_main       [expr [gdb_get_line_number "main start" "asmsrc1.s"] + 1]
 274 set line_call_foo2  [expr [gdb_get_line_number "call foo2"  "asmsrc1.s"] + 1]
 275 set line_search_comment [expr [gdb_get_line_number "search" "asmsrc1.s"] + 1]
 276 set line_foo3       [expr [gdb_get_line_number "foo3 start" "asmsrc1.s"] + 1]
 277 set line_main_exit  [expr [gdb_get_line_number "main exit"  "asmsrc1.s"] + 1]
 278 set line_foo2       [expr [gdb_get_line_number "foo2 start" "asmsrc2.s"] + 1]
 279 set line_call_foo3  [expr [gdb_get_line_number "call foo3"  "asmsrc2.s"] + 1]
 280 set line_call_foo3_again [expr $line_call_foo3 + 1]
 281 set line_foo2_leave [expr [gdb_get_line_number "foo2 leave" "asmsrc2.s"] + 1]
 282
 283 gdb_start
 284 gdb_reinitialize_dir $srcdir/$subdir
 285 gdb_load ${binfile}
 286
 287 #
 288 # Run to `main' where we begin our tests.
 289 #
 290
 291 if {![runto_main]} {
 292     return 0
 293 }
 294
 295 # Execute the `f' command and see if the result includes source info.
 296 gdb_test "f" "asmsrc1\[.\]s:$line_enter.*gdbasm_enter" "f at main"
 297
 298 # Execute the `n' command.
 299 gdb_test "n" "$line_main\[      \]*.*several_nops" "n at main"
 300
 301 # See if we properly `next' over a macro with several insns.
 302 gdb_test "n" "$line_call_foo2\[         \]*.*foo2" "next over macro"
 303
 304 # See if we can properly `step' into a subroutine call.
 305 gdb_test "s" "$line_foo2\[      \]*.*" "step into foo2"
 306
 307 # Test 'info target', and incidentally capture the entry point address.
 308 set entry_point 0
 309 gdb_test_multiple "info target" "info target" {
 310     -re "Symbols from .*asm-source.*Entry point: 0x(\[01232456789abcdefABCDEF\]+).*$gdb_prompt $" {
 311         set entry_point $expect_out(1,string)
 312         pass "info target"
 313     }
 314 }
 315
 316 # Capture the start symbol (may be '_start' or 'start')
 317 set entry_symbol ""
 318 gdb_test_multiple "info symbol 0x$entry_point" "info symbol" {
 319     -re "info symbol 0x$entry_point\[\r\n\]+(\[^\r\n\]*) in section .*$gdb_prompt $" {
 320         # We match the echoed `info symbol' command here, to help us
 321         # reliably identify the beginning of the start symbol in the
 322         # command's output.  You might think we could just use '^' to
 323         # start matching at the beginning of the line, but
 324         # unfortunately, in Expect, '^' matches the beginning of the
 325         # input that hasn't been matched by any expect clause yet.  If
 326         # every expect clause consumes a complete line, along with its
 327         # terminating CR/LF, this is equivalent to the beginning of a
 328         # line.  But expect clauses that end with `.*' will consume as
 329         # much as happened to arrive from the TTY --- exactly where
 330         # they leave you depends on inter-process timing.  :(
 331         set entry_symbol $expect_out(1,string)
 332         pass "info symbol"
 333     }
 334 }
 335
 336 # Now try a 'list' from the other source file.
 337 gdb_test "list $entry_symbol" ".*gdbasm_startup.*" "list"
 338
 339 # Now try a source file search
 340 gdb_test "search A routine for foo2 to call" \
 341         "$line_search_comment\[ \t\]+comment \"A routine for foo2 to call.\"" "search"
 342
 343 # See if `f' prints the right source file.
 344 gdb_test "f" ".*asmsrc2\[.\]s:$line_foo2.*" "f in foo2"
 345
 346 # `next' one insn (or macro) to set up our stackframe (for the following bt).
 347 gdb_test "n" "$line_call_foo3\[         \]*.*foo3" "n in foo2"
 348
 349 # See if a simple `bt' prints the right source files and
 350 # doesn't fall off the stack.
 351
 352 gdb_test "bt 10" \
 353         "\#0.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#1.*main.*asmsrc1\[.\]s:$line_call_foo2" \
 354         "bt ALL in foo2"
 355
 356 # See if a capped `bt' prints the right source files.
 357 gdb_test "bt 2" "\#0.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#1.*main.*asmsrc1\[.\]s:$line_call_foo2.*" "bt 2 in foo2"
 358
 359 # Step into another subroutine which lives back in the first source file.
 360 gdb_test "s" ".*" "s 2"
 361
 362 # Next over insns to set up the stack frame.
 363 gdb_test "n" ".*" "n 2"
 364
 365 # Now see if a capped `bt' is correct.
 366 gdb_test "bt 3" "\#0.*foo3.*asmsrc1\[.\]s:$line_foo3.*\#1.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#2.*main.*asmsrc1\[.\]s:$line_call_foo2.*" "bt 3 in foo3"
 367
 368 # Try 'info source' from asmsrc1.s
 369 gdb_test "info source" \
 370         "Current source file is .*asmsrc1.s.*Source language is asm.*" \
 371         "info source asmsrc1.s"
 372
 373 # Try 'finishing' from foo3
 374 # Some architectures will have one or more instructions after the
 375 # call instruction which still is part of the call sequence, so we
 376 # must be prepared for a "finish" to show us the caller line
 377 # again as well as the statement after.
 378 gdb_test_multiple "finish" "finish from foo3" {
 379     -re "Run till exit from.*\[\r\n\]$line_call_foo3\[ \t\]+gdbasm_call foo3.*$gdb_prompt $" {
 380         pass "finish from foo3"
 381         gdb_test "s" ".*" "s after finish"
 382     }
 383     -re "Run till exit from.*\[\r\n\]$line_call_foo3_again\[ \t\]+gdbasm_call foo3.*$gdb_prompt $" {
 384         pass "finish from foo3"
 385     }
 386 }
 387
 388 # Try 'info source' from asmsrc2.s
 389 gdb_test "info source" \
 390         "Current source file is .*asmsrc2.s.*Source language is asm.*" \
 391         "info source asmsrc2.s"
 392
 393 # Try 'info sources'.  This can produce a lot of output on systems
 394 # with dynamic linking, where the system's shared libc was compiled
 395 # with debugging info; for example, on Linux, this produces 47kb of
 396 # output.  So we consume it as we go.
 397 set seen_asmsrc_1 0
 398 set seen_asmsrc_2 0
 399 gdb_test_multiple "info sources" "info sources" {
 400     -re "^\[^,\]*asmsrc1.s(, |\[\r\n\]+)" {
 401         set seen_asmsrc_1 1
 402         exp_continue
 403     }
 404     -re "^\[^,\]*asmsrc2.s(, |\[\r\n\]+)" {
 405         set seen_asmsrc_2 1
 406         exp_continue
 407     }
 408     -re ", " {
 409         exp_continue
 410     }
 411     -re "$gdb_prompt $" {
 412         if {$seen_asmsrc_1 && $seen_asmsrc_2} {
 413             pass "info sources"
 414         } else {
 415             fail "info sources"
 416         }
 417     }
 418 }
 419
 420
 421 # Try 'info line'
 422 gdb_test "info line" \
 423         "Line $line_call_foo3_again of.*asmsrc2.s.*starts at.*<\\.?foo2+.*> and ends at.*<\\.?foo2+.*>."
 424
 425 # Try 'nexting' over next call to foo3
 426 gdb_test "next" "$line_foo2_leave\[ \t\]+gdbasm_leave" "next over foo3"
 427
 428 # Try 'return' from foo2
 429 # Like "finish", "return" command also can return to the caller
 430 # line again or the statement after, depending on the architecture.
 431 gdb_test_multiple "return" "return from foo2" {
 432     -re "Make (foo2|selected stack frame) return now\\? .y or n. " {
 433         send_gdb "y\n"
 434         exp_continue
 435     }
 436     -re "\#0.*main .*$line_call_foo2\[ \t\]+gdbasm_call foo2.*$gdb_prompt $" {
 437         pass "return from foo2"
 438         gdb_test "s" ".*" "s after return"
 439     }
 440     -re "\#0.*main .*$line_main_exit\[ \t\]+gdbasm_exit0.*$gdb_prompt $" {
 441         pass "return from foo2"
 442     }
 443 }
 444
 445 # Disassemble something, check the output
 446 proc test_dis { command var } {
 447     global gdb_prompt
 448     gdb_test_multiple "${command}" "${command}" {
 449         -re "${var}.*:.*(Cannot access|Bad address)" {
 450             # The "disassembler" was only accessing the local
 451             # executable and that would cause attempts to disassemble
 452             # variables to fail (memory not valid).
 453             fail "${command} (memory read error)"
 454         }
 455         -re "${var}.*:.*${gdb_prompt}" {
 456             pass "${command}"
 457         }
 458     }
 459 }
 460
 461 # See if we can look at a global variable, three ways
 462 gdb_test "print (int) globalvar" ".* = 11" "look at global variable"
 463 test_dis "x/i &globalvar" "globalvar"
 464 test_dis "disassem &globalvar, (int *) &globalvar+1" "globalvar"
 465
 466 # See if we can look at a static variable, three ways
 467 gdb_test "print (int) staticvar" ".* = 5" "look at static variable"
 468 test_dis "x/i &staticvar" "staticvar"
 469 test_dis "disassem &staticvar, (int *) &staticvar+1" "staticvar"
 470
 471 # See if we can look at a static function
 472 gdb_test "disassem foostatic" ".*<\\+0>:.*End of assembler dump." \
 473         "look at static function"
 474
 475 remote_exec build "rm -f $arch_inc"
 476 remote_exec build "rm -f $note_inc"