Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-egd        do not compile support for the entropy-gathering daemon APIs
  63 # [no-]zlib     [don't] compile support for zlib compression.
  64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  65 #               library and will be loaded in run-time by the OpenSSL library.
  66 # sctp          include SCTP support
  67 # no-uplink     Don't build support for UPLINK interface.
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least
 104 # get past these.  Note that we only use these with C compilers, not with
 105 # C++ compilers.
 106
 107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 108 # -DPEDANTIC complements -pedantic and is meant to mask code that
 109 # is not strictly standard-compliant and/or implementation-specific,
 110 # e.g. inline assembly, disregards to alignment requirements, such
 111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 112 # to be used even in sanitized builds, because sanitizer too is
 113 # supposed to and does take notice of non-standard behaviour. Then
 114 # -pedantic with pre-C9x compiler would also complain about 'long
 115 # long' not being supported. As 64-bit algorithms are common now,
 116 # it grew impossible to resolve this without sizeable additional
 117 # code, so we just tell compiler to be pedantic about everything
 118 # but 'long long' type.
 119
 120 my @gcc_devteam_warn = qw(
 121     -DDEBUG_UNUSED
 122     -DPEDANTIC -pedantic -Wno-long-long
 123     -Wall
 124     -Wextra
 125     -Wno-unused-parameter
 126     -Wno-missing-field-initializers
 127     -Wswitch
 128     -Wsign-compare
 129     -Wshadow
 130     -Wformat
 131     -Wtype-limits
 132     -Wundef
 133     -Werror
 134     -Wmissing-prototypes
 135     -Wstrict-prototypes
 136 );
 137
 138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 139 # TODO(openssl-team): fix problems and investigate if (at least) the
 140 # following warnings can also be enabled:
 141 #       -Wcast-align
 142 #       -Wunreachable-code -- no, too ugly/compiler-specific
 143 #       -Wlanguage-extension-token -- no, we use asm()
 144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 146 my @clang_devteam_warn = qw(
 147     -Wswitch-default
 148     -Wno-parentheses-equality
 149     -Wno-language-extension-token
 150     -Wno-extended-offsetof
 151     -Wconditional-uninitialized
 152     -Wincompatible-pointer-types-discards-qualifiers
 153     -Wno-unknown-warning-option
 154     -Wmissing-variable-declarations
 155 );
 156
 157 # This adds backtrace information to the memory leak info.  Is only used
 158 # when crypto-mdebug-backtrace is enabled.
 159 my $memleak_devteam_backtrace = "-rdynamic";
 160
 161 my $strict_warnings = 0;
 162
 163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 164 # which would cover all BSD flavors. -pthread applies to them all,
 165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 167 # which has to be accompanied by explicit -D_THREAD_SAFE and
 168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 169 # seems to be sufficient?
 170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 171
 172 #
 173 # API compatibility name to version number mapping.
 174 #
 175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 176 my $apitable = {
 177     "3.0.0" => 3,
 178     "1.1.1" => 2,
 179     "1.1.0" => 2,
 180     "1.0.2" => 1,
 181     "1.0.1" => 1,
 182     "1.0.0" => 1,
 183     "0.9.8" => 0,
 184 };
 185
 186 our %table = ();
 187 our %config = ();
 188 our %withargs = ();
 189 our $now_printing;      # set to current entry's name in print_table_entry
 190                         # (todo: right thing would be to encapsulate name
 191                         # into %target [class] and make print_table_entry
 192                         # a method)
 193
 194 # Forward declarations ###############################################
 195
 196 # read_config(filename)
 197 #
 198 # Reads a configuration file and populates %table with the contents
 199 # (which the configuration file places in %targets).
 200 sub read_config;
 201
 202 # resolve_config(target)
 203 #
 204 # Resolves all the late evaluations, inheritances and so on for the
 205 # chosen target and any target it inherits from.
 206 sub resolve_config;
 207
 208
 209 # Information collection #############################################
 210
 211 # Unified build supports separate build dir
 212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 215
 216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 217
 218 $config{sourcedir} = abs2rel($srcdir);
 219 $config{builddir} = abs2rel($blddir);
 220
 221 # Collect reconfiguration information if needed
 222 my @argvcopy=@ARGV;
 223
 224 if (grep /^reconf(igure)?$/, @argvcopy) {
 225     die "reconfiguring with other arguments present isn't supported"
 226         if scalar @argvcopy > 1;
 227     if (-f "./configdata.pm") {
 228         my $file = "./configdata.pm";
 229         unless (my $return = do $file) {
 230             die "couldn't parse $file: $@" if $@;
 231             die "couldn't do $file: $!"    unless defined $return;
 232             die "couldn't run $file"       unless $return;
 233         }
 234
 235         @argvcopy = defined($configdata::config{perlargv}) ?
 236             @{$configdata::config{perlargv}} : ();
 237         die "Incorrect data to reconfigure, please do a normal configuration\n"
 238             if (grep(/^reconf/,@argvcopy));
 239         $config{perlenv} = $configdata::config{perlenv} // {};
 240     } else {
 241         die "Insufficient data to reconfigure, please do a normal configuration\n";
 242     }
 243 }
 244
 245 $config{perlargv} = [ @argvcopy ];
 246
 247 # Collect version numbers
 248 $config{major} = "unknown";
 249 $config{minor} = "unknown";
 250 $config{patch} = "unknown";
 251 $config{prerelease} = "";
 252 $config{build_metadata} = "";
 253 $config{shlib_version} = "unknown";
 254
 255 collect_information(
 256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 258         sub { $config{major} = $1; },
 259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 260         sub { $config{minor} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 262         sub { $config{patch} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 264         sub { $config{prerelease} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{build_metadata} = $1; },
 267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 268         sub { $config{shlib_version} = $1; },
 269     );
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 272     if ($config{major} eq "unknown"
 273             || $config{minor} eq "unknown"
 274             || $config{patch} eq "unknown"
 275             || $config{shlib_version} eq "unknown");
 276
 277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 279
 280 # Collect target configurations
 281
 282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 283 foreach (sort glob($pattern)) {
 284     &read_config($_);
 285 }
 286
 287 if (defined env($local_config_envname)) {
 288     if ($^O eq 'VMS') {
 289         # VMS environment variables are logical names,
 290         # which can be used as is
 291         $pattern = $local_config_envname . ':' . '*.conf';
 292     } else {
 293         $pattern = catfile(env($local_config_envname), '*.conf');
 294     }
 295
 296     foreach (sort glob($pattern)) {
 297         &read_config($_);
 298     }
 299 }
 300
 301 # Save away perl command information
 302 $config{perl_cmd} = $^X;
 303 $config{perl_version} = $Config{version};
 304 $config{perl_archname} = $Config{archname};
 305
 306 $config{prefix}="";
 307 $config{openssldir}="";
 308 $config{processor}="";
 309 $config{libdir}="";
 310 my $auto_threads=1;    # enable threads automatically? true by default
 311 my $default_ranlib;
 312
 313 # Known TLS and DTLS protocols
 314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 315 my @dtls = qw(dtls1 dtls1_2);
 316
 317 # Explicitly known options that are possible to disable.  They can
 318 # be regexps, and will be used like this: /^no-${option}$/
 319 # For developers: keep it sorted alphabetically
 320
 321 my @disablables = (
 322     "ktls",
 323     "afalgeng",
 324     "aria",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "autoload-config",
 331     "bf",
 332     "blake2",
 333     "buildtest-c++",
 334     "camellia",
 335     "capieng",
 336     "cast",
 337     "chacha",
 338     "cmac",
 339     "cmp",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dtls",
 352     "dynamic-engine",
 353     "ec",
 354     "ec2m",
 355     "ecdh",
 356     "ecdsa",
 357     "ec_nistp_64_gcc_128",
 358     "egd",
 359     "engine",
 360     "err",
 361     "external-tests",
 362     "filenames",
 363     "fips",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "idea",
 368     "legacy",
 369     "makedepend",
 370     "md2",
 371     "md4",
 372     "mdc2",
 373     "module",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "padlockeng",
 381     "pic",
 382     "poly1305",
 383     "posix-io",
 384     "psk",
 385     "rc2",
 386     "rc4",
 387     "rc5",
 388     "rdrand",
 389     "rfc3779",
 390     "rmd160",
 391     "scrypt",
 392     "sctp",
 393     "seed",
 394     "shared",
 395     "siphash",
 396     "siv",
 397     "sm2",
 398     "sm3",
 399     "sm4",
 400     "sock",
 401     "srp",
 402     "srtp",
 403     "sse2",
 404     "ssl",
 405     "ssl-trace",
 406     "static-engine",
 407     "stdio",
 408     "tests",
 409     "threads",
 410     "tls",
 411     "trace",
 412     "ts",
 413     "ubsan",
 414     "ui-console",
 415     "unit-test",
 416     "uplink",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 426         }
 427
 428 # Internal disablables, for aliasing purposes.  They serve no special
 429 # purpose here, but allow scripts to get to know them through configdata.pm,
 430 # where these are merged with @disablables.
 431 # The actual aliasing mechanism is done via %disable_cascades
 432 my @disablables_int = qw(
 433     crmf
 434     );
 435
 436 my %deprecated_disablables = (
 437     "ssl2" => undef,
 438     "buf-freelists" => undef,
 439     "hw" => "hw",               # causes cascade, but no macro
 440     "hw-padlock" => "padlockeng",
 441     "ripemd" => "rmd160",
 442     "ui" => "ui-console",
 443     "dso" => undef,
 444     "heartbeats" => undef,
 445     );
 446
 447 # All of the following are disabled by default:
 448
 449 our %disabled = ( # "what"         => "comment"
 450                   "asan"                => "default",
 451                   "buildtest-c++"       => "default",
 452                   "crypto-mdebug"       => "default",
 453                   "crypto-mdebug-backtrace" => "default",
 454                   "devcryptoeng"        => "default",
 455                   "ec_nistp_64_gcc_128" => "default",
 456                   "egd"                 => "default",
 457                   "external-tests"      => "default",
 458                   "fuzz-libfuzzer"      => "default",
 459                   "fuzz-afl"            => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "trace"               => "default",
 468                   "ubsan"               => "default",
 469                   "unit-test"           => "default",
 470                   "weak-ssl-ciphers"    => "default",
 471                   "zlib"                => "default",
 472                   "zlib-dynamic"        => "default",
 473                   "ktls"                => "default",
 474                 );
 475
 476 # Note: => pair form used for aesthetics, not to truly make a hash table
 477 my @disable_cascades = (
 478     # "what"            => [ "cascade", ... ]
 479     sub { $config{processor} eq "386" }
 480                         => [ "sse2" ],
 481     "ssl"               => [ "ssl3" ],
 482     "ssl3-method"       => [ "ssl3" ],
 483     "zlib"              => [ "zlib-dynamic" ],
 484     "des"               => [ "mdc2" ],
 485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 486     sub { $disabled{"ec"} && $disabled{"dh"} }
 487                         => [ "tls1_3" ],
 488     "dgram"             => [ "dtls", "sctp" ],
 489     "sock"              => [ "dgram" ],
 490     "dtls"              => [ @dtls ],
 491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 492                         => [ "dtls" ],
 493
 494     "tls"               => [ @tls ],
 495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 496                         => [ "tls" ],
 497
 498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 499
 500     # If no modules, then no dynamic engines either
 501     "module"            => [ "dynamic-engine" ],
 502
 503     # Without shared libraries, dynamic engines aren't possible.
 504     # This is due to them having to link with libcrypto and register features
 505     # using the ENGINE functionality, and since that relies on global tables,
 506     # those *have* to be exacty the same as the ones accessed from the app,
 507     # which cannot be guaranteed if shared libraries aren't present.
 508     # (note that even with shared libraries, both the app and dynamic engines
 509     # must be linked with the same library)
 510     "shared"            => [ "dynamic-engine", "uplink" ],
 511     # Other modules don't necessarily have to link with libcrypto, so shared
 512     # libraries do not have to be a condition to produce those.
 513
 514     # Without position independent code, there can be no shared libraries
 515     # or modules.
 516     "pic"               => [ "shared", "module" ],
 517
 518     "module"            => [ "fips", "legacy" ],
 519
 520     "engine"            => [ grep /eng$/, @disablables ],
 521     "hw"                => [ "padlockeng" ],
 522
 523     # no-autoalginit is only useful when building non-shared
 524     "autoalginit"       => [ "shared", "apps" ],
 525
 526     "stdio"             => [ "apps", "capieng", "egd" ],
 527     "apps"              => [ "tests" ],
 528     "tests"             => [ "external-tests" ],
 529     "comp"              => [ "zlib" ],
 530     "sm3"               => [ "sm2" ],
 531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 532
 533     sub { !$disabled{"msan"} } => [ "asm" ],
 534
 535     sub { $disabled{cmac}; } => [ "siv" ],
 536     "legacy"                 => [ "md2" ],
 537
 538     "cmp"               => [ "crmf" ],
 539     );
 540
 541 # Avoid protocol support holes.  Also disable all versions below N, if version
 542 # N is disabled while N+1 is enabled.
 543 #
 544 my @list = (reverse @tls);
 545 while ((my $first, my $second) = (shift @list, shift @list)) {
 546     last unless @list;
 547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 548                               => [ @list ] );
 549     unshift @list, $second;
 550 }
 551 my @list = (reverse @dtls);
 552 while ((my $first, my $second) = (shift @list, shift @list)) {
 553     last unless @list;
 554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 555                               => [ @list ] );
 556     unshift @list, $second;
 557 }
 558
 559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 560 # To remove something from %disabled, use "enable-foo".
 561 # For symmetry, "disable-foo" is a synonym for "no-foo".
 562
 563 &usage if ($#ARGV < 0);
 564
 565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 566 # platform specific list separators.  Users from those platforms should
 567 # recognise those separators from how you set up the PATH to find executables.
 568 # The default is the Unix like separator, :, but as an exception, we also
 569 # support the space as separator.
 570 my $list_separator_re =
 571     { VMS           => qr/(?<!\^),/,
 572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 573 # All the "make variables" we support
 574 # Some get pre-populated for the sake of backward compatibility
 575 # (we supported those before the change to "make variable" support.
 576 my %user = (
 577     AR          => env('AR'),
 578     ARFLAGS     => [],
 579     AS          => undef,
 580     ASFLAGS     => [],
 581     CC          => env('CC'),
 582     CFLAGS      => [ env('CFLAGS') || () ],
 583     CXX         => env('CXX'),
 584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 585     CPP         => undef,
 586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 587     CPPDEFINES  => [],  # Alternative for -D
 588     CPPINCLUDES => [],  # Alternative for -I
 589     CROSS_COMPILE => env('CROSS_COMPILE'),
 590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 591     LD          => undef,
 592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 594     MT          => undef,
 595     MTFLAGS     => [],
 596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 597     RANLIB      => env('RANLIB'),
 598     RC          => env('RC') || env('WINDRES'),
 599     RCFLAGS     => [ env('RCFLAGS') || () ],
 600     RM          => undef,
 601    );
 602 # Info about what "make variables" may be prefixed with the cross compiler
 603 # prefix.  This should NEVER mention any such variable with a list for value.
 604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 605 # The same but for flags given as Configure options.  These are *additional*
 606 # input, as opposed to the VAR=string option that override the corresponding
 607 # config target attributes
 608 my %useradd = (
 609     CPPDEFINES  => [],
 610     CPPINCLUDES => [],
 611     CPPFLAGS    => [],
 612     CFLAGS      => [],
 613     CXXFLAGS    => [],
 614     LDFLAGS     => [],
 615     LDLIBS      => [],
 616     RCFLAGS     => [],
 617    );
 618
 619 my %user_synonyms = (
 620     HASHBANGPERL=> 'PERL',
 621     RC          => 'WINDRES',
 622    );
 623
 624 # Some target attributes have been renamed, this is the translation table
 625 my %target_attr_translate =(
 626     ar          => 'AR',
 627     as          => 'AS',
 628     cc          => 'CC',
 629     cxx         => 'CXX',
 630     cpp         => 'CPP',
 631     hashbangperl => 'HASHBANGPERL',
 632     ld          => 'LD',
 633     mt          => 'MT',
 634     ranlib      => 'RANLIB',
 635     rc          => 'RC',
 636     rm          => 'RM',
 637    );
 638
 639 # Initialisers coming from 'config' scripts
 640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 647
 648 $config{openssl_api_defines}=[];
 649 $config{openssl_sys_defines}=[];
 650 $config{openssl_feature_defines}=[];
 651 $config{options}="";
 652 $config{build_type} = "release";
 653 my $target="";
 654
 655 my %cmdvars = ();               # Stores FOO='blah' type arguments
 656 my %unsupported_options = ();
 657 my %deprecated_options = ();
 658 # If you change this, update apps/version.c
 659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 660 my @seed_sources = ();
 661 while (@argvcopy)
 662         {
 663         $_ = shift @argvcopy;
 664
 665         # Support env variable assignments among the options
 666         if (m|^(\w+)=(.+)?$|)
 667                 {
 668                 $cmdvars{$1} = $2;
 669                 # Every time a variable is given as a configuration argument,
 670                 # it acts as a reset if the variable.
 671                 if (exists $user{$1})
 672                         {
 673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 674                         }
 675                 #if (exists $useradd{$1})
 676                 #       {
 677                 #       $useradd{$1} = [];
 678                 #       }
 679                 next;
 680                 }
 681
 682         # VMS is a case insensitive environment, and depending on settings
 683         # out of our control, we may receive options uppercased.  Let's
 684         # downcase at least the part before any equal sign.
 685         if ($^O eq "VMS")
 686                 {
 687                 s/^([^=]*)/lc($1)/e;
 688                 }
 689
 690         # some people just can't read the instructions, clang people have to...
 691         s/^-no-(?!integrated-as)/no-/;
 692
 693         # rewrite some options in "enable-..." form
 694         s /^-?-?shared$/enable-shared/;
 695         s /^sctp$/enable-sctp/;
 696         s /^threads$/enable-threads/;
 697         s /^zlib$/enable-zlib/;
 698         s /^zlib-dynamic$/enable-zlib-dynamic/;
 699
 700         if (/^(no|disable|enable)-(.+)$/)
 701                 {
 702                 my $word = $2;
 703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 704                         && !exists $deprecated_disablables{$word}
 705                         && !grep { $word eq $_ } @disablables)
 706                         {
 707                         $unsupported_options{$_} = 1;
 708                         next;
 709                         }
 710                 }
 711         if (/^no-(.+)$/ || /^disable-(.+)$/)
 712                 {
 713                 foreach my $proto ((@tls, @dtls))
 714                         {
 715                         if ($1 eq "$proto-method")
 716                                 {
 717                                 $disabled{"$proto"} = "option($proto-method)";
 718                                 last;
 719                                 }
 720                         }
 721                 if ($1 eq "dtls")
 722                         {
 723                         foreach my $proto (@dtls)
 724                                 {
 725                                 $disabled{$proto} = "option(dtls)";
 726                                 }
 727                         $disabled{"dtls"} = "option(dtls)";
 728                         }
 729                 elsif ($1 eq "ssl")
 730                         {
 731                         # Last one of its kind
 732                         $disabled{"ssl3"} = "option(ssl)";
 733                         }
 734                 elsif ($1 eq "tls")
 735                         {
 736                         # XXX: Tests will fail if all SSL/TLS
 737                         # protocols are disabled.
 738                         foreach my $proto (@tls)
 739                                 {
 740                                 $disabled{$proto} = "option(tls)";
 741                                 }
 742                         }
 743                 elsif ($1 eq "static-engine")
 744                         {
 745                         delete $disabled{"dynamic-engine"};
 746                         }
 747                 elsif ($1 eq "dynamic-engine")
 748                         {
 749                         $disabled{"dynamic-engine"} = "option";
 750                         }
 751                 elsif (exists $deprecated_disablables{$1})
 752                         {
 753                         $deprecated_options{$_} = 1;
 754                         if (defined $deprecated_disablables{$1})
 755                                 {
 756                                 $disabled{$deprecated_disablables{$1}} = "option";
 757                                 }
 758                         }
 759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 760                         {
 761                         $deprecated_options{$_} = 1;
 762                         }
 763                 else
 764                         {
 765                         $disabled{$1} = "option";
 766                         }
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^enable-(.+)$/)
 771                 {
 772                 if ($1 eq "static-engine")
 773                         {
 774                         $disabled{"dynamic-engine"} = "option";
 775                         }
 776                 elsif ($1 eq "dynamic-engine")
 777                         {
 778                         delete $disabled{"dynamic-engine"};
 779                         }
 780                 elsif ($1 eq "zlib-dynamic")
 781                         {
 782                         delete $disabled{"zlib"};
 783                         }
 784                 my $algo = $1;
 785                 delete $disabled{$algo};
 786
 787                 # No longer an automatic choice
 788                 $auto_threads = 0 if ($1 eq "threads");
 789                 }
 790         elsif (/^--strict-warnings$/)
 791                 {
 792                 # Pretend that our strict flags is a C flag, and replace it
 793                 # with the proper flags later on
 794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 795                 $strict_warnings=1;
 796                 }
 797         elsif (/^--debug$/)
 798                 {
 799                 $config{build_type} = "debug";
 800                 }
 801         elsif (/^--release$/)
 802                 {
 803                 $config{build_type} = "release";
 804                 }
 805         elsif (/^386$/)
 806                 { $config{processor}=386; }
 807         elsif (/^fips$/)
 808                 {
 809                 die "FIPS mode not supported\n";
 810                 }
 811         elsif (/^rsaref$/)
 812                 {
 813                 # No RSAref support any more since it's not needed.
 814                 # The check for the option is there so scripts aren't
 815                 # broken
 816                 }
 817         elsif (/^nofipscanistercheck$/)
 818                 {
 819                 die "FIPS mode not supported\n";
 820                 }
 821         elsif (/^[-+]/)
 822                 {
 823                 if (/^--prefix=(.*)$/)
 824                         {
 825                         $config{prefix}=$1;
 826                         die "Directory given with --prefix MUST be absolute\n"
 827                                 unless file_name_is_absolute($config{prefix});
 828                         }
 829                 elsif (/^--api=(.*)$/)
 830                         {
 831                         $config{api}=$1;
 832                         }
 833                 elsif (/^--libdir=(.*)$/)
 834                         {
 835                         $config{libdir}=$1;
 836                         }
 837                 elsif (/^--openssldir=(.*)$/)
 838                         {
 839                         $config{openssldir}=$1;
 840                         }
 841                 elsif (/^--with-zlib-lib=(.*)$/)
 842                         {
 843                         $withargs{zlib_lib}=$1;
 844                         }
 845                 elsif (/^--with-zlib-include=(.*)$/)
 846                         {
 847                         $withargs{zlib_include}=$1;
 848                         }
 849                 elsif (/^--with-fuzzer-lib=(.*)$/)
 850                         {
 851                         $withargs{fuzzer_lib}=$1;
 852                         }
 853                 elsif (/^--with-fuzzer-include=(.*)$/)
 854                         {
 855                         $withargs{fuzzer_include}=$1;
 856                         }
 857                 elsif (/^--with-rand-seed=(.*)$/)
 858                         {
 859                         foreach my $x (split(m|,|, $1))
 860                             {
 861                             die "Unknown --with-rand-seed choice $x\n"
 862                                 if ! grep { $x eq $_ } @known_seed_sources;
 863                             push @seed_sources, $x;
 864                             }
 865                         }
 866                 elsif (/^--cross-compile-prefix=(.*)$/)
 867                         {
 868                         $user{CROSS_COMPILE}=$1;
 869                         }
 870                 elsif (/^--config=(.*)$/)
 871                         {
 872                         read_config $1;
 873                         }
 874                 elsif (/^-l(.*)$/)
 875                         {
 876                         push @{$useradd{LDLIBS}}, $_;
 877                         }
 878                 elsif (/^-framework$/)
 879                         {
 880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 881                         }
 882                 elsif (/^-L(.*)$/ or /^-Wl,/)
 883                         {
 884                         push @{$useradd{LDFLAGS}}, $_;
 885                         }
 886                 elsif (/^-rpath$/ or /^-R$/)
 887                         # -rpath is the OSF1 rpath flag
 888                         # -R is the old Solaris rpath flag
 889                         {
 890                         my $rpath = shift(@argvcopy) || "";
 891                         $rpath .= " " if $rpath ne "";
 892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 893                         }
 894                 elsif (/^-static$/)
 895                         {
 896                         push @{$useradd{LDFLAGS}}, $_;
 897                         }
 898                 elsif (/^-D(.*)$/)
 899                         {
 900                         push @{$useradd{CPPDEFINES}}, $1;
 901                         }
 902                 elsif (/^-I(.*)$/)
 903                         {
 904                         push @{$useradd{CPPINCLUDES}}, $1;
 905                         }
 906                 elsif (/^-Wp,$/)
 907                         {
 908                         push @{$useradd{CPPFLAGS}}, $1;
 909                         }
 910                 else    # common if (/^[-+]/), just pass down...
 911                         {
 912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 913                         push @{$useradd{CFLAGS}}, $_;
 914                         push @{$useradd{CXXFLAGS}}, $_;
 915                         }
 916                 }
 917         else
 918                 {
 919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 920                 $target=$_;
 921                 }
 922         unless ($_ eq $target || /^no-/ || /^disable-/)
 923                 {
 924                 # "no-..." follows later after implied deactivations
 925                 # have been derived.  (Don't take this too seriously,
 926                 # we really only write OPTIONS to the Makefile out of
 927                 # nostalgia.)
 928
 929                 if ($config{options} eq "")
 930                         { $config{options} = $_; }
 931                 else
 932                         { $config{options} .= " ".$_; }
 933                 }
 934         }
 935
 936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 937         die "***** Unsupported api compatibility level: $config{api}\n",
 938 }
 939
 940 if (keys %deprecated_options)
 941         {
 942         warn "***** Deprecated options: ",
 943                 join(", ", keys %deprecated_options), "\n";
 944         }
 945 if (keys %unsupported_options)
 946         {
 947         die "***** Unsupported options: ",
 948                 join(", ", keys %unsupported_options), "\n";
 949         }
 950
 951 # If any %useradd entry has been set, we must check that the "make
 952 # variables" haven't been set.  We start by checking of any %useradd entry
 953 # is set.
 954 if (grep { scalar @$_ > 0 } values %useradd) {
 955     # Hash of env / make variables names.  The possible values are:
 956     # 1 - "make vars"
 957     # 2 - %useradd entry set
 958     # 3 - both set
 959     my %detected_vars =
 960         map { my $v = 0;
 961               $v += 1 if $cmdvars{$_};
 962               $v += 2 if @{$useradd{$_}};
 963               $_ => $v }
 964         keys %useradd;
 965
 966     # If any of the corresponding "make variables" is set, we error
 967     if (grep { $_ & 1 } values %detected_vars) {
 968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 969                                sort keys %detected_vars);
 970         die <<"_____";
 971 ***** Mixing make variables and additional compiler/linker flags as
 972 ***** configure command line option is not permitted.
 973 ***** Affected make variables: $names
 974 _____
 975     }
 976 }
 977
 978 # Check through all supported command line variables to see if any of them
 979 # were set, and canonicalise the values we got.  If no compiler or linker
 980 # flag or anything else that affects %useradd was set, we also check the
 981 # environment for values.
 982 my $anyuseradd =
 983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 984 foreach (keys %user) {
 985     my $value = $cmdvars{$_};
 986     $value //= env($_) unless $anyuseradd;
 987     $value //=
 988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 990         unless $anyuseradd;
 991
 992     if (defined $value) {
 993         if (ref $user{$_} eq 'ARRAY') {
 994             $user{$_} = [ split /$list_separator_re/, $value ];
 995         } elsif (!defined $user{$_}) {
 996             $user{$_} = $value;
 997         }
 998     }
 999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1408         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1409     }
