gdb/testsuite/lib/gdbserver-support.exp

   1 # Copyright 2000-2015 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # This file is based on config/gdbserver.exp, which was written by
  17 # Michael Snyder (msnyder@redhat.com).
  18
  19 #
  20 # To be addressed or set in your baseboard config file:
  21 #
  22 #   set_board_info gdb_protocol "remote"
  23 #       Unles you have a gdbserver that uses a different protocol...
  24 #       After GDB starts you should check global $gdbserver_protocol instead as
  25 #       the testfile may force a specific different target protocol itself.
  26 #
  27 #   set_board_info gdb_server_prog
  28 #       This will be the path to the gdbserver program you want to test.
  29 #       Defaults to "gdbserver".
  30 #
  31 #   set_board_info sockethost
  32 #       The name of the host computer whose socket is being used.
  33 #       Defaults to "localhost".  Note: old gdbserver requires
  34 #       that you define this, but libremote/gdbserver does not.
  35 #
  36 #   set_board_info gdb,socketport
  37 #       Port id to use for socket connection.  If not set explicitly,
  38 #       it will start at "2345" and increment for each use.
  39 #       After GDB starts you should check global $gdbserver_gdbport for the
  40 #       real port used.  It is not useful if $gdbserver_reconnect_p was not set.
  41 #
  42
  43 #
  44 # gdb_target_cmd
  45 # Send gdb the "target" command
  46 #
  47 proc gdb_target_cmd { targetname serialport } {
  48     global gdb_prompt
  49
  50     set serialport_re [string_to_regexp $serialport]
  51     for {set i 1} {$i <= 3} {incr i} {
  52         send_gdb "target $targetname $serialport\n"
  53         gdb_expect 60 {
  54             -re "A program is being debugged already.*ill it.*y or n. $" {
  55                 send_gdb "y\n"
  56                 exp_continue
  57             }
  58             -re "unknown host.*$gdb_prompt" {
  59                 verbose "Couldn't look up $serialport"
  60             }
  61             -re "Couldn't establish connection to remote.*$gdb_prompt $" {
  62                 verbose "Connection failed"
  63             }
  64             -re "Remote MIPS debugging.*$gdb_prompt" {
  65                 verbose "Set target to $targetname"
  66                 return 0
  67             }
  68             -re "Remote debugging using .*$serialport_re.*$gdb_prompt $" {
  69                 verbose "Set target to $targetname"
  70                 return 0
  71             }
  72             -re "Remote debugging using stdio.*$gdb_prompt $" {
  73                 verbose "Set target to $targetname"
  74                 return 0
  75             }
  76             -re "Remote target $targetname connected to.*$gdb_prompt $" {
  77                 verbose "Set target to $targetname"
  78                 return 0
  79             }
  80             -re "Connected to.*$gdb_prompt $" {
  81                 verbose "Set target to $targetname"
  82                 return 0
  83             }
  84             -re "Ending remote.*$gdb_prompt $" { }
  85             -re "Connection refused.*$gdb_prompt $" {
  86                 verbose "Connection refused by remote target.  Pausing, and trying again."
  87                 sleep 30
  88                 continue
  89             }
  90             -re "Timeout reading from remote system.*$gdb_prompt $" {
  91                 verbose "Got timeout error from gdb."
  92             }
  93             -notransfer -re "Remote debugging using .*\r\n> $" {
  94                 # We got an unexpected prompt while creating the target.
  95                 # Leave it there for the test to diagnose.
  96                 return 1
  97             }
  98             timeout {
  99                 send_gdb "\ 3"
 100                 break
 101             }
 102         }
 103     }
 104     return 1
 105 }
 106
 107
 108 global portnum
 109 set portnum "2345"
 110
 111 # Locate the gdbserver binary.  Returns "" if gdbserver could not be found.
 112
 113 proc find_gdbserver { } {
 114   global GDB
 115   global GDBSERVER
 116
 117   if [info exists GDBSERVER] {
 118     return ${GDBSERVER}
 119   }
 120
 121   if [target_info exists gdb_server_prog] {
 122     return [target_info gdb_server_prog]
 123   }
 124
 125   set gdbserver "${GDB}server"
 126   if { [file isdirectory $gdbserver] } {
 127     append gdbserver "/gdbserver"
 128   }
 129
 130   if { [file executable $gdbserver] } {
 131     return $gdbserver
 132   }
 133
 134   return ""
 135 }
 136
 137 # Return non-zero if we should skip gdbserver-specific tests.
 138
 139 proc skip_gdbserver_tests { } {
 140   if { [find_gdbserver] == "" } {
 141     return 1
 142   }
 143
 144   return 0
 145 }
 146
 147 # Download the currently loaded program to the target if necessary.
 148 # Return the target system filename.
 149 # NOTE: This was named "gdbserver_download", but that collides with the
 150 # dejagnu "download" API function when using load_generic_config "gdbserver".
 151
 152 proc gdbserver_download_current_prog { } {
 153     global gdbserver_host_exec
 154     global gdbserver_host_mtime
 155     global gdbserver_server_exec
 156     global last_loaded_file
 157
 158     set host_exec $last_loaded_file
 159
 160     # If we already downloaded a file to the target, see if we can reuse it.
 161     set reuse 0
 162     if { [info exists gdbserver_server_exec] } {
 163         set reuse 1
 164
 165         # If the file has changed, we can not.
 166         if { $host_exec != $gdbserver_host_exec } {
 167             set reuse 0
 168         }
 169
 170         # If the mtime has changed, we can not.
 171         if { [file mtime $host_exec] != $gdbserver_host_mtime } {
 172             set reuse 0
 173         }
 174     }
 175
 176     if { $reuse == 0 } {
 177         set gdbserver_host_exec $host_exec
 178         set gdbserver_host_mtime [file mtime $host_exec]
 179         if [is_remote target] {
 180             set gdbserver_server_exec [gdb_download $host_exec]
 181         } else {
 182             set gdbserver_server_exec $host_exec
 183         }
 184     }
 185
 186     return $gdbserver_server_exec
 187 }
 188
 189 # Default routine to compute the argument to "target remote".
 190
 191 proc gdbserver_default_get_remote_address { host port } {
 192     # Historically HOST included the trailing ":".
 193     # To avoid breaking any board files out there we leave things alone.
 194     return "$host$port"
 195 }
 196
 197 # Default routine to compute the "comm" argument for gdbserver.
 198
 199 proc gdbserver_default_get_comm_port { port } {
 200     return ":$port"
 201 }
 202
 203 # Start a gdbserver process with initial OPTIONS and trailing ARGUMENTS.
 204 # The port will be filled in between them automatically.
 205 #
 206 # Returns the target protocol and socket to connect to.
 207
 208 proc gdbserver_start { options arguments } {
 209     global portnum
 210
 211     # Port id -- either specified in baseboard file, or managed here.
 212     if [target_info exists gdb,socketport] {
 213         set portnum [target_info gdb,socketport]
 214     } else {
 215         # Bump the port number to avoid conflicts with hung ports.
 216         incr portnum
 217     }
 218
 219     # Extract the local and remote host ids from the target board struct.
 220     if [target_info exists sockethost] {
 221         set debughost [target_info sockethost]
 222     } else {
 223         set debughost "localhost:"
 224     }
 225
 226     # Some boards use a different value for the port that is passed to
 227     # gdbserver and the port that is passed to the "target remote" command.
 228     # One example is the stdio gdbserver support.
 229     if [target_info exists gdb,get_remote_address] {
 230         set get_remote_address [target_info gdb,get_remote_address]
 231     } else {
 232         set get_remote_address gdbserver_default_get_remote_address
 233     }
 234     if [target_info exists gdbserver,get_comm_port] {
 235         set get_comm_port [target_info gdbserver,get_comm_port]
 236     } else {
 237         set get_comm_port gdbserver_default_get_comm_port
 238     }
 239
 240     # Extract the protocol
 241     if [target_info exists gdb_protocol] {
 242         set protocol [target_info gdb_protocol]
 243     } else {
 244         set protocol "remote"
 245     }
 246
 247     set gdbserver [find_gdbserver]
 248
 249     # Loop till we find a free port.
 250     while 1 {
 251         # Fire off the debug agent.
 252         set gdbserver_command "$gdbserver"
 253
 254         # If gdbserver_reconnect will be called $gdbserver_reconnect_p must be
 255         # set to true already during gdbserver_start.
 256         global gdbserver_reconnect_p
 257         if {![info exists gdbserver_reconnect_p] || !$gdbserver_reconnect_p} {
 258             # GDB client could accidentally connect to a stale server.
 259             # append gdbserver_command " --debug --once"
 260             append gdbserver_command " --once"
 261         }
 262
 263         if { $options != "" } {
 264             append gdbserver_command " $options"
 265         }
 266         if { $portnum != "" } {
 267             append gdbserver_command " [$get_comm_port $portnum]"
 268         }
 269         if { $arguments != "" } {
 270             append gdbserver_command " $arguments"
 271         }
 272
 273         global server_spawn_id
 274         set server_spawn_id [remote_spawn target $gdbserver_command]
 275
 276         # Wait for the server to open its TCP socket, so that GDB can connect.
 277         expect {
 278             -i $server_spawn_id
 279             -timeout 120
 280             -notransfer
 281             -re "Listening on" { }
 282             -re "Can't bind address: Address already in use\\.\r\n" {
 283                 verbose -log "Port $portnum is already in use."
 284                 if ![target_info exists gdb,socketport] {
 285                     # Bump the port number to avoid the conflict.
 286                     wait -i $expect_out(spawn_id)
 287                     incr portnum
 288                     continue
 289                 }
 290             }
 291             timeout {
 292                 error "Timeout waiting for gdbserver response."
 293             }
 294         }
 295         break
 296     }
 297
 298     return [list $protocol [$get_remote_address $debughost $portnum]]
 299 }
 300
 301 # Start a gdbserver process running SERVER_EXEC, and connect GDB
 302 # to it.  CHILD_ARGS are passed to the inferior.
 303 #
 304 # Returns the target protocol and socket to connect to.
 305
 306 proc gdbserver_spawn { child_args } {
 307     set target_exec [gdbserver_download_current_prog]
 308
 309     # Fire off the debug agent.  This flavour of gdbserver takes as
 310     # arguments the port information, the name of the executable file to
 311     # be debugged, and any arguments.
 312     set arguments "$target_exec"
 313     if { $child_args != "" } {
 314         append arguments " $child_args"
 315     }
 316     return [gdbserver_start "" $arguments]
 317 }
 318
 319 # Close the GDBserver connection.
 320
 321 proc close_gdbserver {} {
 322     global server_spawn_id
 323
 324     # We can't just call close, because if gdbserver is local then that means
 325     # that it will get a SIGHUP.  Doing it this way could also allow us to
 326     # get at the inferior's input or output if necessary, and means that we
 327     # don't need to redirect output.
 328
 329     if {![info exists server_spawn_id]} {
 330         return
 331     }
 332
 333     verbose "Quitting GDBserver"
 334
 335     catch "close -i $server_spawn_id"
 336     catch "wait -i $server_spawn_id"
 337     unset server_spawn_id
 338 }
 339
 340 # Hook into GDB exit, and close GDBserver.
 341
 342 if { [info procs gdbserver_gdb_exit] == "" } {
 343     rename gdb_exit gdbserver_orig_gdb_exit
 344 }
 345 proc gdb_exit {} {
 346     global gdb_spawn_id server_spawn_id
 347     global gdb_prompt
 348
 349     if {[info exists gdb_spawn_id] && [info exists server_spawn_id]} {
 350         send_gdb "monitor exit\n";
 351         gdb_expect {
 352             -re "$gdb_prompt $" {
 353                 exp_continue
 354             }
 355             -i "$server_spawn_id" eof {
 356                 wait -i $expect_out(spawn_id)
 357                 unset server_spawn_id
 358             }
 359         }
 360     }
 361     close_gdbserver
 362
 363     gdbserver_orig_gdb_exit
 364 }
 365
 366 # Start a gdbserver process running HOST_EXEC and pass CHILD_ARGS
 367 # to it.  Return 0 on success, or non-zero on failure: 2 if gdbserver
 368 # failed to start or 1 if we couldn't connect to it.
 369
 370 proc gdbserver_run { child_args } {
 371     global gdbserver_protocol
 372     global gdbserver_gdbport
 373
 374     # Kill anything running before we try to start gdbserver, in case
 375     # we are sharing a serial connection.
 376     global gdb_prompt
 377     send_gdb "kill\n"
 378     gdb_expect 120 {
 379         -re "Kill the program being debugged. .y or n. $" {
 380             send_gdb "y\n"
 381             verbose "\t\tKilling previous program being debugged"
 382             exp_continue
 383         }
 384         -re "$gdb_prompt $" {
 385             # OK.
 386         }
 387     }
 388
 389     if { [catch { gdbserver_spawn $child_args } res] == 1 } {
 390         perror $res
 391         return 2
 392     }
 393     set gdbserver_protocol [lindex $res 0]
 394     set gdbserver_gdbport [lindex $res 1]
 395
 396     return [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
 397 }
 398
 399 # Reconnect to the previous gdbserver session.
 400
 401 proc gdbserver_reconnect { } {
 402     global gdbserver_protocol
 403     global gdbserver_gdbport
 404
 405     global gdbserver_reconnect_p
 406     if {![info exists gdbserver_reconnect_p] || !$gdbserver_reconnect_p} {
 407         error "gdbserver_reconnect_p is not set before gdbserver_reconnect"
 408         return 0
 409     }
 410
 411     return [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
 412 }
 413
 414 # Start and connect to a gdbserver in extended mode.  Note this frobs
 415 # $gdbserver_protocol, so should be used only from a board that
 416 # usually connects in target remote mode.
 417 proc gdbserver_start_extended { } {
 418     global gdbserver_protocol
 419     global gdbserver_gdbport
 420     global use_gdb_stub
 421
 422     if { [catch { gdbserver_start "--multi" "" } res] == 1 } {
 423         perror $res
 424         return 2
 425     }
 426     set gdbserver_protocol [lindex $res 0]
 427     if { [string first "extended-" $gdbserver_protocol] != 0} {
 428         set gdbserver_protocol "extended-$gdbserver_protocol"
 429     }
 430     set gdbserver_gdbport [lindex $res 1]
 431
 432     # Even if the board file is testing with target remote, our caller
 433     # wants to test against gdbserver in extended-remote mode.  Make sure to
 434     # disable stub-like techniques.
 435     set use_gdb_stub 0
 436
 437     return [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
 438 }
 439
 440 # Start and connect to a gdbserver in extended/multi mode.  Unlike
 441 # gdbserver_start_extended, this does not frob $gdbserver_protocol.
 442
 443 proc gdbserver_start_multi { } {
 444     global gdbserver_protocol
 445     global gdbserver_gdbport
 446
 447     if { [catch { gdbserver_start "--multi" "" } res] == 1 } {
 448         perror $res
 449         return 2
 450     }
 451     set gdbserver_protocol [lindex $res 0]
 452     set gdbserver_gdbport [lindex $res 1]
 453
 454     return [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
 455 }
 456
 457 # Start a gdbserver process in multi/extended mode, and have GDB
 458 # connect to it (MI version).  Return 0 on success, or non-zero on
 459 # failure.
 460
 461 proc mi_gdbserver_start_multi { } {
 462     global gdbserver_protocol
 463     global gdbserver_gdbport
 464
 465     if { [catch { gdbserver_start "--multi" "" } res] == 1 } {
 466         perror $res
 467         return 2
 468     }
 469     set gdbserver_protocol [lindex $res 0]
 470     set gdbserver_gdbport [lindex $res 1]
 471
 472     return [mi_gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
 473 }