gdb/testsuite/gdb.dwarf2/implref-struct.exp

   1 # Copyright 2016-2023 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Test a C++ reference marked with DW_OP_GNU_implicit_pointer.
  17 # The referenced value is a global struct whose location is a DW_OP_addr.
  18
  19 if [skip_cplus_tests] {
  20     return
  21 }
  22
  23 load_lib dwarf.exp
  24
  25 # This test can only be run on targets which support DWARF-2 and use gas.
  26 if ![dwarf2_support] {
  27     return 0
  28 }
  29
  30 # We'll place the output of Dwarf::assemble in implref-struct.S.
  31 standard_testfile .c .S
  32
  33 # ${testfile} is now "implref-struct".  srcfile2 is "implref-struct.S".
  34 set executable ${testfile}
  35 set asm_file [standard_output_file ${srcfile2}]
  36
  37 # We need to know the size of integer and address types in order
  38 # to write some of the debugging info we'd like to generate.
  39 #
  40 # For that, we ask GDB by debugging our implref-struct program.
  41 # Any program would do, but since we already have implref-struct
  42 # specifically for this testcase, might as well use that.
  43 if [prepare_for_testing "failed to prepare" ${testfile} ${srcfile} {debug c++}] {
  44     return -1
  45 }
  46
  47 # Create the DWARF.  We need a regular variable for the struct and a reference
  48 # to it that'll be marked with DW_OP_GNU_implicit_pointer. The variable must be
  49 # global so that its name is an exported symbol that can we can reference from
  50 # the DWARF using gdb_target_symbol.
  51 Dwarf::assemble ${asm_file} {
  52     cu {} {
  53         DW_TAG_compile_unit {
  54             {DW_AT_language @DW_LANG_C_plus_plus}
  55         } {
  56             declare_labels int_label struct_label variable_label ref_label
  57             set int_size [get_sizeof "int" -1]
  58
  59             # gdb always assumes references are implemented as pointers.
  60             set addr_size [get_sizeof "void *" -1]
  61             set S_size [get_sizeof "S" -1]
  62
  63             # The compiler shouldn't introduce structure padding here.
  64             set b_offset 4
  65             set c_offset 8
  66
  67             int_label: DW_TAG_base_type {
  68                 {DW_AT_byte_size ${int_size} DW_FORM_udata}
  69                 {DW_AT_encoding @DW_ATE_signed}
  70                 {DW_AT_name "int"}
  71             }
  72
  73             struct_label: DW_TAG_structure_type {
  74                 {DW_AT_name "S"}
  75                 {DW_AT_byte_size ${S_size} DW_FORM_udata}
  76             } {
  77                 DW_TAG_member {
  78                     {DW_AT_name "a"}
  79                     {DW_AT_type :${int_label}}
  80                     {DW_AT_data_member_location 0 DW_FORM_udata}
  81                 }
  82
  83                 DW_TAG_member {
  84                     {DW_AT_name "b"}
  85                     {DW_AT_type :${int_label}}
  86                     {DW_AT_data_member_location ${b_offset} DW_FORM_udata}
  87                 }
  88
  89                 DW_TAG_member {
  90                     {DW_AT_name "c"}
  91                     {DW_AT_type :${int_label}}
  92                     {DW_AT_data_member_location ${c_offset} DW_FORM_udata}
  93                 }
  94             }
  95
  96             ref_label: DW_TAG_reference_type {
  97                 {DW_AT_byte_size ${addr_size} DW_FORM_udata}
  98                 {DW_AT_type :${struct_label}}
  99             }
 100
 101             variable_label: DW_TAG_variable {
 102                 {DW_AT_name "s1"}
 103                 {DW_AT_type :${struct_label}}
 104                 {DW_AT_external 1 DW_FORM_flag}
 105                 {DW_AT_location {DW_OP_addr [gdb_target_symbol "s1"]} SPECIAL_expr}
 106             }
 107
 108             DW_TAG_variable {
 109                 {DW_AT_name "s2"}
 110                 {DW_AT_type :${struct_label}}
 111                 {DW_AT_external 1 DW_FORM_flag}
 112                 {DW_AT_location {DW_OP_addr [gdb_target_symbol "s2"]} SPECIAL_expr}
 113             }
 114
 115             DW_TAG_subprogram {
 116                 {MACRO_AT_func { "main" }}
 117                 {DW_AT_type :${int_label}}
 118                 {DW_AT_external 1 DW_FORM_flag}
 119             } {
 120                 DW_TAG_variable {
 121                     {DW_AT_name "ref"}
 122                     {DW_AT_type :${ref_label}}
 123                     {DW_AT_location {DW_OP_GNU_implicit_pointer ${variable_label} 0} SPECIAL_expr}
 124                 }
 125             }
 126         }
 127     }
 128 }
 129
 130 if [prepare_for_testing "failed to prepare" ${executable} [list ${asm_file} ${srcfile}] {}] {
 131     return -1
 132 }
 133
 134 # DW_OP_GNU_implicit_pointer implementation requires a valid frame.
 135 if ![runto_main] {
 136     return -1
 137 }
 138
 139 # Returns the struct members, e.g. '{a = 0, b = 1, c = 2}'.
 140 proc get_members {var} {
 141     set members [get_valueof "" ${var} ""]
 142
 143     # Trim leading/trailing whitespace, '{' and '}' since they confuse TCL to no end.
 144     set members [string trim ${members}]
 145     set members [string trim ${members} "{}"]
 146
 147     return ${members}
 148 }
 149
 150 # Values of the struct members.
 151 set s1_members [get_members "s1"]
 152 set s2_members [get_members "s2"]
 153
 154 # Address of the referenced value.
 155 set address [get_hexadecimal_valueof "&s1" ""]
 156
 157 # Test printing with both 'set print object off' and 'on', just to make sure
 158 # the output doesn't change.
 159 foreach_with_prefix print-object {"off" "on"} {
 160     gdb_test_no_output "set print object ${print-object}"
 161
 162     # Doing 'print ref' should show us e.g.
 163     # '(S &) @0xdeadbeef: {a = 0, b = 1, c = 2}'.
 164     gdb_test "print ref" " = \\(S &\\) @${address}: \\{${s1_members}\\}"
 165
 166     # Doing 'print &ref' should show us e.g. '(S *) 0xdeadbeef <s1>'.
 167     gdb_test "print &ref" " = \\(S \\*\\) ${address} <s1>"
 168
 169     # gdb assumes C++ references are implemented as pointers, and
 170     # print &(&ref) shows us the underlying pointer's address.
 171     # Since in this case there's no physical pointer, gdb should tell us so.
 172     gdb_test "print &(&ref)" "Attempt to take address of value not located in memory."
 173 }
 174
 175 # Test assignment through the synthetic reference.
 176 gdb_test_no_output "set (ref = s2)"
 177
 178 with_test_prefix "after assignment" {
 179     foreach_with_prefix print-object {"off" "on"} {
 180         gdb_test_no_output "set print object ${print-object}"
 181
 182         gdb_test "print ref" " = \\(S &\\) @${address}: \\{${s2_members}\\}" "print ref"
 183         gdb_test "print s1" " = \\{${s2_members}\\}" "print s1"
 184     }
 185 }