sim/testsuite/lib/sim-defs.exp

   1 # Simulator dejagnu utilities.
   2
   3 # Communicate simulator path from sim_init to sim_version.
   4 # For some reason [board_info target sim] doesn't work in sim_version.
   5 # [Presumubly because the target has been "popped" by then.  Odd though.]
   6 set sim_path "unknown-run"
   7
   8 # Initialize the testrun.
   9 # Required by dejagnu.
  10
  11 proc sim_init { args } {
  12     global sim_path
  13     set sim_path [board_info target sim]
  14     # Need to return an empty string (copied from GAS).
  15     return ""
  16 }
  17
  18 # Print the version of the simulator being tested.
  19 # Required by dejagnu.
  20
  21 proc sim_version {} {
  22     global sim_path
  23     set version 0.5
  24     clone_output "$sim_path $version\n"
  25 }
  26
  27 # Cover function to target_compile.
  28 # Copied from gdb_compile.
  29
  30 proc sim_compile { source dest type options } {
  31     set result [target_compile $source $dest $type $options]
  32     regsub "\[\r\n\]*$" "$result" "" result
  33     regsub "^\[\r\n\]*" "$result" "" result
  34     if { $result != "" } {
  35         clone_output "sim compile output: $result"
  36     }
  37     return $result
  38 }
  39
  40 # Run a program on the simulator.
  41 # Required by dejagnu (at least ${tool}_run used to be).
  42 #
  43 # SIM_OPTS are options for the simulator.
  44 # PROG_OPTS are options passed to the simulated program.
  45 # At present REDIR must be "" or "> foo".
  46 # OPTIONS is a list of options internal to this routine.
  47 # This is modelled after target_compile.  We want to be able to add new
  48 # options without having to update all our users.
  49 # Currently:
  50 #       env(foo)=val    - set environment variable foo to val for this run
  51 #       timeout=val     - set the timeout to val for this run
  52 #
  53 # The result is a list of two elements.
  54 # The first is one of pass/fail/etc.
  55 # The second is the program's output.
  56 #
  57 # This is different than the sim_load routine provided by
  58 # dejagnu/config/sim.exp.  It's not clear how to pass arguments to the
  59 # simulator (not the simulated program, the simulator) with sim_load.
  60
  61 proc sim_run { prog sim_opts prog_opts redir options } {
  62     global SIMFLAGS
  63
  64     # Set the default value of the timeout.
  65     # FIXME: The timeout value we actually want is a function of
  66     # host, target, and testcase.
  67     set testcase_timeout [board_info target sim_time_limit]
  68     if { "$testcase_timeout" == "" } {
  69         set testcase_timeout [board_info host testcase_timeout]
  70     }
  71     if { "$testcase_timeout" == "" } {
  72         set testcase_timeout 240 ;# 240 same as in dejagnu/config/sim.exp.
  73     }
  74
  75     # Initial the environment we pass to the testcase.
  76     set testcase_env ""
  77
  78     # Process OPTIONS ...
  79     foreach o $options {
  80         if [regexp {^env\((.*)\)=(.*)} $o full var val] {
  81             set testcase_env "$testcase_env $var=$val"
  82         } elseif [regexp {^timeout=(.*)} $o full val] {
  83             set testcase_timeout $val
  84         }
  85
  86     }
  87
  88     verbose "testcase timeout is set to $testcase_timeout" 1
  89
  90     set sim [board_info target sim]
  91
  92     if [is_remote host] {
  93         set prog [remote_download host $prog]
  94         if { $prog == "" } {
  95             error "download failed"
  96             return -1;
  97         }
  98     }
  99
 100     set board [target_info name]
 101     if [board_info $board exists sim,options] {
 102         set always_opts [board_info $board sim,options]
 103     } else {
 104         set always_opts ""
 105     }
 106
 107     # FIXME: this works for UNIX only
 108     if { "$testcase_env" != "" } {
 109         set sim "env $testcase_env $sim"
 110     }
 111
 112     send_log "$sim $always_opts $SIMFLAGS $sim_opts $prog $prog_opts\n"
 113
 114     if { "$redir" == "" } {
 115         remote_spawn host "$sim $always_opts $SIMFLAGS $sim_opts $prog $prog_opts"
 116     } else {
 117         remote_spawn host "$sim $always_opts $SIMFLAGS $sim_opts $prog $prog_opts $redir" writeonly
 118     }
 119     set result [remote_wait host $testcase_timeout]
 120
 121     set return_code [lindex $result 0]
 122     set output [lindex $result 1]
 123     # Remove the \r part of "\r\n" so we don't break all the patterns
 124     # we want to match.
 125     regsub -all -- "\r" $output "" output
 126
 127     if [is_remote host] {
 128         # clean up after ourselves.
 129         remote_file host delete $prog
 130     }
 131
 132     # ??? Not sure the test for pass/fail is right.
 133     # We just care that the simulator ran correctly, not whether the simulated
 134     # program return 0 or non-zero from `main'.
 135     set status fail
 136     if { $return_code == 0 } {
 137         set status pass
 138     }
 139
 140     return [list $status $output]
 141 }
 142
 143 # Run testcase NAME.
 144 # NAME is either a fully specified file name, or just the file name in which
 145 # case $srcdir/$subdir will be prepended.
 146 # ALL_MACHS is a list of machs to use if "mach: all" is specified in the file.
 147 # The file can contain options in the form "# option(mach list): value"
 148 # Possibilities:
 149 # mach: [all | machine names]
 150 # as[(mach-list)]: <assembler options>
 151 # ld[(mach-list)]: <linker options>
 152 # sim[(mach-list)]: <simulator options>
 153 # output[(mach-list)]: program output pattern to match with string-match
 154 # xerror[(mach-list)]: program is expected to return with a "failure" exit code
 155 # If `output' is not specified, the program must output "pass" if !xerror or
 156 # "fail" if xerror.
 157 # The parens in "optname()" are optional if the specification is for all machs.
 158
 159 proc run_sim_test { name all_machs } {
 160     global subdir srcdir
 161     global AS ASFLAGS LD LDFLAGS SIMFLAGS
 162     global opts
 163
 164     if [string match "*/*" $name] {
 165         set file $name
 166         set name [file tail $name]
 167     } else {
 168         set file "$srcdir/$subdir/$name"
 169     }
 170
 171     set opt_array [slurp_options "${file}"]
 172     if { $opt_array == -1 } {
 173         unresolved $subdir/$name
 174         return
 175     }
 176     set opts(as) {}
 177     set opts(ld) {}
 178     set opts(sim) {}
 179     set opts(output) {}
 180     set opts(mach) {}
 181     set opts(timeout) {}
 182     set opts(xerror) "no"
 183
 184     foreach i $opt_array {
 185         set opt_name [lindex $i 0]
 186         set opt_machs [lindex $i 1]
 187         set opt_val [lindex $i 2]
 188         if ![info exists opts($opt_name)] {
 189             perror "unknown option $opt_name in file $file"
 190             unresolved $subdir/$name
 191             return
 192         }
 193         foreach m $opt_machs {
 194             set opts($opt_name,$m) $opt_val
 195         }
 196         if { "$opt_machs" == "" } {
 197             set opts($opt_name) $opt_val
 198         }
 199     }
 200
 201     set testname $name
 202     set sourcefile $file
 203     if { $opts(output) == "" } {
 204         if { "$opts(xerror)" == "no" } {
 205             set opts(output) "pass\n"
 206         } else {
 207             set opts(output) "fail\n"
 208         }
 209     }
 210     # Change \n sequences to newline chars.
 211     regsub -all "\\\\n" $opts(output) "\n" opts(output)
 212
 213     foreach mach $opts(mach) {
 214         verbose "Testing $name on $mach."
 215
 216         if ![info exists opts(as,$mach)] {
 217             set opts(as,$mach) $opts(as)
 218         }
 219         send_log "$AS $ASFLAGS $opts(as,$mach) -I$srcdir/$subdir -o ${name}.o $sourcefile\n"
 220         catch "exec $AS $ASFLAGS $opts(as,$mach) -I$srcdir/$subdir -o ${name}.o $sourcefile" comp_output
 221
 222         if ![string match "" $comp_output] {
 223             verbose -log "$comp_output" 3
 224             fail "$mach $testname"
 225             continue
 226         }
 227
 228         if ![info exists opts(ld,$mach)] {
 229             set opts(ld,$mach) $opts(ld)
 230         }
 231         send_log "$LD $LDFLAGS $opts(ld,$mach) -o ${name}.x ${name}.o\n"
 232         catch "exec $LD $LDFLAGS $opts(ld,$mach) -o ${name}.x ${name}.o" comp_output
 233
 234         if ![string match "" $comp_output] {
 235             verbose -log "$comp_output" 3
 236             fail "$mach $testname"
 237             continue
 238         }
 239
 240         # If no machine specific options, default to the general version.
 241         if ![info exists opts(sim,$mach)] {
 242             set opts(sim,$mach) $opts(sim)
 243         }
 244
 245         # Build the options argument.
 246         set options ""
 247         if { "$opts(timeout)" != "" } {
 248             set options "$options timeout=$opts(timeout)"
 249         }
 250
 251         set result [sim_run ${name}.x "$opts(sim,$mach)" "" "" "$options"]
 252         set status [lindex $result 0]
 253         set output [lindex $result 1]
 254
 255         if { "$status" == "pass" } {
 256             if { "$opts(xerror)" == "no" } {
 257                 if [string match $opts(output) $output] {
 258                     pass "$mach $testname"
 259                 } else {
 260                     verbose -log "output:  $output" 3
 261                     verbose -log "pattern: $opts(output)" 3
 262                     fail "$mach $testname"
 263                 }
 264             } else {
 265                 verbose -log "`pass' return code when expecting failure" 3
 266                 fail "$mach $testname"
 267             }
 268         } elseif { "$status" == "fail" } {
 269             if { "$opts(xerror)" == "no" } {
 270                 fail "$mach $testname"
 271             } else {
 272                 if [string match $opts(output) $output] {
 273                     pass "$mach $testname"
 274                 } else {
 275                     verbose -log "output:  $output" 3
 276                     verbose -log "pattern: $opts(output)" 3
 277                     fail "$mach $testname"
 278                 }
 279             }
 280         } else {
 281             $status "$mach $testname"
 282         }
 283     }
 284 }
 285
 286 # Subroutine of run_sim_test to process options in FILE.
 287
 288 proc slurp_options { file } {
 289     if [catch { set f [open $file r] } x] {
 290         #perror "couldn't open `$file': $x"
 291         perror "$x"
 292         return -1
 293     }
 294     set opt_array {}
 295     # whitespace expression
 296     set ws  {[  ]*}
 297     set nws {[^         ]*}
 298     # whitespace is ignored anywhere except within the options list;
 299     # option names are alphabetic only
 300     set pat "^#${ws}(\[a-zA-Z\]*)\\(?(\[^):\]*)\\)?$ws:${ws}(.*)$ws\$"
 301     # Allow comment as first line of file.
 302     set firstline 1
 303     while { [gets $f line] != -1 } {
 304         set line [string trim $line]
 305         # Whitespace here is space-tab.
 306         if [regexp $pat $line xxx opt_name opt_machs opt_val] {
 307             # match!
 308             lappend opt_array [list $opt_name $opt_machs $opt_val]
 309         } else {
 310             if { ! $firstline } {
 311                 break
 312             }
 313         }
 314         set firstline 0
 315     }
 316     close $f
 317     return $opt_array
 318 }