gdb/testsuite/gdb.dwarf2/implptr-64bit.exp

   1 # Copyright 2011-2023 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15 load_lib dwarf.exp
  16
  17 # This test can only be run on targets which support DWARF-2 and use gas.
  18 require dwarf2_support
  19
  20 standard_testfile main.c
  21
  22 proc test_1 { name dwarf_version offset_size addr_size ref_addr_size two_cu } {
  23     global testfile srcfile
  24
  25     # Make some DWARF for the test.
  26     set asm_file [standard_output_file ${testfile}-${name}.S]
  27     Dwarf::assemble $asm_file {
  28         upvar dwarf_version dwarf_version
  29         upvar addr_size addr_size
  30         upvar offset_size offset_size
  31         upvar ref_addr_size ref_addr_size
  32         upvar two_cu two_cu
  33
  34         set is_64 [expr { $offset_size == 4 ? 0 : 1 }]
  35
  36         cu {
  37             version $dwarf_version
  38             addr_size $addr_size
  39             is_64 $is_64
  40         } {
  41             compile_unit {
  42                 { producer "GNU C 4.4.3" }
  43                 { language @DW_LANG_C89 }
  44                 { name 1.c }
  45             } {
  46                 declare_labels struct_label variable_label int_label pointer_label
  47
  48                 int_label: base_type {
  49                     { byte_size 4 DW_FORM_sdata }
  50                     { DW_AT_encoding @DW_ATE_signed }
  51                     { name int }
  52                 }
  53
  54                 struct_label: structure_type {
  55                     { name s }
  56                     { byte_size 4 sdata }
  57                 } {
  58                     member {
  59                         { name f }
  60                         { type :$int_label }
  61                         { data_member_location 0 data1 }
  62                     }
  63                 }
  64
  65                 pointer_label: pointer_type {
  66                     { byte_size $Dwarf::_cu_addr_size sdata }
  67                     { type  :$struct_label }
  68                 }
  69
  70                 variable_label: DW_TAG_variable {
  71                     { name v }
  72                     { location {
  73                         DW_OP_implicit_value 0x1 0x1 0x1 0x1
  74                     } SPECIAL_expr}
  75                     { type :$struct_label "DW_FORM_ref$ref_addr_size" }
  76                 }
  77
  78                 if { !$two_cu } {
  79                     subprogram {
  80                         {MACRO_AT_func {main}}
  81                         { type :$int_label }
  82                         { external 1 flag }
  83                     } {
  84                         DW_TAG_variable {
  85                             { name p }
  86                             { location {
  87                                 GNU_implicit_pointer $variable_label 0
  88                             } SPECIAL_expr }
  89                             { type :$pointer_label "DW_FORM_ref$ref_addr_size" }
  90                         }
  91                     }
  92                 }
  93             }
  94         }
  95
  96         if { $two_cu } {
  97             cu {
  98                 version $dwarf_version
  99                 addr_size $addr_size
 100                 is_64 $is_64
 101             } {
 102                 compile_unit {
 103                     { producer "GNU C 4.4.3" }
 104                     { language @DW_LANG_C89 }
 105                     { name 1.c }
 106                 } {
 107                     subprogram {
 108                         { MACRO_AT_func {main} }
 109                         { type %$int_label }
 110                         { external 1 flag }
 111                     } {
 112                         DW_TAG_variable {
 113                             { name p }
 114                             { location {
 115                                 GNU_implicit_pointer $variable_label 0
 116                             } SPECIAL_expr }
 117                             { type %$pointer_label }
 118                         }
 119                     }
 120                 }
 121             }
 122         }
 123     }
 124
 125     # 32-bit targets do not support any of the testcases; keep quiet there.
 126     set opts {quiet}
 127     set executable ${testfile}-${name}
 128     if [prepare_for_testing "failed to prepare" $executable "${asm_file} ${srcfile}" $opts] {
 129         return -1
 130     }
 131
 132     if ![runto_main] {
 133         return -1
 134     }
 135
 136     gdb_test "p/x p->f" " = 0x1010101"
 137 }
 138
 139 proc test { dwarf_version offset_size addr_size ref_addr_size two_cu } {
 140
 141     set name \
 142         [list \
 143              "d${dwarf_version}" \
 144              "o${offset_size}" \
 145              "a${addr_size}" \
 146              "r${ref_addr_size}" \
 147              "t${two_cu}"]
 148     set name [join $name "-"]
 149     with_test_prefix $name {
 150         test_1 $name \
 151             $dwarf_version $offset_size $addr_size $ref_addr_size $two_cu
 152     }
 153 }
 154
 155 #    DWARF_VERSION OFFSET_SIZE ADDR_SIZE REF_ADDR_SIZE TWO_CU
 156 test 2 8 4 4 0
 157 test 2 4 8 8 0
 158 test 3 8 4 8 0
 159 test 3 4 8 4 0
 160 test 2 8 4 4 1
 161 test 2 4 8 8 1
 162 test 3 8 4 8 1
 163 test 3 4 8 4 1