1410     if ($target{modes_asm_src} =~ /ghash-/) {
1411         push @{$config{lib_defines}}, "GHASH_ASM";
1412     }
1413     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1414         push @{$config{dso_defines}}, "PADLOCK_ASM";
1415     }
1416     if ($target{poly1305_asm_src} ne "") {
1417         push @{$config{lib_defines}}, "POLY1305_ASM";
1418     }
1419 }
1420
1421 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1422 my %predefined_CXX = $config{CXX}
1423     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1424     : ();
1425
1426 # Check for makedepend capabilities.
1427 if (!$disabled{makedepend}) {
1428     if ($config{target} =~ /^(VC|vms)-/) {
1429         # For VC- and vms- targets, there's nothing more to do here.  The
1430         # functionality is hard coded in the corresponding build files for
1431         # cl (Windows) and CC/DECC (VMS).
1432     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1433              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1434         # We know that GNU C version 3 and up as well as all clang
1435         # versions support dependency generation, but Xcode did not
1436         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1437         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1438     } else {
1439         # In all other cases, we look for 'makedepend', and disable the
1440         # capability if not found.
1441         $config{makedepprog} = which('makedepend');
1442         disable('unavailable', 'makedepend') unless $config{makedepprog};
1443     }
1444 }
1445
1446 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1447     # probe for -Wa,--noexecstack option...
1448     if ($predefined_C{__clang__}) {
1449         # clang has builtin assembler, which doesn't recognize --help,
1450         # but it apparently recognizes the option in question on all
1451         # supported platforms even when it's meaningless. In other words
1452         # probe would fail, but probed option always accepted...
1453         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1454     } else {
1455         my $cc = $config{CROSS_COMPILE}.$config{CC};
1456         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1457         while(<PIPE>) {
1458             if (m/--noexecstack/) {
1459                 push @{$config{cflags}}, "-Wa,--noexecstack";
1460                 last;
1461             }
1462         }
1463         close(PIPE);
1464         unlink("null.$$.o");
1465     }
1466 }
1467
1468 # Deal with bn_ops ###################################################
1469
1470 $config{bn_ll}                  =0;
1471 $config{export_var_as_fn}       =0;
1472 my $def_int="unsigned int";
1473 $config{rc4_int}                =$def_int;
1474 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1475
1476 my $count = 0;
1477 foreach (sort split(/\s+/,$target{bn_ops})) {
1478     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1479     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1480     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1481     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1482     ($config{b64l},$config{b64},$config{b32})
1483         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1484     ($config{b64l},$config{b64},$config{b32})
1485         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1486     ($config{b64l},$config{b64},$config{b32})
1487         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1488 }
1489 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1490     if $count > 1;
1491
1492
1493 # Hack cflags for better warnings (dev option) #######################
1494
1495 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1496 # a string and works as well on command lines.
1497 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1498                         @{$config{cflags}} ];
1499 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1500                           @{$config{cxxflags}} ] if $config{CXX};
1501
1502 $config{openssl_api_defines} = [
1503     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1504 ];
1505
1506 my @strict_warnings_collection=();
1507 if ($strict_warnings)
1508         {
1509         my $wopt;
1510         my $gccver = $predefined_C{__GNUC__} // -1;
1511
1512         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1513             unless $gccver >= 4;
1514         push @strict_warnings_collection, @gcc_devteam_warn;
1515         push @strict_warnings_collection, @clang_devteam_warn
1516             if (defined($predefined_C{__clang__}));
1517         }
1518
1519 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1520     disable('static', 'pic', 'threads');
1521 }
1522
1523 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1524                               ? @strict_warnings_collection
1525                               : ( $_ ) }
1526                     @{$config{CFLAGS}} ];
1527
1528 unless ($disabled{"crypto-mdebug-backtrace"})
1529         {
1530         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1531                 {
1532                 push @{$config{cflags}}, $wopt
1533                         unless grep { $_ eq $wopt } @{$config{cflags}};
1534                 }
1535         if ($target =~ /^BSD-/)
1536                 {
1537                 push @{$config{ex_libs}}, "-lexecinfo";
1538                 }
1539         }
1540
1541 unless ($disabled{afalgeng}) {
1542     $config{afalgeng}="";
1543     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1544         my $minver = 4*10000 + 1*100 + 0;
1545         if ($config{CROSS_COMPILE} eq "") {
1546             my $verstr = `uname -r`;
1547             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1548             ($mi2) = $mi2 =~ /(\d+)/;
1549             my $ver = $ma*10000 + $mi1*100 + $mi2;
1550             if ($ver < $minver) {
1551                 disable('too-old-kernel', 'afalgeng');
1552             } else {
1553                 push @{$config{engdirs}}, "afalg";
1554             }
1555         } else {
1556             disable('cross-compiling', 'afalgeng');
1557         }
1558     } else {
1559         disable('not-linux', 'afalgeng');
1560     }
1561 }
1562
1563 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1564
1565 unless ($disabled{ktls}) {
1566     $config{ktls}="";
1567     if ($target =~ m/^linux/) {
1568         my $usr = "/usr/$config{cross_compile_prefix}";
1569         chop($usr);
1570         if ($config{cross_compile_prefix} eq "") {
1571             $usr = "/usr";
1572         }
1573         my $minver = (4 << 16) + (13 << 8) + 0;
1574         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1575
1576         if ($verstr[2] < $minver) {
1577             disable('too-old-kernel', 'ktls');
1578         }
1579     } else {
1580         disable('not-linux', 'ktls');
1581     }
1582 }
1583
1584 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1585
1586 # Get the extra flags used when building shared libraries and modules.  We
1587 # do this late because some of them depend on %disabled.
1588
1589 # Make the flags to build DSOs the same as for shared libraries unless they
1590 # are already defined
1591 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1592 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1593 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1594 {
1595     my $shared_info_pl =
1596         catfile(dirname($0), "Configurations", "shared-info.pl");
1597     my %shared_info = read_eval_file($shared_info_pl);
1598     push @{$target{_conf_fname_int}}, $shared_info_pl;
1599     my $si = $target{shared_target};
1600     while (ref $si ne "HASH") {
1601         last if ! defined $si;
1602         if (ref $si eq "CODE") {
1603             $si = $si->();
1604         } else {
1605             $si = $shared_info{$si};
1606         }
1607     }
1608
1609     # Some of the 'shared_target' values don't have any entries in
1610     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1611     # template knows how to handle this.  That is currently the case for
1612     # Windows and VMS.
1613     if (defined $si) {
1614         # Just as above, copy certain shared_* attributes to the corresponding
1615         # module_ attribute unless the latter is already defined
1616         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1617         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1618         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1619         foreach (sort keys %$si) {
1620             $target{$_} = defined $target{$_}
1621                 ? add($si->{$_})->($target{$_})
1622                 : $si->{$_};
1623         }
1624     }
1625 }
1626
1627 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1628
1629 # If we use the unified build, collect information from build.info files
1630 my %unified_info = ();
1631
1632 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1633 if ($builder eq "unified") {
1634     use with_fallback qw(Text::Template);
1635
1636     sub cleandir {
1637         my $base = shift;
1638         my $dir = shift;
1639         my $relativeto = shift || ".";
1640
1641         $dir = catdir($base,$dir) unless isabsolute($dir);
1642
1643         # Make sure the directories we're building in exists
1644         mkpath($dir);
1645
1646         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1647         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1648         return $res;
1649     }
1650
1651     sub cleanfile {
1652         my $base = shift;
1653         my $file = shift;
1654         my $relativeto = shift || ".";
1655
1656         $file = catfile($base,$file) unless isabsolute($file);
1657
1658         my $d = dirname($file);
1659         my $f = basename($file);
1660
1661         # Make sure the directories we're building in exists
1662         mkpath($d);
1663
1664         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1665         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1666         return $res;
1667     }
1668
1669     # Store the name of the template file we will build the build file from
1670     # in %config.  This may be useful for the build file itself.
1671     my @build_file_template_names =
1672         ( $builder_platform."-".$target{build_file}.".tmpl",
1673           $target{build_file}.".tmpl" );
1674     my @build_file_templates = ();
1675
1676     # First, look in the user provided directory, if given
1677     if (defined env($local_config_envname)) {
1678         @build_file_templates =
1679             map {
1680                 if ($^O eq 'VMS') {
1681                     # VMS environment variables are logical names,
1682                     # which can be used as is
1683                     $local_config_envname . ':' . $_;
1684                 } else {
1685                     catfile(env($local_config_envname), $_);
1686                 }
1687             }
1688             @build_file_template_names;
1689     }
1690     # Then, look in our standard directory
1691     push @build_file_templates,
1692         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1693           @build_file_template_names );
1694
1695     my $build_file_template;
1696     for $_ (@build_file_templates) {
1697         $build_file_template = $_;
1698         last if -f $build_file_template;
1699
1700         $build_file_template = undef;
1701     }
1702     if (!defined $build_file_template) {
1703         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1704     }
1705     $config{build_file_templates}
1706       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1707                     $blddir),
1708           $build_file_template,
1709           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1710                     $blddir) ];
1711
1712     my @build_dirs = ( [ ] );   # current directory
1713
1714     $config{build_infos} = [ ];
1715
1716     my %ordinals = ();
1717     while (@build_dirs) {
1718         my @curd = @{shift @build_dirs};
1719         my $sourced = catdir($srcdir, @curd);
1720         my $buildd = catdir($blddir, @curd);
1721
1722         my $unixdir = join('/', @curd);
1723         if (exists $skipdir{$unixdir}) {
1724             my $what = $skipdir{$unixdir};
1725             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1726             next;
1727         }
1728
1729         mkpath($buildd);
1730
1731         my $f = 'build.info';
1732         # The basic things we're trying to build
1733         my @programs = ();
1734         my @libraries = ();
1735         my @modules = ();
1736         my @scripts = ();
1737
1738         my %attributes = ();
1739         my %sources = ();
1740         my %shared_sources = ();
1741         my %includes = ();
1742         my %defines = ();
1743         my %depends = ();
1744         my %generate = ();
1745
1746         # Support for $variablename in build.info files.
1747         # Embedded perl code is the ultimate master, still.  If its output
1748         # contains a dollar sign, it had better be escaped, or it will be
1749         # taken for a variable name prefix.
1750         my %variables = ();
1751         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1752         my $expand_variables = sub {
1753             my $value = '';
1754             my $value_rest = shift;
1755
1756             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1757                 $value .= $`;
1758                 $value .= $variables{$1};
1759                 $value_rest = $';
1760             }
1761             return $value . $value_rest;
1762         };
1763
1764         # We want to detect configdata.pm in the source tree, so we
1765         # don't use it if the build tree is different.
1766         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1767
1768         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1769         my $template =
1770             Text::Template->new(TYPE => 'FILE',
1771                                 SOURCE => catfile($sourced, $f),
1772                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1773         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1774         my @text =
1775             split /^/m,
1776             $template->fill_in(HASH => { config => \%config,
1777                                          target => \%target,
1778                                          disabled => \%disabled,
1779                                          withargs => \%withargs,
1780                                          builddir => abs2rel($buildd, $blddir),
1781                                          sourcedir => abs2rel($sourced, $blddir),
1782                                          buildtop => abs2rel($blddir, $blddir),
1783                                          sourcetop => abs2rel($srcdir, $blddir) },
1784                                DELIMITERS => [ "{-", "-}" ]);
1785
1786         # The top item of this stack has the following values
1787         # -2 positive already run and we found ELSE (following ELSIF should fail)
1788         # -1 positive already run (skip until ENDIF)
1789         # 0 negatives so far (if we're at a condition, check it)
1790         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1791         # 2 positive ELSE (following ELSIF should fail)
1792         my @skip = ();
1793         collect_information(
1794             collect_from_array([ @text ],
1795                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1796                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1797             # Info we're looking for
1798             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1799             => sub {
1800                 if (! @skip || $skip[$#skip] > 0) {
1801                     push @skip, !! $expand_variables->($1);
1802                 } else {
1803                     push @skip, -1;
1804                 }
1805             },
1806             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1807             => sub { die "ELSIF out of scope" if ! @skip;
1808                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1809                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1810                      $skip[$#skip] = !! $expand_variables->($1)
1811                          if $skip[$#skip] == 0; },
1812             qr/^\s*ELSE\s*$/
1813             => sub { die "ELSE out of scope" if ! @skip;
1814                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1815                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1816             qr/^\s*ENDIF\s*$/
1817             => sub { die "ENDIF out of scope" if ! @skip;
1818                      pop @skip; },
1819             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1820             => sub {
1821                 if (!@skip || $skip[$#skip] > 0) {
1822                     my $n = $1;
1823                     my $v = $2;
1824                     $variables{$n} = $expand_variables->($v);
1825                 }
1826             },
1827             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1828             => sub {
1829                 if (!@skip || $skip[$#skip] > 0) {
1830                     foreach (tokenize($expand_variables->($1))) {
1831                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1832                     }
1833                 }
1834             },
1835             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1836             => sub {
1837                 if (!@skip || $skip[$#skip] > 0) {
1838                     my @a = tokenize($1, qr|\s*,\s*|);
1839                     my @p = tokenize($expand_variables->($2));
1840                     push @programs, @p;
1841                     foreach my $a (@a) {
1842                         my $ak = $a;
1843                         my $av = 1;
1844                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1845                             $ak = $1;
1846                             $av = $2;
1847                         }
1848                         foreach my $p (@p) {
1849                             $attributes{$p}->{$ak} = $av;
1850                         }
1851                     }
1852                 }
1853             },
1854             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1855             => sub {
1856                 if (!@skip || $skip[$#skip] > 0) {
1857                     my @a = tokenize($1, qr|\s*,\s*|);
1858                     my @l = tokenize($expand_variables->($2));
1859                     push @libraries, @l;
1860                     foreach my $a (@a) {
1861                         my $ak = $a;
1862                         my $av = 1;
1863                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1864                             $ak = $1;
1865                             $av = $2;
1866                         }
1867                         foreach my $l (@l) {
1868                             $attributes{$l}->{$ak} = $av;
1869                         }
1870                     }
1871                 }
1872             },
1873             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1874             => sub {
1875                 if (!@skip || $skip[$#skip] > 0) {
1876                     my @a = tokenize($1, qr|\s*,\s*|);
1877                     my @m = tokenize($expand_variables->($2));
1878                     push @modules, @m;
1879                     foreach my $a (@a) {
1880                         my $ak = $a;
1881                         my $av = 1;
1882                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1883                             $ak = $1;
1884                             $av = $2;
1885                         }
1886                         foreach my $m (@m) {
1887                             $attributes{$m}->{$ak} = $av;
1888                         }
1889                     }
1890                 }
1891             },
1892             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1893             => sub {
1894                 if (!@skip || $skip[$#skip] > 0) {
1895                     my @a = tokenize($1, qr|\s*,\s*|);
1896                     my @s = tokenize($expand_variables->($2));
1897                     push @scripts, @s;
1898                     foreach my $a (@a) {
1899                         my $ak = $a;
1900                         my $av = 1;
1901                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1902                             $ak = $1;
1903                             $av = $2;
1904                         }
1905                         foreach my $s (@s) {
1906                             $attributes{$s}->{$ak} = $av;
1907                         }
1908                     }
1909                 }
1910             },
1911
1912             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1913             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1914                          if !@skip || $skip[$#skip] > 0 },
1915             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1916             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1917                          if !@skip || $skip[$#skip] > 0 },
1918             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1919             => sub { push @{$shared_sources{$1}},
1920                          tokenize($expand_variables->($2))
1921                          if !@skip || $skip[$#skip] > 0 },
1922             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1923             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1924                          if !@skip || $skip[$#skip] > 0 },
1925             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1926             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1927                          if !@skip || $skip[$#skip] > 0 },
1928             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1929             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1930                          if !@skip || $skip[$#skip] > 0 },
1931             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1932             => sub { push @{$generate{$1}}, $2
1933                          if !@skip || $skip[$#skip] > 0 },
1934             qr/^\s*(?:#.*)?$/ => sub { },
1935             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1936             "BEFORE" => sub {
1937                 if ($buildinfo_debug) {
1938                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1939                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1940                 }
1941             },
1942             "AFTER" => sub {
1943                 if ($buildinfo_debug) {
1944                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1945                 }
1946             },
1947             );
1948         die "runaway IF?" if (@skip);
1949
1950         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1951                 and !$config{dynamic_engines}) {
1952             die <<"EOF"
1953 ENGINES can only be used if configured with 'dynamic-engine'.
1954 This is usually a fault in a build.info file.
1955 EOF
1956         }
1957
1958         foreach (keys %attributes) {
1959             my $dest = $_;
1960             my $ddest = cleanfile($buildd, $_, $blddir);
1961             foreach (keys %{$attributes{$dest} // {}}) {
1962                 $unified_info{attributes}->{$ddest}->{$_} =
1963                     $attributes{$dest}->{$_};
1964             }
1965         }
1966
1967         {
1968             my %infos = ( programs  => [ @programs  ],
1969                           libraries => [ @libraries ],
1970                           modules   => [ @modules   ],
1971                           scripts   => [ @scripts   ] );
1972             foreach my $k (keys %infos) {
1973                 foreach (@{$infos{$k}}) {
1974                     my $item = cleanfile($buildd, $_, $blddir);
1975                     $unified_info{$k}->{$item} = 1;
1976                 }
1977             }
1978         }
1979
1980         # Check that we haven't defined any library as both shared and
1981         # explicitly static.  That is forbidden.
1982         my @doubles = ();
1983         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1984             (my $l = $_) =~ s/\.a$//;
1985             push @doubles, $l if defined $unified_info{libraries}->{$l};
1986         }
1987         die "these libraries are both explicitly static and shared:\n  ",
1988             join(" ", @doubles), "\n"
1989             if @doubles;
1990
1991         foreach (keys %sources) {
1992             my $dest = $_;
1993             my $ddest = cleanfile($buildd, $_, $blddir);
1994             foreach (@{$sources{$dest}}) {
1995                 my $s = cleanfile($sourced, $_, $blddir);
1996
1997                 # If it isn't in the source tree, we assume it's generated
1998                 # in the build tree
1999                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2000                     $s = cleanfile($buildd, $_, $blddir);
2001                 }
2002                 # We recognise C++, C and asm files
2003                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2004                     my $o = $_;
2005                     $o =~ s/\.[csS]$/.o/; # C and assembler
2006                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2007                     $o = cleanfile($buildd, $o, $blddir);
2008                     $unified_info{sources}->{$ddest}->{$o} = -1;
2009                     $unified_info{sources}->{$o}->{$s} = -1;
2010                 } elsif ($s =~ /\.rc$/) {
2011                     # We also recognise resource files
2012                     my $o = $_;
2013                     $o =~ s/\.rc$/.res/; # Resource configuration
2014                     my $o = cleanfile($buildd, $o, $blddir);
2015                     $unified_info{sources}->{$ddest}->{$o} = -1;
2016                     $unified_info{sources}->{$o}->{$s} = -1;
2017                 } else {
2018                     $unified_info{sources}->{$ddest}->{$s} = 1;
2019                 }
2020             }
2021         }
2022
2023         foreach (keys %shared_sources) {
2024             my $dest = $_;
2025             my $ddest = cleanfile($buildd, $_, $blddir);
2026             foreach (@{$shared_sources{$dest}}) {
2027                 my $s = cleanfile($sourced, $_, $blddir);
2028
2029                 # If it isn't in the source tree, we assume it's generated
2030                 # in the build tree
2031                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2032                     $s = cleanfile($buildd, $_, $blddir);
2033                 }
2034
2035                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2036                     # We recognise C++, C and asm files
2037                     my $o = $_;
2038                     $o =~ s/\.[csS]$/.o/; # C and assembler
2039                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2040                     $o = cleanfile($buildd, $o, $blddir);
2041                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2042                     $unified_info{sources}->{$o}->{$s} = -1;
2043                 } elsif ($s =~ /\.rc$/) {
2044                     # We also recognise resource files
2045                     my $o = $_;
2046                     $o =~ s/\.rc$/.res/; # Resource configuration
2047                     my $o = cleanfile($buildd, $o, $blddir);
2048                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2049                     $unified_info{sources}->{$o}->{$s} = -1;
2050                 } elsif ($s =~ /\.ld$/) {
2051                     # We also recognise linker scripts (or corresponding)
2052                     # We know they are generated files
2053                     my $ld = cleanfile($buildd, $_, $blddir);
2054                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2055                 } else {
2056                     die "unrecognised source file type for shared library: $s\n";
2057                 }
2058             }
2059         }
2060
2061         foreach (keys %generate) {
2062             my $dest = $_;
2063             my $ddest = cleanfile($buildd, $_, $blddir);
2064             die "more than one generator for $dest: "
2065                     ,join(" ", @{$generate{$_}}),"\n"
2066                     if scalar @{$generate{$_}} > 1;
2067             my @generator = split /\s+/, $generate{$dest}->[0];
2068             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2069             $unified_info{generate}->{$ddest} = [ @generator ];
2070         }
2071
2072         foreach (keys %depends) {
2073             my $dest = $_;
2074             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2075
2076             # If the destination doesn't exist in source, it can only be
2077             # a generated file in the build tree.
2078             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2079                 $ddest = cleanfile($buildd, $_, $blddir);
2080             }
2081             foreach (@{$depends{$dest}}) {
2082                 my $d = cleanfile($sourced, $_, $blddir);
2083
2084                 # If we know it's generated, or assume it is because we can't
2085                 # find it in the source tree, we set file we depend on to be
2086                 # in the build tree rather than the source tree, and assume
2087                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2088                 # section or in the Makefile template.
2089                 if ($d eq $src_configdata
2090                     || ! -f $d
2091                     || (grep { $d eq $_ }
2092                         map { cleanfile($srcdir, $_, $blddir) }
2093                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2094                     $d = cleanfile($buildd, $_, $blddir);
2095                 }
2096                 # Take note if the file to depend on is being renamed
2097                 # Take extra care with files ending with .a, they should
2098                 # be treated without that extension, and the extension
2099                 # should be added back after treatment.
2100                 $d =~ /(\.a)?$/;
2101                 my $e = $1 // "";
2102                 $d = $`.$e;
2103                 $unified_info{depends}->{$ddest}->{$d} = 1;
2104             }
2105         }
2106
2107         foreach (keys %includes) {
2108             my $dest = $_;
2109             my $ddest = cleanfile($sourced, $_, $blddir);
2110
2111             # If the destination doesn't exist in source, it can only be
2112             # a generated file in the build tree.
2113             if ($ddest eq $src_configdata || ! -f $ddest) {
2114                 $ddest = cleanfile($buildd, $_, $blddir);
2115             }
2116             foreach (@{$includes{$dest}}) {
2117                 my $is = cleandir($sourced, $_, $blddir);
2118                 my $ib = cleandir($buildd, $_, $blddir);
2119                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2120                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2121                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2122                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2123             }
2124         }
2125
2126         foreach (keys %defines) {
2127             my $dest = $_;
2128             my $ddest = cleanfile($sourced, $_, $blddir);
2129
2130             # If the destination doesn't exist in source, it can only be
2131             # a generated file in the build tree.
2132             if (! -f $ddest) {
2133                 $ddest = cleanfile($buildd, $_, $blddir);
2134                 if ($unified_info{rename}->{$ddest}) {
2135                     $ddest = $unified_info{rename}->{$ddest};
2136                 }
2137             }
2138             foreach (@{$defines{$dest}}) {
2139                 m|^([^=]*)(=.*)?$|;
2140                 die "0 length macro name not permitted\n" if $1 eq "";
2141                 die "$1 defined more than once\n"
2142                     if defined $unified_info{defines}->{$ddest}->{$1};
2143                 $unified_info{defines}->{$ddest}->{$1} = $2;
2144             }
2145         }
2146     }
2147
2148     my $ordinals_text = join(', ', sort keys %ordinals);
2149     warn <<"EOF" if $ordinals_text;
2150
2151 WARNING: ORDINALS were specified for $ordinals_text
2152 They are ignored and should be replaced with a combination of GENERATE,
2153 DEPEND and SHARED_SOURCE.
2154 EOF
2155
2156
2157     # Go through the sources of all libraries and check that the same basename
2158     # doesn't appear more than once.  Some static library archivers depend on
2159     # them being unique.
2160     {
2161         my $err = 0;
2162         foreach my $prod (keys %{$unified_info{libraries}}) {
2163             my @prod_sources =
2164                 map { keys %{$unified_info{sources}->{$_}} }
2165                 keys %{$unified_info{sources}->{$prod}};
2166             my %srccnt = ();
2167
2168             # Count how many times a given each source basename
2169             # appears for each product.
2170             foreach my $src (@prod_sources) {
2171                 $srccnt{basename $src}++;
2172             }
2173
2174             foreach my $src (keys %srccnt) {
2175                 if ((my $cnt = $srccnt{$src}) > 1) {
2176                     print STDERR "$src appears $cnt times for the product $prod\n";
2177                     $err++
2178                 }
2179             }
2180         }
2181         die if $err > 0;
2182     }
2183
2184     # Massage the result
2185
2186     # If we depend on a header file or a perl module, add an inclusion of
2187     # its directory to allow smoothe inclusion
2188     foreach my $dest (keys %{$unified_info{depends}}) {
2189         next if $dest eq "";
2190         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2191             next unless $d =~ /\.(h|pm)$/;
2192             my $i = dirname($d);
2193             my $spot =
2194                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2195                 ? 'build' : 'source';
2196             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2197                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2198         }
2199     }
2200
2201     # Go through all intermediary files and change their names to something that
2202     # reflects what they will be built for.  Note that for some source files,
2203     # this leads to duplicate object files because they are used multiple times.
2204     # the goal is to rename all object files according to this scheme:
2205     #    {productname}-{midfix}-{origobjname}.[o|res]
2206     # the {midfix} is a keyword indicating the type of product, which is mostly
2207     # valuable for libraries since they come in two forms.
2208     #
2209     # This also reorganises the {sources} and {shared_sources} so that the
2210     # former only contains ALL object files that are supposed to end up in
2211     # static libraries and programs, while the latter contains ALL object files
2212     # that are supposed to end up in shared libraries and DSOs.
2213     # The main reason for having two different source structures is to allow
2214     # the same name to be used for the static and the shared variants of a
2215     # library.
2216     {
2217         # Take copies so we don't get interference from added stuff
2218         my %unified_copy = ();
2219         foreach (('sources', 'shared_sources')) {
2220             $unified_copy{$_} = { %{$unified_info{$_}} }
2221                 if defined($unified_info{$_});
2222             delete $unified_info{$_};
2223         }
2224         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2225             # $intent serves multi purposes:
2226             # - give a prefix for the new object files names
2227             # - in the case of libraries, rearrange the object files so static
2228             #   libraries use the 'sources' structure exclusively, while shared
2229             #   libraries use the 'shared_sources' structure exclusively.
2230             my $intent = {
2231                 programs  => { bin    => { src => [ 'sources' ],
2232                                            dst => 'sources' } },
2233                 libraries => { lib    => { src => [ 'sources' ],
2234                                            dst => 'sources' },
2235                                shlib  => { prodselect =>
2236                                                sub { grep !/\.a$/, @_ },
2237                                            src => [ 'sources',
2238                                                     'shared_sources' ],
2239                                            dst => 'shared_sources' } },
2240                 modules   => { dso    => { src => [ 'sources' ],
2241                                            dst => 'sources' } },
2242                 scripts   => { script => { src => [ 'sources' ],
2243                                            dst => 'sources' } }
2244                } -> {$prodtype};
2245             foreach my $kind (keys %$intent) {
2246                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2247                              && $disabled{shared});
2248
2249                 my @src = @{$intent->{$kind}->{src}};
2250                 my $dst = $intent->{$kind}->{dst};
2251                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2252                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2253                     # %prod_sources has all applicable objects as keys, and
2254                     # their corresponding sources as values
2255                     my %prod_sources =
2256                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2257                         map { keys %{$unified_copy{$_}->{$prod}} }
2258                         @src;
2259                     foreach (keys %prod_sources) {
2260                         # Only affect object files and resource files,
2261                         # the others simply get a new value
2262                         # (+1 instead of -1)
2263                         if ($_ =~ /\.(o|res)$/) {
2264                             (my $prodname = $prod) =~ s|\.a$||;
2265                             my $newobj =
2266                                 catfile(dirname($_),
2267                                         basename($prodname)
2268                                             . '-' . $kind
2269                                             . '-' . basename($_));
2270                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2271                             foreach my $src (@{$prod_sources{$_}}) {
2272                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2273                             }
2274                             # Adjust dependencies
2275                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2276                                 $unified_info{depends}->{$_}->{$deps} = -1;
2277                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2278                             }
2279                             # Adjust includes
2280                             foreach my $k (('source', 'build')) {
2281                                 next unless
2282                                     defined($unified_info{includes}->{$_}->{$k});
2283                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2284                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2285                             }
2286                         } else {
2287                             $unified_info{$dst}->{$prod}->{$_} = 1;
2288                         }
2289                     }
2290                 }
2291             }
2292         }
2293     }
2294
2295     # At this point, we have a number of sources with the value -1.  They
2296     # aren't part of the local build and are probably meant for a different
2297     # platform, and can therefore be cleaned away.  That happens when making
2298     # %unified_info more efficient below.
2299
2300     ### Make unified_info a bit more efficient
2301     # One level structures
2302     foreach (("programs", "libraries", "modules", "scripts")) {
2303         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2304     }
2305     # Two level structures
2306     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2307         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2308             my @items =
2309                 sort
2310                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2311                 keys %{$unified_info{$l1}->{$l2}};
2312             if (@items) {
2313                 $unified_info{$l1}->{$l2} = [ @items ];
2314             } else {
2315                 delete $unified_info{$l1}->{$l2};
2316             }
2317         }
2318     }
2319     # Defines
2320     foreach my $dest (sort keys %{$unified_info{defines}}) {
2321         $unified_info{defines}->{$dest}
2322             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2323                 sort keys %{$unified_info{defines}->{$dest}} ];
2324     }
2325     # Includes
2326     foreach my $dest (sort keys %{$unified_info{includes}}) {
2327         if (defined($unified_info{includes}->{$dest}->{build})) {
2328             my @source_includes = ();
2329             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2330                 if defined($unified_info{includes}->{$dest}->{source});
2331             $unified_info{includes}->{$dest} =
2332                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2333             foreach my $inc (@source_includes) {
2334                 push @{$unified_info{includes}->{$dest}}, $inc
2335                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2336             }
2337         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2338             $unified_info{includes}->{$dest} =
2339                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2340         } else {
2341             delete $unified_info{includes}->{$dest};
2342         }
2343     }
2344
2345     # For convenience collect information regarding directories where
2346     # files are generated, those generated files and the end product
2347     # they end up in where applicable.  Then, add build rules for those
2348     # directories
2349     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2350                      "dso" => [ @{$unified_info{modules}} ],
2351                      "bin" => [ @{$unified_info{programs}} ],
2352                      "script" => [ @{$unified_info{scripts}} ] );
2353     foreach my $type (keys %loopinfo) {
2354         foreach my $product (@{$loopinfo{$type}}) {
2355             my %dirs = ();
2356             my $pd = dirname($product);
2357
2358             foreach (@{$unified_info{sources}->{$product} // []},
2359                      @{$unified_info{shared_sources}->{$product} // []}) {
2360                 my $d = dirname($_);
2361
2362                 # We don't want to create targets for source directories
2363                 # when building out of source
2364                 next if ($config{sourcedir} ne $config{builddir}
2365                              && $d =~ m|^\Q$config{sourcedir}\E|);
2366                 # We already have a "test" target, and the current directory
2367                 # is just silly to make a target for
2368                 next if $d eq "test" || $d eq ".";
2369
2370                 $dirs{$d} = 1;
2371                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2372                     if $d ne $pd;
2373             }
2374             foreach (keys %dirs) {
2375                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2376                     $product;
2377             }
2378         }
2379     }
2380 }
2381
2382 # For the schemes that need it, we provide the old *_obj configs
2383 # from the *_asm_obj ones
2384 foreach (grep /_(asm|aux)_src$/, keys %target) {
2385     my $src = $_;
2386     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2387     $target{$obj} = $target{$src};
2388     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2389     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2390 }
2391
2392 # Write down our configuration where it fits #########################
2393
2394 print "Creating configdata.pm\n";
2395 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2396 print OUT <<"EOF";
2397 #! $config{HASHBANGPERL}
2398
2399 package configdata;
2400
2401 use strict;
2402 use warnings;
2403
2404 use Exporter;
2405 #use vars qw(\@ISA \@EXPORT);
2406 our \@ISA = qw(Exporter);
2407 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2408
2409 EOF
2410 print OUT "our %config = (\n";
2411 foreach (sort keys %config) {
2412     if (ref($config{$_}) eq "ARRAY") {
2413         print OUT "  ", $_, " => [ ", join(", ",
2414                                            map { quotify("perl", $_) }
2415                                            @{$config{$_}}), " ],\n";
2416     } elsif (ref($config{$_}) eq "HASH") {
2417         print OUT "  ", $_, " => {";
2418         if (scalar keys %{$config{$_}} > 0) {
2419             print OUT "\n";
2420             foreach my $key (sort keys %{$config{$_}}) {
2421                 print OUT "      ",
2422                     join(" => ",
2423                          quotify("perl", $key),
2424                          defined $config{$_}->{$key}
2425                              ? quotify("perl", $config{$_}->{$key})
2426                              : "undef");
2427                 print OUT ",\n";
2428             }
2429             print OUT "  ";
2430         }
2431         print OUT "},\n";
2432     } else {
2433         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2434     }
2435 }
2436 print OUT <<"EOF";
2437 );
2438
2439 EOF
2440 print OUT "our %target = (\n";
2441 foreach (sort keys %target) {
2442     if (ref($target{$_}) eq "ARRAY") {
2443         print OUT "  ", $_, " => [ ", join(", ",
2444                                            map { quotify("perl", $_) }
2445                                            @{$target{$_}}), " ],\n";
2446     } else {
2447         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2448     }
2449 }
2450 print OUT <<"EOF";
2451 );
2452
2453 EOF
2454 print OUT "our \%available_protocols = (\n";
2455 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2456 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2457 print OUT <<"EOF";
2458 );
2459
2460 EOF
2461 print OUT "our \@disablables = (\n";
2462 foreach (@disablables) {
2463     print OUT "  ", quotify("perl", $_), ",\n";
2464 }
2465 print OUT <<"EOF";
2466 );
2467
2468 EOF
2469 print OUT "# The following come from Configure's @disablables_int\n";
2470 print OUT "our \@disablables_int = (\n";
2471 foreach (@disablables_int) {
2472     print OUT "  ", quotify("perl", $_), ",\n";
2473 }
2474 print OUT <<"EOF";
2475 );
2476
2477 EOF
2478 print OUT "our \%disabled = (\n";
2479 foreach (sort keys %disabled) {
2480     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2481 }
2482 print OUT <<"EOF";
2483 );
2484
2485 EOF
2486 print OUT "our %withargs = (\n";
2487 foreach (sort keys %withargs) {
2488     if (ref($withargs{$_}) eq "ARRAY") {
2489         print OUT "  ", $_, " => [ ", join(", ",
2490                                            map { quotify("perl", $_) }
2491                                            @{$withargs{$_}}), " ],\n";
2492     } else {
2493         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2494     }
2495 }
2496 print OUT <<"EOF";
2497 );
2498
2499 EOF
2500 if ($builder eq "unified") {
2501     my $recurse;
2502     $recurse = sub {
2503         my $indent = shift;
2504         foreach (@_) {
2505             if (ref $_ eq "ARRAY") {
2506                 print OUT " "x$indent, "[\n";
2507                 foreach (@$_) {
2508                     $recurse->($indent + 4, $_);
2509                 }
2510                 print OUT " "x$indent, "],\n";
2511             } elsif (ref $_ eq "HASH") {
2512                 my %h = %$_;
2513                 print OUT " "x$indent, "{\n";
2514                 foreach (sort keys %h) {
2515                     if (ref $h{$_} eq "") {
2516                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2517                     } else {
2518                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2519                         $recurse->($indent + 8, $h{$_});
2520                     }
2521                 }
2522                 print OUT " "x$indent, "},\n";
2523             } else {
2524                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2525             }
2526         }
2527     };
2528     print OUT "our %unified_info = (\n";
2529     foreach (sort keys %unified_info) {
2530         if (ref $unified_info{$_} eq "") {
2531             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2532         } else {
2533             print OUT " "x4, quotify("perl", $_), " =>\n";
2534             $recurse->(8, $unified_info{$_});
2535         }
2536     }
2537     print OUT <<"EOF";
2538 );
2539
2540 EOF
2541 }
2542 print OUT
2543     "# The following data is only used when this files is use as a script\n";
2544 print OUT "my \@makevars = (\n";
2545 foreach (sort keys %user) {
2546     print OUT "    '",$_,"',\n";
2547 }
2548 print OUT ");\n";
2549 print OUT "my \%disabled_info = (\n";
2550 foreach my $what (sort keys %disabled_info) {
2551     print OUT "    '$what' => {\n";
2552     foreach my $info (sort keys %{$disabled_info{$what}}) {
2553         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2554             print OUT "        $info => [ ",
2555                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2556                 " ],\n";
2557         } else {
2558             print OUT "        $info => '", $disabled_info{$what}->{$info},
2559                 "',\n";
2560         }
2561     }
2562     print OUT "    },\n";
2563 }
2564 print OUT ");\n";
2565 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2566 print OUT << 'EOF';
2567 # If run directly, we can give some answers, and even reconfigure
2568 unless (caller) {
2569     use Getopt::Long;
2570     use File::Spec::Functions;
2571     use File::Basename;
2572     use Pod::Usage;
2573
2574     my $here = dirname($0);
2575
2576     my $dump = undef;
2577     my $cmdline = undef;
2578     my $options = undef;
2579     my $target = undef;
2580     my $envvars = undef;
2581     my $makevars = undef;
2582     my $buildparams = undef;
2583     my $reconf = undef;
2584     my $verbose = undef;
2585     my $help = undef;
2586     my $man = undef;
2587     GetOptions('dump|d'                 => \$dump,
2588                'command-line|c'         => \$cmdline,
2589                'options|o'              => \$options,
2590                'target|t'               => \$target,
2591                'environment|e'          => \$envvars,
2592                'make-variables|m'       => \$makevars,
2593                'build-parameters|b'     => \$buildparams,
2594                'reconfigure|reconf|r'   => \$reconf,
2595                'verbose|v'              => \$verbose,
2596                'help'                   => \$help,
2597                'man'                    => \$man)
2598         or die "Errors in command line arguments\n";
2599
2600     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2601             || $buildparams || $reconf || $verbose || $help || $man) {
2602         print STDERR <<"_____";
2603 You must give at least one option.
2604 For more information, do '$0 --help'
2605 _____
2606         exit(2);
2607     }
2608
2609     if ($help) {
2610         pod2usage(-exitval => 0,
2611                   -verbose => 1);
2612     }
2613     if ($man) {
2614         pod2usage(-exitval => 0,
2615                   -verbose => 2);
2616     }
2617     if ($dump || $cmdline) {
2618         print "\nCommand line (with current working directory = $here):\n\n";
2619         print '    ',join(' ',
2620                           $config{PERL},
2621                           catfile($config{sourcedir}, 'Configure'),
2622                           @{$config{perlargv}}), "\n";
2623         print "\nPerl information:\n\n";
2624         print '    ',$config{perl_cmd},"\n";
2625         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2626     }
2627     if ($dump || $options) {
2628         my $longest = 0;
2629         my $longest2 = 0;
2630         foreach my $what (@disablables) {
2631             $longest = length($what) if $longest < length($what);
2632             $longest2 = length($disabled{$what})
2633                 if $disabled{$what} && $longest2 < length($disabled{$what});
2634         }
2635         print "\nEnabled features:\n\n";
2636         foreach my $what (@disablables) {
2637             print "    $what\n" unless $disabled{$what};
2638         }
2639         print "\nDisabled features:\n\n";
2640         foreach my $what (@disablables) {
2641             if ($disabled{$what}) {
2642                 print "    $what", ' ' x ($longest - length($what) + 1),
2643                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2644                 print $disabled_info{$what}->{macro}
2645                     if $disabled_info{$what}->{macro};
2646                 print ' (skip ',
2647                     join(', ', @{$disabled_info{$what}->{skipped}}),
2648                     ')'
2649                     if $disabled_info{$what}->{skipped};
2650                 print "\n";
2651             }
2652         }
2653     }
2654     if ($dump || $target) {
2655         print "\nConfig target attributes:\n\n";
2656         foreach (sort keys %target) {
2657             next if $_ =~ m|^_| || $_ eq 'template';
2658             my $quotify = sub {
2659                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2660             };
2661             print '    ', $_, ' => ';
2662             if (ref($target{$_}) eq "ARRAY") {
2663                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2664             } else {
2665                 print $quotify->($target{$_}), ",\n"
2666             }
2667         }
2668     }
2669     if ($dump || $envvars) {
2670         print "\nRecorded environment:\n\n";
2671         foreach (sort keys %{$config{perlenv}}) {
2672             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2673         }
2674     }
2675     if ($dump || $makevars) {
2676         print "\nMakevars:\n\n";
2677         foreach my $var (@makevars) {
2678             my $prefix = '';
2679             $prefix = $config{CROSS_COMPILE}
2680                 if grep { $var eq $_ } @user_crossable;
2681             $prefix //= '';
2682             print '    ',$var,' ' x (16 - length $var),'= ',
2683                 (ref $config{$var} eq 'ARRAY'
2684                  ? join(' ', @{$config{$var}})
2685                  : $prefix.$config{$var}),
2686                 "\n"
2687                 if defined $config{$var};
2688         }
2689
2690         my @buildfile = ($config{builddir}, $config{build_file});
2691         unshift @buildfile, $here
2692             unless file_name_is_absolute($config{builddir});
2693         my $buildfile = canonpath(catdir(@buildfile));
2694         print <<"_____";
2695
2696 NOTE: These variables only represent the configuration view.  The build file
2697 template may have processed these variables further, please have a look at the
2698 build file for more exact data:
2699     $buildfile
2700 _____
2701     }
2702     if ($dump || $buildparams) {
2703         my @buildfile = ($config{builddir}, $config{build_file});
2704         unshift @buildfile, $here
2705             unless file_name_is_absolute($config{builddir});
2706         print "\nbuild file:\n\n";
2707         print "    ", canonpath(catfile(@buildfile)),"\n";
2708
2709         print "\nbuild file templates:\n\n";
2710         foreach (@{$config{build_file_templates}}) {
2711             my @tmpl = ($_);
2712             unshift @tmpl, $here
2713                 unless file_name_is_absolute($config{sourcedir});
2714             print '    ',canonpath(catfile(@tmpl)),"\n";
2715         }
2716     }
2717     if ($reconf) {
2718         if ($verbose) {
2719             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2720             foreach (sort keys %{$config{perlenv}}) {
2721                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2722             }
2723         }
2724
2725         chdir $here;
2726         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2727     }
2728 }
2729
2730 1;
2731
2732 __END__
2733
2734 =head1 NAME
2735
2736 configdata.pm - configuration data for OpenSSL builds
2737
2738 =head1 SYNOPSIS
2739
2740 Interactive:
2741
2742   perl configdata.pm [options]
2743
2744 As data bank module:
2745
2746   use configdata;
2747
2748 =head1 DESCRIPTION
2749
2750 This module can be used in two modes, interactively and as a module containing
2751 all the data recorded by OpenSSL's Configure script.
2752
2753 When used interactively, simply run it as any perl script, with at least one
2754 option, and you will get the information you ask for.  See L</OPTIONS> below.
2755
2756 When loaded as a module, you get a few databanks with useful information to
2757 perform build related tasks.  The databanks are:
2758
2759     %config             Configured things.
2760     %target             The OpenSSL config target with all inheritances
2761                         resolved.
2762     %disabled           The features that are disabled.
2763     @disablables        The list of features that can be disabled.
2764     %withargs           All data given through --with-THING options.
2765     %unified_info       All information that was computed from the build.info
2766                         files.
2767
2768 =head1 OPTIONS
2769
2770 =over 4
2771
2772 =item B<--help>
2773
2774 Print a brief help message and exit.
2775
2776 =item B<--man>
2777
2778 Print the manual page and exit.
2779
2780 =item B<--dump> | B<-d>
2781
2782 Print all relevant configuration data.  This is equivalent to B<--command-line>
2783 B<--options> B<--target> B<--environment> B<--make-variables>
2784 B<--build-parameters>.
2785
2786 =item B<--command-line> | B<-c>
2787
2788 Print the current configuration command line.
2789
2790 =item B<--options> | B<-o>
2791
2792 Print the features, both enabled and disabled, and display defined macro and
2793 skipped directories where applicable.
2794
2795 =item B<--target> | B<-t>
2796
2797 Print the config attributes for this config target.
2798
2799 =item B<--environment> | B<-e>
2800
2801 Print the environment variables and their values at the time of configuration.
2802
2803 =item B<--make-variables> | B<-m>
2804
2805 Print the main make variables generated in the current configuration
2806
2807 =item B<--build-parameters> | B<-b>
2808
2809 Print the build parameters, i.e. build file and build file templates.
2810
2811 =item B<--reconfigure> | B<--reconf> | B<-r>
2812
2813 Redo the configuration.
2814
2815 =item B<--verbose> | B<-v>
2816
2817 Verbose output.
2818
2819 =back
2820
2821 =cut
2822
2823 EOF
2824 close(OUT);
2825 if ($builder_platform eq 'unix') {
2826     my $mode = (0755 & ~umask);
2827     chmod $mode, 'configdata.pm'
2828         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2829 }
2830
2831 my %builders = (
2832     unified => sub {
2833         print 'Creating ',$target{build_file},"\n";
2834         run_dofile(catfile($blddir, $target{build_file}),
2835                    @{$config{build_file_templates}});
2836     },
2837     );
2838
2839 $builders{$builder}->($builder_platform, @builder_opts);
2840
2841 $SIG{__DIE__} = $orig_death_handler;
2842
2843 print <<"EOF" if ($disabled{threads} eq "unavailable");
2844
2845 The library could not be configured for supporting multi-threaded
2846 applications as the compiler options required on this system are not known.
2847 See file INSTALL for details if you need multi-threading.
2848 EOF
2849
2850 print <<"EOF" if ($no_shared_warn);
2851
2852 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2853 platform, so we will pretend you gave the option 'no-pic', which also disables
2854 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2855 or position independent code, please let us know (but please first make sure
2856 you have tried with a current version of OpenSSL).
2857 EOF
2858
2859 print <<"EOF";
2860
2861 **********************************************************************
2862 ***                                                                ***
2863 ***   OpenSSL has been successfully configured                     ***
2864 ***                                                                ***
2865 ***   If you encounter a problem while building, please open an    ***
2866 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2867 ***   and include the output from the following command:           ***
2868 ***                                                                ***
2869 ***       perl configdata.pm --dump                                ***
2870 ***                                                                ***
2871 ***   (If you are new to OpenSSL, you might want to consult the    ***
2872 ***   'Troubleshooting' section in the INSTALL file first)         ***
2873 ***                                                                ***
2874 **********************************************************************
2875 EOF
2876
2877 exit(0);
2878
2879 ######################################################################
2880 #
2881 # Helpers and utility functions
2882 #
2883
2884 # Death handler, to print a helpful message in case of failure #######
2885 #
2886 sub death_handler {
2887     die @_ if $^S;              # To prevent the added message in eval blocks
2888     my $build_file = $target{build_file} // "build file";
2889     my @message = ( <<"_____", @_ );
2890
2891 Failure!  $build_file wasn't produced.
2892 Please read INSTALL and associated NOTES files.  You may also have to look over
2893 your available compiler tool chain or change your configuration.
2894
2895 _____
2896
2897     # Dying is terminal, so it's ok to reset the signal handler here.
2898     $SIG{__DIE__} = $orig_death_handler;
2899     die @message;
2900 }
2901
2902 # Configuration file reading #########################################
2903
2904 # Note: All of the helper functions are for lazy evaluation.  They all
2905 # return a CODE ref, which will return the intended value when evaluated.
2906 # Thus, whenever there's mention of a returned value, it's about that
2907 # intended value.
2908
2909 # Helper function to implement conditional inheritance depending on the
2910 # value of $disabled{asm}.  Used in inherit_from values as follows:
2911 #
2912 #      inherit_from => [ "template", asm("asm_tmpl") ]
2913 #
2914 sub asm {
2915     my @x = @_;
2916     sub {
2917         $disabled{asm} ? () : @x;
2918     }
2919 }
2920
2921 # Helper function to implement conditional value variants, with a default
2922 # plus additional values based on the value of $config{build_type}.
2923 # Arguments are given in hash table form:
2924 #
2925 #       picker(default => "Basic string: ",
2926 #              debug   => "debug",
2927 #              release => "release")
2928 #
2929 # When configuring with --debug, the resulting string will be
2930 # "Basic string: debug", and when not, it will be "Basic string: release"
2931 #
2932 # This can be used to create variants of sets of flags according to the
2933 # build type:
2934 #
2935 #       cflags => picker(default => "-Wall",
2936 #                        debug   => "-g -O0",
2937 #                        release => "-O3")
2938 #
2939 sub picker {
2940     my %opts = @_;
2941     return sub { add($opts{default} || (),
2942                      $opts{$config{build_type}} || ())->(); }
2943 }
2944
2945 # Helper function to combine several values of different types into one.
2946 # This is useful if you want to combine a string with the result of a
2947 # lazy function, such as:
2948 #
2949 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2950 #
2951 sub combine {
2952     my @stuff = @_;
2953     return sub { add(@stuff)->(); }
2954 }
2955
2956 # Helper function to implement conditional values depending on the value
2957 # of $disabled{threads}.  Can be used as follows:
2958 #
2959 #       cflags => combine("-Wall", threads("-pthread"))
2960 #
2961 sub threads {
2962     my @flags = @_;
2963     return sub { add($disabled{threads} ? () : @flags)->(); }
2964 }
2965
2966 sub shared {
2967     my @flags = @_;
2968     return sub { add($disabled{shared} ? () : @flags)->(); }
2969 }
2970
2971 our $add_called = 0;
2972 # Helper function to implement adding values to already existing configuration
2973 # values.  It handles elements that are ARRAYs, CODEs and scalars
2974 sub _add {
2975     my $separator = shift;
2976
2977     # If there's any ARRAY in the collection of values OR the separator
2978     # is undef, we will return an ARRAY of combined values, otherwise a
2979     # string of joined values with $separator as the separator.
2980     my $found_array = !defined($separator);
2981
2982     my @values =
2983         map {
2984             my $res = $_;
2985             while (ref($res) eq "CODE") {
2986                 $res = $res->();
2987             }
2988             if (defined($res)) {
2989                 if (ref($res) eq "ARRAY") {
2990                     $found_array = 1;
2991                     @$res;
2992                 } else {
2993                     $res;
2994                 }
2995             } else {
2996                 ();
2997             }
2998     } (@_);
2999
3000     $add_called = 1;
3001
3002     if ($found_array) {
3003         [ @values ];
3004     } else {
3005         join($separator, grep { defined($_) && $_ ne "" } @values);
3006     }
3007 }
3008 sub add_before {
3009     my $separator = " ";
3010     if (ref($_[$#_]) eq "HASH") {
3011         my $opts = pop;
3012         $separator = $opts->{separator};
3013     }
3014     my @x = @_;
3015     sub { _add($separator, @x, @_) };
3016 }
3017 sub add {
3018     my $separator = " ";
3019     if (ref($_[$#_]) eq "HASH") {
3020         my $opts = pop;
3021         $separator = $opts->{separator};
3022     }
3023     my @x = @_;
3024     sub { _add($separator, @_, @x) };
3025 }
3026
3027 sub read_eval_file {
3028     my $fname = shift;
3029     my $content;
3030     my @result;
3031
3032     open F, "< $fname" or die "Can't open '$fname': $!\n";
3033     {
3034         undef local $/;
3035         $content = <F>;
3036     }
3037     close F;
3038     {
3039         local $@;
3040
3041         @result = ( eval $content );
3042         warn $@ if $@;
3043     }
3044     return wantarray ? @result : $result[0];
3045 }
3046
3047 # configuration reader, evaluates the input file as a perl script and expects
3048 # it to fill %targets with target configurations.  Those are then added to
3049 # %table.
3050 sub read_config {
3051     my $fname = shift;
3052     my %targets;
3053
3054     {
3055         # Protect certain tables from tampering
3056         local %table = ();
3057
3058         %targets = read_eval_file($fname);
3059     }
3060     my %preexisting = ();
3061     foreach (sort keys %targets) {
3062         $preexisting{$_} = 1 if $table{$_};
3063     }
3064     die <<"EOF",
3065 The following config targets from $fname
3066 shadow pre-existing config targets with the same name:
3067 EOF
3068         map { "  $_\n" } sort keys %preexisting
3069         if %preexisting;
3070
3071
3072     # For each target, check that it's configured with a hash table.
3073     foreach (keys %targets) {
3074         if (ref($targets{$_}) ne "HASH") {
3075             if (ref($targets{$_}) eq "") {
3076                 warn "Deprecated target configuration for $_, ignoring...\n";
3077             } else {
3078                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3079             }
3080             delete $targets{$_};
3081         } else {
3082             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3083         }
3084     }
3085
3086     %table = (%table, %targets);
3087
3088 }
3089
3090 # configuration resolver.  Will only resolve all the lazy evaluation
3091 # codeblocks for the chosen target and all those it inherits from,
3092 # recursively
3093 sub resolve_config {
3094     my $target = shift;
3095     my @breadcrumbs = @_;
3096
3097 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3098
3099     if (grep { $_ eq $target } @breadcrumbs) {
3100         die "inherit_from loop!  target backtrace:\n  "
3101             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3102     }
3103
3104     if (!defined($table{$target})) {
3105         warn "Warning! target $target doesn't exist!\n";
3106         return ();
3107     }
3108     # Recurse through all inheritances.  They will be resolved on the
3109     # fly, so when this operation is done, they will all just be a
3110     # bunch of attributes with string values.
3111     # What we get here, though, are keys with references to lists of
3112     # the combined values of them all.  We will deal with lists after
3113     # this stage is done.
3114     my %combined_inheritance = ();
3115     if ($table{$target}->{inherit_from}) {
3116         my @inherit_from =
3117             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3118         foreach (@inherit_from) {
3119             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3120
3121             # 'template' is a marker that's considered private to
3122             # the config that had it.
3123             delete $inherited_config{template};
3124
3125             foreach (keys %inherited_config) {
3126                 if (!$combined_inheritance{$_}) {
3127                     $combined_inheritance{$_} = [];
3128                 }
3129                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3130             }
3131         }
3132     }
3133
3134     # We won't need inherit_from in this target any more, since we've
3135     # resolved all the inheritances that lead to this
3136     delete $table{$target}->{inherit_from};
3137
3138     # Now is the time to deal with those lists.  Here's the place to
3139     # decide what shall be done with those lists, all based on the
3140     # values of the target we're currently dealing with.
3141     # - If a value is a coderef, it will be executed with the list of
3142     #   inherited values as arguments.
3143     # - If the corresponding key doesn't have a value at all or is the
3144     #   empty string, the inherited value list will be run through the
3145     #   default combiner (below), and the result becomes this target's
3146     #   value.
3147     # - Otherwise, this target's value is assumed to be a string that
3148     #   will simply override the inherited list of values.
3149     my $default_combiner = add();
3150
3151     my %all_keys =
3152         map { $_ => 1 } (keys %combined_inheritance,
3153                          keys %{$table{$target}});
3154
3155     sub process_values {
3156         my $object    = shift;
3157         my $inherited = shift;  # Always a [ list ]
3158         my $target    = shift;
3159         my $entry     = shift;
3160
3161         $add_called = 0;
3162
3163         while(ref($object) eq "CODE") {
3164             $object = $object->(@$inherited);
3165         }
3166         if (!defined($object)) {
3167             return ();
3168         }
3169         elsif (ref($object) eq "ARRAY") {
3170             local $add_called;  # To make sure recursive calls don't affect it
3171             return [ map { process_values($_, $inherited, $target, $entry) }
3172                      @$object ];
3173         } elsif (ref($object) eq "") {
3174             return $object;
3175         } else {
3176             die "cannot handle reference type ",ref($object)
3177                 ," found in target ",$target," -> ",$entry,"\n";
3178         }
3179     }
3180
3181     foreach (sort keys %all_keys) {
3182         my $previous = $combined_inheritance{$_};
3183
3184         # Current target doesn't have a value for the current key?
3185         # Assign it the default combiner, the rest of this loop body
3186         # will handle it just like any other coderef.
3187         if (!exists $table{$target}->{$_}) {
3188             $table{$target}->{$_} = $default_combiner;
3189         }
3190
3191         $table{$target}->{$_} = process_values($table{$target}->{$_},
3192                                                $combined_inheritance{$_},
3193                                                $target, $_);
3194         unless(defined($table{$target}->{$_})) {
3195             delete $table{$target}->{$_};
3196         }
3197 #        if ($extra_checks &&
3198 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3199 #            warn "$_ got replaced in $target\n";
3200 #        }
3201     }
3202
3203     # Finally done, return the result.
3204     return %{$table{$target}};
3205 }
3206
3207 sub usage
3208         {
3209         print STDERR $usage;
3210         print STDERR "\npick os/compiler from:\n";
3211         my $j=0;
3212         my $i;
3213         my $k=0;
3214         foreach $i (sort keys %table)
3215                 {
3216                 next if $table{$i}->{template};
3217                 next if $i =~ /^debug/;
3218                 $k += length($i) + 1;
3219                 if ($k > 78)
3220                         {
3221                         print STDERR "\n";
3222                         $k=length($i);
3223                         }
3224                 print STDERR $i . " ";
3225                 }
3226         foreach $i (sort keys %table)
3227                 {
3228                 next if $table{$i}->{template};
3229                 next if $i !~ /^debug/;
3230                 $k += length($i) + 1;
3231                 if ($k > 78)
3232                         {
3233                         print STDERR "\n";
3234                         $k=length($i);
3235                         }
3236                 print STDERR $i . " ";
3237                 }
3238         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3239         exit(1);
3240         }
3241
3242 sub run_dofile
3243 {
3244     my $out = shift;
3245     my @templates = @_;
3246
3247     unlink $out || warn "Can't remove $out, $!"
3248         if -f $out;
3249     foreach (@templates) {
3250         die "Can't open $_, $!" unless -f $_;
3251     }
3252     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3253     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3254     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3255     system($cmd);
3256     exit 1 if $? != 0;
3257     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3258 }
3259
3260 sub compiler_predefined {
3261     state %predefined;
3262     my $cc = shift;
3263
3264     return () if $^O eq 'VMS';
3265
3266     die 'compiler_predefined called without a compiler command'
3267         unless $cc;
3268
3269     if (! $predefined{$cc}) {
3270
3271         $predefined{$cc} = {};
3272
3273         # collect compiler pre-defines from gcc or gcc-alike...
3274         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3275         while (my $l = <PIPE>) {
3276             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3277             $predefined{$cc}->{$1} = $2 // '';
3278         }
3279         close(PIPE);
3280     }
3281
3282     return %{$predefined{$cc}};
3283 }
3284
3285 sub which
3286 {
3287     my ($name)=@_;
3288
3289     if (eval { require IPC::Cmd; 1; }) {
3290         IPC::Cmd->import();
3291         return scalar IPC::Cmd::can_run($name);
3292     } else {
3293         # if there is $directories component in splitpath,
3294         # then it's not something to test with $PATH...
3295         return $name if (File::Spec->splitpath($name))[1];
3296
3297         foreach (File::Spec->path()) {
3298             my $fullpath = catfile($_, "$name$target{exe_extension}");
3299             if (-f $fullpath and -x $fullpath) {
3300                 return $fullpath;
3301             }
3302         }
3303     }
3304 }
3305
3306 sub env
3307 {
3308     my $name = shift;
3309     my %opts = @_;
3310
3311     unless ($opts{cacheonly}) {
3312         # Note that if $ENV{$name} doesn't exist or is undefined,
3313         # $config{perlenv}->{$name} will be created with the value
3314         # undef.  This is intentional.
3315
3316         $config{perlenv}->{$name} = $ENV{$name}
3317             if ! exists $config{perlenv}->{$name};
3318     }
3319     return $config{perlenv}->{$name};
3320 }
3321
3322 # Configuration printer ##############################################
3323
3324 sub print_table_entry
3325 {
3326     local $now_printing = shift;
3327     my %target = resolve_config($now_printing);
3328     my $type = shift;
3329
3330     # Don't print the templates
3331     return if $target{template};
3332
3333     my @sequence = (
3334         "sys_id",
3335         "cpp",
3336         "cppflags",
3337         "defines",
3338         "includes",
3339         "cc",
3340         "cflags",
3341         "unistd",
3342         "ld",
3343         "lflags",
3344         "loutflag",
3345         "ex_libs",
3346         "bn_ops",
3347         "modes_asm_src",
3348         "padlock_asm_src",
3349         "chacha_asm_src",
3350         "poly1035_asm_src",
3351         "thread_scheme",
3352         "perlasm_scheme",
3353         "dso_scheme",
3354         "shared_target",
3355         "shared_cflag",
3356         "shared_defines",
3357         "shared_ldflag",
3358         "shared_rcflag",
3359         "shared_extension",
3360         "dso_extension",
3361         "obj_extension",
3362         "exe_extension",
3363         "ranlib",
3364         "ar",
3365         "arflags",
3366         "aroutflag",
3367         "rc",
3368         "rcflags",
3369         "rcoutflag",
3370         "mt",
3371         "mtflags",
3372         "mtinflag",
3373         "mtoutflag",
3374         "multilib",
3375         "build_scheme",
3376         );
3377
3378     if ($type eq "TABLE") {
3379         print "\n";
3380         print "*** $now_printing\n";
3381         foreach (@sequence) {
3382             if (ref($target{$_}) eq "ARRAY") {
3383                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3384             } else {
3385                 printf "\$%-12s = %s\n", $_, $target{$_};
3386             }
3387         }
3388     } elsif ($type eq "HASH") {
3389         my $largest =
3390             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3391         print "    '$now_printing' => {\n";
3392         foreach (@sequence) {
3393             if ($target{$_}) {
3394                 if (ref($target{$_}) eq "ARRAY") {
3395                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3396                 } else {
3397                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3398                 }
3399             }
3400         }
3401         print "    },\n";
3402     }
3403 }
3404
3405 # Utility routines ###################################################
3406
3407 # On VMS, if the given file is a logical name, File::Spec::Functions
3408 # will consider it an absolute path.  There are cases when we want a
3409 # purely syntactic check without checking the environment.
3410 sub isabsolute {
3411     my $file = shift;
3412
3413     # On non-platforms, we just use file_name_is_absolute().
3414     return file_name_is_absolute($file) unless $^O eq "VMS";
3415
3416     # If the file spec includes a device or a directory spec,
3417     # file_name_is_absolute() is perfectly safe.
3418     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3419
3420     # Here, we know the given file spec isn't absolute
3421     return 0;
3422 }
3423
3424 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3425 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3426 # realpath() requires that at least all path components except the last is an
3427 # existing directory.  On VMS, the last component of the directory spec must
3428 # exist.
3429 sub absolutedir {
3430     my $dir = shift;
3431
3432     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3433     # will return the volume name for the device, no matter what.  Also,
3434     # it will return an incorrect directory spec if the argument is a
3435     # directory that doesn't exist.
3436     if ($^O eq "VMS") {
3437         return rel2abs($dir);
3438     }
3439
3440     # We use realpath() on Unix, since no other will properly clean out
3441     # a directory spec.
3442     use Cwd qw/realpath/;
3443
3444     return realpath($dir);
3445 }
3446
3447 sub quotify {
3448     my %processors = (
3449         perl    => sub { my $x = shift;
3450                          $x =~ s/([\\\$\@"])/\\$1/g;
3451                          return '"'.$x.'"'; },
3452         maybeshell => sub { my $x = shift;
3453                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3454                             if ($x ne $y || $x =~ m|\s|) {
3455                                 return '"'.$y.'"';
3456                             } else {
3457                                 return $x;
3458                             }
3459                         },
3460         );
3461     my $for = shift;
3462     my $processor =
3463         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3464
3465     return map { $processor->($_); } @_;
3466 }
3467
3468 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3469 # $filename is a file name to read from
3470 # $line_concat_cond_re is a regexp detecting a line continuation ending
3471 # $line_concat is a CODEref that takes care of concatenating two lines
3472 sub collect_from_file {
3473     my $filename = shift;
3474     my $line_concat_cond_re = shift;
3475     my $line_concat = shift;
3476
3477     open my $fh, $filename || die "unable to read $filename: $!\n";
3478     return sub {
3479         my $saved_line = "";
3480         $_ = "";
3481         while (<$fh>) {
3482             s|\R$||;
3483             if (defined $line_concat) {
3484                 $_ = $line_concat->($saved_line, $_);
3485                 $saved_line = "";
3486             }
3487             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3488                 $saved_line = $_;
3489                 next;
3490             }
3491             return $_;
3492         }
3493         die "$filename ending with continuation line\n" if $_;
3494         close $fh;
3495         return undef;
3496     }
3497 }
3498
3499 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3500 # $array is an ARRAYref of lines
3501 # $line_concat_cond_re is a regexp detecting a line continuation ending
3502 # $line_concat is a CODEref that takes care of concatenating two lines
3503 sub collect_from_array {
3504     my $array = shift;
3505     my $line_concat_cond_re = shift;
3506     my $line_concat = shift;
3507     my @array = (@$array);
3508
3509     return sub {
3510         my $saved_line = "";
3511         $_ = "";
3512         while (defined($_ = shift @array)) {
3513             s|\R$||;
3514             if (defined $line_concat) {
3515                 $_ = $line_concat->($saved_line, $_);
3516                 $saved_line = "";
3517             }
3518             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3519                 $saved_line = $_;
3520                 next;
3521             }
3522             return $_;
3523         }
3524         die "input text ending with continuation line\n" if $_;
3525         return undef;
3526     }
3527 }
3528
3529 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3530 # $lineiterator is a CODEref that delivers one line at a time.
3531 # All following arguments are regex/CODEref pairs, where the regexp detects a
3532 # line and the CODEref does something with the result of the regexp.
3533 sub collect_information {
3534     my $lineiterator = shift;
3535     my %collectors = @_;
3536
3537     while(defined($_ = $lineiterator->())) {
3538         s|\R$||;
3539         my $found = 0;
3540         if ($collectors{"BEFORE"}) {
3541             $collectors{"BEFORE"}->($_);
3542         }
3543         foreach my $re (keys %collectors) {
3544             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3545                 $collectors{$re}->($lineiterator);
3546                 $found = 1;
3547             };
3548         }
3549         if ($collectors{"OTHERWISE"}) {
3550             $collectors{"OTHERWISE"}->($lineiterator, $_)
3551                 unless $found || !defined $collectors{"OTHERWISE"};
3552         }
3553         if ($collectors{"AFTER"}) {
3554             $collectors{"AFTER"}->($_);
3555         }
3556     }
3557 }
3558
3559 # tokenize($line)
3560 # tokenize($line,$separator)
3561 # $line is a line of text to split up into tokens
3562 # $separator [optional] is a regular expression that separates the tokens,
3563 # the default being spaces.  Do not use quotes of any kind as separators,
3564 # that will give undefined results.
3565 # Returns a list of tokens.
3566 #
3567 # Tokens are divided by separator (spaces by default).  If the tokens include
3568 # the separators, they have to be quoted with single or double quotes.
3569 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3570 # with backslash.
3571 # Basically, the same quoting rules apply for " and ' as in any
3572 # Unix shell.
3573 sub tokenize {
3574     my $line = my $debug_line = shift;
3575     my $separator = shift // qr|\s+|;
3576     my @result = ();
3577
3578     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3579         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3580     }
3581
3582     while ($line =~ s|^${separator}||, $line ne "") {
3583         my $token = "";
3584     again:
3585         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3586         $token .= $1;
3587         $line = $2.$';
3588
3589         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3590             $token .= $1;
3591             $line = $';
3592             goto again;
3593         } elsif ($line =~ m/^'([^']*)'/) {
3594             $token .= $1;
3595             $line = $';
3596             goto again;
3597         }
3598         push @result, $token;
3599     }
3600
3601     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3602         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3603         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3604     }
3605     return @result;
3606 }