libctf/configure.ac

   1 dnl                                            -*- Autoconf -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3 dnl
   4 dnl   Copyright (C) 2019-2020 Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; see the file COPYING.  If not see
  18 dnl <http://www.gnu.org/licenses/>.
  19 dnl
  20
  21 AC_PREREQ(2.64)
  22 AC_INIT([libctf library], 1.2.0-pre)
  23 AC_CONFIG_SRCDIR(ctf-impl.h)
  24 AC_CONFIG_MACRO_DIR(../config)
  25 AC_CONFIG_MACRO_DIR(../bfd)
  26 AC_USE_SYSTEM_EXTENSIONS
  27 AM_INIT_AUTOMAKE
  28
  29 # Checks for programs.
  30 AC_PROG_MAKE_SET
  31 AC_PROG_CC
  32 AC_PROG_RANLIB
  33 AM_PROG_AR
  34
  35 dnl Default to a non shared library.  This may be overridden by the
  36 dnl configure option --enable-shared.
  37 AC_DISABLE_SHARED
  38
  39 LT_INIT
  40 AC_SYS_LARGEFILE
  41
  42 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  43 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  44 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  45 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  46
  47 # Figure out what compiler warnings we can enable.
  48 # See config/warnings.m4 for details.
  49
  50 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wno-narrowing -Wwrite-strings \
  51                           -Wmissing-format-attribute], [warn])
  52 ACX_PROG_CC_WARNING_OPTS([-Wstrict-prototypes -Wmissing-prototypes \
  53                           -Wold-style-definition], [c_warn])
  54 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  55
  56 # Only enable with --enable-werror-always until existing warnings are
  57 # corrected.
  58 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  59
  60 AM_MAINTAINER_MODE
  61 AM_INSTALL_LIBBFD
  62 ACX_PROG_CC_WARNING_OPTS([-Wall], [ac_libctf_warn_cflags])
  63
  64 AC_FUNC_MMAP
  65 # Needed for BFD capability checks.
  66 AC_SEARCH_LIBS(dlopen, dl)
  67 AM_ZLIB
  68
  69 # Similar to GDB_AC_CHECK_BFD.
  70 OLD_CFLAGS=$CFLAGS
  71 OLD_LDFLAGS=$LDFLAGS
  72 OLD_LIBS=$LIBS
  73 # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
  74 # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
  75 # always want our bfd.
  76 CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
  77 ZLIBDIR=`echo $zlibdir | sed 's,\$(top_builddir)/,,g'`
  78 LDFLAGS="-L../bfd -L../libiberty $ZLIBDIR $LDFLAGS"
  79 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
  80 LIBS="-lbfd -liberty -lz $intl $LIBS"
  81 AC_CACHE_CHECK([for ELF support in BFD], ac_cv_libctf_bfd_elf,
  82 [AC_TRY_LINK([#include <stdlib.h>
  83              #include "bfd.h"
  84              #include "elf-bfd.h"],
  85             [(void) bfd_section_from_elf_index (NULL, 0);
  86              return 0;],
  87             [ac_cv_libctf_bfd_elf=yes],
  88             [ac_cv_libctf_bfd_elf=no])])
  89 CFLAGS=$OLD_CFLAGS
  90 LDFLAGS=$OLD_LDFLAGS
  91 LIBS=$OLD_LIBS
  92
  93 if test $ac_cv_libctf_bfd_elf = yes; then
  94   AC_DEFINE([HAVE_BFD_ELF], 1,
  95             [Whether libbfd was configured for an ELF target.])
  96 fi
  97
  98 AC_C_BIGENDIAN
  99 AC_CHECK_HEADERS(byteswap.h endian.h)
 100 AC_CHECK_FUNCS(pread)
 101
 102 AC_CHECK_DECLS([asprintf])
 103 dnl Check for bswap_{16,32,64}
 104 AC_CHECK_DECLS([bswap_16, bswap_32, bswap_64], [], [], [[#include <byteswap.h>]])
 105
 106 dnl Check for qsort_r.  (Taken from gnulib.)
 107 AC_CHECK_FUNCS_ONCE([qsort_r])
 108 if test $ac_cv_func_qsort_r = yes; then
 109   AC_CACHE_CHECK([for qsort_r signature], [ac_cv_libctf_qsort_r_signature],
 110     [AC_LINK_IFELSE(
 111        [AC_LANG_PROGRAM([[#undef qsort_r
 112                           #include <stdlib.h>
 113                           void qsort_r (void *, size_t, size_t,
 114                                         int (*) (void const *, void const *,
 115                                                  void *),
 116                                         void *);
 117                           void (*p) (void *, size_t, size_t,
 118                                      int (*) (void const *, void const *,
 119                                               void *),
 120                                      void *) = qsort_r;
 121                         ]])],
 122        [ac_cv_libctf_qsort_r_signature=GNU],
 123        [AC_LINK_IFELSE(
 124           [AC_LANG_PROGRAM([[#undef qsort_r
 125                              #include <stdlib.h>
 126                              void qsort_r (void *, size_t, size_t, void *,
 127                                            int (*) (void *,
 128                                                     void const *,
 129                                                     void const *));
 130                              void (*p) (void *, size_t, size_t, void *,
 131                                         int (*) (void *, void const *,
 132                                                  void const *)) = qsort_r;
 133                            ]])],
 134           [ac_cv_libctf_qsort_r_signature=BSD],
 135           [ac_cv_libctf_qsort_r_signature=unknown])])])
 136 fi
 137
 138 case x$ac_cv_libctf_qsort_r_signature in
 139   xGNU)     AC_DEFINE([HAVE_QSORT_R_ARG_LAST], 1,
 140              [Whether a qsort_r exists with a void *arg as its last arg.]);;
 141   xBSD)     AC_DEFINE([HAVE_QSORT_R_COMPAR_LAST], 1,
 142              [Whether a qsort_r exists with the compar function as its last arg.]);;
 143   *) ac_cv_libctf_qsort_r_signature=unknown;;
 144 esac
 145
 146 AM_CONDITIONAL(NEED_CTF_QSORT_R, test "${ac_cv_libctf_qsort_r_signature}" = unknown)
 147
 148 AC_CACHE_CHECK([for O_CLOEXEC], [ac_cv_libctf_macro_O_CLOEXEC],
 149   [AC_LINK_IFELSE(
 150     [AC_LANG_PROGRAM([[#include <fcntl.h>
 151                        #ifndef O_CLOEXEC
 152                          choke me;
 153                        #endif
 154                      ]],
 155                      [[return O_CLOEXEC;]])],
 156     [ac_cv_libctf_macro_O_CLOEXEC=yes],
 157     [ac_cv_libctf_macro_O_CLOEXEC=no])])
 158
 159 if test $ac_cv_libctf_macro_O_CLOEXEC = yes; then
 160   AC_DEFINE([HAVE_O_CLOEXEC], 1,
 161             [Whether the platform has a definition of O_CLOEXEC.])
 162 fi
 163
 164 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 165 SHARED_LIBADD=
 166 SHARED_LDFLAGS=
 167 BFD_LIBADD=
 168 BFD_DEPENDENCIES=
 169 if test "$enable_shared" = "yes"; then
 170 # When building a shared libctf, link against the pic version of libiberty
 171 # so that apps that use libctf won't need libiberty just to satisfy any
 172 # libctf references.
 173 # We can't do that if a pic libiberty is unavailable since including non-pic
 174 # code would insert text relocations into libctf.
 175 # Note that linking against libbfd as we do here, which is itself linked
 176 # against libiberty, may not satisfy all the libctf libiberty references
 177 # since libbfd may not pull in the entirety of libiberty.
 178 changequote(,)dnl
 179   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 180 changequote([,])dnl
 181   if test -n "$x"; then
 182     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 183   fi
 184
 185   case "${host}" in
 186   # More hacks to build DLLs on Windows.
 187     *-*-cygwin*)
 188       SHARED_LDFLAGS="-no-undefined"
 189       SHARED_LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 190       BFD_LIBADD="-L`pwd`/../bfd -lbfd"
 191       ;;
 192
 193     *-*-darwin*)
 194       BFD_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.dylib"
 195       BFD_DEPENDENCIES="../bfd/libbfd.la"
 196       ;;
 197     *)
 198       case "$host_vendor" in
 199         hp)
 200           BFD_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.sl"
 201           ;;
 202         *)
 203           BFD_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.so"
 204           ;;
 205       esac
 206       BFD_DEPENDENCIES="../bfd/libbfd.la"
 207       ;;
 208   esac
 209 fi
 210 AC_SUBST(SHARED_LDFLAGS)
 211 AC_SUBST(SHARED_LIBADD)
 212 AC_SUBST(BFD_LIBADD)
 213 AC_SUBST(BFD_DEPENDENCIES)
 214
 215 # Use a version script, if possible, or an -export-symbols-regex otherwise.
 216 VERSION_FLAGS='-export-symbols-regex ctf_.*'
 217 if $LD --help 2>&1 | grep -- --version-script >/dev/null; then
 218     VERSION_FLAGS="-Wl,--version-script='$srcdir/libctf.ver'"
 219 fi
 220 AC_SUBST(VERSION_FLAGS)
 221
 222 AC_CONFIG_FILES(Makefile)
 223 AC_CONFIG_HEADERS(config.h)
 224 AC_OUTPUT