configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([kmod],
   3         [31],
   4         [linux-modules@vger.kernel.org],
   5         [kmod],
   6         [http://git.kernel.org/?p=utils/kernel/kmod/kmod.git])
   7
   8 AC_CONFIG_SRCDIR([libkmod/libkmod.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AC_CONFIG_HEADERS(config.h)
  11 AC_CONFIG_AUX_DIR([build-aux])
  12
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AC_SYS_LARGEFILE
  15 AC_PREFIX_DEFAULT([/usr])
  16 AM_MAINTAINER_MODE([enable])
  17 AM_INIT_AUTOMAKE([check-news foreign 1.11 silent-rules tar-pax no-dist-gzip dist-xz subdir-objects color-tests parallel-tests])
  18 AM_SILENT_RULES([yes])
  19 LT_INIT([disable-static pic-only])
  20
  21 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by kmod])])
  22 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by kmod])])
  23
  24 module_compressions=""
  25 module_signatures="legacy"
  26
  27 #####################################################################
  28 # Program checks and configurations
  29 #####################################################################
  30
  31 AC_PROG_SED
  32 AC_PROG_MKDIR_P
  33 AC_PROG_LN_S
  34 PKG_PROG_PKG_CONFIG
  35 AC_PATH_PROG([XSLTPROC], [xsltproc])
  36
  37 AC_PROG_CC_C99
  38
  39 #####################################################################
  40 # Function and structure checks
  41 #####################################################################
  42
  43 AC_CHECK_FUNCS_ONCE(__xstat)
  44 AC_CHECK_FUNCS_ONCE([__secure_getenv secure_getenv])
  45 AC_CHECK_FUNCS_ONCE([finit_module])
  46
  47 CC_CHECK_FUNC_BUILTIN([__builtin_clz])
  48 CC_CHECK_FUNC_BUILTIN([__builtin_types_compatible_p])
  49 CC_CHECK_FUNC_BUILTIN([__builtin_uaddl_overflow], [ ], [ ])
  50 CC_CHECK_FUNC_BUILTIN([__builtin_uaddll_overflow], [ ], [ ])
  51
  52 # dietlibc doesn't have st.st_mtim struct member
  53 AC_CHECK_MEMBERS([struct stat.st_mtim], [], [], [#include <sys/stat.h>])
  54
  55 # musl 1.0 and bionic 4.4 don't have strndupa
  56 AC_CHECK_DECLS_ONCE([strndupa])
  57
  58 # RHEL 5 and older do not have be32toh
  59 AC_CHECK_DECLS_ONCE([be32toh])
  60
  61 # Check kernel headers
  62 AC_CHECK_HEADERS_ONCE([linux/module.h])
  63
  64 AC_MSG_CHECKING([whether _Static_assert() is supported])
  65 AC_COMPILE_IFELSE(
  66         [AC_LANG_SOURCE([[_Static_assert(1, "Test");]])],
  67         [AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define if _Static_assert() is available])
  68          AC_MSG_RESULT([yes])],
  69         [AC_MSG_RESULT([no])])
  70
  71 AC_MSG_CHECKING([whether _Noreturn is supported])
  72 AC_COMPILE_IFELSE(
  73         [AC_LANG_SOURCE([[#include <stdlib.h>
  74         _Noreturn int foo(void) { exit(0); }]])],
  75         [AC_DEFINE([HAVE_NORETURN], [1], [Define if _Noreturn is available])
  76          AC_MSG_RESULT([yes])],
  77         [AC_MSG_RESULT([no])])
  78
  79
  80 #####################################################################
  81 # --with-
  82 #####################################################################
  83
  84 AC_ARG_WITH([distconfdir], AS_HELP_STRING([--with-distconfdir=DIR], [directory to search for distribution configuration files]),
  85         [], [with_distconfdir='${prefix}/lib'])
  86 AC_SUBST([distconfdir], [$with_distconfdir])
  87
  88 AC_ARG_WITH([rootlibdir],
  89         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
  90         [], [with_rootlibdir=$libdir])
  91 AC_SUBST([rootlibdir], [$with_rootlibdir])
  92
  93 # Ideally this would be $prefix/lib/modules but default to /lib/modules for compatibility with earlier versions
  94 AC_ARG_WITH([module_directory],
  95         AS_HELP_STRING([--with-module-directory=DIR], [directory in which to look for kernel modules @<:@default=/lib/modules@:>@]),
  96         [], [with_module_directory=/lib/modules])
  97 AC_SUBST([module_directory], [$with_module_directory])
  98
  99 # Check all directory arguments for consistency.
 100 for ac_var in   distconfdir rootlibdir module_directory
 101 do
 102   eval ac_val=\$$ac_var
 103   # Remove trailing slashes.
 104   case $ac_val in
 105     */ )
 106       ac_val=`expr "X$ac_val" : 'X\(.*@<:@^/@:>@\)' \| "X$ac_val" : 'X\(.*\)'`
 107       eval $ac_var=\$ac_val;;
 108   esac
 109   # Be sure to have absolute directory names.
 110   case $ac_val in
 111     @<:@\\/$@:>@* | ?:@<:@\\/@:>@* )  continue;;
 112   esac
 113   as_fn_error $? "expected an absolute directory name for --$ac_var: $ac_val"
 114 done
 115
 116 AC_ARG_WITH([zstd],
 117         AS_HELP_STRING([--with-zstd], [handle Zstandard-compressed modules @<:@default=disabled@:>@]),
 118         [], [with_zstd=no])
 119 AS_IF([test "x$with_zstd" != "xno"], [
 120         PKG_CHECK_MODULES([libzstd], [libzstd >= 1.4.4], [LIBS="$LIBS $libzstd_LIBS"])
 121         AC_DEFINE([ENABLE_ZSTD], [1], [Enable Zstandard for modules.])
 122         module_compressions="zstd $module_compressions"
 123 ], [
 124         AC_MSG_NOTICE([Zstandard support not requested])
 125 ])
 126 CC_FEATURE_APPEND([with_features], [with_zstd], [ZSTD])
 127
 128 AC_ARG_WITH([xz],
 129         AS_HELP_STRING([--with-xz], [handle Xz-compressed modules @<:@default=disabled@:>@]),
 130         [], [with_xz=no])
 131 AS_IF([test "x$with_xz" != "xno"], [
 132         PKG_CHECK_MODULES([liblzma], [liblzma >= 4.99], [LIBS="$LIBS $liblzma_LIBS"])
 133         AC_DEFINE([ENABLE_XZ], [1], [Enable Xz for modules.])
 134         module_compressions="xz $module_compressions"
 135 ], [
 136         AC_MSG_NOTICE([Xz support not requested])
 137 ])
 138 CC_FEATURE_APPEND([with_features], [with_xz], [XZ])
 139
 140 AC_ARG_WITH([zlib],
 141         AS_HELP_STRING([--with-zlib], [handle gzipped modules @<:@default=disabled@:>@]),
 142         [], [with_zlib=no])
 143 AS_IF([test "x$with_zlib" != "xno"], [
 144         PKG_CHECK_MODULES([zlib], [zlib], [LIBS="$LIBS $zlib_LIBS"])
 145         AC_DEFINE([ENABLE_ZLIB], [1], [Enable zlib for modules.])
 146         module_compressions="gzip $module_compressions"
 147 ], [
 148         AC_MSG_NOTICE([zlib support not requested])
 149 ])
 150 CC_FEATURE_APPEND([with_features], [with_zlib], [ZLIB])
 151
 152 AC_ARG_WITH([openssl],
 153         AS_HELP_STRING([--with-openssl], [handle PKCS7 signatures @<:@default=disabled@:>@]),
 154         [], [with_openssl=no])
 155 AS_IF([test "x$with_openssl" != "xno"], [
 156         PKG_CHECK_MODULES([libcrypto], [libcrypto >= 1.1.0], [LIBS="$LIBS $libcrypto_LIBS"])
 157         AC_DEFINE([ENABLE_OPENSSL], [1], [Enable openssl for modinfo.])
 158         module_signatures="PKCS7 $module_signatures"
 159 ], [
 160         AC_MSG_NOTICE([openssl support not requested])
 161 ])
 162 CC_FEATURE_APPEND([with_features], [with_openssl], [LIBCRYPTO])
 163
 164 AC_ARG_WITH([bashcompletiondir],
 165         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 166         [],
 167         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 168                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 169         ] , [
 170                 with_bashcompletiondir=${datadir}/bash-completion/completions
 171         ])])
 172 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 173
 174 #####################################################################
 175 # --enable-
 176 #####################################################################
 177
 178 AC_ARG_ENABLE([experimental],
 179         AS_HELP_STRING([--enable-experimental], [enable experimental tools and features. Do not enable it unless you know what you are doing. @<:@default=disabled@:>@]),
 180         [], enable_experimental=no)
 181 AM_CONDITIONAL([BUILD_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
 182 AS_IF([test "x$enable_experimental" = "xyes"], [
 183         AC_DEFINE(ENABLE_EXPERIMENTAL, [1], [Experimental features.])
 184 ])
 185 CC_FEATURE_APPEND([with_features], [enable_experimental], [EXPERIMENTAL])
 186
 187 AC_ARG_ENABLE([tools],
 188         AS_HELP_STRING([--disable-tools], [disable building tools that provide same functionality as module-init-tools @<:@default=enabled@:>@]),
 189         [], enable_tools=yes)
 190 AM_CONDITIONAL([BUILD_TOOLS], [test "x$enable_tools" = "xyes"])
 191
 192 AC_ARG_ENABLE([manpages],
 193         AS_HELP_STRING([--disable-manpages], [disable manpages @<:@default=enabled@:>@]),
 194         [], enable_manpages=yes)
 195 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" = "xyes"])
 196
 197 AC_ARG_ENABLE([test-modules],
 198         AS_HELP_STRING([--disable-test-modules], [disable building test modules during make check: cached modules will be used @<:@default=enabled@:>@]),
 199         [], enable_test_modules=yes)
 200 AM_CONDITIONAL([BUILD_MODULES], [test "x$enable_test_modules" = "xyes"])
 201
 202 AC_ARG_ENABLE([logging],
 203         AS_HELP_STRING([--disable-logging], [disable system logging @<:@default=enabled@:>@]),
 204         [], enable_logging=yes)
 205 AS_IF([test "x$enable_logging" = "xyes"], [
 206         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
 207 ])
 208
 209 AC_ARG_ENABLE([debug],
 210         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
 211         [], [enable_debug=no])
 212 AS_IF([test "x$enable_debug" = "xyes"], [
 213         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
 214 ])
 215
 216 AC_ARG_ENABLE([coverage],
 217         AS_HELP_STRING([--enable-coverage], [enable test coverage @<:@default=disabled@:>@]),
 218         [], [enable_coverage=no])
 219 AS_IF([test "x$enable_coverage" = "xyes"], [
 220         AC_CHECK_PROG(have_coverage, [lcov], [yes], [no])
 221         AS_IF([test "x$have_coverage" = xno],[
 222                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 223         ], [
 224                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 225                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 226                 AS_IF([test "$lcov_version_major" -lt 1 -o "$lcov_version_minor" -lt 10], [
 227                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 228                 ], [
 229                         have_coverage=yes
 230                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 231                         -fprofile-arcs \
 232                         -ftest-coverage])
 233                 ])
 234         ])
 235 ])
 236 AM_CONDITIONAL([ENABLE_COVERAGE], [test "x$enable_coverage" = "xyes"])
 237
 238 m4_ifdef([GTK_DOC_CHECK], [
 239 GTK_DOC_CHECK([1.14],[--flavour no-tmpl-flat])
 240 ], [
 241 AM_CONDITIONAL([ENABLE_GTK_DOC], false)])
 242
 243 #####################################################################
 244 # Default CFLAGS and LDFLAGS
 245 #####################################################################
 246
 247 CC_CHECK_FLAGS_APPEND(with_cflags, [CFLAGS], [\
 248                        -pipe \
 249                        -DANOTHER_BRICK_IN_THE \
 250                        -Wall \
 251                        -W \
 252                        -Wextra \
 253                        -Wno-inline \
 254                        -Wvla \
 255                        -Wundef \
 256                        -Wformat=2 \
 257                        -Wlogical-op \
 258                        -Wsign-compare \
 259                        -Wformat-security \
 260                        -Wmissing-include-dirs \
 261                        -Wformat-nonliteral \
 262                        -Wold-style-definition \
 263                        -Wpointer-arith \
 264                        -Winit-self \
 265                        -Wdeclaration-after-statement \
 266                        -Wfloat-equal \
 267                        -Wmissing-prototypes \
 268                        -Wstrict-prototypes \
 269                        -Wredundant-decls \
 270                        -Wmissing-declarations \
 271                        -Wmissing-noreturn \
 272                        -Wshadow \
 273                        -Wendif-labels \
 274                        -Wstrict-aliasing=3 \
 275                        -Wwrite-strings \
 276                        -Wno-long-long \
 277                        -Wno-overlength-strings \
 278                        -Wno-unused-parameter \
 279                        -Wno-missing-field-initializers \
 280                        -Wno-unused-result \
 281                        -Wnested-externs \
 282                        -Wchar-subscripts \
 283                        -Wtype-limits \
 284                        -Wuninitialized \
 285                        -fno-common \
 286                        -fdiagnostics-show-option \
 287                        -fvisibility=hidden \
 288                        -ffunction-sections \
 289                        -fdata-sections])
 290 AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 291
 292
 293 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [ \
 294                        -Wl,--as-needed \
 295                        -Wl,--no-undefined \
 296                        -Wl,--gc-sections])
 297 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 298
 299 AC_DEFINE_UNQUOTED(KMOD_FEATURES, ["$with_features"], [Features in this build])
 300
 301 #####################################################################
 302 # Generate files from *.in
 303 #####################################################################
 304
 305 AC_SUBST([module_compressions], $module_compressions)
 306 AC_SUBST([module_signatures], $module_signatures)
 307
 308 AC_CONFIG_FILES([
 309         Makefile
 310         man/Makefile
 311         libkmod/docs/Makefile
 312         libkmod/docs/version.xml
 313         libkmod/libkmod.pc
 314         tools/kmod.pc
 315 ])
 316
 317
 318 #####################################################################
 319
 320 AC_OUTPUT
 321 AC_MSG_RESULT([
 322         $PACKAGE $VERSION
 323         =======
 324
 325         module_directory:       ${module_directory}
 326         prefix:                 ${prefix}
 327         sysconfdir:             ${sysconfdir}
 328         distconfdir:            ${distconfdir}
 329         libdir:                 ${libdir}
 330         rootlibdir:             ${rootlibdir}
 331         includedir:             ${includedir}
 332         bindir:                 ${bindir}
 333         Bash completions dir:   ${with_bashcompletiondir}
 334
 335         compiler:               ${CC}
 336         cflags:                 ${with_cflags} ${CFLAGS}
 337         ldflags:                ${with_ldflags} ${LDFLAGS}
 338
 339         experimental features:  ${enable_experimental}
 340         tools:                  ${enable_tools}
 341         logging:                ${enable_logging}
 342         compression:            zstd=${with_zstd}  xz=${with_xz}  zlib=${with_zlib}
 343         debug:                  ${enable_debug}
 344         coverage:               ${enable_coverage}
 345         doc:                    ${enable_gtk_doc}
 346         man:                    ${enable_manpages}
 347         test-modules:           ${enable_test_modules}
 348
 349         features:               ${with_features}
 350 ])